configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [5])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.10 no-define])
  63
  64 # Support silent build rules, requires at least automake-1.11. Disable
  65 # by either passing --disable-silent-rules to configure or passing V=1
  66 # to make
  67 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  68
  69 GLIB_MAJOR_VERSION=glib_major_version
  70 GLIB_MINOR_VERSION=glib_minor_version
  71 GLIB_MICRO_VERSION=glib_micro_version
  72 GLIB_INTERFACE_AGE=glib_interface_age
  73 GLIB_BINARY_AGE=glib_binary_age
  74 GLIB_VERSION=glib_version
  75
  76 AC_SUBST(GLIB_MAJOR_VERSION)
  77 AC_SUBST(GLIB_MINOR_VERSION)
  78 AC_SUBST(GLIB_MICRO_VERSION)
  79 AC_SUBST(GLIB_VERSION)
  80 AC_SUBST(GLIB_INTERFACE_AGE)
  81 AC_SUBST(GLIB_BINARY_AGE)
  82
  83 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  84           [Define to the GLIB major version])
  85 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  86           [Define to the GLIB minor version])
  87 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  88           [Define to the GLIB micro version])
  89 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  90           [Define to the GLIB interface age])
  91 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  92           [Define to the GLIB binary age])
  93
  94 # libtool versioning
  95 LT_RELEASE=glib_lt_release
  96 LT_CURRENT=glib_lt_current
  97 LT_REVISION=glib_lt_revision
  98 LT_AGE=glib_lt_age
  99 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 100 AC_SUBST(LT_RELEASE)
 101 AC_SUBST(LT_CURRENT)
 102 AC_SUBST(LT_REVISION)
 103 AC_SUBST(LT_AGE)
 104 AC_SUBST(LT_CURRENT_MINUS_AGE)
 105
 106 dnl Initialize maintainer mode
 107 AM_MAINTAINER_MODE
 108
 109 dnl Checks for programs.
 110 AC_PROG_CC
 111 AC_PROG_CPP
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(threads,
 229               [AC_HELP_STRING([--enable-threads],
 230                               [turn on basic thread support [default=yes]
 231 ([=no] will override --with-threads)])],,
 232               [enable_threads=yes])
 233 AC_ARG_ENABLE(rebuilds,
 234               [AC_HELP_STRING([--disable-rebuilds],
 235                               [disable all source autogeneration rules])],,
 236               [enable_rebuilds=yes])
 237
 238 if test "x$enable_threads" != "xyes"; then
 239   enable_threads=no
 240 fi
 241
 242 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 243 if test "x$enable_gc_friendly" = "xyes"; then
 244   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 245   AC_MSG_RESULT([yes])
 246 else
 247   AC_MSG_RESULT([no])
 248 fi
 249
 250 AC_MSG_CHECKING([whether to disable memory pools])
 251 if test "x$disable_mem_pools" = "xno"; then
 252   AC_MSG_RESULT([no])
 253 else
 254   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 255   AC_SUBST(DISABLE_MEM_POOLS)
 256   AC_MSG_RESULT([yes])
 257 fi
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [Install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_STDC
 281 AM_PROG_CC_C_O
 282 AC_PROG_INSTALL
 283
 284 AC_SYS_LARGEFILE
 285
 286 PKG_PROG_PKG_CONFIG(0.16)
 287
 288 if test "x$enable_debug" = "xyes"; then
 289   if test x$cflags_set != xset ; then
 290       case " $CFLAGS " in
 291       *[[\ \    ]]-g[[\ \       ]]*) ;;
 292       *) CFLAGS="$CFLAGS -g" ;;
 293       esac
 294   fi
 295
 296   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 297 else
 298   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 299
 300   if test "x$enable_debug" = "xno"; then
 301     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 302   fi
 303 fi
 304
 305 # Ensure MSVC-compatible struct packing convention is used when
 306 # compiling for Win32 with gcc.
 307 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 308 # gcc2 uses "-fnative-struct".
 309 if test x"$glib_native_win32" = xyes; then
 310   if test x"$GCC" = xyes; then
 311     msnative_struct=''
 312     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 313     if test -z "$ac_cv_prog_CC"; then
 314       our_gcc="$CC"
 315     else
 316       our_gcc="$ac_cv_prog_CC"
 317     fi
 318     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 319       2.)
 320         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 321           msnative_struct='-fnative-struct'
 322         fi
 323         ;;
 324       *)
 325         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 326           msnative_struct='-mms-bitfields'
 327         fi
 328         ;;
 329     esac
 330     if test x"$msnative_struct" = x ; then
 331       AC_MSG_RESULT([no way])
 332       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 333     else
 334       CFLAGS="$CFLAGS $msnative_struct"
 335       AC_MSG_RESULT([${msnative_struct}])
 336     fi
 337   fi
 338 fi
 339 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 340 AC_SUBST(GLIB_EXTRA_CFLAGS)
 341
 342 AC_EXEEXT
 343
 344 # define a MAINT-like variable REBUILD which is set if Perl
 345 # and awk are found, so autogenerated sources can be rebuilt
 346 AC_PROG_AWK
 347 AC_CHECK_PROGS(PERL, [perl5 perl])
 348 # We would like indent, but don't require it.
 349 AC_CHECK_PROG(INDENT, indent, indent)
 350 REBUILD=\#
 351 if test "x$enable_rebuilds" = "xyes" && \
 352      test -n "$PERL" && \
 353      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 354      test -n "$AWK" ; then
 355   REBUILD=
 356 fi
 357 AC_SUBST(REBUILD)
 358
 359 # Need full path to Perl for glib-mkenums
 360 #
 361 if test "x$PERL" != x ; then
 362   AC_PATH_PROG(PERL_PATH, [$PERL])
 363 fi
 364 if test "x$PERL_PATH" = x ; then
 365   PERL_PATH="/usr/bin/env perl"
 366 fi
 367 AC_SUBST(PERL_PATH)
 368
 369 # Need suitable python path for greport
 370 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 371
 372
 373 dnl ***********************
 374 dnl *** Tests for iconv ***
 375 dnl ***********************
 376 dnl
 377 dnl We do this before the gettext checks, to avoid distortion
 378
 379 dnl On Windows we use a native implementation
 380
 381 if test x"$glib_native_win32" = xyes; then
 382   with_libiconv=native
 383 else
 384   AC_ARG_WITH(libiconv,
 385               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 386                               [use the libiconv library])],,
 387               [with_libiconv=maybe])
 388
 389   found_iconv=no
 390   case $with_libiconv in
 391     maybe)
 392       # Check in the C library first
 393       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394       # Check if we have GNU libiconv
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397       fi
 398       # Check if we have a iconv in -liconv, possibly from vendor
 399       if test $found_iconv = "no"; then
 400         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 401       fi
 402       ;;
 403     no)
 404       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 405       ;;
 406     gnu|yes)
 407       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 408       ;;
 409     native)
 410       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 411       ;;
 412   esac
 413
 414   if test "x$found_iconv" = "xno" ; then
 415      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 416   fi
 417 fi
 418
 419 AC_ARG_ENABLE(iconv-cache,
 420               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 421                               [cache iconv descriptors [default=auto]])],,
 422               [enable_iconv_cache=auto])
 423
 424 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 425 case $enable_iconv_cache in
 426   auto)
 427     if test $ac_cv_gnu_library_2_1 = yes; then
 428       enable_iconv_cache=no
 429     else
 430       enable_iconv_cache=yes
 431     fi
 432   ;;
 433   yes|no)
 434   ;;
 435   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 436   ;;
 437 esac
 438
 439 if test $enable_iconv_cache = yes; then
 440    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 441 fi
 442
 443 AC_MSG_RESULT($enable_iconv_cache)
 444
 445
 446 dnl
 447 dnl zlib support
 448 dnl
 449 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 450 if test "x$found_zlib" = "xno" ; then
 451   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 452   if test "x$found_zlib" = "xno" ; then
 453     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 454   fi
 455   ZLIB_LIBS='-lz'
 456   AC_SUBST(ZLIB_LIBS)
 457 fi
 458
 459 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 460 AC_SUBST(LIBFFI_CFLAGS)
 461 AC_SUBST(LIBFFI_LIBS)
 462
 463 dnl
 464 dnl gettext support
 465 dnl
 466
 467 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 468 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 469 GLIB_GNU_GETTEXT
 470
 471 if test "$gt_cv_have_gettext" != "yes" ; then
 472   AC_MSG_ERROR([
 473 *** You must have either have gettext support in your C library, or use the
 474 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 475 ])
 476 fi
 477
 478 LIBS="$INTLLIBS $LIBS"
 479
 480 GETTEXT_PACKAGE=glib20
 481 AC_SUBST(GETTEXT_PACKAGE)
 482 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 483   [Define the gettext package to be used])
 484
 485 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 486
 487 dnl
 488 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 489 dnl
 490
 491 if test x"$glib_native_win32" != xyes; then
 492   if test x$with_libiconv != xno ; then
 493     case " $INTLLIBS " in
 494     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 495     *) ICONV_LIBS="-liconv" ;;
 496     esac
 497   fi
 498 fi
 499 AC_SUBST(ICONV_LIBS)
 500
 501 case $with_libiconv in
 502   gnu)
 503     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 504     ;;
 505   native)
 506     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 507     ;;
 508 esac
 509
 510 dnl Initialize libtool
 511 LT_PREREQ([2.2])
 512 LT_INIT([disable-static win32-dll])
 513 dnl when using libtool 2.x create libtool early, because it's used in configure
 514 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 515
 516
 517 if test "x$GCC" = "xyes"; then
 518   case " $CFLAGS " in
 519   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 520   *) CFLAGS="$CFLAGS -Wall" ;;
 521   esac
 522 fi
 523
 524 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 525
 526 if test "$glib_native_win32" = "yes"; then
 527   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 528     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 529   fi
 530   if test x$enable_static = xyes; then
 531     glib_win32_static_compilation=yes
 532     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 533 #define GOBJECT_STATIC_COMPILATION 1"
 534     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 535   fi
 536 fi
 537 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 538
 539 dnl
 540 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 541 dnl
 542 if test $cross_compiling != yes ; then
 543     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 544     glib_save_LIBS=$LIBS
 545     LIBS="$LIBS -lm"
 546     AC_TRY_RUN([#include <math.h>
 547                  int main (void) { return (log(1) != log(1.)); }],
 548          AC_MSG_RESULT(none needed),
 549          glib_save_CFLAGS=$CFLAGS
 550          CFLAGS="$CFLAGS -std1"
 551          AC_TRY_RUN([#include <math.h>
 552                      int main (void) { return (log(1) != log(1.)); }],
 553              AC_MSG_RESULT(-std1),
 554              AC_MSG_RESULT()
 555              CFLAGS=$glib_save_CFLAGS
 556              AC_MSG_WARN(
 557                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 558          )
 559     )
 560     LIBS=$glib_save_LIBS
 561 fi
 562
 563 dnl NeXTStep cc seems to need this
 564 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 565 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 566   AC_MSG_RESULT(none needed),
 567   glib_save_CFLAGS=$CFLAGS
 568   CFLAGS="$CFLAGS -posix"
 569   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570     AC_MSG_RESULT(-posix),
 571     AC_MSG_RESULT()
 572     CFLAGS=$glib_save_CFLAGS
 573     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 574
 575 # Checks for header files.
 576 AC_HEADER_STDC
 577
 578 # Checks for library functions.
 579 AC_FUNC_VPRINTF
 580 AC_FUNC_ALLOCA
 581 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 582 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 583 # BSD has a qsort_r with wrong argument order
 584 AC_CACHE_CHECK([for qsort_r], glib_cv_have_qsort_r, [
 585 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 586 #define _GNU_SOURCE
 587 #include <stdlib.h>
 588
 589 static int
 590 cmp (const void *a, const void *b, void *c)
 591 {
 592   const int *ia = a;
 593   const int *ib = b;
 594
 595   if (*ia < *ib)
 596     return -1;
 597   else if (*ia > *ib)
 598     return 1;
 599   else
 600     return 0;
 601 }
 602
 603 int
 604 main (int argc, char **argv)
 605 {
 606   int arr[3] = { 1, 2, 0 };
 607   int d = 3;
 608
 609   qsort_r (arr, 3, sizeof (int), cmp, &d);
 610
 611   if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 612     return 0;
 613   else
 614     return 1;
 615 }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 616
 617 if test $glib_cv_have_qsort_r = yes ; then
 618   AC_MSG_RESULT([yes])
 619     AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 620 else
 621   AC_MSG_RESULT([no])
 622 fi
 623
 624 AC_CHECK_SIZEOF(char)
 625 AC_CHECK_SIZEOF(short)
 626 AC_CHECK_SIZEOF(long)
 627 AC_CHECK_SIZEOF(int)
 628 AC_CHECK_SIZEOF(void *)
 629 AC_CHECK_SIZEOF(long long)
 630 AC_CHECK_SIZEOF(__int64)
 631
 632 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 633   :
 634 else
 635   AC_MSG_ERROR([
 636 *** GLib requires a 64 bit type. You might want to consider
 637 *** using the GNU C compiler.
 638 ])
 639 fi
 640
 641 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 642         # long long is a 64 bit integer.
 643         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 644         AC_CACHE_VAL(glib_cv_long_long_format,[
 645                 for format in ll q I64; do
 646                   AC_TRY_RUN([#include <stdio.h>
 647                         int main()
 648                         {
 649                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 650                           char buffer[1000];
 651                           sprintf (buffer, "%${format}u", a);
 652                           sscanf (buffer, "%${format}u", &b);
 653                           exit (b!=a);
 654                         }
 655                         ],
 656                         [glib_cv_long_long_format=${format}
 657                         break],
 658                         [],[:])
 659                 done])
 660         if test -n "$glib_cv_long_long_format"; then
 661           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 662           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 663           if test x"$glib_cv_long_long_format" = xI64; then
 664             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 665           fi
 666         else
 667           AC_MSG_RESULT(none)
 668         fi
 669 elif test x$ac_cv_sizeof___int64 = x8; then
 670         # __int64 is a 64 bit integer.
 671         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 672         # We know this is MSVCRT.DLL, and what the formats are
 673         glib_cv_long_long_format=I64
 674         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 675         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 676         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 677 fi
 678
 679 dnl long doubles were not used, and a portability problem
 680 dnl AC_C_LONG_DOUBLE
 681 AC_C_CONST
 682
 683 dnl ok, here we try to check whether the systems prototypes for
 684 dnl malloc and friends actually match the prototypes provided
 685 dnl by gmem.h (keep in sync). i currently only know how to check
 686 dnl this reliably with gcc (-Werror), improvements for other
 687 dnl compilers are apprechiated.
 688 SANE_MALLOC_PROTOS=no
 689 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 690 glib_save_CFLAGS=$CFLAGS
 691 if test "x$GCC" = "xyes"; then
 692   CFLAGS="$CFLAGS -Werror"
 693   AC_TRY_COMPILE([#include <stdlib.h>], [
 694     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 695     void* (*my_malloc_p)  (size_t)         = malloc;
 696     void  (*my_free_p)    (void*)          = free;
 697     void* (*my_realloc_p) (void*, size_t)  = realloc;
 698     my_calloc_p = 0;
 699     my_malloc_p = 0;
 700     my_free_p = 0;
 701     my_realloc_p = 0;
 702   ],
 703     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 704       [Define if you have correct malloc prototypes])
 705     SANE_MALLOC_PROTOS=yes)
 706 fi
 707 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 708 CFLAGS=$glib_save_CFLAGS
 709
 710 dnl
 711 dnl check in which direction the stack grows
 712 dnl
 713 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 714         AC_TRY_RUN([
 715         volatile int *a = 0, *b = 0;
 716         void foo (void);
 717         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 718         void foo (void) { volatile int x = 5; b = &x; }
 719         ],
 720         glib_cv_stack_grows=no
 721         ,
 722         glib_cv_stack_grows=yes
 723         ,)
 724 ])
 725
 726 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 727 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 728 dnl actually supported.
 729 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 730         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 731         __inline int foo () { return 0; }
 732         int main () { return foo (); }
 733         ]])],
 734         glib_cv_has__inline=yes
 735         ,
 736         glib_cv_has__inline=no
 737         ,)
 738 ])
 739 case x$glib_cv_has__inline in
 740 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 741 esac
 742 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 743         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 744         __inline__ int foo () { return 0; }
 745         int main () { return foo (); }
 746         ]])],
 747         glib_cv_has__inline__=yes
 748         ,
 749         glib_cv_has__inline__=no
 750         ,)
 751 ])
 752 case x$glib_cv_has__inline__ in
 753 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 754 esac
 755 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 756         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 757         #undef inline
 758         inline int foo () { return 0; }
 759         int main () { return foo (); }
 760         ]])],
 761         glib_cv_hasinline=yes
 762         ,
 763         glib_cv_hasinline=no
 764         ,)
 765 ])
 766 case x$glib_cv_hasinline in
 767 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 768 esac
 769
 770 # if we can use inline functions in headers
 771 AC_MSG_CHECKING(if inline functions in headers work)
 772 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 773 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 774 #  undef inline
 775 #  define inline __inline__
 776 #elif !defined (G_HAVE_INLINE)
 777 #  undef inline
 778 #  if defined (G_HAVE___INLINE__)
 779 #    define inline __inline__
 780 #  elif defined (G_HAVE___INLINE)
 781 #    define inline __inline
 782 #  endif
 783 #endif
 784
 785 int glib_test_func2 (int);
 786
 787 static inline int
 788 glib_test_func1 (void) {
 789   return glib_test_func2 (1);
 790 }
 791
 792 int
 793 main (void) {
 794   int i = 1;
 795 }]])],[g_can_inline=yes],[g_can_inline=no])
 796 AC_MSG_RESULT($g_can_inline)
 797
 798 dnl *** check for working do while(0) macros ***
 799 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 800         AC_TRY_COMPILE([],[
 801         #define STMT_START do
 802         #define STMT_END while(0)
 803         #define STMT_TEST STMT_START { i = 0; } STMT_END
 804         int main(void) { int i = 1; STMT_TEST; return i; }],
 805         [g_cv_support_dowhile_macros=yes],
 806         [g_cv_support_dowhile_macros=no],
 807         [g_cv_support_dowhile_macros=yes])
 808 ])
 809 if test x$g_cv_support_dowhile_macros = xyes; then
 810   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 811 fi
 812
 813 # check for flavours of varargs macros
 814 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 815 AC_TRY_COMPILE([],[
 816 int a(int p1, int p2, int p3);
 817 #define call_a(...) a(1,__VA_ARGS__)
 818 call_a(2,3);
 819 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 820 AC_MSG_RESULT($g_have_iso_c_varargs)
 821
 822 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 823 if test "$CXX" = ""; then
 824 dnl No C++ compiler
 825   g_have_iso_cxx_varargs=no
 826 else
 827   AC_LANG_CPLUSPLUS
 828   AC_TRY_COMPILE([],[
 829 int a(int p1, int p2, int p3);
 830 #define call_a(...) a(1,__VA_ARGS__)
 831 call_a(2,3);
 832 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 833   AC_LANG_C
 834 fi
 835 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 836
 837 AC_MSG_CHECKING(for GNUC varargs macros)
 838 AC_TRY_COMPILE([],[
 839 int a(int p1, int p2, int p3);
 840 #define call_a(params...) a(1,params)
 841 call_a(2,3);
 842 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 843 AC_MSG_RESULT($g_have_gnuc_varargs)
 844
 845 # check for GNUC visibility support
 846 AC_MSG_CHECKING(for GNUC visibility attribute)
 847 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 848 void
 849 __attribute__ ((visibility ("hidden")))
 850      f_hidden (void)
 851 {
 852 }
 853 void
 854 __attribute__ ((visibility ("internal")))
 855      f_internal (void)
 856 {
 857 }
 858 void
 859 __attribute__ ((visibility ("protected")))
 860      f_protected (void)
 861 {
 862 }
 863 void
 864 __attribute__ ((visibility ("default")))
 865      f_default (void)
 866 {
 867 }
 868 int main (int argc, char **argv)
 869 {
 870         f_hidden();
 871         f_internal();
 872         f_protected();
 873         f_default();
 874         return 0;
 875 }
 876 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 877 AC_MSG_RESULT($g_have_gnuc_visibility)
 878 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 879
 880 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 881 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 882 #else
 883 # include "error: this is not Sun Studio."
 884 #endif
 885 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 886 AC_MSG_RESULT($g_have_sunstudio_visibility)
 887 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 888
 889 # check for bytesex stuff
 890 AC_C_BIGENDIAN
 891 if test x$ac_cv_c_bigendian = xuniversal ; then
 892 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 893 #else
 894 #error Not a big endian.
 895 #endif],
 896     ac_cv_c_bigendian=yes
 897     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 898 #else
 899 #error Not a little endian.
 900 #endif],
 901     ac_cv_c_bigendian=no
 902     ,AC_MSG_WARN([Could not determine endianness.])))
 903 fi
 904
 905
 906 # check for header files
 907 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 908 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 909 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 910 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 911 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 912 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 913 AC_CHECK_HEADERS([linux/magic.h])
 914
 915 # check for structure fields
 916 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 917 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 918 #include <sys/stat.h>
 919 #include <unistd.h>
 920 #ifdef HAVE_SYS_STATFS_H
 921 #include <sys/statfs.h>
 922 #endif
 923 #ifdef HAVE_SYS_PARAM_H
 924 #include <sys/param.h>
 925 #endif
 926 #ifdef HAVE_SYS_MOUNT_H
 927 #include <sys/mount.h>
 928 #endif])
 929 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 930 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 931 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 932
 933 # Checks for libcharset
 934 AM_LANGINFO_CODESET
 935 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 936 AC_CHECK_FUNCS(setlocale)
 937
 938 # check additional type sizes
 939 AC_CHECK_SIZEOF(size_t)
 940
 941 dnl Try to figure out whether gsize, gssize should be long or int
 942 AC_MSG_CHECKING([for the appropriate definition for size_t])
 943
 944 case $ac_cv_sizeof_size_t in
 945   $ac_cv_sizeof_short)
 946       glib_size_type=short
 947       ;;
 948   $ac_cv_sizeof_int)
 949       glib_size_type=int
 950       ;;
 951   $ac_cv_sizeof_long)
 952       glib_size_type=long
 953       ;;
 954   $ac_cv_sizeof_long_long)
 955       glib_size_type='long long'
 956       ;;
 957   $ac_cv_sizeof__int64)
 958       glib_size_type='__int64'
 959       ;;
 960   *)  AC_MSG_ERROR([No type matching size_t in size])
 961       ;;
 962 esac
 963
 964 dnl If int/long are the same size, we see which one produces
 965 dnl warnings when used in the location as size_t. (This matters
 966 dnl on AIX with xlc)
 967 dnl
 968 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 969    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 970   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 971 #if defined(_AIX) && !defined(__GNUC__)
 972 #pragma options langlvl=stdc89
 973 #endif
 974 #include <stddef.h>
 975 int main ()
 976 {
 977   size_t s = 1;
 978   unsigned int *size_int = &s;
 979   return (int)*size_int;
 980 }
 981     ]])],glib_size_type=int,
 982       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 983 #if defined(_AIX) && !defined(__GNUC__)
 984 #pragma options langlvl=stdc89
 985 #endif
 986 #include <stddef.h>
 987 int main ()
 988 {
 989    size_t s = 1;
 990    unsigned long *size_long = &s;
 991    return (int)*size_long;
 992 }
 993         ]])],glib_size_type=long)])
 994 fi
 995
 996 AC_MSG_RESULT(unsigned $glib_size_type)
 997
 998 # Check for some functions
 999 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1000 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
1001 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1002 # Check for high-resolution sleep functions
1003 AC_CHECK_FUNCS(splice)
1004
1005 AC_CHECK_HEADERS(crt_externs.h)
1006 AC_CHECK_FUNCS(_NSGetEnviron)
1007
1008 AC_FUNC_VSNPRINTF_C99
1009 AC_FUNC_PRINTF_UNIX98
1010
1011 # Internet address families
1012 if test $glib_native_win32 = yes; then
1013   glib_inet_includes=["
1014 #include <winsock2.h>
1015   "]
1016 else
1017   glib_inet_includes=["
1018 #include <sys/types.h>
1019 #include <sys/socket.h>
1020   "]
1021 fi
1022
1023 glib_failed=false
1024 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1025 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1026 # winsock defines this even though it doesn't support it
1027 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1028 if $glib_failed ; then
1029   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1030 fi
1031
1032 glib_failed=false
1033 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1034 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1035 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1036 if $glib_failed ; then
1037   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1038 fi
1039
1040 AC_CHECK_FUNCS(getprotobyname_r endservent)
1041 AC_CHECK_HEADERS([netdb.h wspiapi.h])
1042
1043 # For gio/libasyncns
1044 if test $glib_native_win32 = no; then
1045   AC_CHECK_FUNCS(strndup setresuid setreuid)
1046   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1047
1048   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1049   AC_MSG_CHECKING([for res_query])
1050   AC_TRY_LINK([#include <sys/types.h>
1051 #include <netinet/in.h>
1052 #include <arpa/nameser.h>
1053 #include <resolv.h>],
1054               [res_query("test", 0, 0, (void *)0, 0);],
1055               [AC_MSG_RESULT([yes])],
1056               [save_libs="$LIBS"
1057                LIBS="-lresolv $LIBS"
1058                AC_TRY_LINK([#include <sys/types.h>
1059 #include <netinet/in.h>
1060 #include <arpa/nameser.h>
1061 #include <resolv.h>],
1062                            [res_query("test", 0, 0, (void *)0, 0);],
1063                            [AC_MSG_RESULT([in -lresolv])
1064                             LIBASYNCNS_LIBADD="-lresolv"],
1065                            [LIBS="-lbind $save_libs"
1066                             AC_TRY_LINK([#include <resolv.h>],
1067                                         [res_query("test", 0, 0, (void *)0, 0);],
1068                                         [AC_MSG_RESULT([in -lbind])
1069                                          LIBASYNCNS_LIBADD="-lbind"],
1070                                         [AC_MSG_ERROR(not found)])])
1071                LIBS="$save_libs"])
1072   AC_SUBST(LIBASYNCNS_LIBADD)
1073 fi
1074
1075 case $host in
1076   *-*-solaris* )
1077      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1078      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1079      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1080      ;;
1081 esac
1082
1083 dnl
1084 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1085 dnl
1086 if test "$ac_cv_func_statfs" = yes ; then
1087   AC_MSG_CHECKING([number of arguments to statfs()])
1088   AC_TRY_COMPILE([#include <unistd.h>
1089   #ifdef HAVE_SYS_PARAM_H
1090   #include <sys/param.h>
1091   #endif
1092   #ifdef HAVE_SYS_VFS_H
1093   #include <sys/vfs.h>
1094   #endif
1095   #ifdef HAVE_SYS_MOUNT_H
1096   #include <sys/mount.h>
1097   #endif
1098   #ifdef HAVE_SYS_STATFS_H
1099   #include <sys/statfs.h>
1100   #endif], [struct statfs st;
1101   statfs(NULL, &st);],[
1102     AC_MSG_RESULT([2])
1103     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1104     AC_TRY_COMPILE([#include <unistd.h>
1105   #ifdef HAVE_SYS_PARAM_H
1106   #include <sys/param.h>
1107   #endif
1108   #ifdef HAVE_SYS_VFS_H
1109   #include <sys/vfs.h>
1110   #endif
1111   #ifdef HAVE_SYS_MOUNT_H
1112   #include <sys/mount.h>
1113   #endif
1114   #ifdef HAVE_SYS_STATFS_H
1115   #include <sys/statfs.h>
1116   #endif], [struct statfs st;
1117   statfs(NULL, &st, sizeof (st), 0);],[
1118       AC_MSG_RESULT([4])
1119       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1120       AC_MSG_RESULT(unknown)
1121       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1122 fi
1123
1124 #
1125 # Check whether to use an included printf
1126 #
1127
1128 AC_ARG_ENABLE(included-printf,
1129               [AC_HELP_STRING([--enable-included-printf],
1130                               [use included printf [default=auto]])],
1131               enable_included_printf="$enableval")
1132
1133 need_included_printf=no
1134 if test "x$enable_included_printf" = "xyes" ; then
1135   need_included_printf=yes
1136 fi
1137 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1138   need_included_printf=yes
1139 fi
1140 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1141   need_included_printf=yes
1142 fi
1143 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1144    test -z "$glib_cv_long_long_format" ; then
1145   need_included_printf=yes
1146 fi
1147
1148 if test "x$enable_included_printf" = "xno" &&
1149    test "x$need_included_printf" = "xyes" ; then
1150   AC_MSG_ERROR([
1151 *** Your C library's printf doesn't appear to have the features that
1152 *** GLib needs, but you specified --enable-included-printf=no.])
1153 fi
1154
1155 enable_included_printf=$need_included_printf
1156
1157 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1158 if test "$enable_included_printf" != "yes" ; then
1159   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1160 else
1161   if test -z "$glib_cv_long_long_format" ; then
1162     glib_cv_long_long_format="ll"
1163   fi
1164   AC_DEFINE(HAVE_VASPRINTF,1)
1165 fi
1166
1167 # Checks needed for gnulib vasnprintf
1168 bh_C_SIGNED
1169 jm_AC_TYPE_LONG_LONG
1170 gt_TYPE_LONGDOUBLE
1171 gt_TYPE_WCHAR_T
1172 gt_TYPE_WINT_T
1173 AC_TYPE_SIZE_T
1174 AC_CHECK_TYPES(ptrdiff_t)
1175 jm_AC_TYPE_INTMAX_T
1176 AC_CHECK_FUNCS([snprintf wcslen])
1177 AC_FUNC_SNPRINTF_C99
1178
1179 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1180 # The check is borrowed from the PERL Configure script.
1181 if test "$ac_cv_func_memmove" != "yes"; then
1182   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1183     glib_cv_working_bcopy,[AC_TRY_RUN([
1184       int main() {
1185         char buf[128], abc[128], *b;
1186         int len, off, align;
1187         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1188         for (align = 7; align >= 0; align--) {
1189           for (len = 36; len; len--) {
1190             b = buf+align; bcopy(abc, b, len);
1191             for (off = 1; off <= len; off++) {
1192               bcopy(b, b+off, len); bcopy(b+off, b, len);
1193                 if (bcmp(b, abc, len)) return(1);
1194             }
1195           }
1196         }
1197         return(0);
1198       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1199
1200   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1201   if test "$glib_cv_working_bcopy" = "yes"; then
1202     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1203   fi
1204 fi
1205
1206 # Check for sys_errlist
1207 AC_MSG_CHECKING(for sys_errlist)
1208 AC_TRY_LINK(, [
1209 extern char *sys_errlist[];
1210 extern int sys_nerr;
1211 sys_errlist[sys_nerr-1][0] = 0;
1212 ], glib_ok=yes, glib_ok=no)
1213 AC_MSG_RESULT($glib_ok)
1214 if test "$glib_ok" = "no"; then
1215     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1216 fi
1217
1218 # Check for sys_siglist
1219 AC_MSG_CHECKING(for sys_siglist)
1220 AC_TRY_LINK(, [
1221 extern char *sys_siglist[];
1222 exit (sys_siglist[0]);
1223 ], glib_ok=yes, glib_ok=no)
1224 AC_MSG_RESULT($glib_ok)
1225 if test "$glib_ok" = "no"; then
1226     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1227 fi
1228
1229 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1230 AC_MSG_CHECKING(for sys_siglist declaration)
1231 AC_TRY_COMPILE([#include <signal.h>], [
1232 strlen (sys_siglist[0]);
1233 ], glib_ok=yes, glib_ok=no)
1234 AC_MSG_RESULT($glib_ok)
1235 if test "$glib_ok" = "no"; then
1236     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1237 fi
1238
1239 # Check if <sys/select.h> needs to be included for fd_set
1240 AC_MSG_CHECKING([for fd_set])
1241 AC_TRY_COMPILE([#include <sys/types.h>],
1242         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1243 if test "$gtk_ok" = "yes"; then
1244     AC_MSG_RESULT([yes, found in sys/types.h])
1245 else
1246     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1247     if test "$gtk_ok" = "yes"; then
1248         # *** FIXME: give it a different name
1249         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1250         AC_MSG_RESULT([yes, found in sys/select.h])
1251     else
1252         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1253         AC_MSG_RESULT(no)
1254     fi
1255 fi
1256
1257 dnl *** check for sane realloc() ***
1258 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1259         AC_TRY_RUN([#include <stdlib.h>
1260         int main() {
1261           return realloc (0, sizeof (int)) == 0;
1262         }],
1263         [glib_cv_sane_realloc=yes],
1264         [glib_cv_sane_realloc=no],
1265         [glib_cv_sane_realloc=yes])
1266 ])
1267 if test x$glib_cv_sane_realloc = xyes; then
1268   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1269 fi
1270
1271 dnl Check for nl_langinfo and CODESET
1272 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1273         AC_TRY_COMPILE([#include <langinfo.h>],
1274                 [char *codeset = nl_langinfo (CODESET);],
1275                 [glib_cv_langinfo_codeset=yes],
1276                 [glib_cv_langinfo_codeset=no])])
1277 if test x$glib_cv_langinfo_codeset = xyes; then
1278   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1279 fi
1280
1281 dnl ****************************************
1282 dnl *** posix_memalign                   ***
1283 dnl ****************************************
1284 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1285 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1286     glib_cv_compliant_posix_memalign=0
1287     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1288         AC_TRY_RUN([
1289                 #define _XOPEN_SOURCE 600
1290                 #include <stdlib.h> /* posix_memalign() should be defined here */
1291                 /* some systems break if #include <malloc.h> used */
1292                 static void test_memalign (size_t boundary, size_t size) {
1293                     void *mem = 0;
1294                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1295                         exit (1);
1296                     else
1297                       free (mem);
1298                 }
1299                 int main() {
1300                     test_memalign (  128,   128 - 2 * sizeof (void*));
1301                     test_memalign (  256,   256 - 2 * sizeof (void*));
1302                     test_memalign (  512,   512 - 2 * sizeof (void*));
1303                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1304                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1305                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1306                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1307                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1308                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1309                     exit (0); /* success */
1310                 }
1311                 ],
1312             [glib_cv_compliant_posix_memalign=1], [], [:])
1313       :
1314     fi
1315     ])
1316 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1317     AC_MSG_RESULT(yes)
1318     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1319 else
1320     AC_MSG_RESULT(no)
1321 fi
1322
1323
1324 dnl ****************************************
1325 dnl *** strlcpy/strlcat                  ***
1326 dnl ****************************************
1327 # Check for strlcpy
1328 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1329 AC_TRY_RUN([#include <stdlib.h>
1330 #include <string.h>
1331 int main() {
1332   char p[10];
1333   (void) strlcpy (p, "hi", 10);
1334   if (strlcat (p, "bye", 0) != 3)
1335     return 1;
1336   return 0;
1337 }], glib_cv_have_strlcpy=yes,
1338     glib_cv_have_strlcpy=no,
1339     glib_cv_have_strlcpy=no)])
1340 if test "$glib_cv_have_strlcpy" = "yes"; then
1341     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1342 fi
1343
1344
1345 dnl **********************
1346 dnl *** va_copy checks ***
1347 dnl **********************
1348 dnl we currently check for all three va_copy possibilities, so we get
1349 dnl all results in config.log for bug reports.
1350 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1351         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1352 #include <stdlib.h>
1353         void f (int i, ...) {
1354         va_list args1, args2;
1355         va_start (args1, i);
1356         va_copy (args2, args1);
1357         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1358           exit (1);
1359         va_end (args1); va_end (args2);
1360         }
1361         int main() {
1362           f (0, 42);
1363           return 0;
1364         }]])],
1365         [glib_cv_va_copy=yes],
1366         [glib_cv_va_copy=no])
1367 ])
1368 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1369         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1370 #include <stdlib.h>
1371         void f (int i, ...) {
1372         va_list args1, args2;
1373         va_start (args1, i);
1374         __va_copy (args2, args1);
1375         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1376           exit (1);
1377         va_end (args1); va_end (args2);
1378         }
1379         int main() {
1380           f (0, 42);
1381           return 0;
1382         }]])],
1383         [glib_cv___va_copy=yes],
1384         [glib_cv___va_copy=no])
1385 ])
1386
1387 if test "x$glib_cv_va_copy" = "xyes"; then
1388   g_va_copy_func=va_copy
1389 else if test "x$glib_cv___va_copy" = "xyes"; then
1390   g_va_copy_func=__va_copy
1391 fi
1392 fi
1393
1394 if test -n "$g_va_copy_func"; then
1395   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1396 fi
1397
1398 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1399         AC_TRY_RUN([#include <stdarg.h>
1400 #include <stdlib.h>
1401         void f (int i, ...) {
1402         va_list args1, args2;
1403         va_start (args1, i);
1404         args2 = args1;
1405         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1406           exit (1);
1407         va_end (args1); va_end (args2);
1408         }
1409         int main() {
1410           f (0, 42);
1411           return 0;
1412         }],
1413         [glib_cv_va_val_copy=yes],
1414         [glib_cv_va_val_copy=no],
1415         [glib_cv_va_val_copy=yes])
1416 ])
1417
1418 if test "x$glib_cv_va_val_copy" = "xno"; then
1419   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1420 fi
1421
1422 dnl ***********************
1423 dnl *** g_module checks ***
1424 dnl ***********************
1425 G_MODULE_LIBS=
1426 G_MODULE_LIBS_EXTRA=
1427 G_MODULE_PLUGIN_LIBS=
1428 if test x"$glib_native_win32" = xyes; then
1429   dnl No use for this on Win32
1430   G_MODULE_LDFLAGS=
1431 else
1432   export SED
1433   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1434 fi
1435 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1436 G_MODULE_NEED_USCORE=0
1437 G_MODULE_BROKEN_RTLD_GLOBAL=0
1438 G_MODULE_HAVE_DLERROR=0
1439 dnl *** force native WIN32 shared lib loader
1440 if test -z "$G_MODULE_IMPL"; then
1441   case "$host" in
1442   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1443   esac
1444 fi
1445 dnl *** force native AIX library loader
1446 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1447 if test -z "$G_MODULE_IMPL"; then
1448   case "$host" in
1449   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1450   esac
1451 fi
1452 dnl *** dlopen() and dlsym() in system libraries
1453 if test -z "$G_MODULE_IMPL"; then
1454         AC_CHECK_FUNC(dlopen,
1455                       [AC_CHECK_FUNC(dlsym,
1456                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1457                       [])
1458 fi
1459 dnl *** load_image (BeOS)
1460 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1461   AC_CHECK_LIB(root, load_image,
1462       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1463       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1464       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1465       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1466       [])
1467 fi
1468 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1469 if test -z "$G_MODULE_IMPL"; then
1470         AC_CHECK_FUNC(NSLinkModule,
1471                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1472                        G_MODULE_NEED_USCORE=1],
1473                       [])
1474 fi
1475 dnl *** dlopen() and dlsym() in libdl
1476 if test -z "$G_MODULE_IMPL"; then
1477         AC_CHECK_LIB(dl, dlopen,
1478                      [AC_CHECK_LIB(dl, dlsym,
1479                                    [G_MODULE_LIBS=-ldl
1480                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1481                      [])
1482 fi
1483 dnl *** shl_load() in libdld (HP-UX)
1484 if test -z "$G_MODULE_IMPL"; then
1485         AC_CHECK_LIB(dld, shl_load,
1486                 [G_MODULE_LIBS=-ldld
1487                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1488                 [])
1489 fi
1490 dnl *** additional checks for G_MODULE_IMPL_DL
1491 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1492         LIBS_orig="$LIBS"
1493         LDFLAGS_orig="$LDFLAGS"
1494         LIBS="$G_MODULE_LIBS $LIBS"
1495         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1496 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1497         echo "void glib_plugin_test(void) { }" > plugin.c
1498         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1499                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1500         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1501                 glib_cv_rtldglobal_broken,[
1502                 AC_TRY_RUN([
1503 #include <dlfcn.h>
1504 #ifndef RTLD_GLOBAL
1505 #  define RTLD_GLOBAL 0
1506 #endif
1507 #ifndef RTLD_LAZY
1508 #  define RTLD_LAZY 0
1509 #endif
1510 int glib_plugin_test;
1511 int main () {
1512     void *handle, *global, *local;
1513     global = &glib_plugin_test;
1514     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1515     if (!handle) return 0;
1516     local = dlsym (handle, "glib_plugin_test");
1517     return global == local;
1518 }                       ],
1519                         [glib_cv_rtldglobal_broken=no],
1520                         [glib_cv_rtldglobal_broken=yes],
1521                         [glib_cv_rtldglobal_broken=no])
1522                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1523                 rmdir .libs 2>/dev/null
1524         ])
1525         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1526                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1527         else
1528                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1529         fi
1530 dnl *** check whether we need preceeding underscores
1531         AC_CACHE_CHECK([for preceeding underscore in symbols],
1532                 glib_cv_uscore,[
1533                 AC_TRY_RUN([#include <dlfcn.h>
1534                 int glib_underscore_test (void) { return 42; }
1535                 int main() {
1536                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1537                   handle = dlopen ((void*)0, 0);
1538                   if (handle) {
1539                     f1 = dlsym (handle, "glib_underscore_test");
1540                     f2 = dlsym (handle, "_glib_underscore_test");
1541                   } return (!f2 || f1);
1542                 }],
1543                         [glib_cv_uscore=yes],
1544                         [glib_cv_uscore=no],
1545                         [])
1546                 rm -f plugin.c plugin.$ac_objext plugin.lo
1547         ])
1548         GLIB_ASSERT_SET(glib_cv_uscore)
1549         if test "x$glib_cv_uscore" = "xyes"; then
1550                 G_MODULE_NEED_USCORE=1
1551         else
1552                 G_MODULE_NEED_USCORE=0
1553         fi
1554
1555         LDFLAGS="$LDFLAGS_orig"
1556 dnl *** check for having dlerror()
1557         AC_CHECK_FUNC(dlerror,
1558                 [G_MODULE_HAVE_DLERROR=1],
1559                 [G_MODULE_HAVE_DLERROR=0])
1560         LIBS="$LIBS_orig"
1561 fi
1562 dnl *** done, have we got an implementation?
1563 if test -z "$G_MODULE_IMPL"; then
1564         G_MODULE_IMPL=0
1565         G_MODULE_SUPPORTED=false
1566 else
1567         G_MODULE_SUPPORTED=true
1568 fi
1569
1570 AC_MSG_CHECKING(for the suffix of module shared libraries)
1571 export SED
1572 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1573 eval $shrext_cmds
1574 module=yes eval std_shrext=$shrext_cmds
1575 # chop the initial dot
1576 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1577 AC_MSG_RESULT(.$glib_gmodule_suffix)
1578 # any reason it may fail?
1579 if test "x$glib_gmodule_suffix" = x; then
1580         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1581 fi
1582
1583 AC_SUBST(G_MODULE_SUPPORTED)
1584 AC_SUBST(G_MODULE_IMPL)
1585 AC_SUBST(G_MODULE_LIBS)
1586 AC_SUBST(G_MODULE_LIBS_EXTRA)
1587 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1588 AC_SUBST(G_MODULE_LDFLAGS)
1589 AC_SUBST(G_MODULE_HAVE_DLERROR)
1590 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1591 AC_SUBST(G_MODULE_NEED_USCORE)
1592 AC_SUBST(GLIB_DEBUG_FLAGS)
1593
1594 dnl **********************
1595 dnl *** g_spawn checks ***
1596 dnl **********************
1597
1598 AC_MSG_CHECKING(for gspawn implementation)
1599 case "$host" in
1600   *-*-mingw*)
1601     GSPAWN=gspawn-win32.lo
1602     ;;
1603   *)
1604     GSPAWN=gspawn.lo
1605     ;;
1606 esac
1607 AC_MSG_RESULT($GSPAWN)
1608 AC_SUBST(GSPAWN)
1609
1610 dnl *************************
1611 dnl *** GIOChannel checks ***
1612 dnl *************************
1613
1614 AC_MSG_CHECKING(for GIOChannel implementation)
1615 case "$host" in
1616   *-*-mingw*)
1617     GIO=giowin32.lo
1618     ;;
1619   *)
1620     GIO=giounix.lo
1621     ;;
1622 esac
1623 AC_MSG_RESULT($GIO)
1624 AC_SUBST(GIO)
1625
1626 dnl *********************************
1627 dnl *** Directory for GIO modules ***
1628 dnl *********************************
1629
1630 AC_ARG_WITH(gio-module-dir,
1631            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1632                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1633            [],
1634            [with_gio_module_dir='${libdir}/gio/modules'])
1635 GIO_MODULE_DIR=$with_gio_module_dir
1636 AC_SUBST(GIO_MODULE_DIR)
1637
1638 dnl **********************************
1639 dnl *** Check for libselinux (GIO) ***
1640 dnl **********************************
1641 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1642 msg_selinux=no
1643 SELINUX_LIBS=
1644 if test "x$enable_selinux" != "xno"; then
1645
1646  AC_CHECK_LIB(selinux, is_selinux_enabled,
1647    [AC_CHECK_HEADERS(selinux/selinux.h,
1648      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1649        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1650         SELINUX_LIBS="-lselinux"
1651         msg_selinux=yes])
1652      ])
1653    ])
1654 fi
1655 AC_SUBST(SELINUX_LIBS)
1656
1657 dnl *****************************
1658 dnl ** Check for inotify (GIO) **
1659 dnl *****************************
1660 inotify_support=no
1661 AC_CHECK_HEADERS([sys/inotify.h],
1662 [
1663         inotify_support=yes
1664         AC_CHECK_FUNCS(inotify_init1)
1665 ])
1666
1667 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1668
1669 dnl *********************************
1670 dnl ** Check for Solaris FEN (GIO) **
1671 dnl *********************************
1672 fen_support=no
1673 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1674 #include <port.h>
1675 #ifndef PORT_SOURCE_FILE
1676 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1677 #endif
1678 int main() { return 0; } ]])],
1679 [
1680         fen_support=yes
1681 ],)
1682
1683 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1684
1685 dnl ****************************
1686 dnl *** Checks for FAM (GIO) ***
1687 dnl ****************************
1688
1689 should_disable_fam=no
1690
1691 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1692                          [
1693                                 if test "x$enable_fam" = "xno"; then
1694                                         should_disable_fam=yes
1695                                         echo "Not building FAM support"
1696                                 fi
1697                          ]
1698                          )
1699 fam_support=no
1700 FAM_LIBS=
1701 if test "x$should_disable_fam" = "xno"; then
1702 AC_CHECK_LIB(fam, FAMOpen,
1703   [AC_CHECK_HEADERS(fam.h,
1704     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1705      AC_CHECK_LIB(fam, FAMNoExists,
1706                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1707      FAM_LIBS="-lfam"]
1708      fam_support=yes,
1709     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1710   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1711 AC_SUBST(FAM_LIBS)
1712 fi
1713 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1714
1715
1716 dnl *****************************
1717 dnl *** Check for xattr (GIO) ***
1718 dnl *****************************
1719 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1720 msg_xattr=no
1721 XATTR_LIBS=
1722 if test "x$enable_xattr" != "xno"; then
1723
1724 dnl either glibc or libattr can provide xattr support
1725
1726 dnl for both of them, we check for getxattr being in
1727 dnl the library and a valid xattr header.
1728
1729 dnl try glibc
1730  AC_CHECK_LIB(c, getxattr,
1731    [AC_CHECK_HEADERS(sys/xattr.h,
1732      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1733       msg_xattr=yes])
1734    ])
1735
1736   if test "x$msg_xattr" != "xyes"; then
1737 dnl   failure. try libattr
1738    AC_CHECK_LIB(attr, getxattr,
1739       [AC_CHECK_HEADERS(attr/xattr.h,
1740        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1741         XATTR_LIBS="-lattr"
1742         msg_xattr=yes])
1743       ])
1744   fi
1745
1746   if test "x$msg_xattr" = "xyes"; then
1747     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1748     AC_TRY_COMPILE([
1749       #include <stdio.h>
1750       #ifdef HAVE_SYS_TYPES_H
1751       #include <sys/types.h>
1752       #endif
1753       #ifdef HAVE_SYS_XATTR_H
1754       #include <sys/xattr.h>
1755       #elif HAVE_ATTR_XATTR_H
1756       #include <attr/xattr.h>
1757       #endif
1758     ],
1759     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1760     [
1761       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1762       AC_MSG_RESULT([yes])
1763     ],
1764     [AC_MSG_RESULT([no])]
1765     )
1766   fi
1767
1768 fi
1769 AC_SUBST(XATTR_LIBS)
1770
1771 dnl ****************************************
1772 dnl *** platform dependent source checks ***
1773 dnl ****************************************
1774
1775 AC_MSG_CHECKING(for platform-dependent source)
1776 case "$host" in
1777   *-*-cygwin*|*-*-mingw*)
1778     PLATFORMDEP=gwin32.lo
1779     ;;
1780   *)
1781     PLATFORMDEP=
1782     ;;
1783 esac
1784 AC_MSG_RESULT($PLATFORMDEP)
1785 AC_SUBST(PLATFORMDEP)
1786
1787 AC_MSG_CHECKING([whether to compile timeloop])
1788 case "$host" in
1789   *-*-cygwin*|*-*-mingw*|*-*-minix)
1790     enable_timeloop=no
1791     ;;
1792   *)
1793     enable_timeloop=yes
1794     ;;
1795 esac
1796 AC_MSG_RESULT($enable_timeloop)
1797 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1798
1799 AC_MSG_CHECKING([if building for some Win32 platform])
1800 case "$host" in
1801   *-*-mingw*|*-*-cygwin*)
1802     platform_win32=yes
1803     ;;
1804   *)
1805     platform_win32=no
1806     ;;
1807 esac
1808 AC_MSG_RESULT($platform_win32)
1809 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1810
1811 dnl ***********************
1812 dnl *** g_thread checks ***
1813 dnl ***********************
1814
1815 AC_ARG_WITH(threads,
1816            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1817                            [specify a thread implementation to use])],
1818            [if test "x$with_threads" = x; then
1819                 want_threads=yes
1820             else
1821                 want_threads=$with_threads
1822             fi],
1823            [want_threads=yes])
1824 if test "x$enable_threads" = "xno"; then
1825         want_threads=no
1826 fi
1827
1828 dnl error and warning message
1829 dnl *************************
1830
1831 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1832                 computer. GLib will not have a default thread implementation."
1833
1834 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1835                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1836                 compilation now, but then your programs might not work.
1837                 Please provide information on how it is done on your system."
1838
1839 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1840                 "
1841
1842 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1843                 provide information on your thread implementation.
1844                 You can also run 'configure --disable-threads'
1845                 to compile without thread support."
1846
1847 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1848                 functions will not be MT-safe during their first call because
1849                 there is no working 'getpwuid_r' on your system."
1850
1851 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1852                 because there is no 'localtime_r' on your system."
1853
1854 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1855                 crude surrogate will be used. If you happen to know a
1856                 yield function for your system, please inform the GLib
1857                 developers."
1858
1859 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1860                 threads on your system. Thus threads can only have the default
1861                 priority. If you happen to know these main/max
1862                 priorities, please inform the GLib developers."
1863
1864 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1865                 linking threaded applications. As GLib cannot do that
1866                 automatically, you will get an linkg error everytime you are
1867                 not using the right compiler. In that case you have to relink
1868                 with the right compiler. Ususally just '_r' is appended
1869                 to the compiler name."
1870
1871 dnl determination of thread implementation
1872 dnl ***************************************
1873
1874 # have_threads=no   means no thread support
1875 # have_threads=none means no default thread implementation
1876
1877 have_threads=no
1878 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1879                                 || test "x$want_threads" = xdce; then
1880         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1881         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1882         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1883         glib_save_CPPFLAGS="$CPPFLAGS"
1884         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1885         if test "x$have_threads" = xno; then
1886                 AC_TRY_COMPILE([#include <pthread.h>],
1887                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1888                         have_threads=posix)
1889         fi
1890         if test "x$have_threads" = xno; then
1891                 AC_TRY_COMPILE([#include <pthread.h>],
1892                         [pthread_mutex_t m;
1893                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1894                         have_threads=dce)
1895         fi
1896         # Tru64Unix requires -pthread to find pthread.h. See #103020
1897         CPPFLAGS="$CPPFLAGS -pthread"
1898         if test "x$have_threads" = xno; then
1899         AC_TRY_COMPILE([#include <pthread.h>],
1900                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1901                        have_threads=posix)
1902         fi
1903         CPPFLAGS="$glib_save_CPPFLAGS"
1904 fi
1905 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1906         case $host in
1907                 *-*-mingw*)
1908                 have_threads=win32
1909                 ;;
1910         esac
1911 fi
1912 if test "x$want_threads" = xnone; then
1913         have_threads=none
1914 fi
1915
1916 AC_MSG_CHECKING(for thread implementation)
1917
1918 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1919         AC_MSG_RESULT(none available)
1920         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1921 else
1922         AC_MSG_RESULT($have_threads)
1923 fi
1924
1925
1926 dnl determination of G_THREAD_CFLAGS
1927 dnl ********************************
1928
1929 G_THREAD_LIBS=
1930 G_THREAD_LIBS_EXTRA=
1931 G_THREAD_CFLAGS=
1932
1933 dnl
1934 dnl Test program for basic POSIX threads functionality
1935 dnl
1936 m4_define([glib_thread_test],[
1937 #include <pthread.h>
1938 int check_me = 0;
1939 void* func(void* data) {check_me = 42; return &check_me;}
1940 int main()
1941  { pthread_t t;
1942    void *ret;
1943    pthread_create (&t, $1, func, 0);
1944    pthread_join (t, &ret);
1945    return (check_me != 42 || ret != &check_me);
1946 }])
1947
1948 dnl
1949 dnl Test program for sched_get_priority_min()
1950 dnl
1951 m4_define([glib_sched_priority_test],[
1952 #include <sched.h>
1953 #include <errno.h>
1954 int main() {
1955     errno = 0;
1956     return sched_get_priority_min(SCHED_OTHER)==-1
1957            && errno != 0;
1958 }])
1959
1960 if test x"$have_threads" != xno; then
1961
1962   if test x"$have_threads" = xposix; then
1963     # First we test for posix, whether -pthread or -pthreads do the trick as
1964     # both CPPFLAG and LIBS.
1965     # One of them does for most gcc versions and some other platforms/compilers
1966     # too and could be considered as the canonical way to go.
1967     case $host in
1968       *-*-cygwin*|*-*-darwin*)
1969          # skip cygwin and darwin -pthread or -pthreads test
1970          ;;
1971       *-solaris*)
1972         # These compiler/linker flags work with both Sun Studio and gcc
1973         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1974         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1975         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1976         G_THREAD_LIBS="-lpthread -lthread"
1977         ;;
1978       *)
1979         for flag in pthread pthreads mt; do
1980           glib_save_CFLAGS="$CFLAGS"
1981           CFLAGS="$CFLAGS -$flag"
1982           AC_TRY_RUN(glib_thread_test(0),
1983                      glib_flag_works=yes,
1984                      glib_flag_works=no,
1985                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1986                                      glib_flag_works=yes,
1987                                      glib_flag_works=no)])
1988           CFLAGS="$glib_save_CFLAGS"
1989           if test $glib_flag_works = yes ; then
1990              G_THREAD_CFLAGS=-$flag
1991              G_THREAD_LIBS=-$flag
1992              break;
1993           fi
1994         done
1995          ;;
1996     esac
1997   fi
1998
1999   if test x"$G_THREAD_CFLAGS" = x; then
2000
2001     # The canonical -pthread[s] does not work. Try something different.
2002
2003     case $host in
2004         *-aix*)
2005                 if test x"$GCC" = xyes; then
2006                         # GCC 3.0 and above needs -pthread.
2007                         # Should be coverd by the case above.
2008                         # GCC 2.x and below needs -mthreads
2009                         G_THREAD_CFLAGS="-mthreads"
2010                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2011                 else
2012                         # We are probably using the aix compiler. Normaly a
2013                         # program would have to be compiled with the _r variant
2014                         # of the corresponding compiler, but we as GLib cannot
2015                         # do that: but the good news is that for compiling the
2016                         # only difference is the added -D_THREAD_SAFE compile
2017                         # option. This is according to the "C for AIX User's
2018                         # Guide".
2019                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2020                 fi
2021                 ;;
2022         *-dg-dgux*)  # DG/UX
2023                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2024                 ;;
2025         *-osf*)
2026                 # So we are using dce threads. posix threads are already
2027                 # catched above.
2028                 G_THREAD_CFLAGS="-threads"
2029                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2030                 ;;
2031         *-sysv5uw7*) # UnixWare 7
2032                 # We are not using gcc with -pthread. Catched above.
2033                 G_THREAD_CFLAGS="-Kthread"
2034                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2035                 ;;
2036         *-mingw*)
2037                 # No flag needed when using MSVCRT.DLL
2038                 G_THREAD_CFLAGS=""
2039                 ;;
2040         *)
2041                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2042                 ;;
2043     esac
2044
2045   fi
2046
2047     # if we are not finding the localtime_r function, then we probably are
2048     # not using the proper multithread flag
2049
2050     glib_save_CPPFLAGS="$CPPFLAGS"
2051     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2052
2053     # First we test, whether localtime_r is declared in time.h
2054     # directly. Then we test whether a macro localtime_r exists, in
2055     # which case localtime_r in the test program is replaced and thus
2056     # if we still find localtime_r in the output, it is not defined as
2057     # a macro.
2058
2059     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2060       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2061                                                            localtime_r(a,b)],
2062                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2063
2064     CPPFLAGS="$glib_save_CPPFLAGS"
2065
2066     AC_MSG_CHECKING(thread related cflags)
2067     AC_MSG_RESULT($G_THREAD_CFLAGS)
2068     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2069 fi
2070
2071 dnl determination of G_THREAD_LIBS
2072 dnl ******************************
2073
2074 mutex_has_default=no
2075 case $have_threads in
2076         posix|dce)
2077           glib_save_CPPFLAGS="$CPPFLAGS"
2078           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2079           if test x"$G_THREAD_LIBS" = x; then
2080             case $host in
2081               *-aix*)
2082                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2083                 # probably using the aix compiler.
2084                 AC_MSG_WARN($AIX_COMPILE_INFO)
2085                 ;;
2086               *)
2087                 G_THREAD_LIBS=error
2088                 glib_save_LIBS="$LIBS"
2089                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2090                         if test x"$thread_lib" = x; then
2091                                 add_thread_lib=""
2092                                 IN=""
2093                         else
2094                                 add_thread_lib="-l$thread_lib"
2095                                 IN=" in -l$thread_lib"
2096                         fi
2097                         if test x"$have_threads" = xposix; then
2098                                 defattr=0
2099                         else
2100                                 defattr=pthread_attr_default
2101                         fi
2102
2103                         LIBS="$add_thread_lib $glib_save_LIBS"
2104
2105                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2106                         AC_TRY_RUN(glib_thread_test($defattr),
2107                                    glib_result=yes,
2108                                    glib_result=no,
2109                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2110                                                    glib_result=yes,
2111                                                    glib_result=no)])
2112                         AC_MSG_RESULT($glib_result)
2113
2114                         if test "$glib_result" = "yes" ; then
2115                           G_THREAD_LIBS="$add_thread_lib"
2116                           break
2117                         fi
2118                 done
2119                 if test "x$G_THREAD_LIBS" = xerror; then
2120                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2121                 fi
2122                 LIBS="$glib_save_LIBS"
2123                 ;;
2124             esac
2125           fi
2126
2127           glib_save_LIBS="$LIBS"
2128           for thread_lib in "" rt rte; do
2129             if test x"$thread_lib" = x; then
2130               add_thread_lib=""
2131               IN=""
2132             else
2133               add_thread_lib="-l$thread_lib"
2134               IN=" in -l$thread_lib"
2135             fi
2136             LIBS="$add_thread_lib $glib_save_LIBS"
2137
2138             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2139             AC_TRY_RUN(glib_sched_priority_test,
2140                        glib_result=yes,
2141                        glib_result=no,
2142                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2143                                        glib_result=yes,
2144                                        glib_result=no)])
2145             AC_MSG_RESULT($glib_result)
2146
2147             if test "$glib_result" = "yes" ; then
2148                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2149                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2150                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2151                break
2152             fi
2153           done
2154           LIBS="$glib_save_LIBS"
2155           mutex_has_default=yes
2156           mutex_default_type='pthread_mutex_t'
2157           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2158           mutex_header_file='pthread.h'
2159           if test "x$have_threads" = "xposix"; then
2160             g_threads_impl="POSIX"
2161           else
2162             g_threads_impl="DCE"
2163             have_threads="posix"
2164           fi
2165           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2166           CPPFLAGS="$glib_save_CPPFLAGS"
2167           ;;
2168         win32)
2169            g_threads_impl="WIN32"
2170            ;;
2171         none|no)
2172            g_threads_impl="NONE"
2173            ;;
2174         *)
2175            g_threads_impl="NONE"
2176            G_THREAD_LIBS=error
2177            ;;
2178 esac
2179
2180 if test "x$G_THREAD_LIBS" = xerror; then
2181         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2182 fi
2183
2184 case $host in
2185   *-*-beos*)
2186     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2187     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2188     ;;
2189   *)
2190     ;;
2191 esac
2192
2193 AC_MSG_CHECKING(thread related libraries)
2194 AC_MSG_RESULT($G_THREAD_LIBS)
2195
2196 dnl check for mt safe function variants and some posix functions
2197 dnl ************************************************************
2198
2199 if test x"$have_threads" != xno; then
2200         glib_save_LIBS="$LIBS"
2201         # we are not doing the following for now, as this might require glib
2202         # to always be linked with the thread libs on some platforms.
2203         # LIBS="$LIBS $G_THREAD_LIBS"
2204         AC_CHECK_FUNCS(localtime_r gmtime_r)
2205         if test "$ac_cv_header_pwd_h" = "yes"; then
2206                 AC_CACHE_CHECK([for posix getpwuid_r],
2207                         ac_cv_func_posix_getpwuid_r,
2208                         [AC_TRY_RUN([
2209 #include <errno.h>
2210 #include <pwd.h>
2211 int main () {
2212     char buffer[10000];
2213     struct passwd pwd, *pwptr = &pwd;
2214     int error;
2215     errno = 0;
2216     error = getpwuid_r (0, &pwd, buffer,
2217                         sizeof (buffer), &pwptr);
2218    return (error < 0 && errno == ENOSYS)
2219            || error == ENOSYS;
2220 }                               ],
2221                                 [ac_cv_func_posix_getpwuid_r=yes],
2222                                 [ac_cv_func_posix_getpwuid_r=no])])
2223                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2224                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2225                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2226                                 [Have POSIX function getpwuid_r])
2227                 else
2228                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2229                                 ac_cv_func_nonposix_getpwuid_r,
2230                                 [AC_TRY_LINK([#include <pwd.h>],
2231                                         [char buffer[10000];
2232                                         struct passwd pwd;
2233                                         getpwuid_r (0, &pwd, buffer,
2234                                                         sizeof (buffer));],
2235                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2236                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2237                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2238                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2239                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2240                                         [Have non-POSIX function getpwuid_r])
2241                         fi
2242                 fi
2243         fi
2244         if test "$ac_cv_header_grp_h" = "yes"; then
2245                 AC_CACHE_CHECK([for posix getgrgid_r],
2246                         ac_cv_func_posix_getgrgid_r,
2247                         [AC_TRY_RUN([
2248 #include <errno.h>
2249 #include <grp.h>
2250 int main () {
2251     char buffer[10000];
2252     struct group grp, *grpptr = &grp;
2253     int error;
2254     errno = 0;
2255     error = getgrgid_r (0, &grp, buffer,
2256                         sizeof (buffer), &grpptr);
2257    return (error < 0 && errno == ENOSYS)
2258            || error == ENOSYS;
2259 }                              ],
2260                                [ac_cv_func_posix_getgrgid_r=yes],
2261                                [ac_cv_func_posix_getgrgid_r=no])])
2262                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2263                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2264                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2265                                 [Have POSIX function getgrgid_r])
2266                 else
2267                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2268                                 ac_cv_func_nonposix_getgrgid_r,
2269                                 [AC_TRY_LINK([#include <grp.h>],
2270                                         [char buffer[10000];
2271                                         struct group grp;
2272                                         getgrgid_r (0, &grp, buffer,
2273                                         sizeof (buffer));],
2274                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2275                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2276                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2277                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2278                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2279                                         [Have non-POSIX function getgrgid_r])
2280                         fi
2281                 fi
2282         fi
2283         LIBS="$G_THREAD_LIBS $LIBS"
2284         if test x"$have_threads" = xposix; then
2285                 glib_save_CPPFLAGS="$CPPFLAGS"
2286                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2287                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2288                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2289                 # This is not AC_CHECK_FUNC to also work with function
2290                 # name mangling in header files.
2291                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2292                 AC_TRY_LINK([#include <pthread.h>],
2293                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2294                         [AC_MSG_RESULT(yes)
2295                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2296                                   [Have function pthread_attr_setstacksize])],
2297                         [AC_MSG_RESULT(no)])
2298                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2299                 if test x"$posix_priority_min" = x; then
2300                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2301                                 PX_PRIO_MIN],,[
2302                                 posix_priority_min=PX_PRIO_MIN
2303                                 posix_priority_max=PX_PRIO_MAX])
2304                 fi
2305                 if test x"$posix_priority_min" = x; then
2306                         # AIX
2307                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2308                                 PTHREAD_PRIO_MIN],,[
2309                                 posix_priority_min=PTHREAD_PRIO_MIN
2310                                 posix_priority_max=PTHREAD_PRIO_MAX])
2311                 fi
2312                 if test x"$posix_priority_min" = x; then
2313                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2314                                 PRI_OTHER_MIN],,[
2315                                 posix_priority_min=PRI_OTHER_MIN
2316                                 posix_priority_max=PRI_OTHER_MAX])
2317                 fi
2318                 if test x"$posix_priority_min" = x; then
2319                         AC_MSG_RESULT(none found)
2320                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2321                         posix_priority_min=-1
2322                         posix_priority_max=-1
2323                 else
2324                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2325                         AC_MSG_CHECKING(for pthread_setschedparam)
2326                         AC_TRY_LINK([#include <pthread.h>],
2327                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2328                           [AC_MSG_RESULT(yes)
2329                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2330                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2331                           [AC_MSG_RESULT(no)
2332                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2333                 fi
2334                 posix_yield_func=none
2335                 AC_MSG_CHECKING(for posix yield function)
2336                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2337                                                         thr_yield; do
2338                         AC_TRY_LINK([#include <pthread.h>],
2339                                 [$yield_func()],
2340                                 [posix_yield_func="$yield_func"
2341                                 break])
2342                 done
2343                 if test x"$posix_yield_func" = xnone; then
2344                         AC_MSG_RESULT(none found)
2345                         AC_MSG_WARN($POSIX_NO_YIELD)
2346                         posix_yield_func="g_usleep(1000)"
2347                 else
2348                         AC_MSG_RESULT($posix_yield_func)
2349                         posix_yield_func="$posix_yield_func()"
2350                 fi
2351                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2352                 CPPFLAGS="$glib_save_CPPFLAGS"
2353
2354         elif test x"$have_threads" = xwin32; then
2355                 # It's a pointer to a private struct
2356                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2357         fi
2358
2359         LIBS="$glib_save_LIBS"
2360
2361         # now spit out all the warnings.
2362         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2363            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2364                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2365         fi
2366         if test "$ac_cv_func_localtime_r" != "yes"; then
2367                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2368         fi
2369 fi
2370
2371 if test x"$glib_cv_sizeof_system_thread" = x; then
2372    # use a pointer as a fallback.
2373    GLIB_SIZEOF(,void *, system_thread)
2374 fi
2375
2376 #
2377 # Hack to deal with:
2378 #
2379 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2380 #     building shared libraries with linux.
2381 #  b) FreeBSD doesn't do this either.
2382 #
2383 case $host in
2384   *-*-freebsd*|*-*-linux*)
2385     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2386     ;;
2387   *)
2388     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2389     ;;
2390 esac
2391
2392 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2393 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2394                    [Source file containing theread implementation])
2395 AC_SUBST(G_THREAD_CFLAGS)
2396 AC_SUBST(G_THREAD_LIBS)
2397 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2398 AC_SUBST(G_THREAD_LIBS_EXTRA)
2399
2400 dnl **********************************************
2401 dnl *** GDefaultMutex setup and initialization ***
2402 dnl **********************************************
2403 dnl
2404 dnl if mutex_has_default = yes, we also got
2405 dnl mutex_default_type, mutex_default_init and mutex_header_file
2406 if test $mutex_has_default = yes ; then
2407         glib_save_CPPFLAGS="$CPPFLAGS"
2408         glib_save_LIBS="$LIBS"
2409         LIBS="$G_THREAD_LIBS $LIBS"
2410         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2411         GLIB_SIZEOF([#include <$mutex_header_file>],
2412                     $mutex_default_type,
2413                     gmutex)
2414         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2415                            $mutex_default_type,
2416                            gmutex,
2417                            $glib_cv_sizeof_gmutex,
2418                            $mutex_default_init)
2419         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2420                 mutex_has_default=no
2421         fi
2422         CPPFLAGS="$glib_save_CPPFLAGS"
2423         LIBS="$glib_save_LIBS"
2424 fi
2425
2426 AC_CHECK_FUNCS(clock_gettime, [], [
2427   AC_CHECK_LIB(rt, clock_gettime, [
2428     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2429     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2430     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2431     GLIB_RT_LIBS="-lrt"
2432   ])
2433 ])
2434 AC_SUBST(GLIB_RT_LIBS)
2435
2436 AC_CACHE_CHECK(for monotonic clocks,
2437     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2438 #include <time.h>
2439 #include <unistd.h>
2440 int main() {
2441 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2442         #error No monotonic clock
2443 #endif
2444         return 0;
2445 }
2446 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2447 if test "$glib_cv_monotonic_clock" = "yes"; then
2448   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2449 fi
2450
2451
2452 dnl ********************************
2453 dnl *** g_atomic_* tests for gcc ***
2454 dnl ********************************
2455
2456 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2457
2458 glib_cv_gcc_has_builtin_atomic_operations=no
2459 if test x"$GCC" = xyes; then
2460   AC_MSG_CHECKING([whether GCC supports build-in atomic intrinsics])
2461   AC_TRY_LINK([],
2462               [int i;
2463                __sync_synchronize ();
2464                __sync_bool_compare_and_swap (&i, 0, 1);
2465                __sync_fetch_and_add (&i, 1);
2466               ],
2467               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2468               [glib_cv_gcc_has_builtin_atomic_operations=no])
2469
2470   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2471   if test $glib_cv_gcc_has_builtin_atomic_operations = yes; then
2472     glib_memory_barrier_needed=yes
2473   else
2474     case $host_cpu in
2475       i386)
2476         AC_MSG_RESULT([none])
2477         glib_memory_barrier_needed=no
2478         ;;
2479       i?86)
2480         AC_MSG_RESULT([i486])
2481         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2482                            [i486 atomic implementation])
2483         glib_memory_barrier_needed=no
2484         ;;
2485       sparc*)
2486         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2487                          when you are using a sparc with v9 instruction set (most
2488                          sparcs nowadays). This will make the code for atomic
2489                          operations much faster. The resulting code will not run
2490                          on very old sparcs though."
2491
2492         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2493           main ()
2494           {
2495             int tmp1, tmp2, tmp3;
2496             __asm__ __volatile__("casx [%2], %0, %1"
2497                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2498           }]])],
2499           AC_MSG_RESULT([sparcv9])
2500           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2501                              [sparcv9 atomic implementation]),
2502           AC_MSG_RESULT([no])
2503           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2504         glib_memory_barrier_needed=yes
2505         ;;
2506       alpha*)
2507         AC_MSG_RESULT([alpha])
2508         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2509                            [alpha atomic implementation])
2510         glib_memory_barrier_needed=yes
2511         ;;
2512       x86_64)
2513         AC_MSG_RESULT([x86_64])
2514         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2515                            [x86_64 atomic implementation])
2516         glib_memory_barrier_needed=no
2517        ;;
2518       powerpc*)
2519         AC_MSG_RESULT([powerpc])
2520         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2521                            [powerpc atomic implementation])
2522         glib_memory_barrier_needed=yes
2523         AC_MSG_CHECKING([whether asm supports numbered local labels])
2524         AC_TRY_COMPILE(
2525                        ,[
2526                        __asm__ __volatile__ ("1:       nop\n"
2527                                "         bne-    1b")
2528                        ],[
2529                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2530                        AC_MSG_RESULT([yes])
2531                        ],[
2532                        AC_MSG_RESULT([no])
2533                        ])
2534         ;;
2535       ia64)
2536         AC_MSG_RESULT([ia64])
2537         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2538                            [ia64 atomic implementation])
2539         glib_memory_barrier_needed=yes
2540         ;;
2541       s390|s390x)
2542         AC_MSG_RESULT([s390])
2543         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2544                            [s390 atomic implementation])
2545         glib_memory_barrier_needed=no
2546         ;;
2547       arm*)
2548         AC_MSG_RESULT([arm])
2549         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2550                            [arm atomic implementation])
2551         glib_memory_barrier_needed=no
2552         ;;
2553       crisv32*|etraxfs*)
2554         AC_MSG_RESULT([crisv32])
2555         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2556                            [crisv32 atomic implementation])
2557         glib_memory_barrier_needed=no
2558         ;;
2559       cris*|etrax*)
2560         AC_MSG_RESULT([cris])
2561         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2562                            [cris atomic implementation])
2563         glib_memory_barrier_needed=no
2564         ;;
2565       *)
2566         AC_MSG_RESULT([none])
2567         glib_memory_barrier_needed=yes
2568         ;;
2569     esac
2570   fi
2571 else
2572   if test $glib_native_win32 = yes; then
2573     # For Windows but not using gcc. No barriers needed then either.
2574     glib_memory_barrier_needed=no
2575   fi
2576 fi
2577
2578 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2579                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2580
2581 dnl ************************
2582 dnl ** Check for futex(2) **
2583 dnl ************************
2584 AC_MSG_CHECKING([for futex(2) system call])
2585 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2586 #include <linux/futex.h>
2587 #include <syscall.h>
2588 #include <unistd.h>
2589 ],[
2590 int
2591 main (void)
2592 {
2593   /* it's not like this actually runs or anything... */
2594   syscall (SYS_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2595   return 0;
2596 }
2597 ])],
2598 [
2599   AC_MSG_RESULT(yes)
2600   AC_DEFINE(HAVE_FUTEX, [test "$have_futex" = "yes"],
2601             [we have the futex(2) system call])
2602 ],
2603 [
2604   AC_MSG_RESULT(no)
2605 ])
2606
2607 dnl ****************************************
2608 dnl *** GLib POLL* compatibility defines ***
2609 dnl ****************************************
2610
2611 glib_poll_includes=["
2612 #include <sys/types.h>
2613 #include <sys/poll.h>
2614 "]
2615
2616 if test $ac_cv_header_sys_types_h = yes &&
2617    test $ac_cv_header_sys_poll_h = yes ; then
2618   glib_failed=false
2619   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2620   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2621   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2622   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2623   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2624   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2625   if $glib_failed ; then
2626     AC_MSG_ERROR([Could not determine values for POLL* constants])
2627   fi
2628 else
2629   glib_cv_value_POLLIN=1
2630   glib_cv_value_POLLOUT=4
2631   glib_cv_value_POLLPRI=2
2632   glib_cv_value_POLLERR=8
2633   glib_cv_value_POLLHUP=16
2634   glib_cv_value_POLLNVAL=32
2635 fi
2636
2637 AC_MSG_CHECKING([for broken poll])
2638 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2639         #include <stdlib.h>
2640         #include <fcntl.h>
2641         #include <poll.h>
2642         #ifdef HAVE_SYS_POLL_H
2643         #include <sys/poll.h>
2644         #endif
2645         int main(void) {
2646           struct pollfd fds[1];
2647           int fd;
2648           fd = open("/dev/null", 1);
2649           fds[0].fd = fd;
2650           fds[0].events = POLLIN;
2651           fds[0].revents = 0;
2652           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2653                 exit(1);  /* Does not work for devices -- fail */
2654           }
2655           exit(0);
2656         }]])],
2657   [broken_poll=no],
2658   [broken_poll=yes
2659    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2660   [broken_poll="no (cross compiling)"])
2661 AC_MSG_RESULT($broken_poll)
2662
2663 dnl *********************
2664 dnl *** GRegex checks ***
2665 dnl *********************
2666 PCRE_REQUIRED_VERSION=8.11
2667
2668 # Check if we should compile GRegex
2669 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2670               [disable the compilation of GRegex]),
2671 [case "${enableval}" in
2672   yes) enable_regex=true ;;
2673   no)  enable_regex=false ;;
2674   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2675 esac],
2676 [enable_regex=true])
2677
2678 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2679
2680 if test x$enable_regex = xtrue; then
2681   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2682   # Check if we should use the internal or the system-supplied pcre
2683   AC_ARG_WITH(pcre,
2684              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2685                              [specify whether to use the internal or the
2686                               system-supplied PCRE library])])
2687
2688   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2689
2690   if test "x$with_pcre" = xsystem; then
2691     PKG_CHECK_MODULES(PCRE,
2692                       libpcre >= $PCRE_REQUIRED_VERSION)
2693     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2694                    glib_save_CFLAGS="$CFLAGS"
2695                    glib_save_LIBS="$LIBS"
2696                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2697                    AC_TRY_RUN([#include <pcre.h>
2698                                int main () {
2699                                  int support;
2700                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2701                                  if (!support)
2702                                    return 1;
2703                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2704                                  if (!support)
2705                                    return 1;
2706                                  return 0;
2707                                }],
2708                    glib_cv_pcre_has_unicode=yes,
2709                    glib_cv_pcre_has_unicode=no,
2710                    glib_cv_pcre_has_unicode=yes)
2711                    CFLAGS="$glib_save_CFLAGS"
2712                    LIBS="$glib_save_LIBS"
2713         ])
2714     if test "$glib_cv_pcre_has_unicode" = "no"; then
2715       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2716     fi
2717     AC_SUBST(PCRE_CFLAGS)
2718     AC_SUBST(PCRE_LIBS)
2719     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2720     PCRE_REQUIRES=libpcre
2721     AC_SUBST(PCRE_REQUIRES)
2722   else
2723     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2724     if test x"$GCC" = xyes; then
2725       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2726       save_CFLAGS="$CFLAGS"
2727       CFLAGS="$CFLAGS -Wno-pointer-sign"
2728       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2729                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2730       CFLAGS="$save_CFLAGS"
2731     fi
2732   fi
2733   AC_SUBST(PCRE_WARN_CFLAGS)
2734 else
2735   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2736 fi
2737
2738 dnl **********************
2739 dnl *** Win32 API libs ***
2740 dnl **********************
2741
2742 case $host in
2743   *-*-cygwin*)
2744         G_LIBS_EXTRA="-luser32 -lkernel32"
2745     ;;
2746   *-*-mingw*)
2747         G_LIBS_EXTRA="-lws2_32 -lole32"
2748     ;;
2749   *)
2750         G_LIBS_EXTRA=""
2751     ;;
2752 esac
2753 AC_SUBST(G_LIBS_EXTRA)
2754
2755 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2756 dnl since we need it for g_iconv()
2757
2758 AC_MSG_CHECKING([for EILSEQ])
2759 AC_TRY_COMPILE([
2760 #include <errno.h>
2761 ],
2762 [
2763 int error = EILSEQ;
2764 ], have_eilseq=yes, have_eilseq=no);
2765 AC_MSG_RESULT($have_eilseq)
2766
2767 dnl ******************************************************************
2768 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2769 dnl *** glib-compile-schemas in PATH                               ***
2770 dnl ******************************************************************
2771
2772 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2773
2774 if test $cross_compiling = yes; then
2775   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2776   if test x$GLIB_GENMARSHAL = xno; then
2777     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2778   fi
2779
2780   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2781   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2782     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2783   fi
2784 fi
2785
2786 dnl **************************
2787 dnl *** Checks for gtk-doc ***
2788 dnl **************************
2789
2790 GTK_DOC_CHECK([1.15])
2791
2792 AC_ARG_ENABLE(man,
2793               [AC_HELP_STRING([--enable-man],
2794                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2795               enable_man=no)
2796
2797 if test "${enable_man}" != no; then
2798 dnl
2799 dnl Check for xsltproc
2800 dnl
2801 AC_PATH_PROG([XSLTPROC], [xsltproc])
2802   if test -z "$XSLTPROC"; then
2803     enable_man=no
2804   fi
2805
2806   dnl check for DocBook DTD and stylesheets in the local catalog.
2807   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2808      [DocBook XML DTD V4.1.2],,enable_man=no)
2809   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2810      [DocBook XSL Stylesheets],,enable_man=no)
2811 fi
2812
2813 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2814
2815 dnl
2816 dnl Tracing
2817 dnl
2818
2819 AC_ARG_ENABLE([dtrace],
2820              [AS_HELP_STRING([--enable-dtrace],
2821                               [Enable inclusion of dtrace trace support])])
2822 have_dtrace=no
2823 AC_MSG_CHECKING([whether to include dtrace tracing support])
2824 if test "x$enable_dtrace" != xno; then
2825   if test x$glib_have_carbon = xyes; then
2826     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2827   else
2828     AC_MSG_RESULT([yes])
2829     AC_CHECK_PROGS(DTRACE, dtrace)
2830     if test -z "$DTRACE"; then
2831       if test "x$enable_dtrace" = xyes; then
2832         AC_MSG_ERROR([dtrace not found])
2833       fi
2834     else
2835       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2836                       [if test "x$enable_dtrace" = xyes; then
2837                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2838                        fi])
2839     fi
2840   fi
2841 else
2842   AC_MSG_RESULT([no])
2843 fi
2844 if test "x$have_dtrace" = xyes; then
2845   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2846 fi
2847 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2848
2849 AC_MSG_CHECKING([whether to include systemtap tracing support])
2850 AC_ARG_ENABLE([systemtap],
2851              [AS_HELP_STRING([--enable-systemtap],
2852                               [Enable inclusion of systemtap trace support])])
2853 have_systemtap=no
2854 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2855   have_systemtap=yes
2856 fi
2857 AC_MSG_RESULT(${have_systemtap})
2858
2859 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2860
2861 AC_ARG_WITH([tapset-install-dir],
2862             [AS_HELP_STRING([--with-tapset-install-dir],
2863             [The absolute path where the systemtap tapsets will be installed])],
2864             [if test "x${withval}" = x; then
2865                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2866              else
2867                ABS_TAPSET_DIR="${withval}"
2868               fi],
2869             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2870 AC_SUBST(ABS_TAPSET_DIR)
2871
2872 dnl ************************************
2873 dnl *** Enable lcov coverage reports ***
2874 dnl ************************************
2875
2876 AC_ARG_ENABLE(gcov,
2877   AS_HELP_STRING([--enable-gcov],
2878                  [Enable gcov]),
2879   [use_gcov=$enableval], [use_gcov=no])
2880
2881 if test "x$use_gcov" = "xyes"; then
2882   dnl we need gcc:
2883   if test "$GCC" != "yes"; then
2884     AC_MSG_ERROR([GCC is required for --enable-gcov])
2885   fi
2886
2887   dnl Check if ccache is being used
2888   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2889   case `$SHTOOL path $CC` in
2890     *ccache*[)] gcc_ccache=yes;;
2891     *[)] gcc_ccache=no;;
2892   esac
2893
2894   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2895     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2896   fi
2897
2898   ltp_version_list="1.6 1.7 1.8"
2899   AC_CHECK_PROG(LTP, lcov, lcov)
2900   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2901
2902   if test "$LTP"; then
2903     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2904       glib_cv_ltp_version=invalid
2905       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2906       for ltp_check_version in $ltp_version_list; do
2907         if test "$ltp_version" = "$ltp_check_version"; then
2908           glib_cv_ltp_version="$ltp_check_version (ok)"
2909         fi
2910       done
2911     ])
2912   else
2913     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2914     AC_MSG_ERROR([$ltp_msg])
2915   fi
2916
2917   case $glib_cv_ltp_version in
2918     ""|invalid[)]
2919       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2920       AC_MSG_ERROR([$ltp_msg])
2921       LTP="exit 0;"
2922       ;;
2923   esac
2924
2925   if test -z "$LTP_GENHTML"; then
2926     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2927   fi
2928
2929   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2930
2931   dnl Remove all optimization flags from CFLAGS
2932   changequote({,})
2933   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2934   changequote([,])
2935
2936   dnl Add the special gcc flags
2937   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2938   LDFLAGS="$LDFLAGS -lgcov"
2939 fi
2940
2941 dnl ******************************
2942 dnl *** output the whole stuff ***
2943 dnl ******************************
2944
2945 dnl this section will only be run if config.status is invoked with no
2946 dnl arguments, or with "glib/glibconfig.h" as an argument.
2947 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2948 [
2949         outfile=glib/glibconfig.h-tmp
2950         cat > $outfile <<\_______EOF
2951 /* glibconfig.h
2952  *
2953  * This is a generated file.  Please modify 'configure.ac'
2954  */
2955
2956 #ifndef __G_LIBCONFIG_H__
2957 #define __G_LIBCONFIG_H__
2958
2959 #include <glib/gmacros.h>
2960
2961 _______EOF
2962
2963         if test x$glib_limits_h = xyes; then
2964           echo '#include <limits.h>' >> $outfile
2965         fi
2966         if test x$glib_float_h = xyes; then
2967           echo '#include <float.h>' >> $outfile
2968         fi
2969         if test x$glib_values_h = xyes; then
2970           echo '#include <values.h>' >> $outfile
2971         fi
2972         if test "$glib_header_alloca_h" = "yes"; then
2973           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2974         fi
2975         if test x$glib_sys_poll_h = xyes; then
2976           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2977         fi
2978         if test x$glib_included_printf != xyes; then
2979           echo "
2980 /* Specifies that GLib's g_print*() functions wrap the
2981  * system printf functions.  This is useful to know, for example,
2982  * when using glibc's register_printf_function().
2983  */" >> $outfile
2984           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2985         fi
2986
2987         cat >> $outfile <<_______EOF
2988
2989 G_BEGIN_DECLS
2990
2991 #define G_MINFLOAT      $glib_mf
2992 #define G_MAXFLOAT      $glib_Mf
2993 #define G_MINDOUBLE     $glib_md
2994 #define G_MAXDOUBLE     $glib_Md
2995 #define G_MINSHORT      $glib_ms
2996 #define G_MAXSHORT      $glib_Ms
2997 #define G_MAXUSHORT     $glib_Mus
2998 #define G_MININT        $glib_mi
2999 #define G_MAXINT        $glib_Mi
3000 #define G_MAXUINT       $glib_Mui
3001 #define G_MINLONG       $glib_ml
3002 #define G_MAXLONG       $glib_Ml
3003 #define G_MAXULONG      $glib_Mul
3004
3005 _______EOF
3006
3007
3008         ### this should always be true in a modern C/C++ compiler
3009         cat >>$outfile <<_______EOF
3010 typedef signed char gint8;
3011 typedef unsigned char guint8;
3012 _______EOF
3013
3014
3015         if test -n "$gint16"; then
3016           cat >>$outfile <<_______EOF
3017 typedef signed $gint16 gint16;
3018 typedef unsigned $gint16 guint16;
3019 #define G_GINT16_MODIFIER $gint16_modifier
3020 #define G_GINT16_FORMAT $gint16_format
3021 #define G_GUINT16_FORMAT $guint16_format
3022 _______EOF
3023         fi
3024
3025
3026         if test -n "$gint32"; then
3027           cat >>$outfile <<_______EOF
3028 typedef signed $gint32 gint32;
3029 typedef unsigned $gint32 guint32;
3030 #define G_GINT32_MODIFIER $gint32_modifier
3031 #define G_GINT32_FORMAT $gint32_format
3032 #define G_GUINT32_FORMAT $guint32_format
3033 _______EOF
3034         fi
3035
3036         cat >>$outfile <<_______EOF
3037 #define G_HAVE_GINT64 1          /* deprecated, always true */
3038
3039 ${glib_extension}typedef signed $gint64 gint64;
3040 ${glib_extension}typedef unsigned $gint64 guint64;
3041
3042 #define G_GINT64_CONSTANT(val)  $gint64_constant
3043 #define G_GUINT64_CONSTANT(val) $guint64_constant
3044 _______EOF
3045
3046         if test x$gint64_format != x ; then
3047           cat >>$outfile <<_______EOF
3048 #define G_GINT64_MODIFIER $gint64_modifier
3049 #define G_GINT64_FORMAT $gint64_format
3050 #define G_GUINT64_FORMAT $guint64_format
3051 _______EOF
3052         else
3053           cat >>$outfile <<_______EOF
3054 #undef G_GINT64_MODIFIER
3055 #undef G_GINT64_FORMAT
3056 #undef G_GUINT64_FORMAT
3057 _______EOF
3058         fi
3059
3060         cat >>$outfile <<_______EOF
3061
3062 #define GLIB_SIZEOF_VOID_P $glib_void_p
3063 #define GLIB_SIZEOF_LONG   $glib_long
3064 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3065
3066 _______EOF
3067
3068         cat >>$outfile <<_______EOF
3069 typedef signed $glib_size_type_define gssize;
3070 typedef unsigned $glib_size_type_define gsize;
3071 #define G_GSIZE_MODIFIER $gsize_modifier
3072 #define G_GSSIZE_FORMAT $gssize_format
3073 #define G_GSIZE_FORMAT $gsize_format
3074
3075 #define G_MAXSIZE       G_MAXU$glib_msize_type
3076 #define G_MINSSIZE      G_MIN$glib_msize_type
3077 #define G_MAXSSIZE      G_MAX$glib_msize_type
3078
3079 typedef gint64 goffset;
3080 #define G_MINOFFSET     G_MININT64
3081 #define G_MAXOFFSET     G_MAXINT64
3082
3083 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3084 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3085 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3086
3087 _______EOF
3088
3089         if test -z "$glib_unknown_void_p"; then
3090           cat >>$outfile <<_______EOF
3091
3092 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3093 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3094
3095 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3096 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3097
3098 typedef signed $glib_intptr_type_define gintptr;
3099 typedef unsigned $glib_intptr_type_define guintptr;
3100
3101 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3102 #define G_GINTPTR_FORMAT        $gintptr_format
3103 #define G_GUINTPTR_FORMAT       $guintptr_format
3104 _______EOF
3105         else
3106           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3107         fi
3108
3109
3110
3111         cat >>$outfile <<_______EOF
3112 $glib_atexit
3113 $glib_memmove
3114 $glib_defines
3115 $glib_os
3116 $glib_static_compilation
3117
3118 $glib_vacopy
3119
3120 #ifdef  __cplusplus
3121 #define G_HAVE_INLINE   1
3122 #else   /* !__cplusplus */
3123 $glib_inline
3124 #endif  /* !__cplusplus */
3125
3126 #ifdef  __cplusplus
3127 #define G_CAN_INLINE    1
3128 _______EOF
3129
3130         if test x$g_can_inline = xyes ; then
3131                 cat >>$outfile <<_______EOF
3132 #else   /* !__cplusplus */
3133 #define G_CAN_INLINE    1
3134 _______EOF
3135         fi
3136
3137         cat >>$outfile <<_______EOF
3138 #endif
3139
3140 _______EOF
3141
3142         if test x$g_have_iso_c_varargs = xyes ; then
3143                 cat >>$outfile <<_______EOF
3144 #ifndef __cplusplus
3145 # define G_HAVE_ISO_VARARGS 1
3146 #endif
3147 _______EOF
3148         fi
3149         if test x$g_have_iso_cxx_varargs = xyes ; then
3150                 cat >>$outfile <<_______EOF
3151 #ifdef __cplusplus
3152 # define G_HAVE_ISO_VARARGS 1
3153 #endif
3154 _______EOF
3155         fi
3156         if test x$g_have_gnuc_varargs = xyes ; then
3157                 cat >>$outfile <<_______EOF
3158
3159 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3160  * is passed ISO vararg support is turned off, and there is no work
3161  * around to turn it on, so we unconditionally turn it off.
3162  */
3163 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3164 #  undef G_HAVE_ISO_VARARGS
3165 #endif
3166
3167 #define G_HAVE_GNUC_VARARGS 1
3168 _______EOF
3169         fi
3170
3171         case x$g_stack_grows in
3172         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3173         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3174         esac
3175
3176
3177         echo >>$outfile
3178         if test x$g_have_eilseq = xno; then
3179                 cat >>$outfile <<_______EOF
3180 #ifndef EILSEQ
3181 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3182  * The correspondence between this and the corresponding definition
3183  * in libiconv is essential.
3184  */
3185 #  define EILSEQ ENOENT
3186 #endif
3187 _______EOF
3188
3189         fi
3190
3191         if test x$g_have_gnuc_visibility = xyes; then
3192                 cat >>$outfile <<_______EOF
3193 #define G_HAVE_GNUC_VISIBILITY 1
3194 _______EOF
3195         fi
3196                 cat >>$outfile <<_______EOF
3197 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3198 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3199 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3200 #define G_GNUC_INTERNAL __hidden
3201 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3202 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3203 #else
3204 #define G_GNUC_INTERNAL
3205 #endif
3206 _______EOF
3207
3208
3209         echo >>$outfile
3210         if test x$g_mutex_has_default = xyes; then
3211                 cat >>$outfile <<_______EOF
3212 $g_enable_threads_def G_THREADS_ENABLED
3213 #define G_THREADS_IMPL_$g_threads_impl_def
3214 typedef struct _GStaticMutex GStaticMutex;
3215 struct _GStaticMutex
3216 {
3217   struct _GMutex *runtime_mutex;
3218   union {
3219     char   pad[[$g_mutex_sizeof]];
3220     double dummy_double;
3221     void  *dummy_pointer;
3222     long   dummy_long;
3223   } static_mutex;
3224 };
3225 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3226 #define g_static_mutex_get_mutex(mutex) \\
3227   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3228    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3229 _______EOF
3230         else
3231                 cat >>$outfile <<_______EOF
3232 $g_enable_threads_def G_THREADS_ENABLED
3233 #define G_THREADS_IMPL_$g_threads_impl_def
3234 typedef struct _GMutex* GStaticMutex;
3235 #define G_STATIC_MUTEX_INIT NULL
3236 #define g_static_mutex_get_mutex(mutex) \\
3237   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3238 _______EOF
3239         fi
3240
3241         cat >>$outfile <<_______EOF
3242 /* This represents a system thread as used by the implementation. An
3243  * alien implementaion, as loaded by g_thread_init can only count on
3244  * "sizeof (gpointer)" bytes to store their info. We however need more
3245  * for some of our native implementations. */
3246 typedef union _GSystemThread GSystemThread;
3247 union _GSystemThread
3248 {
3249   char   data[[$g_system_thread_sizeof]];
3250   double dummy_double;
3251   void  *dummy_pointer;
3252   long   dummy_long;
3253 };
3254 _______EOF
3255         if test x"$g_memory_barrier_needed" != xno; then
3256           echo >>$outfile
3257           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3258         fi
3259
3260         echo >>$outfile
3261         g_bit_sizes="16 32 64"
3262         for bits in $g_bit_sizes; do
3263           cat >>$outfile <<_______EOF
3264 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3265 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3266 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3267 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3268 _______EOF
3269         done
3270
3271         cat >>$outfile <<_______EOF
3272 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3273 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3274 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3275 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3276 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3277 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3278 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3279 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3280 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3281 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3282 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3283 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3284 #define G_BYTE_ORDER $g_byte_order
3285
3286 #define GLIB_SYSDEF_POLLIN =$g_pollin
3287 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3288 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3289 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3290 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3291 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3292
3293 #define G_MODULE_SUFFIX "$g_module_suffix"
3294
3295 /* A GPid is an abstraction for a process "handle". It is *not* an
3296  * abstraction for a process identifier in general. GPid is used in
3297  * GLib only for descendant processes spawned with the g_spawn*
3298  * functions. On POSIX there is no "process handle" concept as such,
3299  * but on Windows a GPid is a handle to a process, a kind of pointer,
3300  * not a process identifier.
3301  */
3302 typedef $g_pid_type GPid;
3303
3304 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3305 #define GLIB_SYSDEF_AF_INET $g_af_inet
3306 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3307
3308 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3309 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3310 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3311
3312 G_END_DECLS
3313
3314 #endif /* GLIBCONFIG_H */
3315 _______EOF
3316
3317
3318         if cmp -s $outfile glib/glibconfig.h; then
3319           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3320           rm -f $outfile
3321         else
3322           mv $outfile glib/glibconfig.h
3323         fi
3324 ],[
3325
3326 # Note that if two cases are the same, case goes with the first one.
3327 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3328 # on variable expansion in case labels.  Look at the generated config.status
3329 # for a hint.
3330
3331 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3332   glib_header_alloca_h="$ac_cv_working_alloca_h"
3333 else
3334   glib_header_alloca_h="$ac_cv_header_alloca_h"
3335 fi
3336
3337 case xyes in
3338 x$ac_cv_header_float_h)
3339   glib_float_h=yes
3340   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3341   glib_md=DBL_MIN glib_Md=DBL_MAX
3342   ;;
3343 x$ac_cv_header_values_h)
3344   glib_values_h=yes
3345   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3346   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3347   ;;
3348 esac
3349
3350 case xyes in
3351 x$ac_cv_header_limits_h)
3352   glib_limits_h=yes
3353   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3354   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3355   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3356   ;;
3357 x$ac_cv_header_values_h)
3358   glib_values_h=yes
3359   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3360   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3361   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3362   ;;
3363 esac
3364
3365 if test x$ac_cv_header_sys_poll_h = xyes ; then
3366   glib_sys_poll_h=yes
3367 fi
3368
3369 if test x$enable_included_printf = xyes ; then
3370   glib_included_printf=yes
3371 fi
3372
3373 case 2 in
3374 $ac_cv_sizeof_short)
3375   gint16=short
3376   gint16_modifier='"h"'
3377   gint16_format='"hi"'
3378   guint16_format='"hu"'
3379   ;;
3380 $ac_cv_sizeof_int)
3381   gint16=int
3382   gint16_modifier='""'
3383   gint16_format='"i"'
3384   guint16_format='"u"'
3385   ;;
3386 esac
3387 case 4 in
3388 $ac_cv_sizeof_short)
3389   gint32=short
3390   gint32_modifier='"h"'
3391   gint32_format='"hi"'
3392   guint32_format='"hu"'
3393   ;;
3394 $ac_cv_sizeof_int)
3395   gint32=int
3396   gint32_modifier='""'
3397   gint32_format='"i"'
3398   guint32_format='"u"'
3399   ;;
3400 $ac_cv_sizeof_long)
3401   gint32=long
3402   gint32_modifier='"l"'
3403   gint32_format='"li"'
3404   guint32_format='"lu"'
3405   ;;
3406 esac
3407 case 8 in
3408 $ac_cv_sizeof_int)
3409   gint64=int
3410   gint64_modifier='""'
3411   gint64_format='"i"'
3412   guint64_format='"u"'
3413   glib_extension=
3414   gint64_constant='(val)'
3415   guint64_constant='(val)'
3416   ;;
3417 $ac_cv_sizeof_long)
3418   gint64=long
3419   gint64_modifier='"l"'
3420   gint64_format='"li"'
3421   guint64_format='"lu"'
3422   glib_extension=
3423   gint64_constant='(val##L)'
3424   guint64_constant='(val##UL)'
3425   ;;
3426 $ac_cv_sizeof_long_long)
3427   gint64='long long'
3428   if test -n "$glib_cv_long_long_format"; then
3429     gint64_modifier='"'$glib_cv_long_long_format'"'
3430     gint64_format='"'$glib_cv_long_long_format'i"'
3431     guint64_format='"'$glib_cv_long_long_format'u"'
3432   fi
3433   glib_extension='G_GNUC_EXTENSION '
3434   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3435   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3436   ;;
3437 $ac_cv_sizeof___int64)
3438   gint64='__int64'
3439   if test -n "$glib_cv_long_long_format"; then
3440     gint64_modifier='"'$glib_cv_long_long_format'"'
3441     gint64_format='"'$glib_cv_long_long_format'i"'
3442     guint64_format='"'$glib_cv_long_long_format'u"'
3443   fi
3444   glib_extension=
3445   gint64_constant='(val##i64)'
3446   guint64_constant='(val##ui64)'
3447   ;;
3448 esac
3449 glib_size_t=$ac_cv_sizeof_size_t
3450 glib_size_type_define="$glib_size_type"
3451 glib_void_p=$ac_cv_sizeof_void_p
3452 glib_long=$ac_cv_sizeof_long
3453
3454 case "$glib_size_type" in
3455 short)
3456   gsize_modifier='"h"'
3457   gsize_format='"hu"'
3458   gssize_format='"hi"'
3459   glib_msize_type='SHRT'
3460   ;;
3461 int)
3462   gsize_modifier='""'
3463   gsize_format='"u"'
3464   gssize_format='"i"'
3465   glib_msize_type='INT'
3466   ;;
3467 long)
3468   gsize_modifier='"l"'
3469   gsize_format='"lu"'
3470   gssize_format='"li"'
3471   glib_msize_type='LONG'
3472   ;;
3473 "long long"|__int64)
3474   gsize_modifier='"I64"'
3475   gsize_format='"I64u"'
3476   gssize_format='"I64i"'
3477   glib_msize_type='INT64'
3478   ;;
3479 esac
3480
3481 gintbits=`expr $ac_cv_sizeof_int \* 8`
3482 glongbits=`expr $ac_cv_sizeof_long \* 8`
3483 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3484
3485 case $ac_cv_sizeof_void_p in
3486 $ac_cv_sizeof_int)
3487   glib_intptr_type_define=int
3488   gintptr_modifier='""'
3489   gintptr_format='"i"'
3490   guintptr_format='"u"'
3491   glib_gpi_cast=''
3492   glib_gpui_cast=''
3493   ;;
3494 $ac_cv_sizeof_long)
3495   glib_intptr_type_define=long
3496   gintptr_modifier='"l"'
3497   gintptr_format='"li"'
3498   guintptr_format='"lu"'
3499   glib_gpi_cast='(glong)'
3500   glib_gpui_cast='(gulong)'
3501   ;;
3502 $ac_cv_sizeof_long_long)
3503   glib_intptr_type_define='long long'
3504   gintptr_modifier='"I64"'
3505   gintptr_format='"I64i"'
3506   guintptr_format='"I64u"'
3507   glib_gpi_cast='(gint64)'
3508   glib_gpui_cast='(guint64)'
3509   ;;
3510 $ac_cv_sizeof___int64)
3511   glib_intptr_type_define=__int64
3512   gintptr_modifier='"I64"'
3513   gintptr_format='"I64i"'
3514   guintptr_format='"I64u"'
3515   glib_gpi_cast='(gint64)'
3516   glib_gpui_cast='(guint64)'
3517   ;;
3518 *)
3519   glib_unknown_void_p=yes
3520   ;;
3521 esac
3522
3523
3524 case xyes in
3525 x$ac_cv_func_atexit)
3526   glib_atexit="
3527 #ifdef NeXT /* @#%@! NeXTStep */
3528 # define g_ATEXIT(proc) (!atexit (proc))
3529 #else
3530 # define g_ATEXIT(proc) (atexit (proc))
3531 #endif"
3532   ;;
3533 x$ac_cv_func_on_exit)
3534   glib_atexit="
3535 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3536   ;;
3537 esac
3538
3539 case xyes in
3540 x$ac_cv_func_memmove)
3541   glib_memmove='
3542 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3543   ;;
3544 x$glib_cv_working_bcopy)
3545   glib_memmove="
3546 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3547 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3548   ;;
3549 *)
3550   glib_memmove="
3551 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3552  * so we have to roll our own copy routine. */
3553 void g_memmove (void* dest, const void * src, unsigned long len);"
3554   ;;
3555 esac
3556
3557 glib_defines="
3558 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3559 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3560 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3561 "
3562
3563 case xyes in
3564 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3565 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3566 *)                      glib_vacopy=''
3567 esac
3568
3569 if test x$glib_cv_va_val_copy = xno; then
3570   glib_vacopy="\$glib_vacopy
3571 #define G_VA_COPY_AS_ARRAY 1"
3572 fi
3573
3574 if test x$glib_cv_hasinline = xyes; then
3575     glib_inline='#define G_HAVE_INLINE 1'
3576 fi
3577 if test x$glib_cv_has__inline = xyes; then
3578     glib_inline="\$glib_inline
3579 #define G_HAVE___INLINE 1"
3580 fi
3581 if test x$glib_cv_has__inline__ = xyes; then
3582     glib_inline="\$glib_inline
3583 #define G_HAVE___INLINE__ 1"
3584 fi
3585
3586 g_have_gnuc_varargs=$g_have_gnuc_varargs
3587 g_have_iso_c_varargs=$g_have_iso_c_varargs
3588 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3589
3590 g_can_inline=$g_can_inline
3591 g_have_gnuc_visibility=$g_have_gnuc_visibility
3592 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3593
3594 if test x$ac_cv_c_bigendian = xyes; then
3595   g_byte_order=G_BIG_ENDIAN
3596   g_bs_native=BE
3597   g_bs_alien=LE
3598 else
3599   g_byte_order=G_LITTLE_ENDIAN
3600   g_bs_native=LE
3601   g_bs_alien=BE
3602 fi
3603
3604 g_pollin=$glib_cv_value_POLLIN
3605 g_pollout=$glib_cv_value_POLLOUT
3606 g_pollpri=$glib_cv_value_POLLPRI
3607 g_pollhup=$glib_cv_value_POLLHUP
3608 g_pollerr=$glib_cv_value_POLLERR
3609 g_pollnval=$glib_cv_value_POLLNVAL
3610
3611 g_af_unix=$glib_cv_value_AF_UNIX
3612 g_af_inet=$glib_cv_value_AF_INET
3613 g_af_inet6=$glib_cv_value_AF_INET6
3614
3615 g_msg_peek=$glib_cv_value_MSG_PEEK
3616 g_msg_oob=$glib_cv_value_MSG_OOB
3617 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3618
3619 g_stack_grows=$glib_cv_stack_grows
3620
3621 g_have_eilseq=$have_eilseq
3622
3623 case x$have_threads in
3624 xno)    g_enable_threads_def="#undef";;
3625 *)      g_enable_threads_def="#define";;
3626 esac
3627
3628 g_threads_impl_def=$g_threads_impl
3629
3630 g_mutex_has_default="$mutex_has_default"
3631 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3632 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3633 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3634
3635 g_memory_barrier_needed="$glib_memory_barrier_needed"
3636
3637 g_module_suffix="$glib_gmodule_suffix"
3638
3639 g_pid_type="$glib_pid_type"
3640 case $host in
3641   *-*-beos*)
3642     glib_os="#define G_OS_BEOS"
3643     ;;
3644   *-*-cygwin*)
3645     glib_os="#define G_OS_UNIX
3646 #define G_PLATFORM_WIN32
3647 #define G_WITH_CYGWIN"
3648     ;;
3649   *-*-mingw*)
3650     glib_os="#define G_OS_WIN32
3651 #define G_PLATFORM_WIN32"
3652     ;;
3653   *)
3654     glib_os="#define G_OS_UNIX"
3655     ;;
3656 esac
3657 glib_static_compilation=""
3658 if test x$glib_win32_static_compilation = xyes; then
3659   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3660 #define GOBJECT_STATIC_COMPILATION 1"
3661 fi
3662 ])
3663
3664 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3665 #
3666 # 1.2.14 required for dbus_message_set_serial
3667 PKG_CHECK_MODULES(DBUS1,
3668                   dbus-1 >= 1.2.14,
3669                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3670                   have_dbus1=no)
3671 AC_SUBST(DBUS1_CFLAGS)
3672 AC_SUBST(DBUS1_LIBS)
3673 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3674
3675 dnl
3676 dnl Check for -Bsymbolic-functions linker flag used to avoid
3677 dnl intra-library PLT jumps, if available.
3678 dnl
3679
3680 AC_ARG_ENABLE(Bsymbolic,
3681               [AC_HELP_STRING([--disable-Bsymbolic],
3682                               [avoid linking with -Bsymbolic])],,
3683               [SAVED_LDFLAGS="${LDFLAGS}"
3684                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3685                LDFLAGS=-Wl,-Bsymbolic-functions
3686                AC_TRY_LINK([], [int main (void) { return 0; }],
3687                            AC_MSG_RESULT(yes)
3688                            enable_Bsymbolic=yes,
3689                            AC_MSG_RESULT(no)
3690                            enable_Bsymbolic=no)
3691                LDFLAGS="${SAVED_LDFLAGS}"])
3692
3693 if test "x${enable_Bsymbolic}" == "xyes"; then
3694   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3695 fi
3696
3697 AC_SUBST(GLIB_LINK_FLAGS)
3698
3699 #
3700 # Define variables corresponding to the correct include paths to use for
3701 # in-tree building.
3702 #
3703
3704 # for config.h:
3705 config_h_INCLUDES='-I$(top_builddir)'
3706 AC_SUBST(config_h_INCLUDES)
3707
3708 # glib:
3709 #   config.h
3710 #   $(top_builddir)/glib: for glibconfig.h
3711 #   $(top_srcdir)/glib:   for glib.h
3712 #   $(top_srcdir):        for everything
3713 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3714 AC_SUBST(glib_INCLUDES)
3715
3716 # gthread:
3717 #   same as glib
3718 gthread_INCLUDES='$(glib_INCLUDES)'
3719 AC_SUBST(gthread_INCLUDES)
3720
3721 # gobject:
3722 #   same as gthread
3723 gobject_INCLUDES='$(gthread_INCLUDES)'
3724 AC_SUBST(gobject_INCLUDES)
3725
3726 # gmodule:
3727 #   glib includes
3728 #   $(top_srcdir)/gmodule: for gmodule.h
3729 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3730 AC_SUBST(gmodule_INCLUDES)
3731
3732 # gio:
3733 #   same as gmodule
3734 gio_INCLUDES='$(gmodule_INCLUDES)'
3735 AC_SUBST(gio_INCLUDES)
3736
3737
3738 AC_CONFIG_FILES([
3739 glib-2.0.pc
3740 glib-2.0-uninstalled.pc
3741 gmodule-2.0.pc
3742 gmodule-export-2.0.pc
3743 gmodule-no-export-2.0.pc
3744 gmodule-2.0-uninstalled.pc
3745 gmodule-no-export-2.0-uninstalled.pc
3746 gthread-2.0.pc
3747 gthread-2.0-uninstalled.pc
3748 gobject-2.0.pc
3749 gobject-2.0-uninstalled.pc
3750 gio-2.0.pc
3751 gio-unix-2.0.pc
3752 gio-windows-2.0.pc
3753 gio-2.0-uninstalled.pc
3754 gio-unix-2.0-uninstalled.pc
3755 glib-zip
3756 glib-gettextize
3757 Makefile
3758 build/Makefile
3759 build/win32/Makefile
3760 build/win32/dirent/Makefile
3761 build/win32/vs9/Makefile
3762 build/win32/vs10/Makefile
3763 glib/Makefile
3764 glib/glib.stp
3765 glib/libcharset/Makefile
3766 glib/gnulib/Makefile
3767 glib/pcre/Makefile
3768 glib/update-pcre/Makefile
3769 glib/tests/Makefile
3770 gmodule/Makefile
3771 gmodule/gmoduleconf.h
3772 gobject/Makefile
3773 gobject/gobject.stp
3774 gobject/glib-mkenums
3775 gobject/tests/Makefile
3776 gthread/Makefile
3777 gthread/tests/Makefile
3778 gio/Makefile
3779 gio/gdbus-codegen/Makefile
3780 gio/gdbus-codegen/config.py
3781 gio/xdgmime/Makefile
3782 gio/inotify/Makefile
3783 gio/libasyncns/Makefile
3784 gio/fen/Makefile
3785 gio/fam/Makefile
3786 gio/win32/Makefile
3787 gio/tests/Makefile
3788 po/Makefile.in
3789 docs/Makefile
3790 docs/reference/Makefile
3791 docs/reference/glib/Makefile
3792 docs/reference/glib/version.xml
3793 docs/reference/gobject/Makefile
3794 docs/reference/gobject/version.xml
3795 docs/reference/gio/Makefile
3796 docs/reference/gio/version.xml
3797 tests/Makefile
3798 tests/gobject/Makefile
3799 tests/refcount/Makefile
3800 m4macros/Makefile
3801 ])
3802
3803 AC_CONFIG_COMMANDS([chmod-scripts],
3804 [chmod 0755 glib-zip
3805 chmod 0755 glib-gettextize
3806 chmod 0755 gobject/glib-mkenums])
3807
3808 # we want to invoke this macro solely so that the config.status script
3809 # and automake generated makefiles know about these generated files.
3810 # They are only needed to distcheck the package
3811 if false; then
3812   AC_CONFIG_FILES([
3813     INSTALL
3814     README
3815     config.h.win32
3816     glib/glibconfig.h.win32
3817     glib/makefile.msc
3818     glib/glib.rc
3819     gmodule/makefile.msc
3820     gmodule/gmodule.rc
3821     gobject/makefile.msc
3822     gobject/gobject.rc
3823     gthread/makefile.msc
3824     gthread/gthread.rc
3825     gio/gio.rc
3826     tests/makefile.msc
3827   ])
3828 fi
3829
3830 AC_OUTPUT