configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([GNU Automake], [1.11a], [bug-automake@gnu.org])
  20
  21 m4_ifndef([AC_PACKAGE_URL],
  22           [AC_SUBST([PACKAGE_URL], [http://www.gnu.org/software/automake/])])
  23
  24 AC_CONFIG_SRCDIR(automake.in)
  25 AC_CONFIG_AUX_DIR(lib)
  26
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by `missing'.  Likewise for autoheader.
  32 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  33 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  34
  35 AM_INIT_AUTOMAKE([1.10a dist-bzip2 filename-length-max=99 color-tests
  36                   parallel-tests silent-rules])
  37
  38 # The API version is the base version.  We must guarantee
  39 # compatibility for all releases with the same API version.
  40 # Our current rule is that:
  41 # * All releases, including the prereleases, in an X.Y series
  42 #   are compatible.  So 1.5.1c is compatible with 1.5.
  43 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  44 #   aren't the same.
  45 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  46 AC_SUBST([APIVERSION])
  47
  48 # A versioned directory, defined here for convenience.
  49 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  50
  51 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  52 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  53 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  54 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  55
  56 AC_PATH_PROG(PERL, perl)
  57 if test -z "$PERL"; then
  58    AC_MSG_ERROR([perl not found])
  59 fi
  60 $PERL -e 'require 5.006;' || {
  61    AC_MSG_ERROR(
  62 [perl 5.6 or better is required; perl 5.8.2 or better
  63 is recommended.  If you have several perl versions
  64 installed, select the one Automake should use using
  65   ./configure PERL=/path/to/perl])
  66 }
  67
  68 # We require ithreads support, and version 5.7.2 for CLONE.
  69 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  70 [if $PERL -e '
  71     require 5.007_002;
  72     use Config;
  73     if ($Config{useithreads})
  74       {
  75         require threads;
  76         import threads;
  77         require Thread::Queue;
  78         import Thread::Queue;
  79         exit 0;
  80       }
  81     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  82 then
  83   am_cv_prog_PERL_ithreads=yes
  84 else
  85   am_cv_prog_PERL_ithreads=no
  86 fi])
  87 if test $am_cv_prog_PERL_ithreads = yes; then
  88   PERL_THREADS=1;
  89 else
  90   PERL_THREADS=0;
  91 fi
  92 AC_SUBST([PERL_THREADS])
  93
  94 # The test suite will skip some tests if tex is absent.
  95 AC_CHECK_PROG([TEX], [tex], [tex])
  96
  97 # Generate man pages.
  98 AM_MISSING_PROG([HELP2MAN], [help2man])
  99
 100 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 101 # deletion of any files created (such as those added to
 102 # autom4te.cache).  We used to perform only the last of the three
 103 # following tests, but some users were unable to figure out that their
 104 # installation was broken since --version appeared to work.
 105
 106 required_autoconf_version=2.62
 107 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 108 [if AM_RUN_LOG([eval $am_AUTOCONF --version]);
 109 then
 110   am_cv_autoconf_installed=yes
 111 else
 112   am_cv_autoconf_installed=no
 113 fi])
 114 if test "$am_cv_autoconf_installed" = no; then
 115   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 116     Please make sure it is installed and in your PATH.])
 117 fi
 118
 119 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 120 [mkdir conftest
 121 echo 'AC''_INIT' > conftest/conftest.ac
 122 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 123 then
 124   am_cv_autoconf_works=yes
 125 else
 126   am_cv_autoconf_works=no
 127 fi
 128 rm -rf conftest])
 129 if test "$am_cv_autoconf_works" = no; then
 130   AC_MSG_ERROR([The installed version of autoconf does not work.
 131     Please check config.log for error messages before this one.])
 132 fi
 133
 134 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 135 [mkdir conftest
 136 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 137 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 138 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 139 then
 140   am_cv_autoconf_version=yes
 141 else
 142   am_cv_autoconf_version=no
 143 fi
 144 rm -rf conftest])
 145 if test "$am_cv_autoconf_version" = no; then
 146   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 147 fi
 148
 149 # Test for ln.  We need use it to install the versioned binaries.
 150 AC_MSG_CHECKING([whether ln works])
 151 AC_CACHE_VAL([am_cv_prog_ln], [
 152 rm -f conftest conftest.file
 153 : >conftest.file
 154 if ln conftest.file conftest 2>/dev/null; then
 155   am_cv_prog_ln=ln
 156 else
 157   am_cv_prog_ln='cp -p'
 158 fi
 159 rm -f conftest conftest.file])
 160 AC_SUBST([LN], [$am_cv_prog_ln])
 161 result=no
 162 test "x$am_cv_prog_ln" = xln && result=yes
 163 AC_MSG_RESULT([$result])
 164
 165 # The amount we should wait after modifying files depends on the platform.
 166 # On Windows '95, '98 and ME, files modifications have 2-seconds
 167 # granularity and can be up to 3 seconds in the future w.r.t. the
 168 # system clock.  When it is important to ensure one file is older
 169 # than another we wait at least 5 seconds between creations.
 170 case $build in
 171   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 172   *)               MODIFICATION_DELAY=2;;
 173 esac
 174 AC_SUBST([MODIFICATION_DELAY])
 175
 176 # Test for things needed by the test suite.
 177 AC_PROG_EGREP
 178 AC_PROG_FGREP
 179
 180 AC_CACHE_CHECK([whether /bin/sh has working 'set -e' with exit trap],
 181 [am_cv_sh_errexit_works],
 182 [if /bin/sh -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 183 then
 184   am_cv_sh_errexit_works=yes
 185 else
 186   am_cv_sh_errexit_works=no
 187 fi
 188 ])
 189 if test $am_cv_sh_errexit_works = no; then
 190   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 191   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 192   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 193   dnl restore font-lock: `
 194 fi
 195 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 196
 197 AC_CONFIG_FILES([
 198   Makefile
 199   doc/Makefile
 200   lib/Automake/Makefile
 201   lib/Automake/tests/Makefile
 202   lib/Makefile
 203   lib/am/Makefile
 204   m4/Makefile
 205   tests/Makefile
 206   tests/defs
 207 ])
 208 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 209                 [chmod +x tests/aclocal-${APIVERSION}],
 210                 [APIVERSION=$APIVERSION])
 211 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 212                 [chmod +x tests/automake-${APIVERSION}])
 213
 214 AC_OUTPUT