configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET([])
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 4, 1, 1, GST_ERROR="-Wall", GST_ERROR="-Wall -Werror")
  16 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  17 AS_LIBTOOL(GST_PLUGINS, 0, 0, 0, yes)
  18
  19 dnl FIXME take something else ?
  20 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  21 AM_CONFIG_HEADER(config.h)
  22
  23 dnl Add parameters for aclocal
  24 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  25 ACLOCAL_FLAGS="-I m4 -I common/m4"
  26 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  27
  28 AC_PROG_CC
  29 AM_PROG_CC_STDC
  30 AM_PROG_AS
  31 AS="${CC}"
  32 dnl determine c++ compiler
  33 AC_PROG_CXX
  34 dnl determine if c++ is available on this system
  35 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  36 dnl determine c++ preprocessor
  37 AC_PROG_CXXCPP
  38 AC_ISC_POSIX
  39
  40 AC_HEADER_STDC([])
  41
  42 dnl ############################################
  43 dnl # Super Duper options for plug-in building #
  44 dnl ############################################
  45
  46 dnl ext plug-ins; plug-ins that have external dependencies
  47 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
  48 [HAVE_EXTERNAL=yes],enabled,
  49 [
  50   AC_MSG_WARN(building external plug-ins)
  51   BUILD_EXTERNAL="yes"
  52 ],[
  53   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
  54   BUILD_EXTERNAL="no"
  55 ])
  56 # make BUILD_EXTERNAL available to Makefile.am
  57 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
  58
  59 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
  60 dnl read 'builds, but might not work'UTO
  61 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
  62 [HAVE_EXPERIMENTAL=yes],disabled,
  63 [
  64   AC_MSG_WARN(building experimental plug-ins)
  65   USE_TARKIN="yes"
  66   USE_RTP="yes"
  67 ],[
  68   AC_MSG_NOTICE(not building experimental plug-ins)
  69   USE_TARKIN="no"
  70   USE_RTP="no"
  71 ])
  72
  73 dnl broken plug-ins; stuff that doesn't seem to build at the moment
  74 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
  75 HAVE_BROKEN=yes,disabled,
  76 [
  77   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
  78   USE_SMOOTHWAVE="yes"
  79   USE_VGA="yes"
  80   USE_XMMS="yes"
  81 ],[
  82   USE_SMOOTHWAVE="no"
  83   USE_VGA="no"
  84   USE_XMMS="no"
  85   AC_MSG_NOTICE([not building broken plug-ins])
  86 ])
  87
  88 dnl ##############################
  89 dnl # Do automated configuration #
  90 dnl ##############################
  91
  92 dnl Check for tools:
  93 dnl ================
  94
  95 dnl allow for different autotools
  96 AS_AUTOTOOLS_ALTERNATE()
  97
  98 dnl modify pkg-config path
  99 AC_ARG_WITH(pkg-config-path,
 100    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 101    [export PKG_CONFIG_PATH=${withval}])
 102
 103 dnl Check for nasm
 104 AC_PATH_PROG(NASM_PATH, nasm, no)
 105 AC_SUBST(NASM_PATH)
 106 if test x$NASM_PATH = xno; then
 107   AC_MSG_WARN(Couldn't find nasm)
 108   HAVE_NASM="no"
 109 else
 110   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 111   HAVE_NASM="yes"
 112 fi
 113
 114 dnl check for gconftool-2
 115 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 116 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 117   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 118   if test x$GCONFTOOL = xno; then
 119     AC_MSG_WARN(Not installing GConf schemas)
 120     HAVE_GCONFTOOL="no"
 121   else
 122     AM_GCONF_SOURCE_2
 123     HAVE_GCONFTOOL="yes"
 124   fi
 125   AC_SUBST(HAVE_GCONFTOOL)
 126 ])
 127
 128 dnl check for GConf libraries
 129 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 130 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 131   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 132   AC_SUBST(GCONF_CFLAGS)
 133   AC_SUBST(GCONF_LIBS)
 134 ])
 135
 136 dnl check for gstreamer; uninstalled is selected preferentially -- see pkg-config(1)
 137 PKG_CHECK_MODULES(GST, gstreamer >= $GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR.$GST_PLUGINS_VERSION_MICRO,
 138   HAVE_GST="yes", HAVE_GST="no")
 139
 140 if test "x$HAVE_GST" = "xno"; then
 141   AC_MSG_ERROR(no GStreamer found)
 142 fi
 143
 144 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer`
 145 if test -z $GST_TOOLS_DIR; then
 146   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 147 fi
 148 AC_SUBST(GST_TOOLS_DIR)
 149
 150 dnl Set up conditionals for (target) architecture:
 151 dnl ==============================================
 152
 153 dnl Determine CPU
 154 case "x${target_cpu}" in
 155   xi?86 | k?) HAVE_CPU_I386=yes
 156               AC_DEFINE(HAVE_CPU_I386, 1, [Define if the target CPU is an x86])
 157               dnl FIXME could use some better detection
 158               dnl       (ie CPUID)
 159               case "x${target_cpu}" in
 160                 xi386 | xi486) ;;
 161                 *)             AC_DEFINE(HAVE_RDTSC, 1, [Define if RDTSC is available]) ;;
 162               esac ;;
 163   xpowerpc)   HAVE_CPU_PPC=yes
 164               AC_DEFINE(HAVE_CPU_PPC, 1, [Define if the target CPU is a PPC]) ;;
 165   xalpha)     HAVE_CPU_ALPHA=yes
 166               AC_DEFINE(HAVE_CPU_ALPHA, 1, [Define if the target CPU is an Alpha]) ;;
 167   xarm*)      HAVE_CPU_ARM=yes
 168               AC_DEFINE(HAVE_CPU_ARM, 1, [Define if the target CPU is an ARM]) ;;
 169   xsparc*)    HAVE_CPU_SPARC=yes
 170               AC_DEFINE(HAVE_CPU_SPARC, 1, [Define if the target CPU is a PPC]) ;;
 171   xmips*)     HAVE_CPU_MIPS=yes
 172               AC_DEFINE(HAVE_CPU_MIPS, 1, [Define if the target CPU is a MIPS]) ;;
 173   xhppa*)     HAVE_CPU_HPPA=yes
 174               AC_DEFINE(HAVE_CPU_HPPA, 1, [Define if the target CPU is a HPPA]) ;;
 175 esac
 176
 177 dnl Determine endianness
 178 AC_C_BIGENDIAN
 179
 180 dnl Check for fast float to int casting as defined in C99
 181 AC_C99_FUNC_LRINT()
 182 AC_C99_FUNC_LRINTF()
 183
 184 dnl Check for essential libraries first:
 185 dnl ====================================
 186
 187 GST_GLIB2_CHECK()
 188 PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK=yes, HAVE_GTK=no)
 189 GTK_CFLAGS=$GTK2_CFLAGS
 190 GTK_LIBS=$GTK2_LIBS
 191 AC_SUBST(GTK_LIBS)
 192 AC_SUBST(GTK_CFLAGS)
 193
 194 dnl Check for X11 extensions
 195 AC_PATH_XTRA
 196 if test "-DX_DISPLAY_MISSING" = "$X_CFLAGS"; then
 197   AC_MSG_NOTICE([cannot find X11, the build system needs fixage])
 198 fi
 199 AC_SUBST(X_CFLAGS)
 200 AC_SUBST(X_PRE_LIBS)
 201 AC_SUBST(X_EXTRA_LIBS)
 202 AC_SUBST(X_LIBS)
 203
 204 dnl ===========================================================================
 205 dnl ============================= gst plug-ins ================================
 206 dnl ===========================================================================
 207
 208 GST_PLUGIN_LDFLAGS='-module -avoid-version'
 209 AC_SUBST(GST_PLUGIN_LDFLAGS)
 210
 211 dnl these are all the gst plug-ins, compilable without additional libs
 212 GST_PLUGINS_ALL="\
 213         ac3parse adder audioscale auparse avi cdxaparse chart\
 214         cutter deinterlace effectv festival filter flx goom\
 215         intfloat law level\
 216         median mixmatrix mpeg1enc mpeg1sys mpeg1videoparse mpeg2enc mpeg2sub\
 217         mpegaudio mpegaudioparse mpegstream mpegtypes\
 218         monoscope passthrough playondemand qtdemux rtjpeg silence sine\
 219         smooth spectrum speed stereo stereomono\
 220         synaesthesia udp videocrop videoscale videotestsrc volenv volume\
 221         vumeter wavparse y4m"
 222
 223 dnl see if we can build C++ plug-ins
 224 if test "x$HAVE_CXX" = "xyes"; then
 225   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 226                   modplug"
 227 else
 228   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 229 fi
 230
 231 AC_SUBST(GST_PLUGINS_ALL)
 232
 233 GST_PLUGINS_SELECTED=""
 234
 235 AC_ARG_WITH(plugins,
 236     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 237     [for i in `echo $withval | tr , ' '`; do
 238         if test -n `echo $i | grep $GST_PLUGINS_ALL`; then
 239             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 240         else
 241             echo "plug-in $i not recognized, ignoring..."
 242         fi
 243     done],
 244     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 245
 246 AC_SUBST(GST_PLUGINS_SELECTED)
 247
 248 dnl ==========================================================================
 249 dnl ============================= sys plug-ins ================================
 250 dnl ==========================================================================
 251
 252 dnl *** DXR3 card ***
 253 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 254 GST_CHECK_FEATURE(DXR3, [DXR3 hardware mpeg video decoder], dxr3videosink, [
 255   AC_CHECK_HEADER(linux/em8300.h, HAVE_DXR3="yes", HAVE_DXR3="no")
 256 ])
 257
 258 dnl *** OSS audio ***
 259 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 260 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 261   AC_CHECK_HEADER(sys/soundcard.h, HAVE_OSS="yes", HAVE_OSS="no")
 262 ])
 263
 264 dnl *** QuickCam ***
 265 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 266 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 267 dnl this one is for hadess, no qcam when no nasm found
 268   if test "x$HAVE_NASM" = "xno";
 269   then
 270     HAVE_QCAM="no"
 271     AC_MSG_WARN([QuickCam needs nasm])
 272   else
 273     HAVE_QCAM="yes"
 274   fi
 275 ])
 276
 277 dnl *** Video 4 Linux ***
 278 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 279 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 280   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [#include <linux/videodev.h>])
 281 ])
 282
 283 dnl *** Video 4 Linux 2***
 284 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 285 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 286   AC_CHECK_HEADER(linux/videodev2.h, HAVE_V4L2="yes", HAVE_V4L2="no")
 287 ])
 288
 289 dnl *** Video CD ***
 290 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 291 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 292   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 293 ])
 294
 295 dnl *** VGA ***
 296 translit(dnm, m, l) AM_CONDITIONAL(USE_VGA, true)
 297 GST_CHECK_FEATURE(VGA, [VGA], vgavideosink, [
 298   AC_CHECK_HEADER(asm/vga.h, HAVE_VGA="yes", HAVE_VGA="no")
 299 ])
 300
 301 dnl *** CDROM Audio ***
 302 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 303 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 304   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 305   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 306 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 307
 308   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 309         case "$host" in
 310                 *-sun-* | *-*-linux*)
 311                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 312                 ;;
 313                 *-*-freebsd*)
 314                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 315                 ;;
 316                 *-*-netbsd* | *-*-openbsd*)
 317                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 318                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 319                 ;;
 320                 *-*darwin*)
 321                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 322                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 323                 ;;
 324 dnl             *-irix-*)
 325 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 326 dnl             ;;
 327     esac
 328
 329         HAVE_CDROM="yes"
 330   else
 331         HAVE_CDROM="no"
 332   fi
 333 ])
 334
 335 dnl *** XVideo ***
 336 dnl Look for the PIC library first, Debian requires it.
 337 dnl Check debian-devel archives for gory details.
 338 dnl 20020110:
 339 dnl At the moment XFree86 doesn't distribute shared libXv due
 340 dnl to unstable API.  On many platforms you CAN NOT link a shared
 341 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 342 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 343 dnl version of the static lib for plug-ins to link to when it is
 344 dnl inappropriate to link the main application to libXv directly.
 345 dnl FIXME: add check if this platform can support linking to a
 346 dnl        non-PIC libXv, if not then don not use Xv.
 347 dnl FIXME: perhaps warn user if they have a shared libXv since
 348 dnl        this is an error until XFree86 starts shipping one
 349 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 350 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions], xvideosink videosink, [
 351   dnl check for PIC static lib
 352   GST_CHECK_LIBHEADER(XVIDEO, Xv_pic, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv_pic -lXext")
 353   if test x$HAVE_XVIDEO = xno; then
 354     dnl PIC lib not found, check for regular lib
 355     GST_CHECK_LIBHEADER(XVIDEO, Xv, XvQueryExtension, $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS, X11/extensions/Xvlib.h, XVIDEO_LIBS="-lXv -lXext")
 356   fi
 357   AC_SUBST(XVIDEO_LIBS)
 358 ])
 359
 360 dnl Next, check for the optional libraries:
 361 dnl These are all libraries used in building plug-ins
 362 dnl ================================================
 363 dnl let's try and sort them alphabetically, shall we ?
 364
 365 if test "x$BUILD_EXTERNAL" = "xyes"; then
 366
 367 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 368
 369 dnl *** a52dec ***
 370 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 371 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 372   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 373 ])
 374
 375 dnl *** aalib ***
 376 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 377 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 378   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 379 ])
 380
 381 dnl *** alsa ***
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 383 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 384    AM_PATH_ALSA(0.9.0, HAVE_ALSA=yes, HAVE_ALSA=no)
 385 ])
 386
 387 dnl *** arts ***
 388 dnl if mcopidl can't be found there's no use in compiling it
 389 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 390 if test "xHAVE_MCOPIDL" = "xno";
 391 then
 392   USE_ARTS=no
 393 fi
 394
 395 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 396 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 397   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 398 ])
 399
 400 dnl *** artsc ***
 401 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 402 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 403   GST_CHECK_ARTSC()
 404 ])
 405
 406 dnl *** audiofile ***
 407 dnl this check uses the GST_CHECK_CONFIGPROG macro
 408 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 409 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 410   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 411   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 412   GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 413   dnl we need this function
 414   AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 415 ])
 416
 417 dnl *** avifile ***
 418 translit(dnm, m, l) AM_CONDITIONAL(USE_AVIFILE, true)
 419 GST_CHECK_FEATURE(AVIFILE, [avifile], winenc windec, [
 420   if test "x$no_x" = "xyes"; then
 421     AC_MSG_WARN([No X libraries found, avifile test might fail compilation])
 422   fi
 423   if test "x$HAVE_CXX" != "xyes"; then
 424     AC_MSG_WARN([No C++ compiler found, avifile test will fail compilation])
 425   fi
 426   AC_CHECK_LIB(stdc++, cout,,
 427                [AC_MSG_WARN([no libstdc++ found, avifile test will fail])]
 428               )
 429   AS_AVIFILE(0.7.0)
 430 ])
 431
 432 dnl *** CDParanoia ***
 433 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 434 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 435   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 436                       cdda_open, -lm,
 437                       cdda_interface.h,
 438                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 439                       HEADER_DIR="no"
 440                       FOUND_CDPARANOIA="yes")
 441   if test "x$FOUND_CDPARANOIA" != "xyes";
 442   then
 443     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 444                         cdda_open, -lm,
 445                         cdda/cdda_interface.h,
 446                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 447                         HEADER_DIR="yes"
 448                         FOUND_CDPARANOIA="yes")
 449   fi
 450   if test "x$HEADER_DIR" = "xyes";
 451   then
 452     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 453                        defined if cdda headers are in a cdda/ directory)
 454   fi
 455   AC_SUBST(CDPARANOIA_LIBS)
 456 ])
 457 dnl FIXME : add second check somehow if that is necessary
 458 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 459 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 460
 461 dnl *** libdv ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 463 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 464   PKG_CHECK_MODULES(LIBDV, libdv >= 0.98, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 465   AC_SUBST(LIBDV_CFLAGS)
 466   AC_SUBST(LIBDV_LIBS)
 467 ])
 468
 469 dnl *** dvdread ***
 470 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 471 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 472   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 473   AC_SUBST(DVDREAD_LIBS)
 474 ])
 475
 476 dnl *** dvdnav ***
 477 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 478 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 479   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 480   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 481   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 482 ])
 483
 484 dnl **** ESound ****
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 486 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 487   AM_PATH_ESD(0.2.12, HAVE_ESD=yes, HAVE_ESD=no)
 488 ])
 489
 490 dnl **** festival ****
 491 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 492 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 493   dnl NOTE: just using local net connection now, add this lib check
 494   dnl       in the future if needed
 495   dnl AC_LANG_PUSH(C++)
 496   dnl dnl FIXME: took out func to check for
 497   dnl dnl This check puts festival_tidy_up in extern "C".
 498   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 499   dnl dnl mangling C++ nonsense and symbols can't resolve
 500   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 501   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 502   dnl AC_LANG_POP(C++)
 503   dnl AC_SUBST(FESTIVAL_LIBS)
 504 dnl  HAVE_FESTIVAL=yes
 505 dnl])
 506
 507 dnl *** FLAC ***
 508 dnl FLAC 1.0.3 is needed
 509 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 510 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 511   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_decoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 512   AC_SUBST(FLAC_LIBS)
 513 ])
 514
 515 dnl *** Gnome VFS ***
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 517 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 518   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 519   AC_SUBST(GNOME_VFS_CFLAGS)
 520   AC_SUBST(GNOME_VFS_LIBS)
 521 ])
 522
 523 dnl *** gsm ***
 524 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
 525 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
 526   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
 527   if test $HAVE_GSM != "yes"; then
 528     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
 529     if test $HAVE_GSM = "yes"; then
 530       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
 531     fi
 532   fi
 533   AC_SUBST(GSM_LIBS)
 534 ])
 535
 536 dnl *** Hermes ***
 537 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
 538 GST_CHECK_FEATURE(HERMES, [Hermes library], colorspace, [
 539   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
 540 ], AC_SUBST(HERMES_LIBS))
 541
 542 dnl *** http ***
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
 544 GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
 545   dnl FIXME: need to check for header
 546   GHTTP_LIBS=
 547   GST_HTTPSRC_GET_TYPE=
 548   if test x$USE_GLIB2 = xyes; then
 549     AC_MSG_WARN(ghttp disabled for glib2.0)
 550   else
 551     AC_CHECK_LIB(ghttp, ghttp_request_new,
 552       [HTTP_LIBS="-lghttp"
 553        GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
 554        HAVE_HTTP=yes
 555       ], :, $LIBS)
 556   fi
 557   AC_SUBST(HTTP_LIBS)
 558   AC_SUBST(GST_HTTPSRC_GET_TYPE)
 559 ])
 560
 561 dnl *** Jack ***
 562 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 563 GST_CHECK_FEATURE(JACK, Jack, jack, [
 564   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
 565   AC_SUBST(JACK_CFLAGS)
 566   AC_SUBST(JACK_LIBS)
 567 ])
 568
 569 dnl *** jpeg ***
 570 dnl FIXME: we could use header checks here as well IMO
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 572 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 573   AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 574   JPEG_LIBS="-ljpeg"
 575   AC_SUBST(JPEG_LIBS)
 576 ])
 577
 578 dnl *** ladspa ***
 579 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 580 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 581   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 582 ])
 583
 584 dnl *** lame ***
 585 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 586 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 587   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
 588 ])
 589 AC_SUBST(LAME_LIBS)
 590
 591 dnl *** libcolorspace ***
 592 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
 593 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
 594   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
 595   AC_SUBST(LCS_CFLAGS)
 596   AC_SUBST(LCS_LIBS)
 597 ])
 598
 599 dnl *** libfame ***
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
 601 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
 602   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
 603   AC_SUBST(LIBFAME_CFLAGS)
 604   AC_SUBST(LIBFAME_LIBS)
 605 ])
 606
 607 dnl *** mad ***
 608 dnl FIXME: we could use header checks here as well IMO
 609 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 610 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 611   AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 612   if test "x$HAVE_MAD" = "xyes"; then
 613     # installed with mad >= 0.14
 614     HAVE_MAD="no"
 615     save_libs=$LIBS
 616     LIBS="-lz"
 617     AC_CHECK_LIB(id3tag, id3_tag_query, HAVE_MAD="yes" MAD_LIBS="$MAD_LIBS -lid3tag")
 618     LIBS=$save_LIBS
 619   fi
 620 ])
 621 AC_SUBST(MAD_LIBS)
 622
 623 dnl *** mikmod ***
 624 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
 625 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
 626   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
 627   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
 628   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
 629 ])
 630
 631 dnl *** mjpegtools ***
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_MJPEGTOOLS, true)
 633 GST_CHECK_FEATURE(MJPEGTOOLS, [mjpegtools], jpegmmxenc jpegmmxdec, [
 634   PKG_CHECK_MODULES(MJPEGTOOLS, mjpegtools, HAVE_MJPEGTOOLS="yes", HAVE_MJPEGTOOLS="no")
 635
 636   if [ test x$HAVE_MJPEGTOOLS = x"yes" ]; then
 637     dnl some headers we might want to need
 638     AC_CHECK_HEADERS(stdint.h, HAVE_STDINT_H="yes", HAVE_STDINT_H="no")
 639     if [ test x$HAVE_STDINT_H = x"no" ]; then
 640       AC_CHECK_HEADERS(inttypes.h sys/types.h, HAVE_INTTYPES_H="yes", [
 641         AC_MSG_WARN(No valid header files found, mjpegtools plugins disabled)
 642         HAVE_INTTYPES_H="no" HAVE_MJPEGTOOLS="no"
 643       ])
 644     fi
 645     AC_CHECK_HEADERS(stdbool.h, HAVE_STDBOOL_H="yes", HAVE_STDBOOL_H="no")
 646
 647     dnl sizeof PRId64 etc...
 648     AC_CHECK_SIZEOF(int)
 649     AC_CHECK_SIZEOF(long)
 650     AC_CHECK_SIZEOF(long long)
 651     case 8 in
 652     $ac_cv_sizeof_int)
 653       PRID64_STRING_FORMAT="d"
 654       ;;
 655     $ac_cv_sizeof_long)
 656       PRID64_STRING_FORMAT="ld"
 657       ;;
 658     $ac_cv_sizeof_long_long)
 659       PRID64_STRING_FORMAT="lld"
 660       ;;
 661     *)
 662       AC_MSG_WARN(No suitable variant for 64bits integers found, mjpegtools plugins disabled)
 663       HAVE_MJPEGTOOLS="no"
 664       ;;
 665     esac
 666
 667     AC_DEFINE_UNQUOTED(PRID64_STRING_FORMAT, "$PRID64_STRING_FORMAT",
 668       [ A printf type definition for 64 bit integers ])
 669     AC_SUBST(MJPEGTOOLS_LIBS)
 670     AC_SUBST(MJPEGTOOLS_CFLAGS)
 671   fi
 672 ])
 673
 674 dnl *** mpeg2dec ***
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 676 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 677   AC_CHECK_MPEG2DEC(HAVE_MPEG2DEC=yes, HAVE_MPEG2DEC=no)
 678 ])
 679
 680 dnl *** openquicktime ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_OPENQUICKTIME, true)
 682 GST_CHECK_FEATURE(OPENQUICKTIME, [Open Quicktime], quicktime_parser quicktime_decoder quicktime_demux,[
 683   GST_CHECK_LIBHEADER(OPENQUICKTIME, openquicktime, quicktime_init,, openquicktime/openquicktime.h, OPENQUICKTIME_LIBS="-lopenquicktime")
 684   AC_SUBST(OPENQUICKTIME_LIBS)
 685 ])
 686
 687 dnl *** raw1394 ***
 688 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
 689 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
 690   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_get_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-raw1394")
 691   AC_SUBST(RAW1394_LIBS)
 692 ])
 693
 694 dnl *** rtp ***
 695 dnl FIXME : adapt and make it work
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_RTP, true)
 697 GST_CHECK_FEATURE(RTP, [RTP library], rtpenc rtpdec,[
 698   AC_CHECK_LIB(ortp, ortp_init, HAVE_RTP=yes, HAVE_RTP=no, $GST_CFLAGS $GST_LIBS)
 699   RTP_LIBS="-lortp"
 700   AC_SUBST(RTP_LIBS)
 701 ])
 702
 703 dnl FIXME header check needs to use GLIB_CFLAGS in order to succeed for rtp
 704 dnl can use GST_* which should have GLIB_* info
 705 dnl AC_CHECK_HEADERS(rtp/rtp.h, HAVE_LIBRTP=yes, HAVE_LIBRTP=no)
 706 dnl AC_CHECK_HEADERS(rtp/rtp-packet.h, :, HAVE_LIBRTP=no)
 707 dnl AC_CHECK_HEADERS(rtp/rtcp-packet.h, :, HAVE_LIBRTP=no)
 708 dnl AC_CHECK_HEADERS(rtp/rtp-audio.h, :, HAVE_LIBRTP=no)
 709
 710 dnl *** SDL ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
 712 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
 713  AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
 714 ])
 715
 716 dnl *** shout ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
 718 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
 719   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
 720   AC_SUBST(SHOUT_LIBS)
 721 ])
 722
 723 dnl *** sidplay ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 725 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
 726   GST_PATH_SIDPLAY()
 727 ])
 728
 729 dnl *** smoothwave ***
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
 731 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
 732   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
 733 ])
 734
 735
 736 dnl *** snapshot ***
 737 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 738 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
 739   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz, png.h, LIBPNG_LIBS="-lpng -lz")
 740   AC_SUBST(LIBPNG_LIBS)
 741 ])
 742
 743 dnl *** swfdec ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
 745 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
 746   PKG_CHECK_MODULES(SWFDEC, libswfdec, HAVE_SWFDEC="yes", HAVE_SWFDEC="no")
 747   AC_SUBST(SWFDEC_CFLAGS)
 748   AC_SUBST(SWFDEC_LIBS)
 749 ])
 750
 751 dnl *** tarkin ***
 752 dnl for now the sources are included in the plug-in
 753 dnl and should be moved to ext-libs/ perhaps
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
 755 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
 756   HAVE_TARKIN="yes"
 757 ])
 758
 759 dnl *** vorbis ***
 760 dnl AM_PATH_VORBIS only takes two options
 761 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 762 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 763   XIPH_PATH_VORBIS(HAVE_VORBIS=yes, HAVE_VORBIS=no)
 764 ])
 765
 766 dnl *** XMMS ***
 767 translit(dnm, m, l) AM_CONDITIONAL(USE_XMMS, true)
 768 GST_CHECK_FEATURE(XMMS, [xmms plug-in], xmms, [
 769   AM_PATH_XMMS(0.1.0, HAVE_XMMS=yes, HAVE_XMMS=no)
 770 ])
 771
 772 fi dnl of EXT plugins
 773
 774 dnl Check for atomic.h
 775 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
 776 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
 777 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
 778 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
 779 if test x$HAVE_ATOMIC_H = xyes; then
 780   AC_TRY_RUN([
 781 #include "asm/atomic.h"
 782 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
 783   ],, [
 784     # Not successful
 785     if test x$HAVE_ATOMIC_H = xyes; then
 786       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
 787     fi
 788     HAVE_ATOMIC_H=no
 789   ], [
 790     # Cross compiling
 791     AC_MSG_RESULT(yes)
 792     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
 793   ])
 794 fi
 795
 796
 797 dnl ######################################################################
 798 dnl # Check command line parameters, and set shell variables accordingly #
 799 dnl ######################################################################
 800
 801 GST_DEBUGINFO
 802
 803 AC_ARG_ENABLE(libmmx,
 804   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
 805 [case "${enableval}" in
 806   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
 807   no)  USE_LIBMMX=no ;;
 808   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
 809 esac],
 810 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
 811
 812 AC_ARG_ENABLE(atomic,
 813   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
 814 [case "${enableval}" in
 815   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 816   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
 817   no)  USE_ATOMIC_H=no;;
 818   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
 819 esac],
 820 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
 821
 822 AC_ARG_ENABLE(profiling,
 823   AC_HELP_STRING([--enable-profiling],
 824                  [-pg to compiler commandline, for profiling]),
 825 [case "${enableval}" in
 826   yes) USE_PROFILING=yes ;;
 827   no)  UES_PROFILING=no ;;
 828   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
 829 esac],
 830 [USE_PROFILING=no]) dnl Default value
 831
 832 AC_ARG_ENABLE(tests,
 833   AC_HELP_STRING([--disable-tests],[disable building test apps]),
 834 [case "${enableval}" in
 835   yes) BUILD_TESTS=yes ;;
 836   no)  BUILD_TESTS=no ;;
 837   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 838 esac],
 839 [BUILD_TESTS=yes]) dnl Default value
 840
 841 AC_ARG_ENABLE(examples,
 842   AC_HELP_STRING([--disable-examples],[disable building examples]),
 843 [case "${enableval}" in
 844   yes) BUILD_EXAMPLES=yes ;;
 845   no)  BUILD_EXAMPLES=no ;;
 846   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
 847 esac],
 848 [BUILD_EXAMPLES=yes]) dnl Default value
 849
 850 dnl seeking needs freetype, so check for it here
 851 AC_CHECK_FT2(2.0.9,HAVE_FT2=yes,HAVE_FT2=no)
 852 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 853 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 854 AC_SUBST(FT2_CFLAGS)
 855 AC_SUBST(FT2_LIBS)
 856
 857 dnl ################################################
 858 dnl # Set defines according to variables set above #
 859 dnl ################################################
 860
 861
 862 if test "x$USE_LIBMMX" = xyes; then
 863   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
 864 fi
 865
 866 if test "x$USE_ATOMIC_H" = xyes; then
 867   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
 868 fi
 869
 870 if test "x$USE_DEBUG" = xyes; then
 871   GST_CFLAGS="$GST_CFLAGS -g"
 872 fi
 873
 874 if test "x$USE_PROFILING" = xyes; then
 875 dnl  CFLAGS="$CFLAGS -pg -fprofile-arcs"
 876   FOMIT_FRAME_POINTER=""
 877 else
 878   FOMIT_FRAME_POINTER="-fomit-frame-pointer"
 879 fi
 880
 881 dnl
 882 dnl AC_SUBST(FOMIT_FRAME_POINTER)
 883 dnl
 884
 885 dnl #############################
 886 dnl # Set automake conditionals #
 887 dnl #############################
 888
 889 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
 890 dnl HAVE_ and it is likely to be easier to stick with the old name
 891 AM_CONDITIONAL(HAVE_CPU_I386,       test "x$HAVE_CPU_I386" = "xyes")
 892 AM_CONDITIONAL(HAVE_CPU_PPC,        test "x$HAVE_CPU_PPC" = "xyes")
 893 AM_CONDITIONAL(HAVE_CPU_ALPHA,      test "x$HAVE_CPU_ALPHA" = "xyes")
 894 AM_CONDITIONAL(HAVE_CPU_ARM,        test "x$HAVE_CPU_ARM" = "xyes")
 895 AM_CONDITIONAL(HAVE_CPU_SPARC,      test "x$HAVE_CPU_SPARC" = "xyes")
 896 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
 897
 898 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
 899
 900 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
 901 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
 902
 903 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
 904 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
 905 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
 906 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
 907 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 908 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
 909 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
 910 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
 911 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
 912 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
 913
 914 GST_CFLAGS="$GST_CFLAGS -I\$(top_srcdir)/gst-libs $GST_ERROR"
 915 AC_SUBST(GST_LIBS)
 916 AC_SUBST(GST_CFLAGS)
 917
 918 dnl #########################
 919 dnl # Make the output files #
 920 dnl #########################
 921
 922 AC_CONFIG_FILES(
 923 Makefile
 924 gstreamer-libs.pc
 925 gstreamer-libs-uninstalled.pc
 926 gst-plugins.spec
 927 gst/Makefile
 928 gst/ac3parse/Makefile
 929 gst/adder/Makefile
 930 gst/audioscale/Makefile
 931 gst/auparse/Makefile
 932 gst/avi/Makefile
 933 gst/cdxaparse/Makefile
 934 gst/chart/Makefile
 935 gst/cutter/Makefile
 936 gst/deinterlace/Makefile
 937 gst/effectv/Makefile
 938 gst/festival/Makefile
 939 gst/filter/Makefile
 940 gst/flx/Makefile
 941 gst/goom/Makefile
 942 gst/intfloat/Makefile
 943 gst/law/Makefile
 944 gst/level/Makefile
 945 gst/median/Makefile
 946 gst/mixmatrix/Makefile
 947 gst/mpeg1enc/Makefile
 948 gst/mpeg1sys/Makefile
 949 gst/mpeg1videoparse/Makefile
 950 gst/mpeg2enc/Makefile
 951 gst/mpeg2sub/Makefile
 952 gst/mpegaudio/Makefile
 953 gst/mpegaudioparse/Makefile
 954 gst/mpegstream/Makefile
 955 gst/mpegtypes/Makefile
 956 gst/modplug/Makefile
 957 gst/modplug/libmodplug/Makefile
 958 gst/monoscope/Makefile
 959 gst/passthrough/Makefile
 960 gst/playondemand/Makefile
 961 gst/qtdemux/Makefile
 962 gst/rtjpeg/Makefile
 963 gst/silence/Makefile
 964 gst/sine/Makefile
 965 gst/smooth/Makefile
 966 gst/spectrum/Makefile
 967 gst/speed/Makefile
 968 gst/stereo/Makefile
 969 gst/stereomono/Makefile
 970 gst/synaesthesia/Makefile
 971 gst/udp/Makefile
 972 gst/videoscale/Makefile
 973 gst/videotestsrc/Makefile
 974 gst/videocrop/Makefile
 975 gst/volenv/Makefile
 976 gst/volume/Makefile
 977 gst/vumeter/Makefile
 978 gst/wavparse/Makefile
 979 gst/y4m/Makefile
 980 sys/Makefile
 981 sys/cdrom/Makefile
 982 sys/dxr3/Makefile
 983 sys/oss/Makefile
 984 sys/qcam/Makefile
 985 sys/v4l/Makefile
 986 sys/v4l2/Makefile
 987 sys/vcd/Makefile
 988 sys/vga/Makefile
 989 sys/xvideo/Makefile
 990 sys/videosink/Makefile
 991 ext/Makefile
 992 ext/a52dec/Makefile
 993 ext/aalib/Makefile
 994 ext/alsa/Makefile
 995 ext/arts/Makefile
 996 ext/artsd/Makefile
 997 ext/audiofile/Makefile
 998 ext/avifile/Makefile
 999 ext/cdparanoia/Makefile
1000 ext/dv/Makefile
1001 ext/dvdread/Makefile
1002 ext/dvdnav/Makefile
1003 ext/esd/Makefile
1004 ext/ffmpeg/Makefile
1005 ext/flac/Makefile
1006 ext/gnomevfs/Makefile
1007 ext/gsm/Makefile
1008 ext/hermes/Makefile
1009 ext/http/Makefile
1010 ext/jack/Makefile
1011 ext/jpeg/Makefile
1012 ext/ladspa/Makefile
1013 ext/lame/Makefile
1014 ext/lcs/Makefile
1015 ext/libfame/Makefile
1016 ext/mad/Makefile
1017 ext/mikmod/Makefile
1018 ext/mjpegtools/Makefile
1019 ext/mpeg2dec/Makefile
1020 ext/openquicktime/Makefile
1021 ext/raw1394/Makefile
1022 ext/rtp/Makefile
1023 ext/sdl/Makefile
1024 ext/shout/Makefile
1025 ext/sidplay/Makefile
1026 ext/smoothwave/Makefile
1027 ext/swfdec/Makefile
1028 ext/vorbis/Makefile
1029 ext/tarkin/Makefile
1030 ext/xmms/Makefile
1031 gst-libs/Makefile
1032 gst-libs/gst/Makefile
1033 gst-libs/gst/audio/Makefile
1034 gst-libs/gst/floatcast/Makefile
1035 gst-libs/gst/gconf/Makefile
1036 gst-libs/gst/idct/Makefile
1037 gst-libs/gst/resample/Makefile
1038 gst-libs/gst/riff/Makefile
1039 gst-libs/gst/video/Makefile
1040 examples/dynparams/Makefile
1041 examples/capsfilter/Makefile
1042 examples/seeking/Makefile
1043 examples/Makefile
1044 testsuite/autoplug/Makefile
1045 testsuite/spider/Makefile
1046 testsuite/Makefile
1047 tools/Makefile
1048 gconf/Makefile
1049 )
1050
1051 AC_OUTPUT
1052
1053 echo -e "configure: *** Plug-ins that will be built : $GST_PLUGINS_YES"
1054 echo
1055 echo -e "configure: *** Plug-ins that will not be built : $GST_PLUGINS_NO"
1056 echo
1057 if test "x$BUILD_EXTERNAL" = "xno"; then
1058   echo "configure: *** No external plug-ins will be built"
1059 fi