configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.92.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AG_GST_LIBTOOL_PREPARE
  48 AS_LIBTOOL(GST, 0, 0, 0)
  49
  50 dnl *** required versions of GStreamer stuff ***
  51 GST_REQ=0.11.91
  52 GSTPB_REQ=0.11.91
  53
  54 dnl *** autotools stuff ****
  55
  56 dnl allow for different autotools
  57 AS_AUTOTOOLS_ALTERNATE
  58
  59 dnl Add parameters for aclocal
  60 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  61
  62 dnl set up gettext
  63 dnl the version check needs to stay here because autopoint greps for it
  64 AM_GNU_GETTEXT_VERSION([0.17])
  65 AM_GNU_GETTEXT([external])
  66 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  67
  68 dnl *** check for arguments to configure ***
  69
  70 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  71
  72 AG_GST_ARG_DEBUG
  73 AG_GST_ARG_PROFILING
  74 AG_GST_ARG_VALGRIND
  75 AG_GST_ARG_GCOV
  76
  77 AG_GST_ARG_EXAMPLES
  78
  79 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  80 AG_GST_ARG_WITH_PACKAGE_NAME
  81 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  82
  83 AG_GST_ARG_WITH_PLUGINS
  84
  85 AG_GST_ARG_ENABLE_EXTERNAL
  86
  87 AG_GST_ARG_ENABLE_EXPERIMENTAL
  88
  89 dnl *** checks for platform ***
  90
  91 dnl * hardware/architecture *
  92
  93 dnl common/m4/gst-arch.m4
  94 dnl check CPU type
  95 AG_GST_ARCH
  96
  97 dnl Determine endianness
  98 AC_C_BIGENDIAN
  99
 100 dnl *** checks for programs ***
 101
 102 dnl find a compiler
 103 AC_PROG_CC
 104 AC_PROG_CC_STDC
 105
 106 dnl determine c++ compiler
 107 AC_PROG_CXX
 108 dnl determine if c++ is available on this system
 109 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 110
 111 dnl determine c++ preprocessor
 112 dnl FIXME: do we need this ?
 113 AC_PROG_CXXCPP
 114
 115 AC_PROG_OBJC
 116
 117 dnl check if the compiler supports '-c' and '-o' options
 118 AM_PROG_CC_C_O
 119
 120 dnl find an assembler
 121 AM_PROG_AS
 122
 123 dnl check if the compiler supports do while(0) macros
 124 AG_GST_CHECK_DOWHILE_MACROS
 125
 126 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 127 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 LT_LIB_M
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/udp
 149 AC_CHECK_HEADERS([sys/time.h])
 150
 151 dnl used in gst/udp
 152 AC_CHECK_HEADERS([sys/socket.h])
 153
 154 dnl *** checks for types/defines ***
 155
 156 dnl Check for FIONREAD ioctl declaration.  This check is needed
 157 dnl for the UDP plugin to build on Solaris
 158 GST_CHECK_FIONREAD
 159
 160 dnl *** checks for structures ***
 161
 162 dnl *** checks for compiler characteristics ***
 163
 164 dnl check if we have GCC inline-asm
 165 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 166 if test x$HAVE_GCC_ASM = xyes ; then
 167   AC_DEFINE(HAVE_GCC_ASM, 1,
 168     [Define if compiler supports gcc inline assembly])
 169 fi
 170 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 171
 172 dnl *** checks for library functions ***
 173
 174 LIBS_SAVE=$LIBS
 175 LIBS="$LIBS $LIBM"
 176 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 177 LIBS=$LIBS_SAVE
 178
 179 dnl Check whether isinf() is defined by math.h
 180 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 182 if test "$ac_cv_have_isinf" = "yes"
 183 then
 184     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 185 fi
 186
 187 dnl Check for mmap (needed by electricfence plugin)
 188 AC_FUNC_MMAP
 189 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 190
 191 dnl Check for mmap (needed by electricfence plugin)
 192
 193 AC_CHECK_TYPE([struct ip_mreqn], [
 194               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 195               [#include <netinet/in.h>])
 196
 197 dnl *** checks for dependency libraries ***
 198
 199
 200 dnl GLib
 201 GLIB_REQ=2.31.14
 202 AG_GST_GLIB_CHECK([$GLIB_REQ])
 203
 204 dnl Orc
 205 ORC_CHECK([0.4.11])
 206
 207 dnl checks for gstreamer
 208 dnl uninstalled is selected preferentially -- see pkg-config(1)
 209 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 211 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 212 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 214 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 215
 216 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 217 if test -z $GST_TOOLS_DIR; then
 218   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 219 fi
 220 AC_SUBST(GST_TOOLS_DIR)
 221
 222 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 223 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 224
 225 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 226
 227 dnl Check for documentation xrefs
 228 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 229 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 230 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 231 AC_SUBST(GLIB_PREFIX)
 232 AC_SUBST(GST_PREFIX)
 233 AC_SUBST(GSTPB_PREFIX)
 234
 235 dnl GTK is optional and used in examples
 236 HAVE_GTK=no
 237 GTK_REQ=3.0.0
 238 if test "x$BUILD_EXAMPLES" = "xyes"; then
 239   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 240   dnl some examples need gtk+-x11
 241   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 242   AC_SUBST(GTK_LIBS)
 243   AC_SUBST(GTK_CFLAGS)
 244 fi
 245 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 246 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 247
 248 dnl *** set variables based on configure arguments ***
 249
 250 dnl set license and copyright notice
 251 GST_LICENSE="LGPL"
 252 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 253 AC_SUBST(GST_LICENSE)
 254
 255 dnl set location of plugin directory
 256 AG_GST_SET_PLUGINDIR
 257
 258 dnl set release date/time
 259 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 260   ["${srcdir}/gst-plugins-good.doap"],
 261   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 262
 263 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 264 dnl make sure it doesn't complain about unused variables if debugging is disabled
 265 NO_WARNINGS=""
 266 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 267
 268 dnl define an ERROR_CFLAGS Makefile variable
 269 dnl -Wundef: too many broken headers
 270 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 271       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 272       -Wwrite-strings -Wold-style-definition -Waggregate-return
 273       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 274       -Wnested-externs $NO_WARNINGS])
 275
 276 dnl define an ERROR_CXXFLAGS Makefile variable
 277 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 278         -Wmissing-declarations -Wredundant-decls
 279         -Wwrite-strings
 280         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 281         $NO_WARNINGS])
 282
 283 dnl define an ERROR_OBJCFLAGS Makefile variable
 284 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 285       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 286       -Wwrite-strings -Wold-style-definition
 287       -Winit-self -Wmissing-include-dirs -Wno-multichar
 288       -Wnested-externs $NO_WARNINGS])
 289
 290 dnl define correct level for debugging messages
 291 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 292
 293 dnl used in examples
 294 AG_GST_DEFAULT_ELEMENTS
 295
 296 dnl *** plug-ins to include ***
 297
 298 dnl Non ported plugins (non-dependant, then dependant)
 299 dnl Make sure you have a space before and after all plugins
 300 GST_PLUGINS_NONPORTED="deinterlace \
 301  cairo cairo_gobject gdk_pixbuf \
 302  osx_audio "
 303 AC_SUBST(GST_PLUGINS_NONPORTED)
 304
 305 dnl these are all the gst plug-ins, compilable without additional libs
 306 dnl videofilter is at the top because others depend on it
 307 AG_GST_CHECK_PLUGIN(alpha)
 308 AG_GST_CHECK_PLUGIN(apetag)
 309 AG_GST_CHECK_PLUGIN(audiofx)
 310 AG_GST_CHECK_PLUGIN(audioparsers)
 311 AG_GST_CHECK_PLUGIN(auparse)
 312 AG_GST_CHECK_PLUGIN(autodetect)
 313 AG_GST_CHECK_PLUGIN(avi)
 314 AG_GST_CHECK_PLUGIN(cutter)
 315 AG_GST_CHECK_PLUGIN(debugutils)
 316 AG_GST_CHECK_PLUGIN(deinterlace)
 317 AG_GST_CHECK_PLUGIN(effectv)
 318 AG_GST_CHECK_PLUGIN(equalizer)
 319 AG_GST_CHECK_PLUGIN(flv)
 320 AG_GST_CHECK_PLUGIN(flx)
 321 AG_GST_CHECK_PLUGIN(goom)
 322 AG_GST_CHECK_PLUGIN(goom2k1)
 323 AG_GST_CHECK_PLUGIN(icydemux)
 324 AG_GST_CHECK_PLUGIN(id3demux)
 325 AG_GST_CHECK_PLUGIN(imagefreeze)
 326 AG_GST_CHECK_PLUGIN(interleave)
 327 AG_GST_CHECK_PLUGIN(isomp4)
 328 AG_GST_CHECK_PLUGIN(law)
 329 AG_GST_CHECK_PLUGIN(level)
 330 AG_GST_CHECK_PLUGIN(matroska)
 331 AG_GST_CHECK_PLUGIN(monoscope)
 332 AG_GST_CHECK_PLUGIN(multifile)
 333 AG_GST_CHECK_PLUGIN(multipart)
 334 AG_GST_CHECK_PLUGIN(replaygain)
 335 AG_GST_CHECK_PLUGIN(rtp)
 336 AG_GST_CHECK_PLUGIN(rtpmanager)
 337 AG_GST_CHECK_PLUGIN(rtsp)
 338 AG_GST_CHECK_PLUGIN(shapewipe)
 339 AG_GST_CHECK_PLUGIN(smpte)
 340 AG_GST_CHECK_PLUGIN(spectrum)
 341 AG_GST_CHECK_PLUGIN(udp)
 342 AG_GST_CHECK_PLUGIN(videobox)
 343 AG_GST_CHECK_PLUGIN(videocrop)
 344 AG_GST_CHECK_PLUGIN(videofilter)
 345 AG_GST_CHECK_PLUGIN(videomixer)
 346 AG_GST_CHECK_PLUGIN(wavenc)
 347 AG_GST_CHECK_PLUGIN(wavparse)
 348 AG_GST_CHECK_PLUGIN(y4m)
 349
 350 dnl disable experimental plug-ins
 351 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 352   AG_GST_DISABLE_PLUGIN(monoscope)
 353 fi
 354
 355 dnl *** sys plug-ins ***
 356
 357 echo
 358 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 359 echo
 360
 361 dnl DirectSound
 362 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 363 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 364   HAVE_DIRECTSOUND="no"
 365   save_CFLAGS="$CFLAGS"
 366   save_LDFLAGS="$LDFLAGS"
 367   save_LIBS="$LIBS"
 368   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 369   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 370   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 371   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 372   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 373 #include <windows.h>
 374 #include <dxerr9.h>
 375 #include <dsound.h>
 376 ]], [[
 377   DXGetErrorString9 (0);
 378   DirectSoundCreate(NULL, NULL, NULL);
 379 ]])
 380 ],
 381     [HAVE_DIRECTSOUND="yes"],
 382     [HAVE_DIRECTSOUND="no"])
 383   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 384   CFLAGS=$save_CFLAGS
 385   LDFLAGS=$save_LDFLAGS
 386   LIBS=$save_LIBS
 387
 388   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 389     dnl this is much more than we want
 390     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 391     AC_SUBST(DIRECTSOUND_CFLAGS)
 392     AC_SUBST(DIRECTSOUND_LDFLAGS)
 393     AC_SUBST(DIRECTSOUND_LIBS)
 394   fi
 395   AC_SUBST(HAVE_DIRECTSOUND)
 396 ])
 397
 398 dnl *** Win32 WaveOut ***
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 400 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 401   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 402 ])
 403
 404 dnl *** OSS audio *** (Linux, *BSD)
 405 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 406 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 407  HAVE_OSS="yes"
 408 dnl Linux and newer BSD versions :
 409  AC_CHECK_HEADER(sys/soundcard.h, [
 410    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 411    ] , [
 412 dnl Some old BSD versions and also newer OpenBSD versions :
 413    AC_CHECK_HEADER(soundcard.h, [
 414      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 415      ], [
 416   dnl Some old BSD versions :
 417      AC_CHECK_HEADER(machine/soundcard.h, [
 418        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 419          [Define if OSS includes are in /machine/])
 420        ], [
 421        HAVE_OSS="no"
 422      ])
 423    ])
 424  ])
 425 ])
 426
 427 dnl *** oss4 ***
 428 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 429 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 430   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 431   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 432       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 433       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 434 ])
 435
 436 dnl *** Sun Audio ***
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 438 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 439   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 440 ])
 441
 442 dnl *** OSX Audio ***
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 444 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 445   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 446 ])
 447
 448 dnl *** OS X video ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 450 HAVE_OSX_VIDEO="no"
 451 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 452   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 453 ])
 454 dnl in case header OpenGL/gl.h is found on other platforms
 455 case "$host" in
 456   *-*darwin*)
 457     dnl do nothing
 458     ;;
 459   *)
 460     HAVE_OSX_VIDEO="no"
 461     ;;
 462 esac
 463
 464
 465 dnl *** Video 4 Linux 2 ***
 466 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 467 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 469 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 470   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 471   AC_TRY_COMPILE([
 472 #include <sys/types.h>
 473 #ifdef __sun /* Solaris */
 474 #include <sys/types.h>
 475 #include <sys/videodev2.h>
 476 #else /* Linux */
 477 #include <linux/types.h>
 478 #define _LINUX_TIME_H
 479 #define __user
 480 #include <linux/videodev2.h>
 481 #endif
 482 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 483 #error too early v4l2 version or no v4l2 at all
 484 #endif
 485     ], [
 486 return 0;
 487     ], [
 488       HAVE_GST_V4L2="yes"
 489       AC_MSG_RESULT(yes)
 490     ], [
 491       HAVE_GST_V4L2="no"
 492       AC_MSG_RESULT(no)
 493
 494       HAVE_VIDEODEV=no
 495       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 496       [
 497         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 498       ])
 499
 500       if test "x$HAVE_VIDEODEV" = "xyes"; then
 501         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 502         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 503       else
 504         AC_MSG_WARN([video4linux2 was not found])
 505       fi
 506     ])
 507
 508   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 509     dnl check for missing v4l2_buffer declaration (see #135919)
 510     MISSING_DECL=0
 511     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 512     AC_TRY_COMPILE([
 513 #include <sys/types.h>
 514 #ifdef __sun /* Solaris */
 515 #include <sys/types.h>
 516 #include <sys/videodev2.h>
 517 #else /* Linux */
 518 #include <linux/types.h>
 519 #define _LINUX_TIME_H
 520 #define __user
 521 #include <linux/videodev2.h>
 522 #endif
 523     ],[
 524 struct v4l2_buffer buf;
 525 buf.index = 0;
 526 return 0;
 527     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 528     if [ test x$MISSING_DECL = x1 ]; then
 529       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 530     fi
 531
 532     dnl check for XOverlay libraries
 533     AG_GST_CHECK_XV
 534   fi
 535 ])
 536
 537 # Optional gudev for device probing
 538 AC_ARG_WITH([gudev],
 539   AC_HELP_STRING([--with-gudev],
 540     [device detection with gudev]),
 541   [],
 542   [with_gudev=check])
 543 if test x$HAVE_GST_V4L2 = xyes; then
 544   if test x$with_gudev != xno; then
 545       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 546           [ have_gudev=yes
 547             AC_DEFINE(HAVE_GUDEV, 1,
 548                [Whether gudev is available for device detection])
 549             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 550           ], [
 551           have_gudev=no
 552           ])
 553   else
 554     have_gudev=no
 555   fi
 556 fi
 557 AC_SUBST(GUDEV_CFLAGS)
 558 AC_SUBST(GUDEV_LIBS)
 559
 560 # Make libv4l2 non-automagic
 561 AC_ARG_WITH([libv4l2],
 562   AC_HELP_STRING([--with-libv4l2],
 563     [support video buffer conversion using libv4l2]),
 564   [],
 565   [with_libv4l2=check])
 566 if test x$HAVE_GST_V4L2 = xyes; then
 567   if test x$with_libv4l2 != xno; then
 568       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 569           [ have_libv4l2=yes
 570             AC_DEFINE(HAVE_LIBV4L2, 1,
 571                 [Whether libv4l2 is available for video buffer conversion])
 572           ], [
 573           have_libv4l2=no
 574           ])
 575   else
 576     have_libv4l2=no
 577   fi
 578 fi
 579
 580 dnl Check for X11
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 582 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 583                   [ximagesrc], [
 584   AC_PATH_XTRA
 585
 586   dnl now try to find the HEADER
 587   ac_cflags_save="$CFLAGS"
 588   ac_cppflags_save="$CPPFLAGS"
 589   CFLAGS="$CFLAGS $X_CFLAGS"
 590   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 591   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 592
 593   if test "x$HAVE_X" = "xno"
 594   then
 595     AC_MSG_NOTICE([cannot find X11 development files])
 596   else
 597     dnl this is much more than we want
 598     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 599     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 600     dnl it does not add the libs; therefore we add them here
 601     X_LIBS="$X_LIBS -lX11"
 602     AC_SUBST(X_CFLAGS)
 603     AC_SUBST(X_LIBS)
 604
 605     dnl check for Xfixes
 606     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 607     if test "x$HAVE_XFIXES" = "xyes"
 608     then
 609         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 610     fi
 611     AC_SUBST(XFIXES_LIBS)
 612     AC_SUBST(XFIXES_CFLAGS)
 613
 614     dnl check for Xdamage
 615     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 616     if test "x$HAVE_XDAMAGE" = "xyes"
 617     then
 618         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 619     fi
 620     AC_SUBST(XDAMAGE_LIBS)
 621     AC_SUBST(XDAMAGE_CFLAGS)
 622   fi
 623   AC_SUBST(HAVE_X)
 624   CFLAGS="$ac_cflags_save"
 625   CPPFLAGS="$ac_cppflags_save"
 626 ])
 627
 628 dnl FIXME: this should be rolled into the test above, it's just an additional
 629 dnl feature of the ximagesrc plug-in
 630 dnl This is the same as in gst-plugins-base
 631 dnl check for X Shm
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 633 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 634   if test x$HAVE_X = xyes; then
 635     AC_CHECK_LIB(Xext, XShmAttach,
 636                  HAVE_XSHM="yes", HAVE_XSHM="no",
 637                  $X_LIBS)
 638     if test "x$HAVE_XSHM" = "xyes"; then
 639       XSHM_LIBS="-lXext"
 640     else
 641       dnl On AIX, it is in XextSam instead, but we still need -lXext
 642       AC_CHECK_LIB(XextSam, XShmAttach,
 643                    HAVE_XSHM="yes", HAVE_XSHM="no",
 644                    $X_LIBS)
 645       if test "x$HAVE_XSHM" = "xyes"; then
 646         XSHM_LIBS="-lXext -lXextSam"
 647       fi
 648     fi
 649   fi
 650 ], ,[
 651   AC_SUBST(HAVE_XSHM)
 652   AC_SUBST(XSHM_LIBS)
 653 ])
 654
 655 dnl for V4L2, we also need to know if we have XVIDEO
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 657 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 658                   [], [
 659   AG_GST_CHECK_XV
 660 ])
 661
 662 dnl *** ext plug-ins ***
 663 dnl keep this list sorted alphabetically !
 664
 665 if test "x$BUILD_EXTERNAL" = "xyes"; then
 666
 667 echo
 668 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 669 echo
 670
 671 dnl *** aalib ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 673 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 674   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 675   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 676 ])
 677
 678 dnl *** cairo ***
 679 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 680 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 681   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 682 ])
 683
 684 dnl *** cairo-gobject ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 686 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 687   [Cairo graphics rendering gobject bindings], cairooverlay, [
 688   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 689 ])
 690
 691 dnl *** FLAC ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 693 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 694   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 695 ])
 696
 697 dnl *** GDK pixbuf ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 699 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 700   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 701 ])
 702
 703 dnl *** Jack ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 705 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 706   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 707   AC_SUBST(JACK_CFLAGS)
 708   AC_SUBST(JACK_LIBS)
 709
 710   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 711   if test x$HAVE_JACK_0_120_1 = xyes; then
 712     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 713   fi
 714   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 715   if test x$HAVE_JACK_1_9_7 = xyes; then
 716     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 717   fi
 718
 719 ])
 720
 721 dnl *** jpeg ***
 722 dnl FIXME: we could use header checks here as well IMO
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 724 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 725   AC_ARG_WITH(jpeg-mmx,
 726     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 727   OLD_LIBS="$LIBS"
 728   if test x$with_jpeg_mmx != x; then
 729     LIBS="$LIBS -L$with_jpeg_mmx"
 730   fi
 731   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 732   JPEG_LIBS="$LIBS -ljpeg-mmx"
 733   LIBS="$OLD_LIBS"
 734   if test x$HAVE_JPEG != xyes; then
 735     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 736     JPEG_LIBS="-ljpeg"
 737   fi
 738   AC_SUBST(JPEG_LIBS)
 739 ])
 740
 741 dnl *** libcaca ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 743 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 744   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 745 ])
 746
 747 dnl *** libdv ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 749 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 750   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 751 ])
 752
 753 dnl *** libpng ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 755 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 756   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 757 ])
 758
 759 dnl *** pulseaudio ***
 760 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 761 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 762
 763   dnl used in ext/pulse/pulseutil.c
 764   AC_CHECK_HEADERS([process.h])
 765
 766   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 767 ])
 768
 769 dnl *** dv1394 ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 771 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 772   dnl first test for libraw1394 >= 2.0.0
 773   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 774   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 775   dnl now see how far we got
 776   if test x$HAVE_RAW1394 = xyes && \
 777      test x$HAVE_LIBIEC61883 = xyes; then
 778        AG_GST_CHECK_LIBHEADER(AVC1394,
 779         avc1394, avc1394_send_command, $RAW1394_LIBS,
 780         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 781        AG_GST_CHECK_LIBHEADER(ROM1394,
 782         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 783         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 784        if test x$HAVE_AVC1394 = xyes && \
 785           test x$HAVE_AVC1394 = xyes && \
 786           test x$HAVE_ROM1394 = xyes; then
 787           HAVE_DV1394=yes
 788           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 789           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 790           AC_SUBST(DV1394_CFLAGS)
 791           AC_SUBST(DV1394_LIBS)
 792         fi
 793   else
 794        if test x$HAVE_RAW1394 = xno; then
 795           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 796           AG_GST_CHECK_LIBHEADER(AVC1394,
 797            avc1394, avc1394_send_command, $RAW1394_LIBS,
 798            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 799           AG_GST_CHECK_LIBHEADER(ROM1394,
 800            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 801            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 802           if test x$HAVE_RAW1394 = xyes && \
 803              test x$HAVE_AVC1394 = xyes && \
 804              test x$HAVE_ROM1394 = xyes; then
 805              HAVE_DV1394=yes
 806              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 807              DV1394_CFLAGS="$RAW1394_CFLAGS"
 808              if test x$HAVE_LIBIEC61883 = xyes; then
 809                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 810                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 811              fi
 812              AC_SUBST(DV1394_CFLAGS)
 813              AC_SUBST(DV1394_LIBS)
 814            fi
 815          fi
 816   fi
 817 ])
 818 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 819
 820 dnl *** shout2 ***
 821 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 822 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 823   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 824 ])
 825
 826 dnl *** soup ***
 827 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 828 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 829   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 830     HAVE_SOUP="yes"
 831     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 832   ],[
 833     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 834       HAVE_SOUP="no"
 835     ])
 836   ])
 837   AC_SUBST(SOUP_CFLAGS)
 838   AC_SUBST(SOUP_LIBS)
 839 ])
 840
 841 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 842 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 843 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 844 dnl   speex_jitter.h is 1.1.x only
 845 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 846 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 847   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 848   if test $HAVE_SPEEX = no
 849   then
 850     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 851       AC_CHECK_HEADER(speex/speex_jitter.h, [
 852         dnl speex 1.1.x :
 853         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 854           dnl speex 1.1.5 or + :
 855           HAVE_SPEEX="yes"
 856           SPEEX_LIBS="-lspeex"
 857           AC_SUBST(SPEEX_CFLAGS)
 858           AC_SUBST(SPEEX_LIBS)
 859         ],[
 860           HAVE_SPEEX="no"
 861         ])
 862       ],[
 863         dnl speex 1.0.x :
 864           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 865             dnl speex 1.0.4
 866             HAVE_SPEEX="yes"
 867             SPEEX_LIBS="-lspeex"
 868             AC_SUBST(SPEEX_CFLAGS)
 869             AC_SUBST(SPEEX_LIBS)
 870
 871             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 872               [defined if speex 1.0.x API detected])
 873         ],[
 874             HAVE_SPEEX="no"
 875             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 876         ], [
 877 #include <speex/speex.h>
 878         ])
 879       ])
 880     ])
 881   fi
 882 ])
 883
 884 dnl *** taglib ***
 885 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 886 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 887   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 888   if test "x$HAVE_CXX" != "xyes"; then
 889     USE_TAGLIB=false
 890     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 891   else
 892     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 893     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 894         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 895       ], [
 896         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 897     ])
 898     AC_SUBST(TAGLIB_CXXFLAGS)
 899   fi
 900 ])
 901
 902 dnl *** wavpack ***
 903 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 904 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 905   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 906     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 907       HAVE_WAVPACK=yes
 908       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 909     ],[
 910       HAVE_WAVPACK=no
 911     ])
 912   ])
 913   AC_SUBST(WAVPACK_CFLAGS)
 914   AC_SUBST(WAVPACK_LIBS)
 915 ])
 916
 917 dnl *** qtdemux & matroska prefer to have zlib ***
 918 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 919 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 920   AG_GST_CHECK_LIBHEADER(ZLIB,
 921     z, uncompress,, zlib.h, [
 922     HAVE_ZLIB="yes"
 923     ZLIB_LIBS="-lz"
 924     AC_SUBST(ZLIB_LIBS)
 925   ])
 926 ])
 927
 928 dnl *** matroska prefers to have bz2 ***
 929 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 930 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 931   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 932   AC_SUBST(BZ2_LIBS)
 933 ])
 934
 935 else
 936
 937 dnl not building plugins with external dependencies,
 938 dnl but we still need to set the conditionals
 939 AM_CONDITIONAL(USE_AALIB, false)
 940 AM_CONDITIONAL(USE_BZ2, false)
 941 AM_CONDITIONAL(USE_CAIRO, false)
 942 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 943 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 944 AM_CONDITIONAL(USE_DV1394, false)
 945 AM_CONDITIONAL(USE_FLAC, false)
 946 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 947 AM_CONDITIONAL(USE_GST_V4L2, false)
 948 AM_CONDITIONAL(USE_JACK, false)
 949 AM_CONDITIONAL(USE_JPEG, false)
 950 AM_CONDITIONAL(USE_LIBCACA, false)
 951 AM_CONDITIONAL(USE_LIBDV, false)
 952 AM_CONDITIONAL(USE_LIBIEC61883, false)
 953 AM_CONDITIONAL(USE_LIBPNG, false)
 954 AM_CONDITIONAL(USE_OSS, false)
 955 AM_CONDITIONAL(USE_OSS4, false)
 956 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 957 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 958 AM_CONDITIONAL(USE_PULSE, false)
 959 AM_CONDITIONAL(USE_SHOUT2, false)
 960 AM_CONDITIONAL(USE_SOUP, false)
 961 AM_CONDITIONAL(USE_SPEEX, false)
 962 AM_CONDITIONAL(USE_SUNAUDIO, false)
 963 AM_CONDITIONAL(USE_TAGLIB, false)
 964 AM_CONDITIONAL(USE_WAVEFORM, false)
 965 AM_CONDITIONAL(USE_WAVPACK, false)
 966 AM_CONDITIONAL(USE_X, false)
 967 AM_CONDITIONAL(USE_XSHM, false)
 968 AM_CONDITIONAL(USE_XVIDEO, false)
 969 AM_CONDITIONAL(USE_ZLIB, false)
 970
 971 fi dnl of EXT plugins
 972
 973 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 974
 975 dnl Overview:
 976 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 977 dnl GST_*:              flags shared by all built objects
 978 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 979 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 980 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 981 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 982
 983 dnl GST_OPTION_CFLAGS
 984 if test "x$USE_DEBUG" = xyes; then
 985    PROFILE_CFLAGS="-g"
 986 fi
 987 AC_SUBST(PROFILE_CFLAGS)
 988
 989 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 990   dnl Define _only_ for git (not pre-releases or releases)
 991   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 992 else
 993   DEPRECATED_CFLAGS=""
 994 fi
 995 AC_SUBST(DEPRECATED_CFLAGS)
 996
 997 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 998 dnl at make time with e.g. make ERROR_CFLAGS=""
 999 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1000 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1001 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1002 AC_SUBST(GST_OPTION_CFLAGS)
1003 AC_SUBST(GST_OPTION_CXXFLAGS)
1004 AC_SUBST(GST_OPTION_OBJCFLAGS)
1005
1006 dnl our libraries need to be versioned correctly
1007 AC_SUBST(GST_LT_LDFLAGS)
1008
1009 dnl FIXME: do we want to rename to GST_ALL_* ?
1010 dnl prefer internal headers to already installed ones
1011 dnl also add builddir include for enumtypes and marshal
1012 dnl add ERROR_CFLAGS, but overridable
1013 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1014 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1015 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1016 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1017 AC_SUBST(GST_CFLAGS)
1018 AC_SUBST(GST_CXXFLAGS)
1019 AC_SUBST(GST_OBJCFLAGS)
1020 AC_SUBST(GST_LIBS)
1021
1022 dnl LDFLAGS really should only contain flags, not libs - they get added before
1023 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1024 GST_ALL_LDFLAGS="-no-undefined"
1025 AC_SUBST(GST_ALL_LDFLAGS)
1026
1027 dnl this really should only contain flags, not libs - they get added before
1028 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1029 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1030 AC_SUBST(GST_PLUGIN_LDFLAGS)
1031
1032 dnl *** output files ***
1033
1034 dnl keep this alphabetic per directory, please
1035 AC_CONFIG_FILES(
1036 Makefile
1037 gst/Makefile
1038 gst/alpha/Makefile
1039 gst/apetag/Makefile
1040 gst/audiofx/Makefile
1041 gst/audioparsers/Makefile
1042 gst/auparse/Makefile
1043 gst/autodetect/Makefile
1044 gst/avi/Makefile
1045 gst/cutter/Makefile
1046 gst/deinterlace/Makefile
1047 gst/debugutils/Makefile
1048 gst/effectv/Makefile
1049 gst/equalizer/Makefile
1050 gst/flv/Makefile
1051 gst/goom/Makefile
1052 gst/goom2k1/Makefile
1053 gst/id3demux/Makefile
1054 gst/icydemux/Makefile
1055 gst/imagefreeze/Makefile
1056 gst/interleave/Makefile
1057 gst/isomp4/Makefile
1058 gst/law/Makefile
1059 gst/level/Makefile
1060 gst/matroska/Makefile
1061 gst/monoscope/Makefile
1062 gst/multifile/Makefile
1063 gst/multipart/Makefile
1064 gst/replaygain/Makefile
1065 gst/rtp/Makefile
1066 gst/rtpmanager/Makefile
1067 gst/rtsp/Makefile
1068 gst/shapewipe/Makefile
1069 gst/smpte/Makefile
1070 gst/spectrum/Makefile
1071 gst/udp/Makefile
1072 gst/videobox/Makefile
1073 gst/videocrop/Makefile
1074 gst/videofilter/Makefile
1075 gst/videomixer/Makefile
1076 gst/wavenc/Makefile
1077 gst/wavparse/Makefile
1078 gst/flx/Makefile
1079 gst/y4m/Makefile
1080 ext/Makefile
1081 ext/aalib/Makefile
1082 ext/cairo/Makefile
1083 ext/dv/Makefile
1084 ext/flac/Makefile
1085 ext/gdk_pixbuf/Makefile
1086 ext/jack/Makefile
1087 ext/jpeg/Makefile
1088 ext/libcaca/Makefile
1089 ext/libpng/Makefile
1090 ext/pulse/Makefile
1091 ext/raw1394/Makefile
1092 ext/shout2/Makefile
1093 ext/soup/Makefile
1094 ext/speex/Makefile
1095 ext/taglib/Makefile
1096 ext/wavpack/Makefile
1097 sys/Makefile
1098 sys/directsound/Makefile
1099 sys/oss/Makefile
1100 sys/oss4/Makefile
1101 sys/osxaudio/Makefile
1102 sys/osxvideo/Makefile
1103 sys/sunaudio/Makefile
1104 sys/v4l2/Makefile
1105 sys/waveform/Makefile
1106 sys/ximage/Makefile
1107 po/Makefile.in
1108 tests/Makefile
1109 tests/check/Makefile
1110 tests/examples/Makefile
1111 tests/examples/audiofx/Makefile
1112 tests/examples/cairo/Makefile
1113 tests/examples/equalizer/Makefile
1114 tests/examples/jack/Makefile
1115 tests/examples/level/Makefile
1116 tests/examples/pulse/Makefile
1117 tests/examples/rtp/Makefile
1118 tests/examples/shapewipe/Makefile
1119 tests/examples/spectrum/Makefile
1120 tests/examples/v4l2/Makefile
1121 tests/files/Makefile
1122 tests/icles/Makefile
1123 common/Makefile
1124 common/m4/Makefile
1125 m4/Makefile
1126 docs/Makefile
1127 docs/plugins/Makefile
1128 docs/version.entities
1129 pkgconfig/Makefile
1130 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1131 gst-plugins-good.spec
1132 )
1133
1134 dnl Create the config.h file for Visual Studio builds
1135 dnl Beware of spaces and /'s in some of the shell variable contents.
1136 sed \
1137     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1138     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1139     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1140     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1141     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1142     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1143     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1144     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1145     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1146     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1147     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1148     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1149     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1150     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1151     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1152     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1153     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1154     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1155     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1156     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1157     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1158     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1159     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1160     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1161     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1162     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1163     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1164     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1165     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1166     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1167     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1168     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1169     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1170     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1171     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1172     config.h.in >win32/common/config.h-new
1173
1174 AC_OUTPUT
1175
1176 AG_GST_OUTPUT_PLUGINS
1177 ORC_OUTPUT
1178