configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [13])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_MSG_RESULT([yes])
 247 fi
 248
 249 dnl location to install runtime libraries, e.g. ../../lib to install
 250 dnl to /lib if libdir is /usr/lib
 251 AC_ARG_WITH(runtime-libdir,
 252            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 253                            [install runtime libraries relative to libdir])],
 254            [],
 255            [with_runtime_libdir=""])
 256 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 257 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 258 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 259 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 260 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 261
 262 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 263 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 264 AC_LANG_SAVE
 265 AC_LANG_CPLUSPLUS
 266 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 267 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 268 AC_LANG_RESTORE
 269
 270 AM_PROG_CC_STDC
 271 AM_PROG_CC_C_O
 272 AC_PROG_INSTALL
 273
 274 AC_SYS_LARGEFILE
 275
 276 PKG_PROG_PKG_CONFIG(0.16)
 277
 278 if test "x$enable_debug" = "xyes"; then
 279   if test x$cflags_set != xset ; then
 280       case " $CFLAGS " in
 281       *[[\ \    ]]-g[[\ \       ]]*) ;;
 282       *) CFLAGS="$CFLAGS -g" ;;
 283       esac
 284   fi
 285   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 286 else
 287   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 288
 289   if test "x$enable_debug" = "xno"; then
 290     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 291   fi
 292 fi
 293
 294 # Ensure MSVC-compatible struct packing convention is used when
 295 # compiling for Win32 with gcc.
 296 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 297 # gcc2 uses "-fnative-struct".
 298 if test x"$glib_native_win32" = xyes; then
 299   if test x"$GCC" = xyes; then
 300     msnative_struct=''
 301     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 302     if test -z "$ac_cv_prog_CC"; then
 303       our_gcc="$CC"
 304     else
 305       our_gcc="$ac_cv_prog_CC"
 306     fi
 307     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 308       2.)
 309         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 310           msnative_struct='-fnative-struct'
 311         fi
 312         ;;
 313       *)
 314         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 315           msnative_struct='-mms-bitfields'
 316         fi
 317         ;;
 318     esac
 319     if test x"$msnative_struct" = x ; then
 320       AC_MSG_RESULT([no way])
 321       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 322     else
 323       CFLAGS="$CFLAGS $msnative_struct"
 324       AC_MSG_RESULT([${msnative_struct}])
 325     fi
 326   fi
 327 fi
 328 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 329 AC_SUBST(GLIB_EXTRA_CFLAGS)
 330
 331 AC_EXEEXT
 332
 333 # define a MAINT-like variable REBUILD which is set if Perl
 334 # and awk are found, so autogenerated sources can be rebuilt
 335 AC_PROG_AWK
 336 AC_CHECK_PROGS(PERL, [perl5 perl])
 337 # We would like indent, but don't require it.
 338 AC_CHECK_PROG(INDENT, indent, indent)
 339 REBUILD=\#
 340 if test "x$enable_rebuilds" = "xyes" && \
 341      test -n "$PERL" && \
 342      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 343      test -n "$AWK" ; then
 344   REBUILD=
 345 fi
 346 AC_SUBST(REBUILD)
 347
 348 # Need full path to Perl for glib-mkenums
 349 #
 350 if test "x$PERL" != x ; then
 351   AC_PATH_PROG(PERL_PATH, [$PERL])
 352 fi
 353 if test "x$PERL_PATH" = x ; then
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 # Need suitable python path for greport
 359 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 360
 361
 362 dnl ***********************
 363 dnl *** Tests for iconv ***
 364 dnl ***********************
 365 dnl
 366 dnl We do this before the gettext checks, to avoid distortion
 367
 368 dnl On Windows we use a native implementation
 369
 370 if test x"$glib_native_win32" = xyes; then
 371   with_libiconv=native
 372 else
 373   AC_ARG_WITH(libiconv,
 374               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 375                               [use the libiconv library])],,
 376               [with_libiconv=maybe])
 377
 378   found_iconv=no
 379   case $with_libiconv in
 380     maybe)
 381       # Check in the C library first
 382       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 383       # Check if we have GNU libiconv
 384       if test $found_iconv = "no"; then
 385         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 386       fi
 387       # Check if we have a iconv in -liconv, possibly from vendor
 388       if test $found_iconv = "no"; then
 389         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 390       fi
 391       ;;
 392     no)
 393       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394       ;;
 395     gnu|yes)
 396       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397       ;;
 398     native)
 399       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 400       ;;
 401   esac
 402
 403   if test "x$found_iconv" = "xno" ; then
 404      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 405   fi
 406 fi
 407
 408 AC_ARG_ENABLE(iconv-cache,
 409               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 410                               [cache iconv descriptors [default=auto]])],,
 411               [enable_iconv_cache=auto])
 412
 413 AC_MSG_CHECKING([whether to cache iconv descriptors])
 414 case $enable_iconv_cache in
 415   auto)
 416     if test $ac_cv_gnu_library_2_1 = yes; then
 417       enable_iconv_cache=no
 418     else
 419       enable_iconv_cache=yes
 420     fi
 421   ;;
 422   yes|no)
 423   ;;
 424   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 425   ;;
 426 esac
 427
 428 if test $enable_iconv_cache = yes; then
 429    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 430 fi
 431
 432 AC_MSG_RESULT($enable_iconv_cache)
 433
 434
 435 dnl
 436 dnl zlib support
 437 dnl
 438 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 439 if test "x$found_zlib" = "xno" ; then
 440   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 441   if test "x$found_zlib" = "xno" ; then
 442     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 443   fi
 444   ZLIB_LIBS='-lz'
 445   AC_SUBST(ZLIB_LIBS)
 446 fi
 447
 448 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 449 AC_SUBST(LIBFFI_CFLAGS)
 450 AC_SUBST(LIBFFI_LIBS)
 451
 452 dnl
 453 dnl gettext support
 454 dnl
 455
 456 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 457 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 458 GLIB_GNU_GETTEXT
 459
 460 if test "$gt_cv_have_gettext" != "yes" ; then
 461   AC_MSG_ERROR([
 462 *** You must have either have gettext support in your C library, or use the
 463 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 464 ])
 465 fi
 466
 467 LIBS="$INTLLIBS $LIBS"
 468
 469 GETTEXT_PACKAGE=glib20
 470 AC_SUBST(GETTEXT_PACKAGE)
 471 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 472   [Define the gettext package to be used])
 473
 474 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 475
 476 dnl
 477 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 478 dnl
 479
 480 if test x"$glib_native_win32" != xyes; then
 481   if test x$with_libiconv != xno ; then
 482     case " $INTLLIBS " in
 483     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 484     *) ICONV_LIBS="-liconv" ;;
 485     esac
 486   fi
 487 fi
 488 AC_SUBST(ICONV_LIBS)
 489
 490 case $with_libiconv in
 491   gnu)
 492     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 493     ;;
 494   native)
 495     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 496     ;;
 497 esac
 498
 499 dnl Initialize libtool
 500 LT_PREREQ([2.2])
 501 LT_INIT([disable-static win32-dll])
 502 dnl when using libtool 2.x create libtool early, because it's used in configure
 503 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 504
 505
 506 if test "x$GCC" = "xyes"; then
 507   case " $CFLAGS " in
 508   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 509   *) CFLAGS="$CFLAGS -Wall" ;;
 510   esac
 511 fi
 512
 513 if test "$glib_native_win32" = "yes"; then
 514   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 515     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 516   fi
 517   if test x$enable_static = xyes; then
 518     glib_win32_static_compilation=yes
 519     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 520 #define GOBJECT_STATIC_COMPILATION 1"
 521     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 522   fi
 523 fi
 524 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 525
 526 dnl
 527 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 528 dnl
 529 if test $cross_compiling != yes ; then
 530     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 531     glib_save_LIBS=$LIBS
 532     LIBS="$LIBS -lm"
 533     AC_TRY_RUN([#include <math.h>
 534                  int main (void) { return (log(1) != log(1.)); }],
 535          AC_MSG_RESULT(none needed),
 536          glib_save_CFLAGS=$CFLAGS
 537          CFLAGS="$CFLAGS -std1"
 538          AC_TRY_RUN([#include <math.h>
 539                      int main (void) { return (log(1) != log(1.)); }],
 540              AC_MSG_RESULT(-std1),
 541              AC_MSG_RESULT()
 542              CFLAGS=$glib_save_CFLAGS
 543              AC_MSG_WARN(
 544                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 545          )
 546     )
 547     LIBS=$glib_save_LIBS
 548 fi
 549
 550 dnl NeXTStep cc seems to need this
 551 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 552 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 553   AC_MSG_RESULT(none needed),
 554   glib_save_CFLAGS=$CFLAGS
 555   CFLAGS="$CFLAGS -posix"
 556   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557     AC_MSG_RESULT(-posix),
 558     AC_MSG_RESULT()
 559     CFLAGS=$glib_save_CFLAGS
 560     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 561
 562 # Checks for library functions.
 563 AC_FUNC_VPRINTF
 564 AC_FUNC_ALLOCA
 565 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 566 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 567
 568 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 569 dnl be automatically defined, which we don't want to do
 570 dnl until we have checked this function is actually usable
 571 AC_CHECK_FUNC([qsort_r])
 572
 573 # BSD has a qsort_r with wrong argument order
 574 if test x$ac_cv_func_qsort_r = xyes ; then
 575   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 576   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 577   #define _GNU_SOURCE
 578   #include <stdlib.h>
 579
 580   static int
 581   cmp (const void *a, const void *b, void *c)
 582   {
 583     const int *ia = a;
 584     const int *ib = b;
 585
 586     if (*ia < *ib)
 587       return -1;
 588     else if (*ia > *ib)
 589       return 1;
 590     else
 591       return 0;
 592   }
 593
 594   int
 595   main (int argc, char **argv)
 596   {
 597     int arr[3] = { 1, 2, 0 };
 598     int d = 3;
 599
 600     qsort_r (arr, 3, sizeof (int), cmp, &d);
 601
 602     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 603       return 0;
 604     else
 605       return 1;
 606   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no],[glib_cv_have_qsort_r=no])])
 607 fi
 608
 609 if test x$glib_cv_have_qsort_r = xyes ; then
 610   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 611 fi
 612
 613 AC_CHECK_SIZEOF(char)
 614 AC_CHECK_SIZEOF(short)
 615 AC_CHECK_SIZEOF(long)
 616 AC_CHECK_SIZEOF(int)
 617 AC_CHECK_SIZEOF(void *)
 618 AC_CHECK_SIZEOF(long long)
 619 AC_CHECK_SIZEOF(__int64)
 620
 621 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 622   :
 623 else
 624   AC_MSG_ERROR([
 625 *** GLib requires a 64 bit type. You might want to consider
 626 *** using the GNU C compiler.
 627 ])
 628 fi
 629
 630 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 631         # long long is a 64 bit integer.
 632         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 633         AC_CACHE_VAL(glib_cv_long_long_format,[
 634                 for format in ll q I64; do
 635                   AC_TRY_RUN([#include <stdio.h>
 636                         int main()
 637                         {
 638                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 639                           char buffer[1000];
 640                           sprintf (buffer, "%${format}u", a);
 641                           sscanf (buffer, "%${format}u", &b);
 642                           exit (b!=a);
 643                         }
 644                         ],
 645                         [glib_cv_long_long_format=${format}
 646                         break],
 647                         [],[:])
 648                 done])
 649         if test -n "$glib_cv_long_long_format"; then
 650           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 651           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 652           if test x"$glib_cv_long_long_format" = xI64; then
 653             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 654           fi
 655         else
 656           AC_MSG_RESULT(none)
 657         fi
 658 elif test x$ac_cv_sizeof___int64 = x8; then
 659         # __int64 is a 64 bit integer.
 660         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 661         # We know this is MSVCRT.DLL, and what the formats are
 662         glib_cv_long_long_format=I64
 663         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 664         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 665         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 666 fi
 667
 668 AC_C_CONST
 669
 670 dnl ok, here we try to check whether the systems prototypes for
 671 dnl malloc and friends actually match the prototypes provided
 672 dnl by gmem.h (keep in sync). i currently only know how to check
 673 dnl this reliably with gcc (-Werror), improvements for other
 674 dnl compilers are apprechiated.
 675 SANE_MALLOC_PROTOS=no
 676 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 677 glib_save_CFLAGS=$CFLAGS
 678 if test "x$GCC" = "xyes"; then
 679   CFLAGS="$CFLAGS -Werror"
 680   AC_TRY_COMPILE([#include <stdlib.h>], [
 681     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 682     void* (*my_malloc_p)  (size_t)         = malloc;
 683     void  (*my_free_p)    (void*)          = free;
 684     void* (*my_realloc_p) (void*, size_t)  = realloc;
 685     my_calloc_p = 0;
 686     my_malloc_p = 0;
 687     my_free_p = 0;
 688     my_realloc_p = 0;
 689   ],
 690     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 691       [Define if you have correct malloc prototypes])
 692     SANE_MALLOC_PROTOS=yes)
 693 fi
 694 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 695 CFLAGS=$glib_save_CFLAGS
 696
 697 dnl
 698 dnl check in which direction the stack grows
 699 dnl
 700 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 701         AC_TRY_RUN([
 702         volatile int *a = 0, *b = 0;
 703         void foo (void);
 704         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 705         void foo (void) { volatile int x = 5; b = &x; }
 706         ],
 707         glib_cv_stack_grows=no
 708         ,
 709         glib_cv_stack_grows=yes
 710         ,)
 711 ])
 712
 713 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 714 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 715 dnl actually supported.
 716 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 717         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 718         __inline int foo () { return 0; }
 719         int main () { return foo (); }
 720         ]])],
 721         glib_cv_has__inline=yes
 722         ,
 723         glib_cv_has__inline=no
 724         ,)
 725 ])
 726 case x$glib_cv_has__inline in
 727 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 728 esac
 729 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 730         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 731         __inline__ int foo () { return 0; }
 732         int main () { return foo (); }
 733         ]])],
 734         glib_cv_has__inline__=yes
 735         ,
 736         glib_cv_has__inline__=no
 737         ,)
 738 ])
 739 case x$glib_cv_has__inline__ in
 740 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 741 esac
 742 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 743         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 744         #undef inline
 745         inline int foo () { return 0; }
 746         int main () { return foo (); }
 747         ]])],
 748         glib_cv_hasinline=yes
 749         ,
 750         glib_cv_hasinline=no
 751         ,)
 752 ])
 753 case x$glib_cv_hasinline in
 754 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 755 esac
 756
 757 # if we can use inline functions in headers
 758 AC_MSG_CHECKING(if inline functions in headers work)
 759 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 760 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 761 #  undef inline
 762 #  define inline __inline__
 763 #elif !defined (G_HAVE_INLINE)
 764 #  undef inline
 765 #  if defined (G_HAVE___INLINE__)
 766 #    define inline __inline__
 767 #  elif defined (G_HAVE___INLINE)
 768 #    define inline __inline
 769 #  endif
 770 #endif
 771
 772 int glib_test_func2 (int);
 773
 774 static inline int
 775 glib_test_func1 (void) {
 776   return glib_test_func2 (1);
 777 }
 778
 779 int
 780 main (void) {
 781   int i = 1;
 782 }]])],[g_can_inline=yes],[g_can_inline=no])
 783 AC_MSG_RESULT($g_can_inline)
 784
 785 dnl *** check for working do while(0) macros ***
 786 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 787         AC_TRY_COMPILE([],[
 788         #define STMT_START do
 789         #define STMT_END while(0)
 790         #define STMT_TEST STMT_START { i = 0; } STMT_END
 791         int main(void) { int i = 1; STMT_TEST; return i; }],
 792         [g_cv_support_dowhile_macros=yes],
 793         [g_cv_support_dowhile_macros=no],
 794         [g_cv_support_dowhile_macros=yes])
 795 ])
 796 if test x$g_cv_support_dowhile_macros = xyes; then
 797   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 798 fi
 799
 800 # check for flavours of varargs macros
 801 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 802 AC_TRY_COMPILE([],[
 803 int a(int p1, int p2, int p3);
 804 #define call_a(...) a(1,__VA_ARGS__)
 805 call_a(2,3);
 806 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 807 AC_MSG_RESULT($g_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 810 if test "$CXX" = ""; then
 811 dnl No C++ compiler
 812   g_have_iso_cxx_varargs=no
 813 else
 814   AC_LANG_CPLUSPLUS
 815   AC_TRY_COMPILE([],[
 816 int a(int p1, int p2, int p3);
 817 #define call_a(...) a(1,__VA_ARGS__)
 818 call_a(2,3);
 819 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 820   AC_LANG_C
 821 fi
 822 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 823
 824 AC_MSG_CHECKING(for GNUC varargs macros)
 825 AC_TRY_COMPILE([],[
 826 int a(int p1, int p2, int p3);
 827 #define call_a(params...) a(1,params)
 828 call_a(2,3);
 829 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 830 AC_MSG_RESULT($g_have_gnuc_varargs)
 831
 832 # check for GNUC visibility support
 833 AC_MSG_CHECKING(for GNUC visibility attribute)
 834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 835 void
 836 __attribute__ ((visibility ("hidden")))
 837      f_hidden (void)
 838 {
 839 }
 840 void
 841 __attribute__ ((visibility ("internal")))
 842      f_internal (void)
 843 {
 844 }
 845 void
 846 __attribute__ ((visibility ("protected")))
 847      f_protected (void)
 848 {
 849 }
 850 void
 851 __attribute__ ((visibility ("default")))
 852      f_default (void)
 853 {
 854 }
 855 int main (int argc, char **argv)
 856 {
 857         f_hidden();
 858         f_internal();
 859         f_protected();
 860         f_default();
 861         return 0;
 862 }
 863 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 864 AC_MSG_RESULT($g_have_gnuc_visibility)
 865 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 866
 867 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 868 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 869 #else
 870 # include "error: this is not Sun Studio."
 871 #endif
 872 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 873 AC_MSG_RESULT($g_have_sunstudio_visibility)
 874 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 875
 876 # check for bytesex stuff
 877 AC_C_BIGENDIAN
 878 if test x$ac_cv_c_bigendian = xuniversal ; then
 879 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 880 #else
 881 #error Not a big endian.
 882 #endif],
 883     ac_cv_c_bigendian=yes
 884     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 885 #else
 886 #error Not a little endian.
 887 #endif],
 888     ac_cv_c_bigendian=no
 889     ,AC_MSG_WARN([Could not determine endianness.])))
 890 fi
 891
 892
 893 # check for header files
 894 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 895 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 896 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 897 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 898 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 899 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 900 AC_CHECK_HEADERS([linux/magic.h])
 901 AC_CHECK_HEADERS([sys/prctl.h])
 902
 903 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 904 [#if HAVE_SYS_PARAM_H
 905  #include <sys/param.h>
 906  #endif
 907 ])
 908
 909 AC_CHECK_HEADERS([xlocale.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 AC_STRUCT_DIRENT_D_TYPE
 931
 932 # Checks for libcharset
 933 AM_LANGINFO_CODESET
 934 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 935 AC_CHECK_FUNCS(setlocale)
 936
 937 # check additional type sizes
 938 AC_CHECK_SIZEOF(size_t)
 939
 940 dnl Try to figure out whether gsize, gssize should be long or int
 941 AC_MSG_CHECKING([for the appropriate definition for size_t])
 942
 943 case $ac_cv_sizeof_size_t in
 944   $ac_cv_sizeof_short)
 945       glib_size_type=short
 946       ;;
 947   $ac_cv_sizeof_int)
 948       glib_size_type=int
 949       ;;
 950   $ac_cv_sizeof_long)
 951       glib_size_type=long
 952       ;;
 953   $ac_cv_sizeof_long_long)
 954       glib_size_type='long long'
 955       ;;
 956   $ac_cv_sizeof__int64)
 957       glib_size_type='__int64'
 958       ;;
 959   *)  AC_MSG_ERROR([No type matching size_t in size])
 960       ;;
 961 esac
 962
 963 dnl If int/long are the same size, we see which one produces
 964 dnl warnings when used in the location as size_t. (This matters
 965 dnl on AIX with xlc)
 966 dnl
 967 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 968    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 969   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 970 #if defined(_AIX) && !defined(__GNUC__)
 971 #pragma options langlvl=stdc89
 972 #endif
 973 #include <stddef.h>
 974 int main ()
 975 {
 976   size_t s = 1;
 977   unsigned int *size_int = &s;
 978   return (int)*size_int;
 979 }
 980     ]])],glib_size_type=int,
 981       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 982 #if defined(_AIX) && !defined(__GNUC__)
 983 #pragma options langlvl=stdc89
 984 #endif
 985 #include <stddef.h>
 986 int main ()
 987 {
 988    size_t s = 1;
 989    unsigned long *size_long = &s;
 990    return (int)*size_long;
 991 }
 992         ]])],glib_size_type=long)])
 993 fi
 994
 995 AC_MSG_RESULT(unsigned $glib_size_type)
 996
 997 # Check for some functions
 998 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 999 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1000 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1001 # Check for high-resolution sleep functions
1002 AC_CHECK_FUNCS(splice)
1003 AC_CHECK_FUNCS(prlimit)
1004
1005 # To avoid finding a compatibility unusable statfs, which typically
1006 # successfully compiles, but warns to use the newer statvfs interface:
1007 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1008 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1009
1010 AC_MSG_CHECKING([whether to use statfs or statvfs])
1011 # Some systems have both statfs and statvfs, pick the most "native" for these
1012 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1013    [
1014    # on solaris and irix, statfs doesn't even have the f_bavail field
1015    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1016       [ac_cv_func_statfs=no],
1017    # else, at least on linux, statfs is the actual syscall
1018       [ac_cv_func_statvfs=no])
1019    ])
1020
1021 AS_IF([test x$ac_cv_func_statfs = xyes],
1022       [
1023          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1024          AC_MSG_RESULT([statfs])
1025       ],
1026       [test x$ac_cv_func_statvfs = xyes],
1027       [
1028          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1029          AC_MSG_RESULT([statvfs])
1030       ],
1031       [  AC_MSG_RESULT([neither])])
1032
1033 AC_CHECK_HEADERS(crt_externs.h)
1034 AC_CHECK_FUNCS(_NSGetEnviron)
1035
1036 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1037
1038 AC_FUNC_VSNPRINTF_C99
1039 AC_FUNC_PRINTF_UNIX98
1040
1041 # Internet address families
1042 if test $glib_native_win32 = yes; then
1043   glib_inet_includes=["
1044 #include <winsock2.h>
1045   "]
1046 else
1047   glib_inet_includes=["
1048 #include <sys/types.h>
1049 #include <sys/socket.h>
1050   "]
1051 fi
1052
1053 glib_failed=false
1054 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1055 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1056 # winsock defines this even though it doesn't support it
1057 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1058 if $glib_failed ; then
1059   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1060 fi
1061
1062 glib_failed=false
1063 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1064 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1066 if $glib_failed ; then
1067   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1068 fi
1069
1070 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1071 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1072
1073 if test $glib_native_win32 = no; then
1074   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1075   NETWORK_LIBS=""
1076   AC_MSG_CHECKING([for res_query])
1077   AC_TRY_LINK([#include <sys/types.h>
1078                #include <netinet/in.h>
1079                #include <arpa/nameser.h>
1080                #include <resolv.h>
1081               ],[
1082                res_query("test", 0, 0, (void *)0, 0);
1083               ],[AC_MSG_RESULT([yes])],
1084               [save_libs="$LIBS"
1085                LIBS="-lresolv $LIBS"
1086                AC_TRY_LINK([#include <sys/types.h>
1087                             #include <netinet/in.h>
1088                             #include <arpa/nameser.h>
1089                             #include <resolv.h>
1090                            ],[
1091                             res_query("test", 0, 0, (void *)0, 0);
1092                            ],[AC_MSG_RESULT([in -lresolv])
1093                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1094                            [LIBS="-lbind $save_libs"
1095                             AC_TRY_LINK([#include <resolv.h>],
1096                                         [res_query("test", 0, 0, (void *)0, 0);],
1097                                         [AC_MSG_RESULT([in -lbind])
1098                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1099                                         [AC_MSG_ERROR(not found)])])
1100                LIBS="$save_libs"])
1101   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1102                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1103                                         [AC_MSG_ERROR(Could not find socket())]))
1104 fi
1105 AC_SUBST(NETWORK_LIBS)
1106
1107 AC_CHECK_HEADER([linux/netlink.h],
1108                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1109                 [#include <sys/socket.h>])
1110 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1111
1112 AC_CHECK_TYPE([struct ip_mreqn], [
1113               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1114               [#include <netinet/in.h>])
1115
1116 case $host in
1117   *-*-solaris* )
1118      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1119      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1120      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1121      ;;
1122 esac
1123
1124 dnl
1125 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1126 dnl
1127 if test "$ac_cv_func_statfs" = yes ; then
1128   AC_MSG_CHECKING([number of arguments to statfs()])
1129   AC_TRY_COMPILE([#include <unistd.h>
1130   #ifdef HAVE_SYS_PARAM_H
1131   #include <sys/param.h>
1132   #endif
1133   #ifdef HAVE_SYS_VFS_H
1134   #include <sys/vfs.h>
1135   #endif
1136   #ifdef HAVE_SYS_MOUNT_H
1137   #include <sys/mount.h>
1138   #endif
1139   #ifdef HAVE_SYS_STATFS_H
1140   #include <sys/statfs.h>
1141   #endif], [struct statfs st;
1142   statfs(NULL, &st);],[
1143     AC_MSG_RESULT([2])
1144     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1145     AC_TRY_COMPILE([#include <unistd.h>
1146   #ifdef HAVE_SYS_PARAM_H
1147   #include <sys/param.h>
1148   #endif
1149   #ifdef HAVE_SYS_VFS_H
1150   #include <sys/vfs.h>
1151   #endif
1152   #ifdef HAVE_SYS_MOUNT_H
1153   #include <sys/mount.h>
1154   #endif
1155   #ifdef HAVE_SYS_STATFS_H
1156   #include <sys/statfs.h>
1157   #endif], [struct statfs st;
1158   statfs(NULL, &st, sizeof (st), 0);],[
1159       AC_MSG_RESULT([4])
1160       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1161       AC_MSG_RESULT(unknown)
1162       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1163 fi
1164
1165 #
1166 # Check whether to use an included printf
1167 #
1168
1169 AC_ARG_ENABLE(included-printf,
1170               [AC_HELP_STRING([--enable-included-printf],
1171                               [use included printf [default=auto]])],
1172               enable_included_printf="$enableval")
1173
1174 need_included_printf=no
1175 if test "x$enable_included_printf" = "xyes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1182   need_included_printf=yes
1183 fi
1184 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1185    test -z "$glib_cv_long_long_format" ; then
1186   need_included_printf=yes
1187 fi
1188
1189 if test "x$enable_included_printf" = "xno" &&
1190    test "x$need_included_printf" = "xyes" ; then
1191   AC_MSG_ERROR([
1192 *** Your C library's printf doesn't appear to have the features that
1193 *** GLib needs, but you specified --enable-included-printf=no.])
1194 fi
1195
1196 enable_included_printf=$need_included_printf
1197
1198 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1199 if test "$enable_included_printf" != "yes" ; then
1200   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1201 else
1202   if test -z "$glib_cv_long_long_format" ; then
1203     glib_cv_long_long_format="ll"
1204   fi
1205   AC_DEFINE(HAVE_VASPRINTF,1)
1206 fi
1207
1208 # Checks needed for gnulib vasnprintf
1209 bh_C_SIGNED
1210 jm_AC_TYPE_LONG_LONG
1211 gt_TYPE_LONGDOUBLE
1212 gt_TYPE_WCHAR_T
1213 gt_TYPE_WINT_T
1214 AC_TYPE_SIZE_T
1215 AC_CHECK_TYPES(ptrdiff_t)
1216 jm_AC_TYPE_INTMAX_T
1217 AC_CHECK_FUNCS([snprintf wcslen])
1218 AC_FUNC_SNPRINTF_C99
1219
1220 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1221 # The check is borrowed from the PERL Configure script.
1222 if test "$ac_cv_func_memmove" != "yes"; then
1223   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1224     glib_cv_working_bcopy,[AC_TRY_RUN([
1225       int main() {
1226         char buf[128], abc[128], *b;
1227         int len, off, align;
1228         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1229         for (align = 7; align >= 0; align--) {
1230           for (len = 36; len; len--) {
1231             b = buf+align; bcopy(abc, b, len);
1232             for (off = 1; off <= len; off++) {
1233               bcopy(b, b+off, len); bcopy(b+off, b, len);
1234                 if (bcmp(b, abc, len)) return(1);
1235             }
1236           }
1237         }
1238         return(0);
1239       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1240
1241   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1242   if test "$glib_cv_working_bcopy" = "yes"; then
1243     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1244   fi
1245 fi
1246
1247 # Check if <sys/select.h> needs to be included for fd_set
1248 AC_MSG_CHECKING([for fd_set])
1249 AC_TRY_COMPILE([#include <sys/types.h>],
1250         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1251 if test "$gtk_ok" = "yes"; then
1252     AC_MSG_RESULT([yes, found in sys/types.h])
1253 else
1254     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1255     if test "$gtk_ok" = "yes"; then
1256         # *** FIXME: give it a different name
1257         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1258         AC_MSG_RESULT([yes, found in sys/select.h])
1259     else
1260         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1261         AC_MSG_RESULT(no)
1262     fi
1263 fi
1264
1265 dnl *** check for sane realloc() ***
1266 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1267         AC_TRY_RUN([#include <stdlib.h>
1268         int main() {
1269           return realloc (0, sizeof (int)) == 0;
1270         }],
1271         [glib_cv_sane_realloc=yes],
1272         [glib_cv_sane_realloc=no],
1273         [glib_cv_sane_realloc=yes])
1274 ])
1275 if test x$glib_cv_sane_realloc = xyes; then
1276   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1277 fi
1278
1279 dnl Check for nl_langinfo and CODESET
1280 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *codeset = nl_langinfo (CODESET);],
1283                 [glib_cv_langinfo_codeset=yes],
1284                 [glib_cv_langinfo_codeset=no])])
1285 if test x$glib_cv_langinfo_codeset = xyes; then
1286   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1287 fi
1288
1289 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1290 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1291         AC_TRY_COMPILE([#include <langinfo.h>],
1292                 [char *str;
1293                  str = nl_langinfo (PM_STR);
1294                  str = nl_langinfo (D_T_FMT);
1295                  str = nl_langinfo (D_FMT);
1296                  str = nl_langinfo (T_FMT);
1297                  str = nl_langinfo (T_FMT_AMPM);
1298                  str = nl_langinfo (MON_1);
1299                  str = nl_langinfo (ABMON_12);
1300                  str = nl_langinfo (DAY_1);
1301                  str = nl_langinfo (ABDAY_7);],
1302                 [glib_cv_langinfo_time=yes],
1303                 [glib_cv_langinfo_time=no])])
1304 if test x$glib_cv_langinfo_time = xyes; then
1305   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1306 fi
1307
1308 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1309 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1310         AC_TRY_COMPILE([#include <langinfo.h>],
1311                 [char *str;
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1322                 [glib_cv_langinfo_outdigit=yes],
1323                 [glib_cv_langinfo_outdigit=no])])
1324 if test x$glib_cv_langinfo_outdigit = xyes; then
1325   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1326 fi
1327
1328 dnl ****************************************
1329 dnl *** posix_memalign                   ***
1330 dnl ****************************************
1331 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1332 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1333     glib_cv_compliant_posix_memalign=0
1334     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1335         AC_TRY_RUN([
1336                 #define _XOPEN_SOURCE 600
1337                 #include <stdlib.h> /* posix_memalign() should be defined here */
1338                 /* some systems break if #include <malloc.h> used */
1339                 static void test_memalign (size_t boundary, size_t size) {
1340                     void *mem = 0;
1341                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1342                         exit (1);
1343                     else
1344                       free (mem);
1345                 }
1346                 int main() {
1347                     test_memalign (  128,   128 - 2 * sizeof (void*));
1348                     test_memalign (  256,   256 - 2 * sizeof (void*));
1349                     test_memalign (  512,   512 - 2 * sizeof (void*));
1350                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1351                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1352                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1353                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1354                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1355                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1356                     exit (0); /* success */
1357                 }
1358                 ],
1359             [glib_cv_compliant_posix_memalign=1], [], [:])
1360       :
1361     fi
1362     ])
1363 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1364     AC_MSG_RESULT(yes)
1365     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1366 else
1367     AC_MSG_RESULT(no)
1368 fi
1369
1370
1371 dnl ****************************************
1372 dnl *** strlcpy/strlcat                  ***
1373 dnl ****************************************
1374 # Check for strlcpy
1375 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1376 AC_TRY_RUN([#include <stdlib.h>
1377 #include <string.h>
1378 int main() {
1379   char p[10];
1380   (void) strlcpy (p, "hi", 10);
1381   if (strlcat (p, "bye", 0) != 3)
1382     return 1;
1383   return 0;
1384 }], glib_cv_have_strlcpy=yes,
1385     glib_cv_have_strlcpy=no,
1386     glib_cv_have_strlcpy=no)])
1387 if test "$glib_cv_have_strlcpy" = "yes"; then
1388     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1389 fi
1390
1391
1392 dnl **********************
1393 dnl *** va_copy checks ***
1394 dnl **********************
1395 dnl we currently check for all three va_copy possibilities, so we get
1396 dnl all results in config.log for bug reports.
1397 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1398         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1399 #include <stdlib.h>
1400         void f (int i, ...) {
1401         va_list args1, args2;
1402         va_start (args1, i);
1403         va_copy (args2, args1);
1404         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1405           exit (1);
1406         va_end (args1); va_end (args2);
1407         }
1408         int main() {
1409           f (0, 42);
1410           return 0;
1411         }]])],
1412         [glib_cv_va_copy=yes],
1413         [glib_cv_va_copy=no])
1414 ])
1415 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1416         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1417 #include <stdlib.h>
1418         void f (int i, ...) {
1419         va_list args1, args2;
1420         va_start (args1, i);
1421         __va_copy (args2, args1);
1422         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1423           exit (1);
1424         va_end (args1); va_end (args2);
1425         }
1426         int main() {
1427           f (0, 42);
1428           return 0;
1429         }]])],
1430         [glib_cv___va_copy=yes],
1431         [glib_cv___va_copy=no])
1432 ])
1433
1434 if test "x$glib_cv_va_copy" = "xyes"; then
1435   g_va_copy_func=va_copy
1436 else if test "x$glib_cv___va_copy" = "xyes"; then
1437   g_va_copy_func=__va_copy
1438 fi
1439 fi
1440
1441 if test -n "$g_va_copy_func"; then
1442   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1443 fi
1444
1445 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1446         AC_TRY_RUN([#include <stdarg.h>
1447 #include <stdlib.h>
1448         void f (int i, ...) {
1449         va_list args1, args2;
1450         va_start (args1, i);
1451         args2 = args1;
1452         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1453           exit (1);
1454         va_end (args1); va_end (args2);
1455         }
1456         int main() {
1457           f (0, 42);
1458           return 0;
1459         }],
1460         [glib_cv_va_val_copy=yes],
1461         [glib_cv_va_val_copy=no],
1462         [glib_cv_va_val_copy=yes])
1463 ])
1464
1465 if test "x$glib_cv_va_val_copy" = "xno"; then
1466   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1467 fi
1468
1469 dnl ***********************
1470 dnl *** g_module checks ***
1471 dnl ***********************
1472 G_MODULE_LIBS=
1473 G_MODULE_LIBS_EXTRA=
1474 G_MODULE_PLUGIN_LIBS=
1475 if test x"$glib_native_win32" = xyes; then
1476   dnl No use for this on Win32
1477   G_MODULE_LDFLAGS=
1478 else
1479   export SED
1480   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1481 fi
1482 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1483 G_MODULE_NEED_USCORE=0
1484 G_MODULE_BROKEN_RTLD_GLOBAL=0
1485 G_MODULE_HAVE_DLERROR=0
1486 dnl *** force native WIN32 shared lib loader
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1490   esac
1491 fi
1492 dnl *** force native AIX library loader
1493 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1494 if test -z "$G_MODULE_IMPL"; then
1495   case "$host" in
1496   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1497   esac
1498 fi
1499 dnl *** dlopen() and dlsym() in system libraries
1500 if test -z "$G_MODULE_IMPL"; then
1501         AC_CHECK_FUNC(dlopen,
1502                       [AC_CHECK_FUNC(dlsym,
1503                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1504                       [])
1505 fi
1506 dnl *** load_image (BeOS)
1507 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1508   AC_CHECK_LIB(root, load_image,
1509       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1510       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1511       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1512       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1513       [])
1514 fi
1515 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1516 if test -z "$G_MODULE_IMPL"; then
1517         AC_CHECK_FUNC(NSLinkModule,
1518                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1519                        G_MODULE_NEED_USCORE=1],
1520                       [])
1521 fi
1522 dnl *** dlopen() and dlsym() in libdl
1523 if test -z "$G_MODULE_IMPL"; then
1524         AC_CHECK_LIB(dl, dlopen,
1525                      [AC_CHECK_LIB(dl, dlsym,
1526                                    [G_MODULE_LIBS=-ldl
1527                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1528                      [])
1529 fi
1530 dnl *** shl_load() in libdld (HP-UX)
1531 if test -z "$G_MODULE_IMPL"; then
1532         AC_CHECK_LIB(dld, shl_load,
1533                 [G_MODULE_LIBS=-ldld
1534                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1535                 [])
1536 fi
1537 dnl *** additional checks for G_MODULE_IMPL_DL
1538 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1539         LIBS_orig="$LIBS"
1540         LDFLAGS_orig="$LDFLAGS"
1541         LIBS="$G_MODULE_LIBS $LIBS"
1542         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1543 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1544         echo "void glib_plugin_test(void) { }" > plugin.c
1545         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1546                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1547         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1548                 glib_cv_rtldglobal_broken,[
1549                 AC_TRY_RUN([
1550 #include <dlfcn.h>
1551 #ifndef RTLD_GLOBAL
1552 #  define RTLD_GLOBAL 0
1553 #endif
1554 #ifndef RTLD_LAZY
1555 #  define RTLD_LAZY 0
1556 #endif
1557 int glib_plugin_test;
1558 int main () {
1559     void *handle, *global, *local;
1560     global = &glib_plugin_test;
1561     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1562     if (!handle) return 0;
1563     local = dlsym (handle, "glib_plugin_test");
1564     return global == local;
1565 }                       ],
1566                         [glib_cv_rtldglobal_broken=no],
1567                         [glib_cv_rtldglobal_broken=yes],
1568                         [glib_cv_rtldglobal_broken=no])
1569                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1570                 rmdir .libs 2>/dev/null
1571         ])
1572         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1573                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1574         else
1575                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1576         fi
1577 dnl *** check whether we need preceeding underscores
1578         AC_CACHE_CHECK([for preceeding underscore in symbols],
1579                 glib_cv_uscore,[
1580                 AC_TRY_RUN([#include <dlfcn.h>
1581                 int glib_underscore_test (void) { return 42; }
1582                 int main() {
1583                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1584                   handle = dlopen ((void*)0, 0);
1585                   if (handle) {
1586                     f1 = dlsym (handle, "glib_underscore_test");
1587                     f2 = dlsym (handle, "_glib_underscore_test");
1588                   } return (!f2 || f1);
1589                 }],
1590                         [glib_cv_uscore=yes],
1591                         [glib_cv_uscore=no],
1592                         [])
1593                 rm -f plugin.c plugin.$ac_objext plugin.lo
1594         ])
1595         GLIB_ASSERT_SET(glib_cv_uscore)
1596         if test "x$glib_cv_uscore" = "xyes"; then
1597                 G_MODULE_NEED_USCORE=1
1598         else
1599                 G_MODULE_NEED_USCORE=0
1600         fi
1601
1602         LDFLAGS="$LDFLAGS_orig"
1603 dnl *** check for having dlerror()
1604         AC_CHECK_FUNC(dlerror,
1605                 [G_MODULE_HAVE_DLERROR=1],
1606                 [G_MODULE_HAVE_DLERROR=0])
1607         LIBS="$LIBS_orig"
1608 fi
1609 dnl *** done, have we got an implementation?
1610 if test -z "$G_MODULE_IMPL"; then
1611         G_MODULE_IMPL=0
1612         G_MODULE_SUPPORTED=false
1613 else
1614         G_MODULE_SUPPORTED=true
1615 fi
1616
1617 AC_MSG_CHECKING(for the suffix of module shared libraries)
1618 export SED
1619 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1620 eval $shrext_cmds
1621 module=yes eval std_shrext=$shrext_cmds
1622 # chop the initial dot
1623 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1624 AC_MSG_RESULT(.$glib_gmodule_suffix)
1625 # any reason it may fail?
1626 if test "x$glib_gmodule_suffix" = x; then
1627         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1628 fi
1629
1630 AC_SUBST(G_MODULE_SUPPORTED)
1631 AC_SUBST(G_MODULE_IMPL)
1632 AC_SUBST(G_MODULE_LIBS)
1633 AC_SUBST(G_MODULE_LIBS_EXTRA)
1634 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1635 AC_SUBST(G_MODULE_LDFLAGS)
1636 AC_SUBST(G_MODULE_HAVE_DLERROR)
1637 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1638 AC_SUBST(G_MODULE_NEED_USCORE)
1639 AC_SUBST(GLIB_DEBUG_FLAGS)
1640
1641 dnl **********************
1642 dnl *** g_spawn checks ***
1643 dnl **********************
1644
1645 AC_MSG_CHECKING(for gspawn implementation)
1646 case "$host" in
1647   *-*-mingw*)
1648     GSPAWN=gspawn-win32.lo
1649     ;;
1650   *)
1651     GSPAWN=gspawn.lo
1652     ;;
1653 esac
1654 AC_MSG_RESULT($GSPAWN)
1655 AC_SUBST(GSPAWN)
1656
1657 dnl *************************
1658 dnl *** GIOChannel checks ***
1659 dnl *************************
1660
1661 AC_MSG_CHECKING(for GIOChannel implementation)
1662 case "$host" in
1663   *-*-mingw*)
1664     GIO=giowin32.lo
1665     ;;
1666   *)
1667     GIO=giounix.lo
1668     ;;
1669 esac
1670 AC_MSG_RESULT($GIO)
1671 AC_SUBST(GIO)
1672
1673 dnl *********************************
1674 dnl *** Directory for GIO modules ***
1675 dnl *********************************
1676
1677 AC_ARG_WITH(gio-module-dir,
1678            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1679                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1680            [],
1681            [with_gio_module_dir='${libdir}/gio/modules'])
1682 GIO_MODULE_DIR=$with_gio_module_dir
1683 AC_SUBST(GIO_MODULE_DIR)
1684
1685 dnl **********************************
1686 dnl *** Check for libselinux (GIO) ***
1687 dnl **********************************
1688 AC_ARG_ENABLE(selinux,
1689               AC_HELP_STRING([--disable-selinux],
1690                              [build without selinux support]))
1691 msg_selinux=no
1692 SELINUX_LIBS=
1693 if test "x$enable_selinux" != "xno"; then
1694
1695  AC_CHECK_LIB(selinux, is_selinux_enabled,
1696    [AC_CHECK_HEADERS(selinux/selinux.h,
1697      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1698        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1699         SELINUX_LIBS="-lselinux"
1700         msg_selinux=yes])
1701      ])
1702    ])
1703 fi
1704 AC_SUBST(SELINUX_LIBS)
1705
1706 dnl *****************************
1707 dnl ** Check for inotify (GIO) **
1708 dnl *****************************
1709 inotify_support=no
1710 AC_CHECK_HEADERS([sys/inotify.h],
1711 [
1712         inotify_support=yes
1713         AC_CHECK_FUNCS(inotify_init1)
1714 ])
1715
1716 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1717
1718 dnl *********************************
1719 dnl ** Check for Solaris FEN (GIO) **
1720 dnl *********************************
1721 fen_support=no
1722 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1723 #include <port.h>
1724 #ifndef PORT_SOURCE_FILE
1725 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1726 #endif
1727 int main() { return 0; } ]])],
1728 [
1729         fen_support=yes
1730 ],)
1731
1732 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1733
1734 dnl ****************************
1735 dnl *** Checks for FAM (GIO) ***
1736 dnl ****************************
1737
1738 should_disable_fam=no
1739
1740 AC_ARG_ENABLE(fam,
1741               AC_HELP_STRING([--disable-fam],
1742                              [don't use fam for file system monitoring]),
1743                          [
1744                                 if test "x$enable_fam" = "xno"; then
1745                                         should_disable_fam=yes
1746                                 fi
1747                          ]
1748                          )
1749 fam_support=no
1750 FAM_LIBS=
1751 if test "x$should_disable_fam" = "xno"; then
1752 AC_CHECK_LIB(fam, FAMOpen,
1753   [AC_CHECK_HEADERS(fam.h,
1754     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1755      AC_CHECK_LIB(fam, FAMNoExists,
1756                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1757      FAM_LIBS="-lfam"]
1758      fam_support=yes,
1759     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1760   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1761 AC_SUBST(FAM_LIBS)
1762 fi
1763 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1764
1765
1766 dnl *****************************
1767 dnl *** Check for xattr (GIO) ***
1768 dnl *****************************
1769 AC_ARG_ENABLE(xattr,
1770               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1771 msg_xattr=no
1772 XATTR_LIBS=
1773 if test "x$enable_xattr" != "xno"; then
1774
1775 dnl either glibc or libattr can provide xattr support
1776
1777 dnl for both of them, we check for getxattr being in
1778 dnl the library and a valid xattr header.
1779
1780 dnl try glibc
1781  AC_CHECK_LIB(c, getxattr,
1782    [AC_CHECK_HEADERS(sys/xattr.h,
1783      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1784       msg_xattr=yes])
1785    ])
1786
1787   if test "x$msg_xattr" != "xyes"; then
1788 dnl   failure. try libattr
1789    AC_CHECK_LIB(attr, getxattr,
1790       [AC_CHECK_HEADERS(attr/xattr.h,
1791        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1792         XATTR_LIBS="-lattr"
1793         msg_xattr=yes])
1794       ])
1795   fi
1796
1797   if test "x$msg_xattr" = "xyes"; then
1798     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1799     AC_TRY_COMPILE([
1800       #include <stdio.h>
1801       #ifdef HAVE_SYS_TYPES_H
1802       #include <sys/types.h>
1803       #endif
1804       #ifdef HAVE_SYS_XATTR_H
1805       #include <sys/xattr.h>
1806       #elif HAVE_ATTR_XATTR_H
1807       #include <attr/xattr.h>
1808       #endif
1809     ],
1810     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1811     [
1812       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1813       AC_MSG_RESULT([yes])
1814     ],
1815     [AC_MSG_RESULT([no])]
1816     )
1817   fi
1818
1819 fi
1820 AC_SUBST(XATTR_LIBS)
1821
1822 dnl ************************
1823 dnl *** check for libelf ***
1824 dnl ************************
1825
1826 AC_CHECK_LIB([elf], [elf_begin], have_libelf=yes, have_libelf=no)
1827 if test $have_libelf = yes; then
1828   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1829   ELF_LIBS=-lelf
1830 fi
1831 AC_SUBST(ELF_LIBS)
1832
1833 dnl ****************************************
1834 dnl *** platform dependent source checks ***
1835 dnl ****************************************
1836
1837 AC_MSG_CHECKING(for platform-dependent source)
1838 case "$host" in
1839   *-*-cygwin*|*-*-mingw*)
1840     PLATFORMDEP=gwin32.lo
1841     ;;
1842   *)
1843     PLATFORMDEP=
1844     ;;
1845 esac
1846 AC_MSG_RESULT($PLATFORMDEP)
1847 AC_SUBST(PLATFORMDEP)
1848
1849 AC_MSG_CHECKING([whether to compile timeloop])
1850 case "$host" in
1851   *-*-cygwin*|*-*-mingw*|*-*-minix)
1852     enable_timeloop=no
1853     ;;
1854   *)
1855     enable_timeloop=yes
1856     ;;
1857 esac
1858 AC_MSG_RESULT($enable_timeloop)
1859 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1860
1861 AC_MSG_CHECKING([if building for some Win32 platform])
1862 case "$host" in
1863   *-*-mingw*|*-*-cygwin*)
1864     platform_win32=yes
1865     ;;
1866   *)
1867     platform_win32=no
1868     ;;
1869 esac
1870 AC_MSG_RESULT($platform_win32)
1871 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1872
1873 dnl ***********************
1874 dnl *** g_thread checks ***
1875 dnl ***********************
1876
1877 AC_ARG_WITH(threads,
1878            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1879                            [specify a thread implementation to use])],
1880            [],
1881            [with_threads=yes])
1882
1883 dnl error and warning message
1884 dnl *************************
1885
1886 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1887
1888 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1889                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1890                 compilation now, but then your programs might not work.
1891                 Please provide information on how it is done on your system."
1892
1893 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1894                  "
1895
1896 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1897                   provide information on your thread implementation."
1898
1899 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1900                 functions will not be MT-safe during their first call because
1901                 there is no working 'getpwuid_r' on your system."
1902
1903 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1904                 because there is no 'localtime_r' on your system."
1905
1906 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1907                 linking threaded applications. As GLib cannot do that
1908                 automatically, you will get an linkg error everytime you are
1909                 not using the right compiler. In that case you have to relink
1910                 with the right compiler. Ususally just '_r' is appended
1911                 to the compiler name."
1912
1913 dnl determination of thread implementation
1914 dnl ***************************************
1915
1916 AC_MSG_CHECKING(for thread implementation)
1917
1918 have_threads=no
1919 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1920         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1921         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1922         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1923         glib_save_CPPFLAGS="$CPPFLAGS"
1924         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1925         if test "x$have_threads" = xno; then
1926                 AC_TRY_COMPILE([#include <pthread.h>],
1927                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1928                         have_threads=posix)
1929         fi
1930         # Tru64Unix requires -pthread to find pthread.h. See #103020
1931         CPPFLAGS="$CPPFLAGS -pthread"
1932         if test "x$have_threads" = xno; then
1933         AC_TRY_COMPILE([#include <pthread.h>],
1934                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1935                        have_threads=posix)
1936         fi
1937         CPPFLAGS="$glib_save_CPPFLAGS"
1938 fi
1939 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1940         case $host in
1941                 *-*-mingw*)
1942                 have_threads=win32
1943                 ;;
1944         esac
1945 fi
1946
1947 if test "x$have_threads" = xno; then
1948         AC_MSG_RESULT(none available)
1949         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1950 else
1951         AC_MSG_RESULT($have_threads)
1952 fi
1953
1954
1955 dnl determination of G_THREAD_CFLAGS
1956 dnl ********************************
1957
1958 G_THREAD_LIBS=
1959 G_THREAD_LIBS_EXTRA=
1960 G_THREAD_CFLAGS=
1961
1962 dnl
1963 dnl Test program for basic POSIX threads functionality
1964 dnl
1965 m4_define([glib_thread_test],[
1966 #include <pthread.h>
1967 int check_me = 0;
1968 void* func(void* data) {check_me = 42; return &check_me;}
1969 int main()
1970  { pthread_t t;
1971    void *ret;
1972    pthread_create (&t, $1, func, 0);
1973    pthread_join (t, &ret);
1974    return (check_me != 42 || ret != &check_me);
1975 }])
1976
1977 if test x"$have_threads" = xposix; then
1978   # First we test for posix, whether -pthread or -pthreads do the trick as
1979   # both CPPFLAG and LIBS.
1980   # One of them does for most gcc versions and some other platforms/compilers
1981   # too and could be considered as the canonical way to go.
1982   case $host in
1983     *-*-cygwin*|*-*-darwin*)
1984        # skip cygwin and darwin -pthread or -pthreads test
1985        ;;
1986     *-solaris*)
1987       # These compiler/linker flags work with both Sun Studio and gcc
1988       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1989       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1990       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1991       G_THREAD_LIBS="-lpthread -lthread"
1992       ;;
1993     *)
1994       for flag in pthread pthreads mt; do
1995         glib_save_CFLAGS="$CFLAGS"
1996         CFLAGS="$CFLAGS -$flag"
1997         AC_TRY_RUN(glib_thread_test(0),
1998                    glib_flag_works=yes,
1999                    glib_flag_works=no,
2000                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2001                                    glib_flag_works=yes,
2002                                    glib_flag_works=no)])
2003         CFLAGS="$glib_save_CFLAGS"
2004         if test $glib_flag_works = yes ; then
2005            G_THREAD_CFLAGS=-$flag
2006         G_THREAD_LIBS=-$flag
2007         break;
2008         fi
2009       done
2010        ;;
2011   esac
2012 fi
2013
2014 if test x"$G_THREAD_CFLAGS" = x; then
2015
2016   # The canonical -pthread[s] does not work. Try something different.
2017
2018   case $host in
2019         *-aix*)
2020                 if test x"$GCC" = xyes; then
2021                         # GCC 3.0 and above needs -pthread.
2022                         # Should be coverd by the case above.
2023                         # GCC 2.x and below needs -mthreads
2024                         G_THREAD_CFLAGS="-mthreads"
2025                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2026                 else
2027                         # We are probably using the aix compiler. Normaly a
2028                         # program would have to be compiled with the _r variant
2029                         # of the corresponding compiler, but we as GLib cannot
2030                         # do that: but the good news is that for compiling the
2031                         # only difference is the added -D_THREAD_SAFE compile
2032                         # option. This is according to the "C for AIX User's
2033                         # Guide".
2034                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2035                 fi
2036                 ;;
2037         *-dg-dgux*)  # DG/UX
2038                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2039                 ;;
2040         *-sysv5uw7*) # UnixWare 7
2041                 # We are not using gcc with -pthread. Catched above.
2042                 G_THREAD_CFLAGS="-Kthread"
2043                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2044                 ;;
2045         *-mingw*)
2046                 # No flag needed when using MSVCRT.DLL
2047                 G_THREAD_CFLAGS=""
2048                 ;;
2049         *)
2050                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2051                 ;;
2052   esac
2053
2054 fi
2055
2056 # if we are not finding the localtime_r function, then we probably are
2057 # not using the proper multithread flag
2058
2059 glib_save_CPPFLAGS="$CPPFLAGS"
2060 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2061
2062 # First we test, whether localtime_r is declared in time.h
2063 # directly. Then we test whether a macro localtime_r exists, in
2064 # which case localtime_r in the test program is replaced and thus
2065 # if we still find localtime_r in the output, it is not defined as
2066 # a macro.
2067
2068 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2069   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2070                                                            localtime_r(a,b)],
2071                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2072
2073 CPPFLAGS="$glib_save_CPPFLAGS"
2074
2075 AC_MSG_CHECKING(thread related cflags)
2076 AC_MSG_RESULT($G_THREAD_CFLAGS)
2077 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2078
2079 dnl determination of G_THREAD_LIBS
2080 dnl ******************************
2081
2082 case $have_threads in
2083         posix)
2084           glib_save_CPPFLAGS="$CPPFLAGS"
2085           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2086           if test x"$G_THREAD_LIBS" = x; then
2087             case $host in
2088               *-aix*)
2089                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2090                 # probably using the aix compiler.
2091                 AC_MSG_WARN($AIX_COMPILE_INFO)
2092                 ;;
2093               *)
2094                 G_THREAD_LIBS=error
2095                 glib_save_LIBS="$LIBS"
2096                 for thread_lib in "" pthread pthread32 pthreads thread; do
2097                         if test x"$thread_lib" = x; then
2098                                 add_thread_lib=""
2099                                 IN=""
2100                         else
2101                                 add_thread_lib="-l$thread_lib"
2102                                 IN=" in -l$thread_lib"
2103                         fi
2104                         if test x"$have_threads" = xposix; then
2105                                 defattr=0
2106                         else
2107                                 defattr=pthread_attr_default
2108                         fi
2109
2110                         LIBS="$add_thread_lib $glib_save_LIBS"
2111
2112                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2113                         AC_TRY_RUN(glib_thread_test($defattr),
2114                                    glib_result=yes,
2115                                    glib_result=no,
2116                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2117                                                    glib_result=yes,
2118                                                    glib_result=no)])
2119                         AC_MSG_RESULT($glib_result)
2120
2121                         if test "$glib_result" = "yes" ; then
2122                           G_THREAD_LIBS="$add_thread_lib"
2123                           break
2124                         fi
2125                 done
2126                 if test "x$G_THREAD_LIBS" = xerror; then
2127                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2128                 fi
2129                 LIBS="$glib_save_LIBS"
2130                 ;;
2131             esac
2132           fi
2133
2134           g_threads_impl="POSIX"
2135           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2136           CPPFLAGS="$glib_save_CPPFLAGS"
2137           ;;
2138         win32)
2139            g_threads_impl="WIN32"
2140            ;;
2141         *)
2142            g_threads_impl="NONE"
2143            G_THREAD_LIBS=error
2144            ;;
2145 esac
2146
2147 if test "x$G_THREAD_LIBS" = xerror; then
2148         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2149 fi
2150
2151 case $host in
2152   *-*-beos*)
2153     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2154     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2155     ;;
2156   *)
2157     ;;
2158 esac
2159
2160 AC_MSG_CHECKING(thread related libraries)
2161 AC_MSG_RESULT($G_THREAD_LIBS)
2162
2163 dnl check for mt safe function variants and some posix functions
2164 dnl ************************************************************
2165
2166 glib_save_LIBS="$LIBS"
2167 # we are not doing the following for now, as this might require glib
2168 # to always be linked with the thread libs on some platforms.
2169 # LIBS="$LIBS $G_THREAD_LIBS"
2170 AC_CHECK_FUNCS(localtime_r gmtime_r)
2171 if test "$ac_cv_header_pwd_h" = "yes"; then
2172         AC_CACHE_CHECK([for posix getpwuid_r],
2173                 ac_cv_func_posix_getpwuid_r,
2174                 [AC_TRY_RUN([
2175 #include <errno.h>
2176 #include <pwd.h>
2177 int main () {
2178     char buffer[10000];
2179     struct passwd pwd, *pwptr = &pwd;
2180     int error;
2181     errno = 0;
2182     error = getpwuid_r (0, &pwd, buffer,
2183                         sizeof (buffer), &pwptr);
2184    return (error < 0 && errno == ENOSYS)
2185            || error == ENOSYS;
2186 }                               ],
2187                         [ac_cv_func_posix_getpwuid_r=yes],
2188                         [ac_cv_func_posix_getpwuid_r=no])])
2189         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2190         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2191                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2192                         [Have POSIX function getpwuid_r])
2193         else
2194                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2195                         ac_cv_func_nonposix_getpwuid_r,
2196                         [AC_TRY_LINK([#include <pwd.h>],
2197                                 [char buffer[10000];
2198                                 struct passwd pwd;
2199                                 getpwuid_r (0, &pwd, buffer,
2200                                                 sizeof (buffer));],
2201                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2202                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2203                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2204                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2205                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2206                                 [Have non-POSIX function getpwuid_r])
2207                 fi
2208         fi
2209 fi
2210 if test "$ac_cv_header_grp_h" = "yes"; then
2211         AC_CACHE_CHECK([for posix getgrgid_r],
2212                 ac_cv_func_posix_getgrgid_r,
2213                 [AC_TRY_RUN([
2214 #include <errno.h>
2215 #include <grp.h>
2216 int main () {
2217     char buffer[10000];
2218     struct group grp, *grpptr = &grp;
2219     int error;
2220     errno = 0;
2221     error = getgrgid_r (0, &grp, buffer,
2222                         sizeof (buffer), &grpptr);
2223    return (error < 0 && errno == ENOSYS)
2224            || error == ENOSYS;
2225 }                              ],
2226                        [ac_cv_func_posix_getgrgid_r=yes],
2227                        [ac_cv_func_posix_getgrgid_r=no])])
2228         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2229         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2230                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2231                         [Have POSIX function getgrgid_r])
2232         else
2233                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2234                         ac_cv_func_nonposix_getgrgid_r,
2235                         [AC_TRY_LINK([#include <grp.h>],
2236                                 [char buffer[10000];
2237                                 struct group grp;
2238                                 getgrgid_r (0, &grp, buffer,
2239                                 sizeof (buffer));],
2240                         [ac_cv_func_nonposix_getgrgid_r=yes],
2241                         [ac_cv_func_nonposix_getgrgid_r=no])])
2242                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2243                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2244                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2245                                 [Have non-POSIX function getgrgid_r])
2246                 fi
2247         fi
2248 fi
2249 LIBS="$G_THREAD_LIBS $LIBS"
2250 if test x"$have_threads" = xposix; then
2251         glib_save_CPPFLAGS="$CPPFLAGS"
2252         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2253         # This is not AC_CHECK_FUNC to also work with function
2254         # name mangling in header files.
2255         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2256         AC_LINK_IFELSE(
2257             [AC_LANG_PROGRAM(
2258                 [#include <pthread.h>],
2259                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2260             [AC_MSG_RESULT(yes)
2261              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2262                 [Have function pthread_attr_setstacksize])],
2263             [AC_MSG_RESULT(no)])
2264         AC_MSG_CHECKING(for pthread_condattr_setclock)
2265         AC_LINK_IFELSE(
2266             [AC_LANG_PROGRAM(
2267                 [#include <pthread.h>],
2268                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2269             [AC_MSG_RESULT(yes)
2270              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2271                 [Have function pthread_condattr_setclock])],
2272             [AC_MSG_RESULT(no)])
2273         CPPFLAGS="$glib_save_CPPFLAGS"
2274 fi
2275
2276 LIBS="$glib_save_LIBS"
2277
2278 # now spit out all the warnings.
2279 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2280    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2281         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2282 fi
2283 if test "$ac_cv_func_localtime_r" != "yes"; then
2284         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2285 fi
2286
2287 #
2288 # Hack to deal with:
2289 #
2290 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2291 #     building shared libraries with linux.
2292 #  b) FreeBSD doesn't do this either.
2293 #
2294 case $host in
2295   *-*-freebsd*|*-*-linux*)
2296     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2297     ;;
2298   *-*-openbsd*)
2299     LDFLAGS="$LDFLAGS -pthread"
2300     ;;
2301   *)
2302     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2303     ;;
2304 esac
2305
2306 AC_SUBST(G_THREAD_CFLAGS)
2307 AC_SUBST(G_THREAD_LIBS)
2308 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2309 AC_SUBST(G_THREAD_LIBS_EXTRA)
2310
2311 AC_CHECK_FUNCS(clock_gettime, [], [
2312   AC_CHECK_LIB(rt, clock_gettime, [
2313     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2314     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2315     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2316   ])
2317 ])
2318
2319
2320 dnl ************************
2321 dnl *** g_atomic_* tests ***
2322 dnl ************************
2323
2324 dnl We need to decide at configure time if GLib will use real atomic
2325 dnl operations ("lock free") or emulated ones with a mutex.  This is
2326 dnl because we must put this information in glibconfig.h so we know if
2327 dnl it is safe or not to inline using compiler intrinsics directly from
2328 dnl the header.
2329 dnl
2330 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2331 dnl user is interested in knowing if they can use the atomic ops across
2332 dnl processes.
2333 dnl
2334 dnl We can currently support the atomic ops natively when building GLib
2335 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2336 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2337 dnl we are using GCC.
2338 dnl
2339 dnl Note that the atomic ops are only available with GCC on x86 when
2340 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2341 dnl not available but would be available given the right flags, we want
2342 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2343 dnl that then to silently fall back on emulated atomic ops just because
2344 dnl the user had the wrong build environment.
2345
2346 dnl We may add other compilers here in the future...
2347 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2348 AC_TRY_COMPILE([],
2349                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2350                [glib_cv_g_atomic_lock_free=yes],
2351                [glib_cv_g_atomic_lock_free=no])
2352 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2353
2354 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2355   SAVE_CFLAGS="${CFLAGS}"
2356   CFLAGS="-march=i486"
2357   AC_TRY_COMPILE([],
2358                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2359                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2360                  [])
2361   CFLAGS="${SAVE_CFLAGS}"
2362 fi
2363
2364 dnl We need a more robust approach here...
2365 case $host_cpu in
2366   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2367     glib_memory_barrier_needed=no
2368     ;;
2369   sparc*|alpha*|powerpc*|ia64)
2370     glib_memory_barrier_needed=yes
2371     ;;
2372   *)
2373     glib_memory_barrier_needed=yes
2374     ;;
2375 esac
2376
2377 dnl ************************
2378 dnl ** Check for futex(2) **
2379 dnl ************************
2380 AC_CACHE_CHECK(for futex(2) system call,
2381     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2382 #include <linux/futex.h>
2383 #include <sys/syscall.h>
2384 #include <unistd.h>
2385 ],[
2386 int
2387 main (void)
2388 {
2389   /* it is not like this actually runs or anything... */
2390   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2391   return 0;
2392 }
2393 ])],glib_cv_futex=yes,glib_cv_futex=no))
2394 if test x"$glib_cv_futex" = xyes; then
2395   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2396 fi
2397
2398 AC_CACHE_CHECK(for eventfd(2) system call,
2399     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2400 #include <sys/eventfd.h>
2401 #include <unistd.h>
2402 ],[
2403 int
2404 main (void)
2405 {
2406   eventfd (0, EFD_CLOEXEC);
2407   return 0;
2408 }
2409 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2410 if test x"$glib_cv_eventfd" = x"yes"; then
2411   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2412 fi
2413 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2414
2415 dnl ****************************************
2416 dnl *** GLib POLL* compatibility defines ***
2417 dnl ****************************************
2418
2419 glib_poll_includes=["
2420 #include <sys/types.h>
2421 #include <sys/poll.h>
2422 "]
2423
2424 if test $ac_cv_header_sys_types_h = yes &&
2425    test $ac_cv_header_sys_poll_h = yes ; then
2426   glib_failed=false
2427   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2428   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2429   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2430   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2431   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2432   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2433   if $glib_failed ; then
2434     AC_MSG_ERROR([Could not determine values for POLL* constants])
2435   fi
2436 else
2437   glib_cv_value_POLLIN=1
2438   glib_cv_value_POLLOUT=4
2439   glib_cv_value_POLLPRI=2
2440   glib_cv_value_POLLERR=8
2441   glib_cv_value_POLLHUP=16
2442   glib_cv_value_POLLNVAL=32
2443 fi
2444
2445 AC_MSG_CHECKING([for broken poll])
2446 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2447         #include <stdlib.h>
2448         #include <fcntl.h>
2449         #include <poll.h>
2450         #ifdef HAVE_SYS_POLL_H
2451         #include <sys/poll.h>
2452         #endif
2453         int main(void) {
2454           struct pollfd fds[1];
2455           int fd;
2456           fd = open("/dev/null", 1);
2457           fds[0].fd = fd;
2458           fds[0].events = POLLIN;
2459           fds[0].revents = 0;
2460           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2461                 exit(1);  /* Does not work for devices -- fail */
2462           }
2463           exit(0);
2464         }]])],
2465   [broken_poll=no],
2466   [broken_poll=yes
2467    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2468   [broken_poll="no (cross compiling)"])
2469 AC_MSG_RESULT($broken_poll)
2470
2471 dnl *********************
2472 dnl *** GRegex checks ***
2473 dnl *********************
2474 PCRE_REQUIRED_VERSION=8.11
2475
2476 # Check if we should compile GRegex
2477 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2478                                     [disable the compilation of GRegex]),
2479 [case "${enableval}" in
2480   yes) enable_regex=true ;;
2481   no)  enable_regex=false ;;
2482   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2483 esac],
2484 [enable_regex=true])
2485
2486 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2487
2488 if test x$enable_regex = xtrue; then
2489   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2490   # Check if we should use the internal or the system-supplied pcre
2491   AC_ARG_WITH(pcre,
2492              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2493                              [whether to use system PCRE [default=internal]])])
2494
2495   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2496
2497   if test "x$with_pcre" = xsystem; then
2498     PKG_CHECK_MODULES(PCRE,
2499                       libpcre >= $PCRE_REQUIRED_VERSION)
2500     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2501                    glib_save_CFLAGS="$CFLAGS"
2502                    glib_save_LIBS="$LIBS"
2503                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2504                    AC_TRY_RUN([#include <pcre.h>
2505                                int main () {
2506                                  int support;
2507                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2508                                  if (!support)
2509                                    return 1;
2510                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2511                                  if (!support)
2512                                    return 1;
2513                                  return 0;
2514                                }],
2515                    glib_cv_pcre_has_unicode=yes,
2516                    glib_cv_pcre_has_unicode=no,
2517                    glib_cv_pcre_has_unicode=yes)
2518                    CFLAGS="$glib_save_CFLAGS"
2519                    LIBS="$glib_save_LIBS"
2520         ])
2521     if test "$glib_cv_pcre_has_unicode" = "no"; then
2522       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2523     fi
2524     AC_SUBST(PCRE_CFLAGS)
2525     AC_SUBST(PCRE_LIBS)
2526     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2527     PCRE_REQUIRES=libpcre
2528     AC_SUBST(PCRE_REQUIRES)
2529   else
2530     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2531     if test x"$GCC" = xyes; then
2532       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2533       save_CFLAGS="$CFLAGS"
2534       CFLAGS="$CFLAGS -Wno-pointer-sign"
2535       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2536                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2537       CFLAGS="$save_CFLAGS"
2538     fi
2539   fi
2540   AC_SUBST(PCRE_WARN_CFLAGS)
2541 else
2542   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2543 fi
2544
2545 dnl **********************
2546 dnl *** Win32 API libs ***
2547 dnl **********************
2548
2549 case $host in
2550   *-*-cygwin*)
2551         G_LIBS_EXTRA="-luser32 -lkernel32"
2552     ;;
2553   *-*-mingw*)
2554         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2555     ;;
2556   *)
2557         G_LIBS_EXTRA=""
2558     ;;
2559 esac
2560 AC_SUBST(G_LIBS_EXTRA)
2561
2562 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2563 dnl since we need it for g_iconv()
2564
2565 AC_MSG_CHECKING([for EILSEQ])
2566 AC_TRY_COMPILE([
2567 #include <errno.h>
2568 ],
2569 [
2570 int error = EILSEQ;
2571 ], have_eilseq=yes, have_eilseq=no);
2572 AC_MSG_RESULT($have_eilseq)
2573
2574 dnl ******************************************************************
2575 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2576 dnl *** glib-compile-schemas in PATH                               ***
2577 dnl ******************************************************************
2578
2579 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2580
2581 if test $cross_compiling = yes; then
2582   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2583   if test x$GLIB_GENMARSHAL = xno; then
2584     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2585   fi
2586
2587   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2588   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2589     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2590   fi
2591
2592   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2593   if test x$GLIB_COMPILE_RESOURCES = xno; then
2594     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2595   fi
2596 fi
2597
2598 dnl **************************
2599 dnl *** Checks for gtk-doc ***
2600 dnl **************************
2601
2602 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2603
2604 AC_ARG_ENABLE(man,
2605               [AC_HELP_STRING([--enable-man],
2606                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2607               enable_man=no)
2608
2609 if test "${enable_man}" != no; then
2610 dnl
2611 dnl Check for xsltproc
2612 dnl
2613 AC_PATH_PROG([XSLTPROC], [xsltproc])
2614   if test -z "$XSLTPROC"; then
2615     enable_man=no
2616   fi
2617
2618   dnl check for DocBook DTD and stylesheets in the local catalog.
2619   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2620      [DocBook XML DTD V4.1.2],,enable_man=no)
2621   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2622      [DocBook XSL Stylesheets],,enable_man=no)
2623 fi
2624
2625 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2626
2627 dnl
2628 dnl Tracing
2629 dnl
2630
2631 AC_ARG_ENABLE([dtrace],
2632              [AS_HELP_STRING([--enable-dtrace],
2633                               [include tracing support for dtrace])])
2634 have_dtrace=no
2635 AC_MSG_CHECKING([whether to include dtrace tracing support])
2636 if test "x$enable_dtrace" != xno; then
2637   if test x$glib_have_carbon = xyes; then
2638     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2639   else
2640     AC_MSG_RESULT([yes])
2641     AC_CHECK_PROGS(DTRACE, dtrace)
2642     if test -z "$DTRACE"; then
2643       if test "x$enable_dtrace" = xyes; then
2644         AC_MSG_ERROR([dtrace not found])
2645       fi
2646     else
2647       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2648                       [if test "x$enable_dtrace" = xyes; then
2649                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2650                        fi])
2651     fi
2652   fi
2653 else
2654   AC_MSG_RESULT([no])
2655 fi
2656 if test "x$have_dtrace" = xyes; then
2657   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2658 fi
2659 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2660
2661 AC_MSG_CHECKING([whether to include systemtap tracing support])
2662 AC_ARG_ENABLE([systemtap],
2663              [AS_HELP_STRING([--enable-systemtap],
2664                               [include tracing support for systemtap])])
2665 have_systemtap=no
2666 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2667   have_systemtap=yes
2668 fi
2669 AC_MSG_RESULT(${have_systemtap})
2670
2671 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2672
2673 AC_ARG_WITH([tapset-install-dir],
2674             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2675                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2676             [if test "x${withval}" = x; then
2677                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2678              else
2679                ABS_TAPSET_DIR="${withval}"
2680               fi],
2681             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2682 AC_SUBST(ABS_TAPSET_DIR)
2683
2684 dnl ************************************
2685 dnl *** Enable lcov coverage reports ***
2686 dnl ************************************
2687
2688 AC_ARG_ENABLE(gcov,
2689   AS_HELP_STRING([--enable-gcov],
2690                  [enable coverage testing with gcov]),
2691   [use_gcov=$enableval], [use_gcov=no])
2692
2693 if test "x$use_gcov" = "xyes"; then
2694   dnl we need gcc:
2695   if test "$GCC" != "yes"; then
2696     AC_MSG_ERROR([GCC is required for --enable-gcov])
2697   fi
2698
2699   dnl Check if ccache is being used
2700   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2701   case `$SHTOOL path $CC` in
2702     *ccache*[)] gcc_ccache=yes;;
2703     *[)] gcc_ccache=no;;
2704   esac
2705
2706   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2707     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2708   fi
2709
2710   ltp_version_list="1.6 1.7 1.8 1.9"
2711   AC_CHECK_PROG(LTP, lcov, lcov)
2712   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2713
2714   if test "$LTP"; then
2715     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2716       glib_cv_ltp_version=invalid
2717       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2718       for ltp_check_version in $ltp_version_list; do
2719         if test "$ltp_version" = "$ltp_check_version"; then
2720           glib_cv_ltp_version="$ltp_check_version (ok)"
2721         fi
2722       done
2723     ])
2724   else
2725     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2726     AC_MSG_ERROR([$ltp_msg])
2727   fi
2728
2729   case $glib_cv_ltp_version in
2730     ""|invalid[)]
2731       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2732       AC_MSG_ERROR([$ltp_msg])
2733       LTP="exit 0;"
2734       ;;
2735   esac
2736
2737   if test -z "$LTP_GENHTML"; then
2738     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2739   fi
2740
2741   dnl Remove all optimization flags from CFLAGS
2742   changequote({,})
2743   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2744   changequote([,])
2745
2746   dnl Add the special gcc flags
2747   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2748   LDFLAGS="$LDFLAGS -lgcov"
2749 fi
2750
2751 dnl ******************************
2752 dnl *** output the whole stuff ***
2753 dnl ******************************
2754
2755 dnl this section will only be run if config.status is invoked with no
2756 dnl arguments, or with "glib/glibconfig.h" as an argument.
2757 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2758 [
2759         outfile=glib/glibconfig.h-tmp
2760         cat > $outfile <<\_______EOF
2761 /* glibconfig.h
2762  *
2763  * This is a generated file.  Please modify 'configure.ac'
2764  */
2765
2766 #ifndef __GLIBCONFIG_H__
2767 #define __GLIBCONFIG_H__
2768
2769 #include <glib/gmacros.h>
2770
2771 _______EOF
2772
2773         if test x$glib_limits_h = xyes; then
2774           echo '#include <limits.h>' >> $outfile
2775         fi
2776         if test x$glib_float_h = xyes; then
2777           echo '#include <float.h>' >> $outfile
2778         fi
2779         if test x$glib_values_h = xyes; then
2780           echo '#include <values.h>' >> $outfile
2781         fi
2782         if test "$glib_header_alloca_h" = "yes"; then
2783           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2784         fi
2785         if test x$glib_sys_poll_h = xyes; then
2786           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2787         fi
2788         if test x$glib_included_printf != xyes; then
2789           echo "
2790 /* Specifies that GLib's g_print*() functions wrap the
2791  * system printf functions.  This is useful to know, for example,
2792  * when using glibc's register_printf_function().
2793  */" >> $outfile
2794           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2795         fi
2796
2797         cat >> $outfile <<_______EOF
2798
2799 G_BEGIN_DECLS
2800
2801 #define G_MINFLOAT      $glib_mf
2802 #define G_MAXFLOAT      $glib_Mf
2803 #define G_MINDOUBLE     $glib_md
2804 #define G_MAXDOUBLE     $glib_Md
2805 #define G_MINSHORT      $glib_ms
2806 #define G_MAXSHORT      $glib_Ms
2807 #define G_MAXUSHORT     $glib_Mus
2808 #define G_MININT        $glib_mi
2809 #define G_MAXINT        $glib_Mi
2810 #define G_MAXUINT       $glib_Mui
2811 #define G_MINLONG       $glib_ml
2812 #define G_MAXLONG       $glib_Ml
2813 #define G_MAXULONG      $glib_Mul
2814
2815 _______EOF
2816
2817
2818         ### this should always be true in a modern C/C++ compiler
2819         cat >>$outfile <<_______EOF
2820 typedef signed char gint8;
2821 typedef unsigned char guint8;
2822 _______EOF
2823
2824
2825         if test -n "$gint16"; then
2826           cat >>$outfile <<_______EOF
2827 typedef signed $gint16 gint16;
2828 typedef unsigned $gint16 guint16;
2829 #define G_GINT16_MODIFIER $gint16_modifier
2830 #define G_GINT16_FORMAT $gint16_format
2831 #define G_GUINT16_FORMAT $guint16_format
2832 _______EOF
2833         fi
2834
2835
2836         if test -n "$gint32"; then
2837           cat >>$outfile <<_______EOF
2838 typedef signed $gint32 gint32;
2839 typedef unsigned $gint32 guint32;
2840 #define G_GINT32_MODIFIER $gint32_modifier
2841 #define G_GINT32_FORMAT $gint32_format
2842 #define G_GUINT32_FORMAT $guint32_format
2843 _______EOF
2844         fi
2845
2846         cat >>$outfile <<_______EOF
2847 #define G_HAVE_GINT64 1          /* deprecated, always true */
2848
2849 ${glib_extension}typedef signed $gint64 gint64;
2850 ${glib_extension}typedef unsigned $gint64 guint64;
2851
2852 #define G_GINT64_CONSTANT(val)  $gint64_constant
2853 #define G_GUINT64_CONSTANT(val) $guint64_constant
2854 _______EOF
2855
2856         if test x$gint64_format != x ; then
2857           cat >>$outfile <<_______EOF
2858 #define G_GINT64_MODIFIER $gint64_modifier
2859 #define G_GINT64_FORMAT $gint64_format
2860 #define G_GUINT64_FORMAT $guint64_format
2861 _______EOF
2862         else
2863           cat >>$outfile <<_______EOF
2864 #undef G_GINT64_MODIFIER
2865 #undef G_GINT64_FORMAT
2866 #undef G_GUINT64_FORMAT
2867 _______EOF
2868         fi
2869
2870         cat >>$outfile <<_______EOF
2871
2872 #define GLIB_SIZEOF_VOID_P $glib_void_p
2873 #define GLIB_SIZEOF_LONG   $glib_long
2874 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2875
2876 _______EOF
2877
2878         cat >>$outfile <<_______EOF
2879 typedef signed $glib_size_type_define gssize;
2880 typedef unsigned $glib_size_type_define gsize;
2881 #define G_GSIZE_MODIFIER $gsize_modifier
2882 #define G_GSSIZE_FORMAT $gssize_format
2883 #define G_GSIZE_FORMAT $gsize_format
2884
2885 #define G_MAXSIZE       G_MAXU$glib_msize_type
2886 #define G_MINSSIZE      G_MIN$glib_msize_type
2887 #define G_MAXSSIZE      G_MAX$glib_msize_type
2888
2889 typedef gint64 goffset;
2890 #define G_MINOFFSET     G_MININT64
2891 #define G_MAXOFFSET     G_MAXINT64
2892
2893 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2894 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2895 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2896
2897 _______EOF
2898
2899         if test -z "$glib_unknown_void_p"; then
2900           cat >>$outfile <<_______EOF
2901
2902 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2903 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2904
2905 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2906 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2907
2908 typedef signed $glib_intptr_type_define gintptr;
2909 typedef unsigned $glib_intptr_type_define guintptr;
2910
2911 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2912 #define G_GINTPTR_FORMAT        $gintptr_format
2913 #define G_GUINTPTR_FORMAT       $guintptr_format
2914 _______EOF
2915         else
2916           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2917         fi
2918
2919
2920
2921         cat >>$outfile <<_______EOF
2922 $glib_atexit
2923 $glib_memmove
2924 $glib_defines
2925 $glib_os
2926 $glib_static_compilation
2927
2928 $glib_vacopy
2929
2930 #ifdef  __cplusplus
2931 #define G_HAVE_INLINE   1
2932 #else   /* !__cplusplus */
2933 $glib_inline
2934 #endif  /* !__cplusplus */
2935
2936 #ifdef  __cplusplus
2937 #define G_CAN_INLINE    1
2938 _______EOF
2939
2940         if test x$g_can_inline = xyes ; then
2941                 cat >>$outfile <<_______EOF
2942 #else   /* !__cplusplus */
2943 #define G_CAN_INLINE    1
2944 _______EOF
2945         fi
2946
2947         cat >>$outfile <<_______EOF
2948 #endif
2949
2950 _______EOF
2951
2952         if test x$g_have_iso_c_varargs = xyes ; then
2953                 cat >>$outfile <<_______EOF
2954 #ifndef __cplusplus
2955 # define G_HAVE_ISO_VARARGS 1
2956 #endif
2957 _______EOF
2958         fi
2959         if test x$g_have_iso_cxx_varargs = xyes ; then
2960                 cat >>$outfile <<_______EOF
2961 #ifdef __cplusplus
2962 # define G_HAVE_ISO_VARARGS 1
2963 #endif
2964 _______EOF
2965         fi
2966         if test x$g_have_gnuc_varargs = xyes ; then
2967                 cat >>$outfile <<_______EOF
2968
2969 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2970  * is passed ISO vararg support is turned off, and there is no work
2971  * around to turn it on, so we unconditionally turn it off.
2972  */
2973 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2974 #  undef G_HAVE_ISO_VARARGS
2975 #endif
2976
2977 #define G_HAVE_GNUC_VARARGS 1
2978 _______EOF
2979         fi
2980
2981         case x$g_stack_grows in
2982         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2983         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2984         esac
2985
2986
2987         echo >>$outfile
2988         if test x$g_have_eilseq = xno; then
2989                 cat >>$outfile <<_______EOF
2990 #ifndef EILSEQ
2991 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2992  * The correspondence between this and the corresponding definition
2993  * in libiconv is essential.
2994  */
2995 #  define EILSEQ ENOENT
2996 #endif
2997 _______EOF
2998
2999         fi
3000
3001         if test x$g_have_gnuc_visibility = xyes; then
3002                 cat >>$outfile <<_______EOF
3003 #define G_HAVE_GNUC_VISIBILITY 1
3004 _______EOF
3005         fi
3006                 cat >>$outfile <<_______EOF
3007 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3008 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3009 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3010 #define G_GNUC_INTERNAL __hidden
3011 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3012 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3013 #else
3014 #define G_GNUC_INTERNAL
3015 #endif
3016 _______EOF
3017
3018         echo >>$outfile
3019         cat >>$outfile <<_______EOF
3020 #define G_THREADS_ENABLED
3021 #define G_THREADS_IMPL_$g_threads_impl_def
3022 _______EOF
3023
3024         if test x"$g_memory_barrier_needed" != xno; then
3025           echo >>$outfile
3026           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3027         fi
3028         if test x"$g_atomic_lock_free" = xyes; then
3029           echo >>$outfile
3030           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3031         fi
3032         echo >>$outfile
3033         g_bit_sizes="16 32 64"
3034         for bits in $g_bit_sizes; do
3035           cat >>$outfile <<_______EOF
3036 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3037 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3038 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3039 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3040 _______EOF
3041         done
3042
3043         cat >>$outfile <<_______EOF
3044 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3045 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3046 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3047 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3048 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3049 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3050 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3051 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3052 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3053 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3054 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3055 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3056 #define G_BYTE_ORDER $g_byte_order
3057
3058 #define GLIB_SYSDEF_POLLIN =$g_pollin
3059 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3060 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3061 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3062 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3063 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3064
3065 #define G_MODULE_SUFFIX "$g_module_suffix"
3066
3067 typedef $g_pid_type GPid;
3068
3069 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3070 #define GLIB_SYSDEF_AF_INET $g_af_inet
3071 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3072
3073 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3074 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3075 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3076
3077 G_END_DECLS
3078
3079 #endif /* __GLIBCONFIG_H__ */
3080 _______EOF
3081
3082
3083         if cmp -s $outfile glib/glibconfig.h; then
3084           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3085           rm -f $outfile
3086         else
3087           mv $outfile glib/glibconfig.h
3088         fi
3089 ],[
3090
3091 # Note that if two cases are the same, case goes with the first one.
3092 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3093 # on variable expansion in case labels.  Look at the generated config.status
3094 # for a hint.
3095
3096 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3097   glib_header_alloca_h="$ac_cv_working_alloca_h"
3098 else
3099   glib_header_alloca_h="$ac_cv_header_alloca_h"
3100 fi
3101
3102 case xyes in
3103 x$ac_cv_header_float_h)
3104   glib_float_h=yes
3105   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3106   glib_md=DBL_MIN glib_Md=DBL_MAX
3107   ;;
3108 x$ac_cv_header_values_h)
3109   glib_values_h=yes
3110   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3111   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3112   ;;
3113 esac
3114
3115 case xyes in
3116 x$ac_cv_header_limits_h)
3117   glib_limits_h=yes
3118   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3119   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3120   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3121   ;;
3122 x$ac_cv_header_values_h)
3123   glib_values_h=yes
3124   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3125   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3126   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3127   ;;
3128 esac
3129
3130 if test x$ac_cv_header_sys_poll_h = xyes ; then
3131   glib_sys_poll_h=yes
3132 fi
3133
3134 if test x$enable_included_printf = xyes ; then
3135   glib_included_printf=yes
3136 fi
3137
3138 case 2 in
3139 $ac_cv_sizeof_short)
3140   gint16=short
3141   gint16_modifier='"h"'
3142   gint16_format='"hi"'
3143   guint16_format='"hu"'
3144   ;;
3145 $ac_cv_sizeof_int)
3146   gint16=int
3147   gint16_modifier='""'
3148   gint16_format='"i"'
3149   guint16_format='"u"'
3150   ;;
3151 esac
3152 case 4 in
3153 $ac_cv_sizeof_short)
3154   gint32=short
3155   gint32_modifier='"h"'
3156   gint32_format='"hi"'
3157   guint32_format='"hu"'
3158   ;;
3159 $ac_cv_sizeof_int)
3160   gint32=int
3161   gint32_modifier='""'
3162   gint32_format='"i"'
3163   guint32_format='"u"'
3164   ;;
3165 $ac_cv_sizeof_long)
3166   gint32=long
3167   gint32_modifier='"l"'
3168   gint32_format='"li"'
3169   guint32_format='"lu"'
3170   ;;
3171 esac
3172 case 8 in
3173 $ac_cv_sizeof_int)
3174   gint64=int
3175   gint64_modifier='""'
3176   gint64_format='"i"'
3177   guint64_format='"u"'
3178   glib_extension=
3179   gint64_constant='(val)'
3180   guint64_constant='(val)'
3181   ;;
3182 $ac_cv_sizeof_long)
3183   gint64=long
3184   gint64_modifier='"l"'
3185   gint64_format='"li"'
3186   guint64_format='"lu"'
3187   glib_extension=
3188   gint64_constant='(val##L)'
3189   guint64_constant='(val##UL)'
3190   ;;
3191 $ac_cv_sizeof_long_long)
3192   gint64='long long'
3193   if test -n "$glib_cv_long_long_format"; then
3194     gint64_modifier='"'$glib_cv_long_long_format'"'
3195     gint64_format='"'$glib_cv_long_long_format'i"'
3196     guint64_format='"'$glib_cv_long_long_format'u"'
3197   fi
3198   glib_extension='G_GNUC_EXTENSION '
3199   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3200   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3201   ;;
3202 $ac_cv_sizeof___int64)
3203   gint64='__int64'
3204   if test -n "$glib_cv_long_long_format"; then
3205     gint64_modifier='"'$glib_cv_long_long_format'"'
3206     gint64_format='"'$glib_cv_long_long_format'i"'
3207     guint64_format='"'$glib_cv_long_long_format'u"'
3208   fi
3209   glib_extension=
3210   gint64_constant='(val##i64)'
3211   guint64_constant='(val##ui64)'
3212   ;;
3213 esac
3214 glib_size_t=$ac_cv_sizeof_size_t
3215 glib_size_type_define="$glib_size_type"
3216 glib_void_p=$ac_cv_sizeof_void_p
3217 glib_long=$ac_cv_sizeof_long
3218
3219 case "$glib_size_type" in
3220 short)
3221   gsize_modifier='"h"'
3222   gsize_format='"hu"'
3223   gssize_format='"hi"'
3224   glib_msize_type='SHRT'
3225   ;;
3226 int)
3227   gsize_modifier='""'
3228   gsize_format='"u"'
3229   gssize_format='"i"'
3230   glib_msize_type='INT'
3231   ;;
3232 long)
3233   gsize_modifier='"l"'
3234   gsize_format='"lu"'
3235   gssize_format='"li"'
3236   glib_msize_type='LONG'
3237   ;;
3238 "long long"|__int64)
3239   gsize_modifier='"I64"'
3240   gsize_format='"I64u"'
3241   gssize_format='"I64i"'
3242   glib_msize_type='INT64'
3243   ;;
3244 esac
3245
3246 gintbits=`expr $ac_cv_sizeof_int \* 8`
3247 glongbits=`expr $ac_cv_sizeof_long \* 8`
3248 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3249
3250 case $ac_cv_sizeof_void_p in
3251 $ac_cv_sizeof_int)
3252   glib_intptr_type_define=int
3253   gintptr_modifier='""'
3254   gintptr_format='"i"'
3255   guintptr_format='"u"'
3256   glib_gpi_cast='(gint)'
3257   glib_gpui_cast='(guint)'
3258   ;;
3259 $ac_cv_sizeof_long)
3260   glib_intptr_type_define=long
3261   gintptr_modifier='"l"'
3262   gintptr_format='"li"'
3263   guintptr_format='"lu"'
3264   glib_gpi_cast='(glong)'
3265   glib_gpui_cast='(gulong)'
3266   ;;
3267 $ac_cv_sizeof_long_long)
3268   glib_intptr_type_define='long long'
3269   gintptr_modifier='"I64"'
3270   gintptr_format='"I64i"'
3271   guintptr_format='"I64u"'
3272   glib_gpi_cast='(gint64)'
3273   glib_gpui_cast='(guint64)'
3274   ;;
3275 $ac_cv_sizeof___int64)
3276   glib_intptr_type_define=__int64
3277   gintptr_modifier='"I64"'
3278   gintptr_format='"I64i"'
3279   guintptr_format='"I64u"'
3280   glib_gpi_cast='(gint64)'
3281   glib_gpui_cast='(guint64)'
3282   ;;
3283 *)
3284   glib_unknown_void_p=yes
3285   ;;
3286 esac
3287
3288
3289 case xyes in
3290 x$ac_cv_func_atexit)
3291   glib_atexit="
3292 #ifdef NeXT /* @#%@! NeXTStep */
3293 # define g_ATEXIT(proc) (!atexit (proc))
3294 #else
3295 # define g_ATEXIT(proc) (atexit (proc))
3296 #endif"
3297   ;;
3298 x$ac_cv_func_on_exit)
3299   glib_atexit="
3300 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3301   ;;
3302 esac
3303
3304 case xyes in
3305 x$ac_cv_func_memmove)
3306   glib_memmove='
3307 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3308   ;;
3309 x$glib_cv_working_bcopy)
3310   glib_memmove="
3311 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3312 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3313   ;;
3314 *)
3315   glib_memmove="
3316 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3317  * so we have to roll our own copy routine. */
3318 void g_memmove (void* dest, const void * src, unsigned long len);"
3319   ;;
3320 esac
3321
3322 glib_defines="
3323 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3324 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3325 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3326 "
3327
3328 case xyes in
3329 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3330 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3331 *)                      glib_vacopy=''
3332 esac
3333
3334 if test x$glib_cv_va_val_copy = xno; then
3335   glib_vacopy="\$glib_vacopy
3336 #define G_VA_COPY_AS_ARRAY 1"
3337 fi
3338
3339 if test x$glib_cv_hasinline = xyes; then
3340     glib_inline='#define G_HAVE_INLINE 1'
3341 fi
3342 if test x$glib_cv_has__inline = xyes; then
3343     glib_inline="\$glib_inline
3344 #define G_HAVE___INLINE 1"
3345 fi
3346 if test x$glib_cv_has__inline__ = xyes; then
3347     glib_inline="\$glib_inline
3348 #define G_HAVE___INLINE__ 1"
3349 fi
3350
3351 g_have_gnuc_varargs=$g_have_gnuc_varargs
3352 g_have_iso_c_varargs=$g_have_iso_c_varargs
3353 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3354
3355 g_can_inline=$g_can_inline
3356 g_have_gnuc_visibility=$g_have_gnuc_visibility
3357 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3358
3359 if test x$ac_cv_c_bigendian = xyes; then
3360   g_byte_order=G_BIG_ENDIAN
3361   g_bs_native=BE
3362   g_bs_alien=LE
3363 else
3364   g_byte_order=G_LITTLE_ENDIAN
3365   g_bs_native=LE
3366   g_bs_alien=BE
3367 fi
3368
3369 g_pollin=$glib_cv_value_POLLIN
3370 g_pollout=$glib_cv_value_POLLOUT
3371 g_pollpri=$glib_cv_value_POLLPRI
3372 g_pollhup=$glib_cv_value_POLLHUP
3373 g_pollerr=$glib_cv_value_POLLERR
3374 g_pollnval=$glib_cv_value_POLLNVAL
3375
3376 g_af_unix=$glib_cv_value_AF_UNIX
3377 g_af_inet=$glib_cv_value_AF_INET
3378 g_af_inet6=$glib_cv_value_AF_INET6
3379
3380 g_msg_peek=$glib_cv_value_MSG_PEEK
3381 g_msg_oob=$glib_cv_value_MSG_OOB
3382 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3383
3384 g_stack_grows=$glib_cv_stack_grows
3385
3386 g_have_eilseq=$have_eilseq
3387
3388 g_threads_impl_def=$g_threads_impl
3389
3390 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3391 g_memory_barrier_needed="$glib_memory_barrier_needed"
3392 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3393
3394 g_module_suffix="$glib_gmodule_suffix"
3395
3396 g_pid_type="$glib_pid_type"
3397 case $host in
3398   *-*-beos*)
3399     glib_os="#define G_OS_BEOS"
3400     ;;
3401   *-*-cygwin*)
3402     glib_os="#define G_OS_UNIX
3403 #define G_PLATFORM_WIN32
3404 #define G_WITH_CYGWIN"
3405     ;;
3406   *-*-mingw*)
3407     glib_os="#define G_OS_WIN32
3408 #define G_PLATFORM_WIN32"
3409     ;;
3410   *)
3411     glib_os="#define G_OS_UNIX"
3412     ;;
3413 esac
3414 glib_static_compilation=""
3415 if test x$glib_win32_static_compilation = xyes; then
3416   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3417 #define GOBJECT_STATIC_COMPILATION 1"
3418 fi
3419 ])
3420
3421 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3422 #
3423 # 1.2.14 required for dbus_message_set_serial
3424 PKG_CHECK_MODULES(DBUS1,
3425                   dbus-1 >= 1.2.14,
3426                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3427                   have_dbus1=no)
3428 AC_SUBST(DBUS1_CFLAGS)
3429 AC_SUBST(DBUS1_LIBS)
3430 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3431
3432 dnl
3433 dnl Check for -Bsymbolic-functions linker flag used to avoid
3434 dnl intra-library PLT jumps, if available.
3435 dnl
3436
3437 AC_ARG_ENABLE(Bsymbolic,
3438               [AC_HELP_STRING([--disable-Bsymbolic],
3439                               [avoid linking with -Bsymbolic])],,
3440               [SAVED_LDFLAGS="${LDFLAGS}"
3441                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3442                LDFLAGS=-Wl,-Bsymbolic-functions
3443                AC_TRY_LINK([], [int main (void) { return 0; }],
3444                            AC_MSG_RESULT(yes)
3445                            enable_Bsymbolic=yes,
3446                            AC_MSG_RESULT(no)
3447                            enable_Bsymbolic=no)
3448                LDFLAGS="${SAVED_LDFLAGS}"])
3449
3450 if test "x${enable_Bsymbolic}" = "xyes"; then
3451   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3452 fi
3453
3454 AC_SUBST(GLIB_LINK_FLAGS)
3455
3456 #
3457 # Define variables corresponding to the correct include paths to use for
3458 # in-tree building.
3459 #
3460
3461 # for config.h:
3462 config_h_INCLUDES='-I$(top_builddir)'
3463 AC_SUBST(config_h_INCLUDES)
3464
3465 # glib:
3466 #   config.h
3467 #   $(top_builddir)/glib: for glibconfig.h
3468 #   $(top_srcdir)/glib:   for glib.h
3469 #   $(top_srcdir):        for everything
3470 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3471 AC_SUBST(glib_INCLUDES)
3472
3473 # gthread:
3474 #   same as glib
3475 gthread_INCLUDES='$(glib_INCLUDES)'
3476 AC_SUBST(gthread_INCLUDES)
3477
3478 # gobject:
3479 #   same as gthread
3480 gobject_INCLUDES='$(gthread_INCLUDES)'
3481 AC_SUBST(gobject_INCLUDES)
3482
3483 # gmodule:
3484 #   glib includes
3485 #   $(top_srcdir)/gmodule: for gmodule.h
3486 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3487 AC_SUBST(gmodule_INCLUDES)
3488
3489 # gio:
3490 #   same as gmodule
3491 gio_INCLUDES='$(gmodule_INCLUDES)'
3492 AC_SUBST(gio_INCLUDES)
3493
3494
3495 AC_CONFIG_FILES([
3496 glib-2.0.pc
3497 gmodule-2.0.pc
3498 gmodule-export-2.0.pc
3499 gmodule-no-export-2.0.pc
3500 gthread-2.0.pc
3501 gobject-2.0.pc
3502 gio-2.0.pc
3503 gio-unix-2.0.pc
3504 gio-windows-2.0.pc
3505 glib-zip
3506 glib-gettextize
3507 Makefile
3508 build/Makefile
3509 build/win32/Makefile
3510 build/win32/dirent/Makefile
3511 build/win32/vs9/Makefile
3512 build/win32/vs10/Makefile
3513 glib/Makefile
3514 glib/glib.stp
3515 glib/libcharset/Makefile
3516 glib/gnulib/Makefile
3517 glib/pcre/Makefile
3518 glib/update-pcre/Makefile
3519 glib/tests/Makefile
3520 gmodule/Makefile
3521 gmodule/gmoduleconf.h
3522 gobject/Makefile
3523 gobject/gobject.stp
3524 gobject/glib-mkenums
3525 gobject/tests/Makefile
3526 gthread/Makefile
3527 gio/Makefile
3528 gio/gdbus-2.0/codegen/Makefile
3529 gio/gdbus-2.0/codegen/config.py
3530 gio/xdgmime/Makefile
3531 gio/inotify/Makefile
3532 gio/fen/Makefile
3533 gio/fam/Makefile
3534 gio/win32/Makefile
3535 gio/tests/Makefile
3536 gio/tests/gdbus-object-manager-example/Makefile
3537 po/Makefile.in
3538 docs/Makefile
3539 docs/reference/Makefile
3540 docs/reference/glib/Makefile
3541 docs/reference/glib/version.xml
3542 docs/reference/gobject/Makefile
3543 docs/reference/gobject/version.xml
3544 docs/reference/gio/Makefile
3545 docs/reference/gio/gdbus-object-manager-example/Makefile
3546 docs/reference/gio/version.xml
3547 tests/Makefile
3548 tests/gobject/Makefile
3549 tests/refcount/Makefile
3550 m4macros/Makefile
3551 ])
3552
3553 AC_CONFIG_COMMANDS([chmod-scripts],
3554 [chmod 0755 glib-zip
3555 chmod 0755 glib-gettextize
3556 chmod 0755 gobject/glib-mkenums])
3557
3558 # we want to invoke this macro solely so that the config.status script
3559 # and automake generated makefiles know about these generated files.
3560 # They are only needed to distcheck the package
3561 if false; then
3562   AC_CONFIG_FILES([
3563     INSTALL
3564     README
3565     config.h.win32
3566     glib/glibconfig.h.win32
3567     glib/makefile.msc
3568     glib/glib.rc
3569     gmodule/makefile.msc
3570     gmodule/gmodule.rc
3571     gobject/makefile.msc
3572     gobject/gobject.rc
3573     gthread/makefile.msc
3574     gthread/gthread.rc
3575     gio/gio.rc
3576     tests/makefile.msc
3577   ])
3578 fi
3579
3580 AC_OUTPUT