configure.ac

   1 EFL_VERSION([1], [16], [0], [release])
   2 AC_INIT([elementary], [efl_version], [enlightenment-devel@lists.sourceforge.net])
   3
   4 AC_PREREQ(2.63)
   5 AC_CONFIG_SRCDIR([configure.ac])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CANONICAL_BUILD
   8 AC_CANONICAL_HOST
   9
  10 AC_CONFIG_HEADERS([elementary_config.h])
  11 AH_TOP([
  12 #ifndef EFL_CONFIG_H__
  13 #define EFL_CONFIG_H__
  14 ])
  15 AH_BOTTOM([
  16 #endif /* EFL_CONFIG_H__ */
  17 ])
  18
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_INIT_AUTOMAKE([1.11 dist-bzip2 dist-xz -Wall])
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 LT_INIT([win32-dll disable-static pic-only])
  26 EFL_INIT
  27
  28
  29 ### Additional options to configure
  30
  31 # C++ bindings
  32
  33 AC_ARG_ENABLE([cxx-bindings],
  34    [AS_HELP_STRING([--disable-cxx-bindings],
  35        [Disable C++11 bindings. @<:@default=enabled@:>@])],
  36    [want_cxx11="${enableval}"],
  37    [want_cxx11="yes"])
  38
  39 # Tests
  40
  41 AC_ARG_WITH([tests],
  42    [AS_HELP_STRING([--with-tests=none|regular|coverage],
  43                    [choose elementary testing method: regular, coverage or none @<:@default=none@:>@])],
  44    [build_tests=${withval}],
  45    [build_tests=auto])
  46
  47 want_coverage="no"
  48 want_tests="no"
  49 case "${build_tests}" in
  50    auto)
  51      if test "${build_profile}" = "dev"; then
  52         want_tests="yes"
  53      fi
  54      ;;
  55    regular)
  56      want_tests="yes"
  57      ;;
  58    coverage)
  59      want_tests="yes"
  60      want_coverage="yes"
  61      ;;
  62    no*)
  63      ;;
  64    *)
  65      AC_MSG_ERROR([Unknown build tests option: --with-tests=${build_tests}])
  66      ;;
  67 esac
  68
  69 # Elementary base dir
  70
  71 AC_ARG_WITH([elementary-base-dir],
  72    [AS_HELP_STRING([--with-elementary-base-dir=PATH], [specify the subdirectory for all elementary data @<:@default=${elementary_base_dir}@:>@])],
  73    [elementary_base_dir=${withval}],
  74    [elementary_base_dir=".elementary"])
  75
  76 AC_MSG_NOTICE([ELEMENTARY_BASE_DIR set to ${elementary_base_dir}])
  77 AC_DEFINE_UNQUOTED([ELEMENTARY_BASE_DIR], ["${elementary_base_dir}"], ["subdirectory for all elementary data"])
  78
  79 # Build and install examples
  80
  81 EFL_CHECK_BUILD_EXAMPLES(
  82    [enable_build_examples="yes"],
  83    [enable_build_examples="no"])
  84
  85 EFL_CHECK_INSTALL_EXAMPLES(
  86    [enable_install_examples="yes"],
  87    [enable_install_examples="no"])
  88
  89 # Debug mode
  90
  91 AC_ARG_ENABLE([debug],
  92    [AS_HELP_STRING([--enable-debug], [enable elementary debug support. @<:@default=disabled@:>@])],
  93    [want_elementary_debug=$enableval],
  94    [want_elementary_debug="no"])
  95
  96 ELM_DEBUG_DEF="#undef"
  97 if test "x$want_elementary_debug" = "xyes"; then
  98    AC_DEFINE([HAVE_ELEMENTARY_DEBUG], [1], [Elementary debug.])
  99    ELM_DEBUG_DEF="#define"
 100 fi
 101 AC_SUBST([ELM_DEBUG_DEF])
 102
 103 # quicklaunch support
 104
 105 AC_ARG_ENABLE([quick-launch],
 106    [AS_HELP_STRING([--disable-quick-launch], [disable quick-launch support, @<:@default=detect@:>@])],
 107    [want_quicklaunch=$enableval],
 108    [want_quicklaunch="auto"])
 109
 110
 111 ### Default options with respect to host and default values
 112
 113 ELM_VERSION_MAJOR="v_maj"
 114 ELM_VERSION_MINOR="v_min"
 115 AC_SUBST([ELM_VERSION_MAJOR])
 116 AC_SUBST([ELM_VERSION_MINOR])
 117
 118 MODULE_ARCH="v-v_maj.v_min.v_mic"
 119 AC_SUBST([MODULE_ARCH])
 120 AC_DEFINE_UNQUOTED([MODULE_ARCH], ["$MODULE_ARCH"], ["Module architecture"])
 121
 122 ELM_UNIX_DEF="#undef"
 123 ELM_WIN32_DEF="#undef"
 124 have_windows="no"
 125 have_freebsd="no"
 126
 127 case "$host_os" in
 128    mingw*)
 129       AC_DEFINE([HAVE_EVIL], [1], [Set to 1 if evil package is installed.])
 130       ELM_WIN32_DEF="#define"
 131       have_windows="yes"
 132       ;;
 133    *solaris*)
 134       ELM_UNIX_DEF="#define"
 135       ;;
 136    freebsd*)
 137       ELM_UNIX_DEF="#define"
 138       have_freebsd="yes"
 139       ;;
 140    darwin*)
 141       ELM_UNIX_DEF="#define"
 142       ;;
 143    *)
 144       ELM_UNIX_DEF="#define"
 145       ;;
 146 esac
 147
 148 AM_CONDITIONAL([ELEMENTARY_WINDOWS_BUILD], [test "x${have_windows}" = "xyes"])
 149 AM_CONDITIONAL([HAVE_FREEBSD], [test "x${have_freebsd}" = "xyes"])
 150 AC_SUBST([ELM_UNIX_DEF])
 151 AC_SUBST([ELM_WIN32_DEF])
 152
 153 ### Checks for programs
 154
 155 # compilers
 156 AC_PROG_CC
 157 AC_PROG_CC_STDC
 158 AC_PROG_CXX
 159
 160 EFL_CXX_COMPILE_STDCXX_11([ext])
 161
 162 # pkg-config
 163 PKG_PROG_PKG_CONFIG
 164
 165 # gettext
 166 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
 167 AM_GNU_GETTEXT_VERSION([0.18])
 168 ])
 169
 170 m4_ifdef([AM_GNU_GETTEXT], [
 171 AM_GNU_GETTEXT([external])
 172 po_makefile_in=po/Makefile.in
 173 have_po="yes"
 174 ],[
 175 have_po="no"
 176 ])
 177 AC_SUBST([LTLIBINTL])
 178
 179 if test "x${POSUB}" = "x" ; then
 180    have_po="no"
 181 fi
 182
 183 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
 184
 185 # doxygen
 186 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 187
 188 # EFL binaries
 189 EFL_WITH_BIN([eet], [eet-eet], [eet])
 190 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 191 EFL_WITH_BIN([elementary], [elementary-codegen], [elementary_codegen])
 192 EFL_WITH_BIN([elementary], [elm-prefs-cc], [elm_prefs_cc])
 193 EFL_WITH_BIN([eolian], [eolian-gen], [eolian_gen])
 194 EFL_WITH_BIN([eolian-cxx], [eolian-cxx], [eolian_cxx])
 195 EFL_WITH_BIN([eldbus], [eldbus_codegen], [eldbus-codegen])
 196 # Force the helper to try external eolian generators
 197 AM_CONDITIONAL([HAVE_EOLIAN_GEN], [true])
 198 AM_CONDITIONAL([HAVE_EOLIAN_CXX], [true])
 199
 200 EFL_ENABLE_BIN([elementary-test])
 201 EFL_ENABLE_BIN([elementary-codegen])
 202 EFL_ENABLE_BIN([elm-prefs-cc])
 203 EFL_ENABLE_BIN([elementary-config])
 204
 205
 206 ### Checks for libraries
 207
 208 requirement_elm_pc=""
 209
 210 case "$host_os" in
 211    mingw*)
 212       requirement_elm_pc="evil >= efl_version"
 213       ;;
 214 #TIZEN_ONLY(20160425): Mobile Ux needs icu.
 215    *)
 216       requirement_elm_pc="icu-i18n >= 4.8"
 217       ;;
 218 #
 219 esac
 220
 221 requirement_elm_pc_only="\
 222     efl >= efl_version \
 223     eina >= efl_version \
 224     eet >= efl_version \
 225     evas >= efl_version \
 226     ecore >= efl_version \
 227     ecore-evas >= efl_version \
 228     ecore-file >= efl_version \
 229     ecore-input >= efl_version \
 230     edje >= efl_version \
 231     eo >= efl_version \
 232     ethumb_client >= efl_version \
 233     emotion >= efl_version \
 234     ecore-imf >= efl_version \
 235     ecore-con >= efl_version \
 236     eio >= efl_version \
 237     eldbus >= efl_version \
 238     efreet >= efl_version \
 239     efreet-mime >= efl_version \
 240     efreet-trash >= efl_version \
 241     eio >= efl_version \
 242     "
 243
 244 requirement_elm_pc="\
 245     ${requirement_elm_pc} \
 246     ${requirement_elm_pc_only} \
 247     "
 248
 249 ELM_CHECK_BACKEND([X])
 250 ELM_CHECK_BACKEND([FB])
 251 ELM_CHECK_BACKEND([PSL1GHT])
 252 ELM_CHECK_BACKEND([SDL])
 253 ELM_CHECK_BACKEND([Cocoa])
 254 ELM_CHECK_BACKEND([Win32])
 255 ELM_CHECK_BACKEND([Wayland])
 256 ELM_CHECK_BACKEND([DRM])
 257
 258 ELM_CHECK_OPTION([elocation], [0.1.0])
 259 ELM_CHECK_OPTION([eweather], [0.2.0])
 260 # emap is in svn : trunk/PROTO
 261 ELM_CHECK_OPTION([emap], [0.1.0])
 262 ELM_CHECK_OPTION([eweb])
 263
 264 PKG_CHECK_MODULES([ELEMENTARY], [${requirement_elm_pc}])
 265 PKG_CHECK_MODULES([ELEMENTARY_PC], [${requirement_elm_pc_only}])
 266
 267 EFL_ENABLE_EO_API_SUPPORT
 268 EFL_ENABLE_BETA_API_SUPPORT
 269
 270
 271 if test "x${HAVE_CXX11}" = "x1" -a "x${want_cxx11}" = "xyes"; then
 272    PKG_CHECK_MODULES([ELEMENTARY_CXX],
 273       [
 274         efl-cxx >= efl_version
 275         eo-cxx >= efl_version
 276         eina-cxx >= efl_version
 277         evas-cxx >= efl_version
 278         eio-cxx >= efl_version
 279         edje-cxx >= efl_version
 280       ],
 281       [
 282         requirement_elm_pc="${requirement_elm_pc} \
 283           efl-cxx >= efl_version \
 284           eo-cxx >= efl_version \
 285           eina-cxx >= efl_version \
 286           evas-cxx >= efl_version \
 287           eio-cxx >= efl_version \
 288           edje-cxx >= efl_version \
 289         "
 290         have_cxx11="yes"
 291         LDFLAGS="${LDFLAGS} -fPIC -DPIC"
 292         CXXFLAGS="${CXXFLAGS} -fPIC -DPIC"
 293         AC_CONFIG_FILES([src/lib/Elementary.hh])
 294       ],
 295       [have_cxx11="no"]
 296    )
 297 else
 298    have_cxx11="no"
 299 fi
 300 AM_CONDITIONAL([HAVE_CXX11], [test "x${have_cxx11}" = "xyes"])
 301
 302
 303 MODULE_EDJE=`${PKG_CONFIG} --variable=module_arch edje`
 304 AC_SUBST([MODULE_EDJE])
 305 AC_DEFINE_UNQUOTED([MODULE_EDJE], ["$MODULE_EDJE"], ["Edje module architecture"])
 306
 307 # Needs to be moved into a macro, and also, needs a way to automatically fetch
 308 # from all the dependencies using the Requires.
 309 DEPS_EOLIAN_FLAGS=`${PKG_CONFIG} --variable=eolian_flags eo evas edje ecore efl`
 310 AC_SUBST([DEPS_EOLIAN_FLAGS])
 311
 312 requirement_elm_libs="-lm"
 313
 314 # sockets
 315
 316 case "$host_os" in
 317    mingw*)
 318       have_socket="no"
 319       ;;
 320    *solaris*)
 321       AC_CHECK_LIB([socket], [connect],
 322          [
 323           have_socket="yes"
 324           requirement_elm_libs="-lsocket ${requirement_elm_libs}"
 325          ],
 326          [have_socket="no"])
 327       ;;
 328    darwin*)
 329       have_socket="yes"
 330       ;;
 331    *)
 332       have_socket="yes"
 333       ;;
 334 esac
 335
 336 AM_CONDITIONAL([BUILD_RUN], [test "x$have_socket" = "xyes"])
 337
 338 # dlopen
 339
 340 have_dlopen="no"
 341 case "$host_os" in
 342    mingw*)
 343 dnl managed by evil
 344       AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if you have the `dladdr' function.])
 345       have_dlopen="yes"
 346       requirement_elm_libs="-ldl ${requirement_elm_libs}"
 347       ;;
 348    linux*)
 349       AC_CHECK_LIB([dl], [dlopen], [res=yes], [res=no])
 350       if test "x$res" = "xyes"; then
 351          AC_CHECK_LIB([dl], [dladdr], AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if you have the `dladdr' function.]))
 352          requirement_elm_libs="-ldl ${requirement_elm_libs}"
 353          have_dlopen="yes"
 354       fi
 355       ;;
 356    *)
 357       have_dlopen="yes"
 358       ;;
 359 esac
 360
 361 AM_CONDITIONAL([BUILD_MODULES], [test "x$have_dlopen" = "xyes"])
 362
 363 ELEMENTARY_LIBS="${ELEMENTARY_LIBS} ${requirement_elm_libs}"
 364 ELEMENTARY_PC_LIBS="${ELEMENTARY_PC_LIBS} ${requirement_elm_libs}"
 365
 366 AC_SUBST([requirement_elm_pc])
 367
 368 # check unit testing library
 369 if test "${want_tests}" = "yes"; then
 370    PKG_CHECK_MODULES([CHECK], [check >= 0.9.5])
 371 fi
 372 AM_CONDITIONAL([ELEMENTARY_ENABLE_TESTS], [test "${want_tests}" = "yes"])
 373
 374 # lcov
 375 if test "${want_coverage}" = "yes" ; then
 376    AC_CHECK_PROG([have_lcov], [lcov], [yes], [no])
 377    if test "x${have_lcov}" = "xyes" ; then
 378       ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -fprofile-arcs -ftest-coverage"
 379       ELEMENTARY_LIBS="${ELEMENTARY_LIBS} -lgcov"
 380       if test "x${prefer_assert}" = "xno"; then
 381          ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -DNDEBUG"
 382       else
 383          ELEMENTARY_CFLAGS="${ELEMENTARY_CFLAGS} -g -O0 -DDEBUG"
 384       fi
 385    else
 386       AC_MSG_ERROR([lcov is not found])
 387    fi
 388 fi
 389
 390 AM_CONDITIONAL([ELEMENTARY_ENABLE_COVERAGE], [test "${want_coverage}" = "yes"])
 391
 392
 393 ### Checks for header files
 394
 395 # Check for ttrace
 396 PKG_CHECK_MODULES(TTRACE,
 397                   [ttrace],
 398                   [have_ttrace="yes"], [have_ttrace="no"])
 399 if test "x$have_ttrace" = "xyes"; then
 400   AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available])
 401 fi
 402
 403 ELM_ALLOCA_H_DEF="#undef"
 404 AC_CHECK_HEADER([alloca.h], [ELM_ALLOCA_H_DEF="#define"])
 405 AC_SUBST([ELM_ALLOCA_H_DEF])
 406
 407 ELM_LIBINTL_H_DEF="#undef"
 408 AC_CHECK_HEADER([libintl.h], [ELM_LIBINTL_H_DEF="#define"])
 409 AC_SUBST([ELM_LIBINTL_H_DEF])
 410
 411 ELM_DIRENT_H_DEF="#undef"
 412 AC_CHECK_HEADER([dirent.h], [ELM_DIRENT_H_DEF="#define"])
 413 AC_SUBST([ELM_DIRENT_H_DEF])
 414
 415 AC_CHECK_HEADER([sys/mman.h], [have_mman="yes"], [have_mman="no"])
 416 if test "x${have_mman}" = "xyes"; then
 417    AC_DEFINE([HAVE_MMAN_H], [1], [Have sys/mman.h header file])
 418 fi
 419
 420 AC_CHECK_HEADERS([locale.h langinfo.h sys/times.h])
 421
 422 case "$host_os" in
 423    darwin*)
 424       AC_CHECK_HEADERS([crt_externs.h])
 425       ;;
 426 esac
 427
 428
 429 ### Checks for types
 430
 431
 432 ### Checks for structures
 433
 434
 435 ### Checks for compiler characteristics
 436
 437 AC_C_BIGENDIAN
 438
 439 m4_ifdef([v_mic],
 440    [
 441     EFL_COMPILER_FLAG([-Wshadow])
 442     EFL_COMPILER_FLAG([-Wall])
 443     EFL_COMPILER_FLAG([-W])
 444    ])
 445
 446 EFL_COMPILER_FLAG([-Wall -Wextra -Wpointer-arith -Wno-missing-field-initializers -fvisibility=hidden -fdata-sections -ffunction-sections])
 447
 448 EFL_CHECK_PATH_MAX
 449
 450
 451 ### Checks for linker characteristics
 452
 453 EFL_LINKER_FLAG([-fvisibility=hidden -fdata-sections -ffunction-sections -Wl,--gc-sections -fno-strict-aliasing -Wl,--as-needed -Wl,--no-copy-dt-needed-entries])
 454
 455 # Check if we can build binary with quicklaunch support
 456 ELM_QUICKLAUNCH
 457
 458
 459 ### Checks for library functions
 460
 461 AC_FUNC_ALLOCA
 462
 463 AC_CHECK_FUNCS([geteuid getuid getpwent])
 464
 465 if test "x${want_quicklaunch}" != "xno"; then
 466    AC_CHECK_FUNCS([fork clearenv])
 467 fi
 468
 469 if test "x${have_dlopen}" = "xno"; then
 470    AC_CHECK_FUNCS([dlopen dladdr])
 471 fi
 472
 473 if test "x${ac_cv_func_dlopen}" = "xyes"; then
 474    have_dlopen="yes"
 475 fi
 476
 477 AM_CONDITIONAL([BUILD_QUICKLAUNCH], [test "x${ac_cv_func_fork}" = "xyes" && test "x${have_dlopen}" = "xyes"])
 478
 479 # environ variable
 480
 481 AC_COMPILE_IFELSE(
 482    [AC_LANG_PROGRAM(
 483       [[
 484 # define _GNU_SOURCE 1
 485 #include <unistd.h>
 486       ]],
 487       [[
 488 extern char **environ;
 489       ]])
 490    ],
 491    [AC_DEFINE([HAVE_ENVIRON], [1], [extern environ exists])])
 492
 493 case "$host_os" in
 494    darwin*)
 495       AC_DEFINE([environ], [(*_NSGetEnviron())], ["apple doesn't follow POSIX in this case."])
 496       ;;
 497 esac
 498
 499
 500 AC_CONFIG_FILES([
 501 Makefile
 502 elementary.spec
 503 doc/Makefile
 504 doc/Doxyfile
 505 doc/widgets/Makefile
 506 src/Makefile
 507 src/lib/Makefile
 508 src/lib/Elementary.h
 509 src/lib/elm_intro.h
 510 src/bin/Makefile
 511 src/modules/Makefile
 512 src/modules/prefs/Makefile
 513 src/modules/access_output/Makefile
 514 src/modules/copypasteUI_ctxpopup/Makefile
 515 src/modules/datetime_input_ctxpopup/Makefile
 516 src/modules/test_entry/Makefile
 517 src/modules/test_map/Makefile
 518 src/edje_externals/Makefile
 519 src/examples/Makefile
 520 src/examples/sphere_hunter/Makefile
 521 src/examples/performance/Makefile
 522 src/tests/Makefile
 523 src/imported/Makefile
 524 src/imported/atspi/Makefile
 525 data/Makefile
 526 data/themes/Makefile
 527 data/images/Makefile
 528 data/objects/Makefile
 529 data/desktop/Makefile
 530 data/edje_externals/Makefile
 531 config/Makefile
 532 config/default/Makefile
 533 config/default/base.src
 534 config/standard/Makefile
 535 config/standard/base.src
 536 config/mobile/Makefile
 537 config/mobile/base.src
 538 $po_makefile_in
 539 cmakeconfig/ElementaryConfig.cmake
 540 cmakeconfig/ElementaryConfigVersion.cmake
 541 ])
 542
 543 AC_OUTPUT
 544
 545 #####################################################################
 546 ## Info
 547
 548 echo
 549 echo
 550 echo
 551 echo "------------------------------------------------------------------------"
 552 echo "$PACKAGE $VERSION"
 553 echo "------------------------------------------------------------------------"
 554 echo
 555 echo "Configuration Options Summary:"
 556 echo
 557 echo "  Engines:"
 558 echo "    X11....................: ${have_elementary_x}"
 559 echo "    Framebuffer............: ${have_elementary_fb}"
 560 echo "    DRM....................: ${have_elementary_drm}"
 561 echo "    PSL1GHT................: ${have_elementary_psl1ght}"
 562 echo "    SDL....................: ${have_elementary_sdl}"
 563 echo "    Cocoa..................: ${have_elementary_cocoa}"
 564 echo "    Windows XP.............: ${have_elementary_win32}"
 565 echo "    Wayland................: ${have_elementary_wayland}"
 566 echo
 567 echo "  Features:"
 568 echo "    EWeather...............: ${have_elementary_eweather}"
 569 echo "    EMap...................: ${have_elementary_emap}"
 570 echo "    Web (WebKit)...........: ${elementary_web}"
 571 echo "    Quick Launch...........: ${ac_cv_func_fork}"
 572 echo "    Elocation..............: ${have_elementary_elocation}"
 573 echo
 574 echo "  eet......................: ${eet_eet}"
 575 echo "  edje_cc..................: ${edje_cc}"
 576 echo "  elementary_codegen.......: ${elementary_codegen}"
 577 echo "  elm_prefs_cc.............: ${elm_prefs_cc}"
 578 echo "  eolian_gen...............: ${eolian_gen}"
 579 echo "  eolian_cxx...............: ${eolian_cxx}"
 580 echo "  eldbus_codegen...........: ${eldbus_codegen}"
 581 echo
 582 echo "  Build elementary_test....: ${have_elementary_test}"
 583 echo "  Build elementary_codegen.: ${have_elementary_codegen}"
 584 echo "  Build elm_prefs_cc.......: ${have_elm_prefs_cc}"
 585 echo "  Examples.................: ${enable_build_examples}"
 586 echo "  Examples installed.......: ${enable_install_examples}"
 587 echo "  Build elementary_config..: ${have_elementary_config}"
 588 echo "  Enable debug.............: ${want_elementary_debug}"
 589 echo "  Enable C++...............: ${have_cxx11}"
 590 echo
 591 echo "Compilation................: make (or gmake)"
 592 echo "  CPPFLAGS.................: $CPPFLAGS"
 593 echo "  CFLAGS...................: $CFLAGS"
 594 if test "x${have_cxx11}" = "xyes"; then
 595 echo "  CXXFLAGS.................: $CXXFLAGS"
 596 fi
 597 echo "  LDFLAGS..................: $LDFLAGS"
 598 echo
 599 if test "${build_tests}" = "none"; then
 600 echo "Tests......................: no"
 601 else
 602 echo "Tests......................: make check"
 603 fi
 604 if test "${build_doc}" = "no"; then
 605 echo "Docs.......................: no (doxygen not found)"
 606 else
 607 echo "Docs.......................: make doc"
 608 fi
 609 echo
 610 echo "Installation...............: make install (as root if needed, with 'su' or 'sudo')"
 611 echo "  prefix...................: $prefix"
 612 echo