configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of polypaudio.
   7 #
   8 # polypaudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # polypaudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with polypaudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [1])
  27
  28 AC_INIT([polypaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/polypaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 9)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 9)
  38
  39 AC_SUBST(LIBPOLYP_VERSION_INFO, [0:0:0])
  40 AC_SUBST(LIBPOLYPCORE_VERSION_INFO, [0:1:0])
  41 AC_SUBST(LIBPOLYP_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPOLYP_BROWSE_VERSION_INFO, [0:0:0])
  43 AC_SUBST(LIBPOLYP_MAINLOOP_GLIB_VERSION_INFO, [0:0:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 # LYNX documentation generation
 104 AC_ARG_ENABLE(lynx,
 105         AC_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
 106 [case "${enableval}" in
 107   yes) lynx=yes ;;
 108   no)  lynx=no ;;
 109   *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
 110 esac],[lynx=auto])
 111
 112 if test x$lynx != xno ; then
 113    AC_CHECK_PROG(have_lynx, lynx, yes, no)
 114
 115    if test x$have_lynx = xno ; then
 116        if test x$lynx = xyes ; then
 117            AC_MSG_ERROR([*** lynx not found])
 118        else
 119            AC_MSG_WARN([*** lynx not found, plain text README will not be built ***])
 120        fi
 121    fi
 122 fi
 123
 124 AM_CONDITIONAL([USE_LYNX], [test "x$have_lynx" = xyes])
 125
 126 #### libtool stuff ####
 127
 128 AC_LTDL_ENABLE_INSTALL
 129 AC_LIBLTDL_INSTALLABLE
 130 AC_SUBST(LTDLINCL)
 131 AC_SUBST(LIBLTDL)
 132 AC_LIBTOOL_DLOPEN
 133 AC_LIBTOOL_WIN32_DLL
 134 AC_PROG_LIBTOOL
 135 AC_CONFIG_SUBDIRS(libltdl)
 136
 137 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 138     AC_MSG_ERROR([[
 139
 140         *** Cannot find the libltdl development files.
 141         *** Maybe you need to install the libltdl-dev package.
 142         ]])
 143 fi
 144
 145 #### Determine build environment ####
 146
 147 os_is_win32=0
 148
 149 case "$host_os" in
 150         mingw*)
 151         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 152         os_is_win32=1
 153                 ;;
 154         esac
 155
 156 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 157
 158 ###################################
 159 #   Basic environment checks      #
 160 ###################################
 161
 162 #### Checks for header files. ####
 163
 164 # ISO
 165 AC_HEADER_STDC
 166
 167 # POSIX
 168 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 169     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 170     sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 171     syslog.h])
 172 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 173 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 174
 175 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 176 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 177
 178 # XPG4-UNIX
 179 AC_CHECK_HEADERS([sys/poll.h])
 180
 181 # Linux
 182 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 183
 184 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 185
 186 # Solaris
 187 AC_CHECK_HEADERS([sys/filio.h])
 188
 189 # Windows
 190 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 191
 192 # Other
 193 AC_CHECK_HEADERS([sys/ioctl.h])
 194
 195 #### Typdefs, structures, etc. ####
 196
 197 AC_C_CONST
 198 AC_C_BIGENDIAN
 199 AC_TYPE_PID_T
 200 AC_TYPE_SIZE_T
 201 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 202     [Define ssize_t if it is not done by the standard libs.])])
 203 AC_TYPE_OFF_T
 204 AC_TYPE_SIGNAL
 205 AC_TYPE_UID_T
 206
 207 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 208 HAVE_SIGXCPU=1
 209 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 210 ], [HAVE_SIGXCPU=0])
 211 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 212
 213 # Solaris lacks this
 214 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 215     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 216         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 217
 218 #### Check for libs ####
 219
 220 # ISO
 221 AC_SEARCH_LIBS([pow], [m])
 222
 223 # POSIX
 224 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 225 AC_SEARCH_LIBS([dlopen], [dl])
 226
 227 # BSD
 228 AC_SEARCH_LIBS([connect], [socket])
 229
 230 # Non-standard
 231
 232 # This magic is needed so we do not needlessly add static libs to the win32
 233 # build, disabling its ability to make dlls.
 234 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 235
 236 #### Check for functions ####
 237
 238 # POSIX
 239 AC_FUNC_FORK
 240 AC_FUNC_GETGROUPS
 241 AC_FUNC_SELECT_ARGTYPES
 242 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 243     getuid inet_ntop inet_pton nanosleep pipe setpgid setsid sigaction sleep])
 244 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 245
 246 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 247
 248 # X/OPEN
 249 AC_CHECK_FUNCS([readlink])
 250
 251 # SUSv2
 252 AC_CHECK_FUNCS([ctime_r usleep])
 253
 254 # SUSv3
 255 AC_CHECK_FUNCS([strerror_r])
 256
 257 # BSD
 258 AC_CHECK_FUNCS([lstat])
 259
 260 # Non-standard
 261
 262 AC_CHECK_FUNCS(setresuid)
 263 AC_CHECK_FUNCS(setreuid)
 264
 265 #### POSIX threads ####
 266
 267 ACX_PTHREAD
 268
 269 #### Large File-Support (LFS) ####
 270
 271 AC_SYS_LARGEFILE
 272
 273 #### [lib]iconv ####
 274
 275 AM_ICONV
 276
 277 ###################################
 278 #      External libraries         #
 279 ###################################
 280
 281 #### X11 (optional) ####
 282
 283 HAVE_X11=0
 284
 285 # The macro tests the host, not the build target
 286 if test "x$os_is_win32" != "x1" ; then
 287     AC_PATH_XTRA
 288     test "x$no_x" != "xyes" && HAVE_X11=1
 289 fi
 290
 291 AC_SUBST(HAVE_X11)
 292 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 293 if test "x$HAVE_X11" = "x1" ; then
 294     AC_DEFINE([HAVE_X11], 1, [Have X11])
 295 fi
 296
 297 #### Capabilities (optional) ####
 298
 299 CAP_LIBS=''
 300
 301 AC_ARG_WITH(
 302         [caps],
 303         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 304
 305 if test "x${with_caps}" != "xno"; then
 306     AC_SEARCH_LIBS([cap_init], [cap], [], [
 307                     if test "x${with_caps}" = "xyes" ; then
 308                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 309                     fi])
 310     AC_CHECK_HEADERS([sys/capability.h], [], [
 311                     if test "x${with_caps}" = "xyes" ; then
 312                         AC_MSG_ERROR([*** POSIX caps headers not found])
 313                     fi])
 314 fi
 315
 316 #### pkg-config ####
 317
 318 # Check for pkg-config manually first, as if its not installed the
 319 # PKG_PROG_PKG_CONFIG macro won't be defined.
 320 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 321
 322 if test x"$have_pkg_config" = "xno"; then
 323     AC_MSG_ERROR(pkg-config is required to install this program)
 324 fi
 325
 326 PKG_PROG_PKG_CONFIG
 327
 328 #### Sample rate conversion ####
 329
 330 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 331 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 332 AC_SUBST(LIBSAMPLERATE_LIBS)
 333
 334 #### Sound file ####
 335
 336 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 337 AC_SUBST(LIBSNDFILE_CFLAGS)
 338 AC_SUBST(LIBSNDFILE_LIBS)
 339
 340 #### OSS support (optional) ####
 341
 342 AC_ARG_ENABLE([oss],
 343     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 344         [
 345             case "${enableval}" in
 346                 yes) oss=yes ;;
 347                 no) oss=no ;;
 348                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 349             esac
 350         ],
 351         [oss=auto])
 352
 353 if test "x${oss}" != xno ; then
 354     AC_CHECK_HEADERS([sys/soundcard.h],
 355         [
 356             HAVE_OSS=1
 357             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 358         ],
 359         [
 360             HAVE_OSS=0
 361             if test "x$oss" = xyes ; then
 362                 AC_MSG_ERROR([*** OSS support not found])
 363             fi
 364         ])
 365 else
 366     HAVE_OSS=0
 367 fi
 368
 369 AC_SUBST(HAVE_OSS)
 370 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 371
 372
 373 #### ALSA support (optional) ####
 374
 375 AC_ARG_ENABLE([alsa],
 376     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 377         [
 378             case "${enableval}" in
 379                 yes) alsa=yes ;;
 380                 no) alsa=no ;;
 381                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 382             esac
 383         ],
 384         [alsa=auto])
 385
 386 if test "x${alsa}" != xno ; then
 387     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 388         [
 389             HAVE_ALSA=1
 390             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 391         ],
 392         [
 393             HAVE_ALSA=0
 394             if test "x$alsa" = xyes ; then
 395                 AC_MSG_ERROR([*** ALSA support not found])
 396             fi
 397         ])
 398 else
 399     HAVE_ALSA=0
 400 fi
 401
 402 AC_SUBST(ASOUNDLIB_CFLAGS)
 403 AC_SUBST(ASOUNDLIB_LIBS)
 404 AC_SUBST(HAVE_ALSA)
 405 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 406
 407 #### Solaris audio support (optional) ####
 408
 409 AC_ARG_ENABLE([solaris],
 410     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 411         [
 412             case "${enableval}" in
 413                 yes) solaris=yes ;;
 414                 no) solaris=no ;;
 415                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 416             esac
 417         ],
 418         [solaris=auto])
 419
 420 if test "x${solaris}" != xno ; then
 421     AC_CHECK_HEADERS([sys/audio.h],
 422         [
 423             HAVE_SOLARIS=1
 424             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 425         ],
 426         [
 427             HAVE_SOLARIS=0
 428             if test "x$solaris" = xyes ; then
 429                 AC_MSG_ERROR([*** Solaris audio support not found])
 430             fi
 431         ])
 432 else
 433     HAVE_SOLARIS=0
 434 fi
 435
 436 AC_SUBST(HAVE_SOLARIS)
 437 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 438
 439 #### GLib 2 support (optional) ####
 440
 441 AC_ARG_ENABLE([glib2],
 442     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 443         [
 444             case "${enableval}" in
 445                 yes) glib2=yes ;;
 446                 no) glib2=no ;;
 447                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 448             esac
 449         ],
 450         [glib2=auto])
 451
 452 if test "x${glib2}" != xno ; then
 453     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 454         HAVE_GLIB20=1,
 455         [
 456             HAVE_GLIB20=0
 457             if test "x$glib2" = xyes ; then
 458                 AC_MSG_ERROR([*** GLib 2 support not found])
 459             fi
 460         ])
 461 else
 462     HAVE_GLIB20=0
 463 fi
 464
 465 AC_SUBST(GLIB20_CFLAGS)
 466 AC_SUBST(GLIB20_LIBS)
 467 AC_SUBST(HAVE_GLIB20)
 468 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 469
 470 #### GLib 1 support (optional) ####
 471
 472 AC_ARG_ENABLE([glib1],
 473     AC_HELP_STRING([--disable-glib1], [Disable optional GLib 1 support]),
 474         [
 475             case "${enableval}" in
 476                 yes) glib1=yes ;;
 477                 no) glib1=no ;;
 478                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib1) ;;
 479             esac
 480         ],
 481         [glib1=auto])
 482
 483 if test "x${glib1}" != xno ; then
 484     PKG_CHECK_MODULES(GLIB12, [ glib >= 1.2.0 ],
 485         HAVE_GLIB12=1,
 486         [
 487             HAVE_GLIB12=0
 488             if test "x$glib1" = xyes ; then
 489                 AC_MSG_ERROR([*** GLib 1 support not found])
 490             fi
 491         ])
 492 else
 493     HAVE_GLIB12=0
 494 fi
 495
 496 AC_SUBST(GLIB12_CFLAGS)
 497 AC_SUBST(GLIB12_LIBS)
 498 AC_SUBST(HAVE_GLIB12)
 499 AM_CONDITIONAL([HAVE_GLIB12], [test "x$HAVE_GLIB12" = x1])
 500
 501 #### Howl support (optional) ####
 502
 503 AC_ARG_ENABLE([howl],
 504     AC_HELP_STRING([--disable-howl], [Disable optional Howl support]),
 505         [
 506             case "${enableval}" in
 507                 yes) howl=yes ;;
 508                 no) howl=no ;;
 509                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-howl) ;;
 510             esac
 511         ],
 512         [howl=auto])
 513
 514 if test "x${howl}" != xno ; then
 515     PKG_CHECK_MODULES(HOWL, [ howl >= 0.9.8 ],
 516         HAVE_HOWL=1,
 517         [
 518             PKG_CHECK_MODULES(HOWL, [ avahi-compat-howl >= 0.9.8 ],
 519                 HAVE_HOWL=1,
 520                 [
 521                     HAVE_HOWL=0
 522                     if test "x$howl" = xyes ; then
 523                         AC_MSG_ERROR([*** Howl support not found])
 524                     fi
 525                 ])
 526         ])
 527 else
 528     HAVE_HOWL=0
 529 fi
 530
 531 AC_SUBST(HOWL_CFLAGS)
 532 AC_SUBST(HOWL_LIBS)
 533 AC_SUBST(HAVE_HOWL)
 534 AM_CONDITIONAL([HAVE_HOWL], [test "x$HAVE_HOWL" = x1])
 535
 536 ### LIBOIL ####
 537
 538 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 539 AC_SUBST(LIBOIL_CFLAGS)
 540 AC_SUBST(LIBOIL_LIBS)
 541
 542 ### JACK (optional) ####
 543
 544 AC_ARG_ENABLE([jack],
 545     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 546         [
 547             case "${enableval}" in
 548                 yes) jack=yes ;;
 549                 no) jack=no ;;
 550                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 551             esac
 552         ],
 553         [jack=auto])
 554
 555 if test "x${jack}" != xno ; then
 556     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 557         HAVE_JACK=1,
 558         [
 559             HAVE_JACK=0
 560             if test "x$jack" = xyes ; then
 561                 AC_MSG_ERROR([*** JACK support not found])
 562             fi
 563         ])
 564 else
 565     HAVE_JACK=0
 566 fi
 567
 568 AC_SUBST(JACK_CFLAGS)
 569 AC_SUBST(JACK_LIBS)
 570 AC_SUBST(HAVE_JACK)
 571 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 572
 573 #### Async DNS support (optional) ####
 574
 575 AC_ARG_ENABLE([asyncns],
 576     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 577         [
 578             case "${enableval}" in
 579                 yes) asyncns=yes ;;
 580                 no) asyncns=no ;;
 581                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 582             esac
 583         ],
 584         [asyncns=auto])
 585
 586 if test "x${asyncns}" != xno ; then
 587     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 588         HAVE_LIBASYNCNS=1,
 589         [
 590             HAVE_LIBASYNCNS=0
 591             if test "x$asyncns" = xyes ; then
 592                 AC_MSG_ERROR([*** Async DNS support not found])
 593             fi
 594         ])
 595 else
 596     HAVE_LIBASYNCNS=0
 597 fi
 598
 599 AC_SUBST(LIBASYNCNS_CFLAGS)
 600 AC_SUBST(LIBASYNCNS_LIBS)
 601 AC_SUBST(HAVE_LIBASYNCNS)
 602 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 603
 604 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 605    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 606 fi
 607
 608 #### TCP wrappers (optional) ####
 609
 610 AC_ARG_ENABLE([tcpwrap],
 611     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 612         [
 613             case "${enableval}" in
 614                 yes) tcpwrap=yes ;;
 615                 no) tcpwrap=no ;;
 616                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 617             esac
 618         ],
 619         [tcpwrap=auto])
 620
 621 if test "x${tcpwrap}" != xno ; then
 622     ACX_LIBWRAP
 623     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 624         AC_MSG_ERROR([*** TCP wrappers support not found])
 625     fi
 626 else
 627     LIBWRAP_LIBS=
 628 fi
 629
 630 AC_SUBST(LIBWRAP_LIBS)
 631
 632 #### LIRC support (optional) ####
 633
 634 AC_ARG_ENABLE([lirc],
 635     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 636         [
 637             case "${enableval}" in
 638                 yes) lirc=yes ;;
 639                 no) lirc=no ;;
 640                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 641             esac
 642         ],
 643         [lirc=auto])
 644
 645 if test "x${lirc}" != xno ; then
 646     ACX_LIRC
 647     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 648         AC_MSG_ERROR([*** LIRC support not found])
 649     fi
 650 else
 651     HAVE_LIRC=0
 652 fi
 653
 654 AC_SUBST(LIRC_CFLAGS)
 655 AC_SUBST(LIRC_LIBS)
 656 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 657
 658 ###################################
 659 #            Output               #
 660 ###################################
 661
 662 AC_ARG_ENABLE(
 663         [static-bins],
 664         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 665         [STATIC_BINS=1], [STATIC_BINS=0])
 666 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 667
 668 AC_ARG_WITH(
 669         [preopen-mods],
 670         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 671         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 672 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 673 if test "x$PREOPEN_MODS" != "xall" ; then
 674     tmpLIBS=""
 675     for mod in $PREOPEN_MODS; do
 676         tmpLIBS="$tmpLIBS module-$mod.la"
 677     done
 678     PREOPEN_MODS="$tmpLIBS"
 679     AC_SUBST(PREOPEN_MODS)
 680 fi
 681
 682 AC_ARG_WITH(
 683         [module-dir],
 684         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/polypaudio-${PA_MAJORMINOR}/modules/]),
 685         [modlibexecdir=$withval], [modlibexecdir="${libdir}/polypaudio-${PA_MAJORMINOR}/modules/"])
 686
 687 AC_SUBST(modlibexecdir)
 688
 689 AC_ARG_ENABLE(
 690         [force-preopen],
 691         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 692         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 693 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 694
 695 AC_CONFIG_FILES([
 696 Makefile
 697 src/Makefile
 698 polyplib.pc
 699 polyplib-simple.pc
 700 polyplib-browse.pc
 701 polyplib-glib-mainloop.pc
 702 polyplib-glib12-mainloop.pc
 703 doc/Makefile
 704 doc/README.html
 705 doc/cli.html
 706 doc/daemon.html
 707 doc/modules.html
 708 doxygen/Makefile
 709 doxygen/doxygen.conf
 710 src/polyp/version.h
 711 doc/FAQ.html
 712 ])
 713 AC_OUTPUT