configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # libva package version number, (as distinct from shared library version)
  24 m4_define([libva_major_version], [0])
  25 m4_define([libva_minor_version], [31])
  26 m4_define([libva_micro_version], [1])
  27
  28 m4_define([libva_version],
  29           [libva_major_version.libva_minor_version.libva_micro_version])
  30
  31 # if the library source code has changed, increment revision
  32 m4_define([libva_lt_revision], [2])
  33 # if any interface was added/removed/changed, then inc current, reset revision
  34 m4_define([libva_lt_current], [1])
  35 # if any interface was added since last public release, then increment age
  36 # if any interface was removed since last public release, then set age to 0
  37 m4_define([libva_lt_age], [0])
  38
  39 AC_PREREQ(2.57)
  40 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  41 AC_CONFIG_SRCDIR([Makefile.am])
  42 AM_INIT_AUTOMAKE([dist-bzip2])
  43
  44 AM_CONFIG_HEADER([config.h])
  45
  46 LIBVA_MAJOR_VERSION=libva_major_version
  47 LIBVA_MINOR_VERSION=libva_minor_version
  48 LIBVA_MICRO_VERSION=libva_micro_version
  49 LIBVA_VERSION=libva_version
  50 AC_SUBST(LIBVA_MAJOR_VERSION)
  51 AC_SUBST(LIBVA_MINOR_VERSION)
  52 AC_SUBST(LIBVA_MICRO_VERSION)
  53 AC_SUBST(LIBVA_VERSION)
  54
  55 LIBVA_LT_CURRENT=libva_lt_current
  56 LIBVA_LT_REV=libva_lt_revision
  57 LIBVA_LT_AGE=libva_lt_age
  58 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
  59 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
  60 AC_SUBST(LIBVA_LT_VERSION)
  61 AC_SUBST(LIBVA_LT_LDFLAGS)
  62
  63 AC_ARG_ENABLE(glx,
  64               [AC_HELP_STRING([--enable-glx],
  65                               [build with OpenGL for X11 support])],
  66               [], [enable_glx=yes])
  67
  68 AC_ARG_ENABLE(dummy-driver,
  69               [AC_HELP_STRING([--enable-dummy-driver],
  70                               [build dummy video driver])],
  71               [], [enable_dummy_driver=yes])
  72 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
  73
  74 AC_ARG_ENABLE(dummy-backend,
  75               [AC_HELP_STRING([--enable-dummy-backend],
  76                               [build dummy libva backend])],
  77               [], [enable_dummy_backend=no])
  78
  79 AC_ARG_ENABLE(i965-driver,
  80               [AC_HELP_STRING([--enable-i965-driver],
  81                               [build i965 video driver])],
  82               [], [enable_i965_driver=no])
  83
  84 AC_ARG_WITH(drivers-path,
  85             [AC_HELP_STRING([--with-drivers-path=[[path]]], [drivers path])],,
  86             [with_drivers_path="$libdir/dri"])
  87
  88 LIBVA_DRIVERS_PATH="$with_drivers_path"
  89 AC_SUBST(LIBVA_DRIVERS_PATH)
  90
  91 AC_DISABLE_STATIC
  92 AC_PROG_LIBTOOL
  93 AC_PROG_CC
  94
  95 AC_HEADER_STDC
  96 AC_SYS_LARGEFILE
  97
  98 PKG_CHECK_MODULES([X11], [x11])
  99 PKG_CHECK_MODULES([XEXT],[xext])
 100 PKG_CHECK_MODULES([XFIXES], [xfixes])
 101 PKG_CHECK_MODULES([DRM], [libdrm])
 102
 103 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.0], [gen4asm=yes], [gen4asm=no])
 104 AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
 105
 106 # Check for libdrm >= 2.4 (needed for i965_drv_video.so)
 107 if test x$enable_i965_driver = xyes && ! $PKG_CONFIG --atleast-version=2.4 libdrm; then
 108     AC_MSG_WARN([libdrm < 2.4 found, disabling build of i965 video driver])
 109     enable_i965_driver=no
 110 fi
 111 AM_CONDITIONAL(BUILD_I965_DRIVER, test x$enable_i965_driver = xyes)
 112
 113 if test x$enable_dummy_backend = xyes; then
 114     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 115 fi
 116 if test x$libudev = xno; then
 117    enable_dummy_backend=no
 118 fi
 119 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 120
 121 # Check for OpenGL (X11)
 122 USE_GLX="no"
 123 GL_DEPS_CFLAGS=""
 124 GL_DEPS_LIBS=""
 125 if test x$enable_glx = xyes; then
 126     AC_CHECK_HEADERS([GL/gl.h])
 127     AC_CHECK_HEADERS([GL/glx.h])
 128     AC_CHECK_LIB(GL, glXCreateContext, [
 129         USE_GLX="yes"
 130         GL_DEPS_LIBS="-lX11 -lGL"
 131     ])
 132 fi
 133 AC_SUBST(GL_DEPS_CFLAGS)
 134 AC_SUBST(GL_DEPS_LIBS)
 135 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 136
 137 # We only need the headers, we don't link against the DRM libraries
 138 LIBVA_CFLAGS="$DRM_CFLAGS"
 139 AC_SUBST(LIBVA_CFLAGS)
 140 AC_SUBST(LIBVA_LIBS)
 141
 142 pkgconfigdir=${libdir}/pkgconfig
 143 AC_SUBST(pkgconfigdir)
 144
 145 LIBVA_DISPLAY=x11
 146 libvacorelib=libva.la
 147 libvabackendlib=libva-$LIBVA_DISPLAY.la
 148 AC_SUBST([libvacorelib])
 149 AC_SUBST([libvabackendlib])
 150
 151 AC_OUTPUT([
 152         Makefile
 153         va/Makefile
 154         va/va_version.h
 155         va/x11/Makefile
 156         va/glx/Makefile
 157         va/dummy/Makefile
 158         dummy_drv_video/Makefile
 159         i965_drv_video/Makefile
 160         i965_drv_video/shaders/Makefile
 161         i965_drv_video/shaders/mpeg2/Makefile
 162         i965_drv_video/shaders/mpeg2/vld/Makefile
 163         i965_drv_video/shaders/render/Makefile
 164         test/Makefile
 165         test/basic/Makefile
 166         test/decode/Makefile
 167         test/putsurface/Makefile
 168         test/encode/Makefile
 169         libva.pc
 170         libva-x11.pc
 171         libva-glx.pc
 172 ])
 173