configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.11.0.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.11.0
  58 GSTPB_REQ=0.11.0
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  77
  78 AG_GST_ARG_DEBUG
  79 AG_GST_ARG_PROFILING
  80 AG_GST_ARG_VALGRIND
  81 AG_GST_ARG_GCOV
  82
  83 AG_GST_ARG_EXAMPLES
  84
  85 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  86 AG_GST_ARG_WITH_PACKAGE_NAME
  87 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  88
  89 AG_GST_ARG_WITH_PLUGINS
  90
  91 AG_GST_ARG_ENABLE_EXTERNAL
  92
  93 AG_GST_ARG_ENABLE_EXPERIMENTAL
  94
  95 dnl *** checks for platform ***
  96
  97 dnl * hardware/architecture *
  98
  99 dnl common/m4/gst-arch.m4
 100 dnl check CPU type
 101 AG_GST_ARCH
 102
 103 dnl Determine endianness
 104 AC_C_BIGENDIAN
 105
 106 dnl *** checks for programs ***
 107
 108 dnl find a compiler
 109 AC_PROG_CC
 110 AC_PROG_CC_STDC
 111
 112 dnl determine c++ compiler
 113 AC_PROG_CXX
 114 dnl determine if c++ is available on this system
 115 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 116
 117 dnl determine c++ preprocessor
 118 dnl FIXME: do we need this ?
 119 AC_PROG_CXXCPP
 120
 121 AS_PROG_OBJC
 122
 123 dnl check if the compiler supports '-c' and '-o' options
 124 AM_PROG_CC_C_O
 125
 126 dnl find an assembler
 127 AM_PROG_AS
 128
 129 dnl check if the compiler supports do while(0) macros
 130 AG_GST_CHECK_DOWHILE_MACROS
 131
 132 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 133 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/udp
 155 AC_CHECK_HEADERS([sys/time.h])
 156
 157 dnl *** checks for types/defines ***
 158
 159 dnl Check for FIONREAD ioctl declaration.  This check is needed
 160 dnl for the UDP plugin to build on Solaris
 161 GST_CHECK_FIONREAD
 162
 163 dnl *** checks for structures ***
 164
 165 dnl *** checks for compiler characteristics ***
 166
 167 dnl check if we have GCC inline-asm
 168 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 169 if test x$HAVE_GCC_ASM = xyes ; then
 170   AC_DEFINE(HAVE_GCC_ASM, 1,
 171     [Define if compiler supports gcc inline assembly])
 172 fi
 173 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 174
 175 dnl *** checks for library functions ***
 176
 177 LIBS_SAVE=$LIBS
 178 LIBS="$LIBS $LIBM"
 179 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 180 LIBS=$LIBS_SAVE
 181
 182 dnl Check whether isinf() is defined by math.h
 183 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 185 if test "$ac_cv_have_isinf" = "yes"
 186 then
 187     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 188 fi
 189
 190 dnl Check for mmap (needed by electricfence plugin)
 191 AC_FUNC_MMAP
 192 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195
 196 AC_CHECK_TYPE([struct ip_mreqn], [
 197               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 198               [#include <netinet/in.h>])
 199
 200 dnl *** checks for dependency libraries ***
 201
 202
 203 dnl GLib
 204 GLIB_REQ=2.31.10
 205 AG_GST_GLIB_CHECK([$GLIB_REQ])
 206
 207 dnl Orc
 208 ORC_CHECK([0.4.11])
 209
 210 dnl checks for gstreamer
 211 dnl uninstalled is selected preferentially -- see pkg-config(1)
 212 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 213 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 214 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_NET($GST_MAJORMINOR, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 217 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 218
 219 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 220 if test -z $GST_TOOLS_DIR; then
 221   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 222 fi
 223 AC_SUBST(GST_TOOLS_DIR)
 224
 225 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 226 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 227
 228 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 229
 230 dnl Check for documentation xrefs
 231 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 232 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 233 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 234 AC_SUBST(GLIB_PREFIX)
 235 AC_SUBST(GST_PREFIX)
 236 AC_SUBST(GSTPB_PREFIX)
 237
 238 dnl GTK is optional and used in examples
 239 HAVE_GTK=no
 240 GTK2_REQ=2.14.0
 241 GTK3_REQ=2.91.3
 242 if test "x$BUILD_EXAMPLES" = "xyes"; then
 243   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 244   AC_ARG_WITH([gtk],
 245     AC_HELP_STRING([--with-gtk=3.0|2.0],
 246                    [which gtk+ version to compile against (default: 2.0)]),
 247     [case "$with_gtk" in
 248         2.0) GTK_REQ=$GTK2_REQ ;;
 249         3.0) GTK_REQ=$GTK3_REQ ;;
 250         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 251     esac],
 252     [with_gtk=2.0
 253      GTK_REQ=$GTK2_REQ])
 254   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 255   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 256   dnl some examples need gtk+-x11
 257   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 258   AC_SUBST(GTK_LIBS)
 259   AC_SUBST(GTK_CFLAGS)
 260 fi
 261 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 262 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 263
 264 dnl *** set variables based on configure arguments ***
 265
 266 dnl set license and copyright notice
 267 GST_LICENSE="LGPL"
 268 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 269 AC_SUBST(GST_LICENSE)
 270
 271 dnl set location of plugin directory
 272 AG_GST_SET_PLUGINDIR
 273
 274 dnl set release date/time
 275 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 276   ["${srcdir}/gst-plugins-good.doap"],
 277   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 278
 279 dnl define an ERROR_CFLAGS Makefile variable
 280 dnl -Wundef: too many broken headers
 281 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 282   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 283         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 284         -Wwrite-strings -Wold-style-definition -Waggregate-return
 285         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 286         -Wnested-externs ])
 287 else
 288   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 289   dnl doesn't understand all warning flags that the C compiler knows about
 290   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 291   AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 292         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 293         -Wwrite-strings -Wold-style-definition
 294         -Winit-self -Wmissing-include-dirs -Wno-multichar
 295         -Wnested-externs ])
 296 fi
 297
 298 dnl define an ERROR_CXXFLAGS Makefile variable
 299 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 300         -Wmissing-declarations -Wredundant-decls
 301         -Wwrite-strings
 302         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 303
 304 dnl define correct level for debugging messages
 305 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 306
 307 dnl used in examples
 308 AG_GST_DEFAULT_ELEMENTS
 309
 310 dnl *** plug-ins to include ***
 311
 312 dnl Non ported plugins (non-dependant, then dependant)
 313 dnl Make sure you have a space before and after all plugins
 314 GST_PLUGINS_NONPORTED="deinterlace interleave flx goom2k1 \
 315  imagefreeze monoscope smpte \
 316  videobox \
 317  cairo cairo_gobject dv1394 gdk_pixbuf \
 318  oss oss4 shout2 \
 319  wavpack \
 320  osx_video osx_audio "
 321 AC_SUBST(GST_PLUGINS_NONPORTED)
 322
 323 dnl these are all the gst plug-ins, compilable without additional libs
 324 dnl videofilter is at the top because others depend on it
 325 AG_GST_CHECK_PLUGIN(alpha)
 326 AG_GST_CHECK_PLUGIN(apetag)
 327 AG_GST_CHECK_PLUGIN(audiofx)
 328 AG_GST_CHECK_PLUGIN(audioparsers)
 329 AG_GST_CHECK_PLUGIN(auparse)
 330 AG_GST_CHECK_PLUGIN(autodetect)
 331 AG_GST_CHECK_PLUGIN(avi)
 332 AG_GST_CHECK_PLUGIN(cutter)
 333 AG_GST_CHECK_PLUGIN(debugutils)
 334 AG_GST_CHECK_PLUGIN(deinterlace)
 335 AG_GST_CHECK_PLUGIN(effectv)
 336 AG_GST_CHECK_PLUGIN(equalizer)
 337 AG_GST_CHECK_PLUGIN(flv)
 338 AG_GST_CHECK_PLUGIN(flx)
 339 AG_GST_CHECK_PLUGIN(goom)
 340 AG_GST_CHECK_PLUGIN(goom2k1)
 341 AG_GST_CHECK_PLUGIN(icydemux)
 342 AG_GST_CHECK_PLUGIN(id3demux)
 343 AG_GST_CHECK_PLUGIN(imagefreeze)
 344 AG_GST_CHECK_PLUGIN(interleave)
 345 AG_GST_CHECK_PLUGIN(isomp4)
 346 AG_GST_CHECK_PLUGIN(law)
 347 AG_GST_CHECK_PLUGIN(level)
 348 AG_GST_CHECK_PLUGIN(matroska)
 349 AG_GST_CHECK_PLUGIN(monoscope)
 350 AG_GST_CHECK_PLUGIN(multifile)
 351 AG_GST_CHECK_PLUGIN(multipart)
 352 AG_GST_CHECK_PLUGIN(replaygain)
 353 AG_GST_CHECK_PLUGIN(rtp)
 354 AG_GST_CHECK_PLUGIN(rtpmanager)
 355 AG_GST_CHECK_PLUGIN(rtsp)
 356 AG_GST_CHECK_PLUGIN(shapewipe)
 357 AG_GST_CHECK_PLUGIN(smpte)
 358 AG_GST_CHECK_PLUGIN(spectrum)
 359 AG_GST_CHECK_PLUGIN(udp)
 360 AG_GST_CHECK_PLUGIN(videobox)
 361 AG_GST_CHECK_PLUGIN(videocrop)
 362 AG_GST_CHECK_PLUGIN(videofilter)
 363 AG_GST_CHECK_PLUGIN(videomixer)
 364 AG_GST_CHECK_PLUGIN(wavenc)
 365 AG_GST_CHECK_PLUGIN(wavparse)
 366 AG_GST_CHECK_PLUGIN(y4m)
 367
 368 dnl disable experimental plug-ins
 369 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 370   AG_GST_DISABLE_PLUGIN(monoscope)
 371 fi
 372
 373 dnl *** sys plug-ins ***
 374
 375 echo
 376 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 377 echo
 378
 379 dnl DirectSound
 380 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 381 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 382   HAVE_DIRECTSOUND="no"
 383   save_CFLAGS="$CFLAGS"
 384   save_LDFLAGS="$LDFLAGS"
 385   save_LIBS="$LIBS"
 386   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 387   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 388   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 389   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 390   AC_LINK_IFELSE([
 391 #include <windows.h>
 392 #include <dxerr9.h>
 393 #include <dsound.h>
 394
 395 int main ()
 396 {
 397   DXGetErrorString9 (0);
 398   DirectSoundCreate(NULL, NULL, NULL);
 399
 400   return 0;
 401 }
 402 ],
 403     [HAVE_DIRECTSOUND="yes"],
 404     [HAVE_DIRECTSOUND="no"])
 405   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 406   CFLAGS=$save_CFLAGS
 407   LDFLAGS=$save_LDFLAGS
 408   LIBS=$save_LIBS
 409
 410   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 411     dnl this is much more than we want
 412     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 413     AC_SUBST(DIRECTSOUND_CFLAGS)
 414     AC_SUBST(DIRECTSOUND_LDFLAGS)
 415     AC_SUBST(DIRECTSOUND_LIBS)
 416   fi
 417   AC_SUBST(HAVE_DIRECTSOUND)
 418 ])
 419
 420 dnl *** Win32 WaveOut ***
 421 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 422 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 423   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 424 ])
 425
 426 dnl *** OSS audio *** (Linux, *BSD)
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 428 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 429  HAVE_OSS="yes"
 430 dnl Linux and newer BSD versions :
 431  AC_CHECK_HEADER(sys/soundcard.h, [
 432    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 433    ] , [
 434 dnl Some old BSD versions and also newer OpenBSD versions :
 435    AC_CHECK_HEADER(soundcard.h, [
 436      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 437      ], [
 438   dnl Some old BSD versions :
 439      AC_CHECK_HEADER(machine/soundcard.h, [
 440        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 441          [Define if OSS includes are in /machine/])
 442        ], [
 443        HAVE_OSS="no"
 444      ])
 445    ])
 446  ])
 447 ])
 448
 449 dnl *** oss4 ***
 450 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 451 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 452   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 453   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 454       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 455       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 456 ])
 457
 458 dnl *** Sun Audio ***
 459 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 460 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 461   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 462 ])
 463
 464 dnl *** OSX Audio ***
 465 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 468 ])
 469
 470 dnl *** OS X video ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 472 HAVE_OSX_VIDEO="no"
 473 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 474   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 475 ])
 476 dnl in case header OpenGL/gl.h is found on other platforms
 477 case "$host" in
 478   *-*darwin*)
 479     dnl do nothing
 480     ;;
 481   *)
 482     HAVE_OSX_VIDEO="no"
 483     ;;
 484 esac
 485
 486
 487 dnl *** Video 4 Linux 2 ***
 488 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 489 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 491 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 492   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 493   AC_TRY_COMPILE([
 494 #include <sys/types.h>
 495 #ifdef __sun /* Solaris */
 496 #include <sys/types.h>
 497 #include <sys/videodev2.h>
 498 #else /* Linux */
 499 #include <linux/types.h>
 500 #define _LINUX_TIME_H
 501 #define __user
 502 #include <linux/videodev2.h>
 503 #endif
 504 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 505 #error too early v4l2 version or no v4l2 at all
 506 #endif
 507     ], [
 508 return 0;
 509     ], [
 510       HAVE_GST_V4L2="yes"
 511       AC_MSG_RESULT(yes)
 512     ], [
 513       HAVE_GST_V4L2="no"
 514       AC_MSG_RESULT(no)
 515
 516       HAVE_VIDEODEV=no
 517       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 518       [
 519         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 520       ])
 521
 522       if test "x$HAVE_VIDEODEV" = "xyes"; then
 523         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 524         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 525       else
 526         AC_MSG_WARN([video4linux2 was not found])
 527       fi
 528     ])
 529
 530   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 531     dnl check for missing v4l2_buffer declaration (see #135919)
 532     MISSING_DECL=0
 533     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 534     AC_TRY_COMPILE([
 535 #include <sys/types.h>
 536 #ifdef __sun /* Solaris */
 537 #include <sys/types.h>
 538 #include <sys/videodev2.h>
 539 #else /* Linux */
 540 #include <linux/types.h>
 541 #define _LINUX_TIME_H
 542 #define __user
 543 #include <linux/videodev2.h>
 544 #endif
 545     ],[
 546 struct v4l2_buffer buf;
 547 buf.index = 0;
 548 return 0;
 549     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 550     if [ test x$MISSING_DECL = x1 ]; then
 551       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 552     fi
 553
 554     dnl check for XOverlay libraries
 555     AG_GST_CHECK_XV
 556   fi
 557 ])
 558
 559 # Optional gudev for device probing
 560 AC_ARG_WITH([gudev],
 561   AC_HELP_STRING([--with-gudev],
 562     [device detection with gudev]),
 563   [],
 564   [with_gudev=check])
 565 if test x$HAVE_GST_V4L2 = xyes; then
 566   if test x$with_gudev != xno; then
 567       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 568           [ have_gudev=yes
 569             AC_DEFINE(HAVE_GUDEV, 1,
 570                [Whether gudev is available for device detection])
 571             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 572           ], [
 573           have_gudev=no
 574           ])
 575   else
 576     have_gudev=no
 577   fi
 578 fi
 579 AC_SUBST(GUDEV_CFLAGS)
 580 AC_SUBST(GUDEV_LIBS)
 581
 582 # Make libv4l2 non-automagic
 583 AC_ARG_WITH([libv4l2],
 584   AC_HELP_STRING([--with-libv4l2],
 585     [support video buffer conversion using libv4l2]),
 586   [],
 587   [with_libv4l2=check])
 588 if test x$HAVE_GST_V4L2 = xyes; then
 589   if test x$with_libv4l2 != xno; then
 590       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 591           [ have_libv4l2=yes
 592             AC_DEFINE(HAVE_LIBV4L2, 1,
 593                 [Whether libv4l2 is available for video buffer conversion])
 594           ], [
 595           have_libv4l2=no
 596           ])
 597   else
 598     have_libv4l2=no
 599   fi
 600 fi
 601
 602 dnl Check for X11
 603 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 604 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 605                   [ximagesrc], [
 606   AC_PATH_XTRA
 607
 608   dnl now try to find the HEADER
 609   ac_cflags_save="$CFLAGS"
 610   ac_cppflags_save="$CPPFLAGS"
 611   CFLAGS="$CFLAGS $X_CFLAGS"
 612   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 613   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 614
 615   if test "x$HAVE_X" = "xno"
 616   then
 617     AC_MSG_NOTICE([cannot find X11 development files])
 618   else
 619     dnl this is much more than we want
 620     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 621     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 622     dnl it does not add the libs; therefore we add them here
 623     X_LIBS="$X_LIBS -lX11"
 624     AC_SUBST(X_CFLAGS)
 625     AC_SUBST(X_LIBS)
 626
 627     dnl check for Xfixes
 628     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 629     if test "x$HAVE_XFIXES" = "xyes"
 630     then
 631         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 632     fi
 633     AC_SUBST(XFIXES_LIBS)
 634     AC_SUBST(XFIXES_CFLAGS)
 635
 636     dnl check for Xdamage
 637     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 638     if test "x$HAVE_XDAMAGE" = "xyes"
 639     then
 640         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 641     fi
 642     AC_SUBST(XDAMAGE_LIBS)
 643     AC_SUBST(XDAMAGE_CFLAGS)
 644   fi
 645   AC_SUBST(HAVE_X)
 646   CFLAGS="$ac_cflags_save"
 647   CPPFLAGS="$ac_cppflags_save"
 648 ])
 649
 650 dnl FIXME: this should be rolled into the test above, it's just an additional
 651 dnl feature of the ximagesrc plug-in
 652 dnl This is the same as in gst-plugins-base
 653 dnl check for X Shm
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 655 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 656   if test x$HAVE_X = xyes; then
 657     AC_CHECK_LIB(Xext, XShmAttach,
 658                  HAVE_XSHM="yes", HAVE_XSHM="no",
 659                  $X_LIBS)
 660     if test "x$HAVE_XSHM" = "xyes"; then
 661       XSHM_LIBS="-lXext"
 662     else
 663       dnl On AIX, it is in XextSam instead, but we still need -lXext
 664       AC_CHECK_LIB(XextSam, XShmAttach,
 665                    HAVE_XSHM="yes", HAVE_XSHM="no",
 666                    $X_LIBS)
 667       if test "x$HAVE_XSHM" = "xyes"; then
 668         XSHM_LIBS="-lXext -lXextSam"
 669       fi
 670     fi
 671   fi
 672 ], ,[
 673   AC_SUBST(HAVE_XSHM)
 674   AC_SUBST(XSHM_LIBS)
 675 ])
 676
 677 dnl for V4L2, we also need to know if we have XVIDEO
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 679 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 680                   [], [
 681   AG_GST_CHECK_XV
 682 ])
 683
 684 dnl *** ext plug-ins ***
 685 dnl keep this list sorted alphabetically !
 686
 687 if test "x$BUILD_EXTERNAL" = "xyes"; then
 688
 689 echo
 690 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 691 echo
 692
 693 dnl *** aalib ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 695 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 696   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 697   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 698 ])
 699
 700 dnl *** annodex ***
 701 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 702 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 703   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 704 ])
 705
 706 dnl *** cairo ***
 707 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 708 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 709   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 710 ])
 711
 712 dnl *** cairo-gobject ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 714 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 715   [Cairo graphics rendering gobject bindings], cairooverlay, [
 716   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 717 ])
 718
 719 dnl *** FLAC ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 721 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 722   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 723 ])
 724
 725 dnl *** GDK pixbuf ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 727 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 728   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 729 ])
 730
 731 dnl *** Jack ***
 732 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 733 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 734   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 735   AC_SUBST(JACK_CFLAGS)
 736   AC_SUBST(JACK_LIBS)
 737
 738   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 739   if test x$HAVE_JACK_0_120_1 = xyes; then
 740     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 741   fi
 742   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 743   if test x$HAVE_JACK_1_9_7 = xyes; then
 744     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 745   fi
 746
 747 ])
 748
 749 dnl *** jpeg ***
 750 dnl FIXME: we could use header checks here as well IMO
 751 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 752 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 753   AC_ARG_WITH(jpeg-mmx,
 754     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 755   OLD_LIBS="$LIBS"
 756   if test x$with_jpeg_mmx != x; then
 757     LIBS="$LIBS -L$with_jpeg_mmx"
 758   fi
 759   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 760   JPEG_LIBS="$LIBS -ljpeg-mmx"
 761   LIBS="$OLD_LIBS"
 762   if test x$HAVE_JPEG != xyes; then
 763     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 764     JPEG_LIBS="-ljpeg"
 765   fi
 766   AC_SUBST(JPEG_LIBS)
 767 ])
 768
 769 dnl *** libcaca ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 771 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 772   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 773 ])
 774
 775 dnl *** libdv ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 777 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 778   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 779 ])
 780
 781 dnl *** libpng ***
 782 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 783 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 784   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 785 ])
 786
 787 dnl *** pulseaudio ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 789 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 790
 791   dnl used in ext/pulse/pulseutil.c
 792   AC_CHECK_HEADERS([process.h])
 793
 794   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 795 ])
 796
 797 dnl *** dv1394 ***
 798 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 799 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 800   dnl first test for libraw1394 >= 2.0.0
 801   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 802   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 803   dnl now see how far we got
 804   if test x$HAVE_RAW1394 = xyes && \
 805      test x$HAVE_LIBIEC61883 = xyes; then
 806        AG_GST_CHECK_LIBHEADER(AVC1394,
 807         avc1394, avc1394_send_command, $RAW1394_LIBS,
 808         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 809        AG_GST_CHECK_LIBHEADER(ROM1394,
 810         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 811         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 812        if test x$HAVE_AVC1394 = xyes && \
 813           test x$HAVE_AVC1394 = xyes && \
 814           test x$HAVE_ROM1394 = xyes; then
 815           HAVE_DV1394=yes
 816           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 817           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 818           AC_SUBST(DV1394_CFLAGS)
 819           AC_SUBST(DV1394_LIBS)
 820         fi
 821   else
 822        if test x$HAVE_RAW1394 = xno; then
 823           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 824           AG_GST_CHECK_LIBHEADER(AVC1394,
 825            avc1394, avc1394_send_command, $RAW1394_LIBS,
 826            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 827           AG_GST_CHECK_LIBHEADER(ROM1394,
 828            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 829            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 830           if test x$HAVE_RAW1394 = xyes && \
 831              test x$HAVE_AVC1394 = xyes && \
 832              test x$HAVE_ROM1394 = xyes; then
 833              HAVE_DV1394=yes
 834              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 835              DV1394_CFLAGS="$RAW1394_CFLAGS"
 836              if test x$HAVE_LIBIEC61883 = xyes; then
 837                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 838                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 839              fi
 840              AC_SUBST(DV1394_CFLAGS)
 841              AC_SUBST(DV1394_LIBS)
 842            fi
 843          fi
 844   fi
 845 ])
 846 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 847
 848 dnl *** shout2 ***
 849 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 850 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 851   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 852 ])
 853
 854 dnl *** soup ***
 855 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 856 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 857   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 858     HAVE_SOUP="yes"
 859     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 860   ],[
 861     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 862       HAVE_SOUP="no"
 863     ])
 864   ])
 865   AC_SUBST(SOUP_CFLAGS)
 866   AC_SUBST(SOUP_LIBS)
 867 ])
 868
 869 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 870 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 871 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 872 dnl   speex_jitter.h is 1.1.x only
 873 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 874 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 875   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 876   if test $HAVE_SPEEX = no
 877   then
 878     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 879       AC_CHECK_HEADER(speex/speex_jitter.h, [
 880         dnl speex 1.1.x :
 881         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 882           dnl speex 1.1.5 or + :
 883           HAVE_SPEEX="yes"
 884           SPEEX_LIBS="-lspeex"
 885           AC_SUBST(SPEEX_CFLAGS)
 886           AC_SUBST(SPEEX_LIBS)
 887         ],[
 888           HAVE_SPEEX="no"
 889         ])
 890       ],[
 891         dnl speex 1.0.x :
 892           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 893             dnl speex 1.0.4
 894             HAVE_SPEEX="yes"
 895             SPEEX_LIBS="-lspeex"
 896             AC_SUBST(SPEEX_CFLAGS)
 897             AC_SUBST(SPEEX_LIBS)
 898
 899             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 900               [defined if speex 1.0.x API detected])
 901         ],[
 902             HAVE_SPEEX="no"
 903             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 904         ], [
 905 #include <speex/speex.h>
 906         ])
 907       ])
 908     ])
 909   fi
 910 ])
 911
 912 dnl *** taglib ***
 913 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 914 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 915   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 916   if test "x$HAVE_CXX" != "xyes"; then
 917     USE_TAGLIB=false
 918     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 919   else
 920     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 921     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 922         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 923       ], [
 924         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 925     ])
 926     AC_SUBST(TAGLIB_CXXFLAGS)
 927   fi
 928 ])
 929
 930 dnl *** wavpack ***
 931 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 932 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 933   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 934     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 935       HAVE_WAVPACK=yes
 936       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 937     ],[
 938       HAVE_WAVPACK=no
 939     ])
 940   ])
 941   AC_SUBST(WAVPACK_CFLAGS)
 942   AC_SUBST(WAVPACK_LIBS)
 943 ])
 944
 945 dnl *** qtdemux & matroska prefer to have zlib ***
 946 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 947 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 948   AG_GST_CHECK_LIBHEADER(ZLIB,
 949     z, uncompress,, zlib.h, [
 950     HAVE_ZLIB="yes"
 951     ZLIB_LIBS="-lz"
 952     AC_SUBST(ZLIB_LIBS)
 953   ])
 954 ])
 955
 956 dnl *** matroska prefers to have bz2 ***
 957 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 958 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 959   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 960   AC_SUBST(BZ2_LIBS)
 961 ])
 962
 963 else
 964
 965 dnl not building plugins with external dependencies,
 966 dnl but we still need to set the conditionals
 967 AM_CONDITIONAL(USE_AALIB, false)
 968 AM_CONDITIONAL(USE_ANNODEX, false)
 969 AM_CONDITIONAL(USE_BZ2, false)
 970 AM_CONDITIONAL(USE_CAIRO, false)
 971 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 972 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 973 AM_CONDITIONAL(USE_DV1394, false)
 974 AM_CONDITIONAL(USE_FLAC, false)
 975 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 976 AM_CONDITIONAL(USE_GST_V4L2, false)
 977 AM_CONDITIONAL(USE_JACK, false)
 978 AM_CONDITIONAL(USE_JPEG, false)
 979 AM_CONDITIONAL(USE_LIBCACA, false)
 980 AM_CONDITIONAL(USE_LIBDV, false)
 981 AM_CONDITIONAL(USE_LIBIEC61883, false)
 982 AM_CONDITIONAL(USE_LIBPNG, false)
 983 AM_CONDITIONAL(USE_OSS, false)
 984 AM_CONDITIONAL(USE_OSS4, false)
 985 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 986 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 987 AM_CONDITIONAL(USE_PULSE, false)
 988 AM_CONDITIONAL(USE_SHOUT2, false)
 989 AM_CONDITIONAL(USE_SOUP, false)
 990 AM_CONDITIONAL(USE_SPEEX, false)
 991 AM_CONDITIONAL(USE_SUNAUDIO, false)
 992 AM_CONDITIONAL(USE_TAGLIB, false)
 993 AM_CONDITIONAL(USE_WAVEFORM, false)
 994 AM_CONDITIONAL(USE_WAVPACK, false)
 995 AM_CONDITIONAL(USE_X, false)
 996 AM_CONDITIONAL(USE_XSHM, false)
 997 AM_CONDITIONAL(USE_XVIDEO, false)
 998 AM_CONDITIONAL(USE_ZLIB, false)
 999
1000 fi dnl of EXT plugins
1001
1002 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1003
1004 dnl Overview:
1005 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1006 dnl GST_*:              flags shared by all built objects
1007 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1008 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1009 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1010 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1011
1012 dnl GST_OPTION_CFLAGS
1013 if test "x$USE_DEBUG" = xyes; then
1014    PROFILE_CFLAGS="-g"
1015 fi
1016 AC_SUBST(PROFILE_CFLAGS)
1017
1018 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1019   dnl Define _only_ for git (not pre-releases or releases)
1020   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1021 else
1022   DEPRECATED_CFLAGS=""
1023 fi
1024 AC_SUBST(DEPRECATED_CFLAGS)
1025
1026 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1027 dnl at make time with e.g. make ERROR_CFLAGS=""
1028 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1029 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1030 AC_SUBST(GST_OPTION_CFLAGS)
1031 AC_SUBST(GST_OPTION_CXXFLAGS)
1032
1033 dnl our libraries need to be versioned correctly
1034 AC_SUBST(GST_LT_LDFLAGS)
1035
1036 dnl FIXME: do we want to rename to GST_ALL_* ?
1037 dnl prefer internal headers to already installed ones
1038 dnl also add builddir include for enumtypes and marshal
1039 dnl add ERROR_CFLAGS, but overridable
1040 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1041 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1042 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1043 AC_SUBST(GST_CFLAGS)
1044 AC_SUBST(GST_CXXFLAGS)
1045 AC_SUBST(GST_LIBS)
1046
1047 dnl LDFLAGS really should only contain flags, not libs - they get added before
1048 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1049 GST_ALL_LDFLAGS="-no-undefined"
1050 AC_SUBST(GST_ALL_LDFLAGS)
1051
1052 dnl this really should only contain flags, not libs - they get added before
1053 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1054 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1055 AC_SUBST(GST_PLUGIN_LDFLAGS)
1056
1057 dnl *** output files ***
1058
1059 dnl keep this alphabetic per directory, please
1060 AC_CONFIG_FILES(
1061 Makefile
1062 gst/Makefile
1063 gst/alpha/Makefile
1064 gst/apetag/Makefile
1065 gst/audiofx/Makefile
1066 gst/audioparsers/Makefile
1067 gst/auparse/Makefile
1068 gst/autodetect/Makefile
1069 gst/avi/Makefile
1070 gst/cutter/Makefile
1071 gst/deinterlace/Makefile
1072 gst/debugutils/Makefile
1073 gst/effectv/Makefile
1074 gst/equalizer/Makefile
1075 gst/flv/Makefile
1076 gst/goom/Makefile
1077 gst/goom2k1/Makefile
1078 gst/id3demux/Makefile
1079 gst/icydemux/Makefile
1080 gst/imagefreeze/Makefile
1081 gst/interleave/Makefile
1082 gst/isomp4/Makefile
1083 gst/law/Makefile
1084 gst/level/Makefile
1085 gst/matroska/Makefile
1086 gst/monoscope/Makefile
1087 gst/multifile/Makefile
1088 gst/multipart/Makefile
1089 gst/replaygain/Makefile
1090 gst/rtp/Makefile
1091 gst/rtpmanager/Makefile
1092 gst/rtsp/Makefile
1093 gst/shapewipe/Makefile
1094 gst/smpte/Makefile
1095 gst/spectrum/Makefile
1096 gst/udp/Makefile
1097 gst/videobox/Makefile
1098 gst/videocrop/Makefile
1099 gst/videofilter/Makefile
1100 gst/videomixer/Makefile
1101 gst/wavenc/Makefile
1102 gst/wavparse/Makefile
1103 gst/flx/Makefile
1104 gst/y4m/Makefile
1105 ext/Makefile
1106 ext/aalib/Makefile
1107 ext/annodex/Makefile
1108 ext/cairo/Makefile
1109 ext/dv/Makefile
1110 ext/flac/Makefile
1111 ext/gdk_pixbuf/Makefile
1112 ext/jack/Makefile
1113 ext/jpeg/Makefile
1114 ext/libcaca/Makefile
1115 ext/libpng/Makefile
1116 ext/pulse/Makefile
1117 ext/raw1394/Makefile
1118 ext/shout2/Makefile
1119 ext/soup/Makefile
1120 ext/speex/Makefile
1121 ext/taglib/Makefile
1122 ext/wavpack/Makefile
1123 sys/Makefile
1124 sys/directsound/Makefile
1125 sys/oss/Makefile
1126 sys/oss4/Makefile
1127 sys/osxaudio/Makefile
1128 sys/osxvideo/Makefile
1129 sys/sunaudio/Makefile
1130 sys/v4l2/Makefile
1131 sys/waveform/Makefile
1132 sys/ximage/Makefile
1133 po/Makefile.in
1134 tests/Makefile
1135 tests/check/Makefile
1136 tests/examples/Makefile
1137 tests/examples/audiofx/Makefile
1138 tests/examples/cairo/Makefile
1139 tests/examples/equalizer/Makefile
1140 tests/examples/jack/Makefile
1141 tests/examples/level/Makefile
1142 tests/examples/pulse/Makefile
1143 tests/examples/rtp/Makefile
1144 tests/examples/shapewipe/Makefile
1145 tests/examples/spectrum/Makefile
1146 tests/examples/v4l2/Makefile
1147 tests/files/Makefile
1148 tests/icles/Makefile
1149 common/Makefile
1150 common/m4/Makefile
1151 m4/Makefile
1152 docs/Makefile
1153 docs/plugins/Makefile
1154 docs/version.entities
1155 pkgconfig/Makefile
1156 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1157 gst-plugins-good.spec
1158 )
1159
1160 dnl Create the config.h file for Visual Studio builds
1161 dnl Beware of spaces and /'s in some of the shell variable contents.
1162 sed \
1163     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1164     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1165     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1166     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1167     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1168     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1169     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1170     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1171     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1172     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1173     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1174     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1175     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1176     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1177     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1178     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1179     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1180     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1181     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1182     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1183     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1184     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1185     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1186     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1187     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1188     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1189     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1190     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1191     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1192     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1193     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1194     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1195     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1196     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1197     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1198     config.h.in >win32/common/config.h-new
1199
1200 AC_OUTPUT
1201
1202 AG_GST_OUTPUT_PLUGINS
1203 ORC_OUTPUT
1204