configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [4])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 if test "$glib_native_win32" != yes; then
 214     # libtool option to control which symbols are exported
 215     # right now, symbols starting with _ are not exported
 216     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 217 else
 218     # We currently use .def files on Windows
 219     LIBTOOL_EXPORT_OPTIONS=
 220 fi
 221 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 222
 223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 224   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 225   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 226 ])
 227
 228 if test "x$glib_have_cocoa" = "xyes"; then
 229   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 230   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 231 fi
 232
 233 gl_GLIBC21
 234 AS_IF([test "x$GLIBC21" = "xyes"], [
 235   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 236 ])
 237
 238 dnl declare --enable-* args and collect ac_help strings
 239 AC_ARG_ENABLE(debug,
 240               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 241                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 242               enable_debug=glib_debug_default)
 243
 244 AC_ARG_ENABLE(gc_friendly,
 245               [AS_HELP_STRING([--enable-gc-friendly],
 246                               [turn on garbage collector friendliness [default=no]])],,
 247               [enable_gc_friendly=no])
 248 AC_ARG_ENABLE(mem_pools,
 249               [AS_HELP_STRING([--disable-mem-pools],
 250                               [disable all glib memory pools])],,
 251               [disable_mem_pools=no])
 252 AC_ARG_ENABLE(rebuilds,
 253               [AS_HELP_STRING([--disable-rebuilds],
 254                               [disable all source autogeneration rules])],,
 255               [enable_rebuilds=yes])
 256 AC_ARG_ENABLE(modular_tests,
 257               AS_HELP_STRING([--disable-modular-tests],
 258                              [Disable build of test programs (default: no)]),,
 259               [enable_modular_tests=yes])
 260 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 261
 262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 264   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 265   AC_MSG_RESULT([yes])
 266 ], [ AC_MSG_RESULT([no]) ])
 267
 268 AC_MSG_CHECKING([whether to disable memory pools])
 269 AS_IF([test "x$disable_mem_pools" = "xno"], [
 270   AC_MSG_RESULT([no])
 271 ], [
 272   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 273   AC_MSG_RESULT([yes])
 274 ])
 275
 276 dnl location to install runtime libraries, e.g. ../../lib to install
 277 dnl to /lib if libdir is /usr/lib
 278 AC_ARG_WITH(runtime-libdir,
 279            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 280                            [install runtime libraries relative to libdir])],
 281            [],
 282            [with_runtime_libdir=""])
 283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 284 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 285 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 286 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 287 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 288
 289 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 290 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 291 AC_LANG_SAVE
 292 AC_LANG_CPLUSPLUS
 293 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 294 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 295 AC_LANG_RESTORE
 296
 297 AM_PROG_CC_STDC
 298 AM_PROG_CC_C_O
 299 AC_PROG_INSTALL
 300
 301 AC_SYS_LARGEFILE
 302
 303 PKG_PROG_PKG_CONFIG(0.16)
 304
 305 if test "x$enable_debug" = "xyes"; then
 306   if test x$cflags_set != xset ; then
 307       case " $CFLAGS " in
 308       *[[\ \    ]]-g[[\ \       ]]*) ;;
 309       *) CFLAGS="$CFLAGS -g" ;;
 310       esac
 311   fi
 312   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 313 else
 314   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 315
 316   if test "x$enable_debug" = "xno"; then
 317     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 318   fi
 319 fi
 320
 321 # Ensure MSVC-compatible struct packing convention is used when
 322 # compiling for Win32 with gcc.
 323 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 324 # gcc2 uses "-fnative-struct".
 325 if test x"$glib_native_win32" = xyes; then
 326   if test x"$GCC" = xyes; then
 327     msnative_struct=''
 328     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 329     if test -z "$ac_cv_prog_CC"; then
 330       our_gcc="$CC"
 331     else
 332       our_gcc="$ac_cv_prog_CC"
 333     fi
 334     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 335       2.)
 336         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 337           msnative_struct='-fnative-struct'
 338         fi
 339         ;;
 340       *)
 341         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 342           msnative_struct='-mms-bitfields'
 343         fi
 344         ;;
 345     esac
 346     if test x"$msnative_struct" = x ; then
 347       AC_MSG_RESULT([no way])
 348       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 349     else
 350       CFLAGS="$CFLAGS $msnative_struct"
 351       AC_MSG_RESULT([${msnative_struct}])
 352     fi
 353   fi
 354 fi
 355 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 356 AC_SUBST(GLIB_EXTRA_CFLAGS)
 357
 358 AC_EXEEXT
 359
 360 # define a MAINT-like variable REBUILD which is set if Perl
 361 # and awk are found, so autogenerated sources can be rebuilt
 362 AC_PROG_AWK
 363 AC_CHECK_PROGS(PERL, [perl5 perl])
 364 # We would like indent, but don't require it.
 365 AC_CHECK_PROG(INDENT, indent, indent)
 366 REBUILD=\#
 367 if test "x$enable_rebuilds" = "xyes" && \
 368      test -n "$PERL" && \
 369      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 370      test -n "$AWK" ; then
 371   REBUILD=
 372 fi
 373 AC_SUBST(REBUILD)
 374
 375 # Need full path to Perl for glib-mkenums
 376 #
 377 if test "x$PERL" != x ; then
 378   AC_PATH_PROG(PERL_PATH, [$PERL])
 379 fi
 380 if test "x$PERL_PATH" = x ; then
 381   PERL_PATH="/usr/bin/env perl"
 382 fi
 383 AC_SUBST(PERL_PATH)
 384
 385 # Need suitable python path for greport
 386 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 387
 388
 389 dnl ***********************
 390 dnl *** Tests for iconv ***
 391 dnl ***********************
 392 dnl
 393 dnl We do this before the gettext checks, to avoid distortion
 394
 395 dnl On Windows we use a native implementation
 396
 397 AS_IF([ test x"$glib_native_win32" = xyes], [
 398   with_libiconv=native
 399 ], [
 400   AC_ARG_WITH(libiconv,
 401               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 402                               [use the libiconv library])],,
 403               [with_libiconv=maybe])
 404
 405   found_iconv=no
 406   case $with_libiconv in
 407     maybe)
 408       # Check in the C library first
 409       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 410       # Check if we have GNU libiconv
 411       if test $found_iconv = "no"; then
 412         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 413       fi
 414       # Check if we have a iconv in -liconv, possibly from vendor
 415       if test $found_iconv = "no"; then
 416         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 417       fi
 418       ;;
 419     no)
 420       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 421       ;;
 422     gnu|yes)
 423       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 424       ;;
 425     native)
 426       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 427       ;;
 428   esac
 429
 430   if test "x$found_iconv" = "xno" ; then
 431      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 432   fi
 433 ])
 434
 435 AC_ARG_ENABLE(iconv-cache,
 436               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 437                               [cache iconv descriptors [default=auto]])],,
 438               [enable_iconv_cache=auto])
 439
 440 AC_MSG_CHECKING([whether to cache iconv descriptors])
 441 case $enable_iconv_cache in
 442   auto)
 443     if test $ac_cv_gnu_library_2_1 = yes; then
 444       enable_iconv_cache=no
 445     else
 446       enable_iconv_cache=yes
 447     fi
 448   ;;
 449   yes|no)
 450   ;;
 451   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 452   ;;
 453 esac
 454
 455 if test $enable_iconv_cache = yes; then
 456    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 457 fi
 458
 459 AC_MSG_RESULT($enable_iconv_cache)
 460
 461
 462 dnl
 463 dnl zlib support
 464 dnl
 465 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 466 AS_IF([test "x$found_zlib" = "xno"], [
 467   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 468   if test "x$found_zlib" = "xno" ; then
 469     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 470   fi
 471   ZLIB_LIBS='-lz'
 472   AC_SUBST(ZLIB_LIBS)
 473 ])
 474
 475 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 476 AC_SUBST(LIBFFI_CFLAGS)
 477 AC_SUBST(LIBFFI_LIBS)
 478
 479 dnl
 480 dnl gettext support
 481 dnl
 482
 483 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 484 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 485 GLIB_GNU_GETTEXT
 486
 487 if test "$gt_cv_have_gettext" != "yes" ; then
 488   AC_MSG_ERROR([
 489 *** You must have either have gettext support in your C library, or use the
 490 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 491 ])
 492 fi
 493
 494 LIBS="$INTLLIBS $LIBS"
 495
 496 GETTEXT_PACKAGE=glib20
 497 AC_SUBST(GETTEXT_PACKAGE)
 498 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 499   [Define the gettext package to be used])
 500
 501 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 502
 503 dnl
 504 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 505 dnl
 506
 507 AS_IF([test x"$glib_native_win32" != xyes], [
 508   if test x$with_libiconv != xno ; then
 509     case " $INTLLIBS " in
 510     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 511     *) ICONV_LIBS="-liconv" ;;
 512     esac
 513   fi
 514 ])
 515 AC_SUBST(ICONV_LIBS)
 516
 517 case $with_libiconv in
 518   gnu)
 519     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 520     ;;
 521   native)
 522     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 523     ;;
 524 esac
 525
 526 dnl Initialize libtool
 527 LT_PREREQ([2.2])
 528 LT_INIT([disable-static win32-dll])
 529 dnl when using libtool 2.x create libtool early, because it's used in configure
 530 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 531
 532
 533 AS_IF([test "$glib_native_win32" = "yes"], [
 534   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 535     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 536   fi
 537   if test x$enable_static = xyes; then
 538     glib_win32_static_compilation=yes
 539     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 540 #define GOBJECT_STATIC_COMPILATION 1"
 541     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 542   fi
 543 ])
 544 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 545
 546 dnl
 547 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 548 dnl
 549 AS_IF([test $cross_compiling != yes], [
 550     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 551     glib_save_LIBS=$LIBS
 552     LIBS="$LIBS -lm"
 553     AC_TRY_RUN([#include <math.h>
 554                  int main (void) { return (log(1) != log(1.)); }],
 555          AC_MSG_RESULT(none needed),
 556          glib_save_CFLAGS=$CFLAGS
 557          CFLAGS="$CFLAGS -std1"
 558          AC_TRY_RUN([#include <math.h>
 559                      int main (void) { return (log(1) != log(1.)); }],
 560              AC_MSG_RESULT(-std1),
 561              AC_MSG_RESULT()
 562              CFLAGS=$glib_save_CFLAGS
 563              AC_MSG_WARN(
 564                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 565          )
 566     )
 567     LIBS=$glib_save_LIBS
 568 ])
 569
 570 dnl NeXTStep cc seems to need this
 571 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 572 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 573   AC_MSG_RESULT(none needed),
 574   glib_save_CFLAGS=$CFLAGS
 575   CFLAGS="$CFLAGS -posix"
 576   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 577     AC_MSG_RESULT(-posix),
 578     AC_MSG_RESULT()
 579     CFLAGS=$glib_save_CFLAGS
 580     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 581
 582 # Checks for library functions.
 583 AC_FUNC_VPRINTF
 584 AC_FUNC_ALLOCA
 585 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 586 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 587
 588 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 589   [AC_TRY_LINK([#include <unistd.h>
 590     extern int __libc_enable_secure;],
 591     [return __libc_enable_secure;],
 592    glib_cv_have_libc_enable_secure=yes,
 593    glib_cv_have_libc_enable_secure=no)])
 594 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 595    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 596      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 597 ])
 598
 599 AC_CHECK_SIZEOF(char)
 600 AC_CHECK_SIZEOF(short)
 601 AC_CHECK_SIZEOF(long)
 602 AC_CHECK_SIZEOF(int)
 603 AC_CHECK_SIZEOF(void *)
 604 AC_CHECK_SIZEOF(long long)
 605 AC_CHECK_SIZEOF(__int64)
 606
 607 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 608   [AC_TRY_LINK([#include <signal.h>
 609      #include <sys/types.h>
 610      sig_atomic_t val = 42;],
 611     [return val == 42 ? 0 : 1],
 612    ac_cv_type_sig_atomic_t=yes,
 613    ac_cv_type_sig_atomic_t=no)])
 614 if test x$ac_cv_type_sig_atomic_t = xyes; then
 615    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 616      [Define if you have the 'sig_atomic_t' type.])
 617 fi
 618
 619 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 620   :
 621 else
 622   AC_MSG_ERROR([
 623 *** GLib requires a 64 bit type. You might want to consider
 624 *** using the GNU C compiler.
 625 ])
 626 fi
 627
 628 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 629         # long long is a 64 bit integer.
 630         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 631         AC_CACHE_VAL(glib_cv_long_long_format,[
 632                 for format in ll q I64; do
 633                   AC_TRY_RUN([#include <stdio.h>
 634                         int main()
 635                         {
 636                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 637                           char buffer[1000];
 638                           sprintf (buffer, "%${format}u", a);
 639                           sscanf (buffer, "%${format}u", &b);
 640                           exit (b!=a);
 641                         }
 642                         ],
 643                         [glib_cv_long_long_format=${format}
 644                         break],
 645                         [],[:])
 646                 done])
 647         AS_IF([ test -n "$glib_cv_long_long_format"], [
 648           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 649           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 650           if test x"$glib_cv_long_long_format" = xI64; then
 651             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 652           fi
 653         ], [AC_MSG_RESULT(none)])
 654 ],[ test x$ac_cv_sizeof___int64 = x8], [
 655         # __int64 is a 64 bit integer.
 656         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 657         # We know this is MSVCRT.DLL, and what the formats are
 658         glib_cv_long_long_format=I64
 659         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 660         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 661         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 662 ])
 663
 664 AC_C_CONST
 665
 666 dnl ok, here we try to check whether the systems prototypes for
 667 dnl malloc and friends actually match the prototypes provided
 668 dnl by gmem.h (keep in sync). i currently only know how to check
 669 dnl this reliably with gcc (-Werror), improvements for other
 670 dnl compilers are apprechiated.
 671 SANE_MALLOC_PROTOS=no
 672 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 673 glib_save_CFLAGS=$CFLAGS
 674 AS_IF([test "x$GCC" = "xyes"], [
 675   CFLAGS="$CFLAGS -Werror"
 676   AC_TRY_COMPILE([#include <stdlib.h>], [
 677     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 678     void* (*my_malloc_p)  (size_t)         = malloc;
 679     void  (*my_free_p)    (void*)          = free;
 680     void* (*my_realloc_p) (void*, size_t)  = realloc;
 681     my_calloc_p = 0;
 682     my_malloc_p = 0;
 683     my_free_p = 0;
 684     my_realloc_p = 0;
 685   ],
 686     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 687       [Define if you have correct malloc prototypes])
 688     SANE_MALLOC_PROTOS=yes)
 689 ])
 690 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 691 CFLAGS=$glib_save_CFLAGS
 692
 693 dnl
 694 dnl check in which direction the stack grows
 695 dnl
 696 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 697         AC_TRY_RUN([
 698         volatile int *a = 0, *b = 0;
 699         void foo (void);
 700         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 701         void foo (void) { volatile int x = 5; b = &x; }
 702         ],
 703         glib_cv_stack_grows=no
 704         ,
 705         glib_cv_stack_grows=yes
 706         ,)
 707 ])
 708
 709 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 710 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 711 dnl actually supported.
 712 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 713         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 714         __inline int foo () { return 0; }
 715         int main () { return foo (); }
 716         ]])],
 717         glib_cv_has__inline=yes
 718         ,
 719         glib_cv_has__inline=no
 720         ,)
 721 ])
 722 case x$glib_cv_has__inline in
 723 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 724 esac
 725 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline__ int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline__=yes
 731         ,
 732         glib_cv_has__inline__=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline__ in
 736 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 737 esac
 738 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         #undef inline
 741         inline int foo () { return 0; }
 742         int main () { return foo (); }
 743         ]])],
 744         glib_cv_hasinline=yes
 745         ,
 746         glib_cv_hasinline=no
 747         ,)
 748 ])
 749 case x$glib_cv_hasinline in
 750 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 751 esac
 752
 753 # if we can use inline functions in headers
 754 AC_MSG_CHECKING(if inline functions in headers work)
 755 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 756 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 757 #  undef inline
 758 #  define inline __inline__
 759 #elif !defined (G_HAVE_INLINE)
 760 #  undef inline
 761 #  if defined (G_HAVE___INLINE__)
 762 #    define inline __inline__
 763 #  elif defined (G_HAVE___INLINE)
 764 #    define inline __inline
 765 #  endif
 766 #endif
 767
 768 int glib_test_func2 (int);
 769
 770 static inline int
 771 glib_test_func1 (void) {
 772   return glib_test_func2 (1);
 773 }
 774
 775 int
 776 main (void) {
 777   int i = 1;
 778 }]])],[g_can_inline=yes],[g_can_inline=no])
 779 AC_MSG_RESULT($g_can_inline)
 780
 781 dnl *** check for working do while(0) macros ***
 782 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 783         AC_TRY_COMPILE([],[
 784         #define STMT_START do
 785         #define STMT_END while(0)
 786         #define STMT_TEST STMT_START { i = 0; } STMT_END
 787         int main(void) { int i = 1; STMT_TEST; return i; }],
 788         [g_cv_support_dowhile_macros=yes],
 789         [g_cv_support_dowhile_macros=no],
 790         [g_cv_support_dowhile_macros=yes])
 791 ])
 792 if test x$g_cv_support_dowhile_macros = xyes; then
 793   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 794 fi
 795
 796 # check for flavours of varargs macros
 797 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 798 AC_TRY_COMPILE([],[
 799 int a(int p1, int p2, int p3);
 800 #define call_a(...) a(1,__VA_ARGS__)
 801 call_a(2,3);
 802 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 803 AC_MSG_RESULT($g_have_iso_c_varargs)
 804
 805 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 806 AS_IF([test "$CXX" = ""], [
 807 dnl No C++ compiler
 808   g_have_iso_cxx_varargs=no
 809 else
 810   AC_LANG_CPLUSPLUS
 811   AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 816   AC_LANG_C
 817 ])
 818 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 819
 820 AC_MSG_CHECKING(for GNUC varargs macros)
 821 AC_TRY_COMPILE([],[
 822 int a(int p1, int p2, int p3);
 823 #define call_a(params...) a(1,params)
 824 call_a(2,3);
 825 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 826 AC_MSG_RESULT($g_have_gnuc_varargs)
 827
 828 # check for GNUC visibility support
 829 AC_MSG_CHECKING(for GNUC visibility attribute)
 830 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 831 void
 832 __attribute__ ((visibility ("hidden")))
 833      f_hidden (void)
 834 {
 835 }
 836 void
 837 __attribute__ ((visibility ("internal")))
 838      f_internal (void)
 839 {
 840 }
 841 void
 842 __attribute__ ((visibility ("protected")))
 843      f_protected (void)
 844 {
 845 }
 846 void
 847 __attribute__ ((visibility ("default")))
 848      f_default (void)
 849 {
 850 }
 851 int main (void)
 852 {
 853         f_hidden();
 854         f_internal();
 855         f_protected();
 856         f_default();
 857         return 0;
 858 }
 859 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 860 AC_MSG_RESULT($g_have_gnuc_visibility)
 861 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 862
 863 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 864 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 865 #else
 866 # include "error: this is not Sun Studio."
 867 #endif
 868 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 869 AC_MSG_RESULT($g_have_sunstudio_visibility)
 870 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 871
 872 # check for bytesex stuff
 873 AC_C_BIGENDIAN
 874 if test x$ac_cv_c_bigendian = xuniversal ; then
 875 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 876 #else
 877 #error Not a big endian.
 878 #endif],
 879     ac_cv_c_bigendian=yes
 880     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 881 #else
 882 #error Not a little endian.
 883 #endif],
 884     ac_cv_c_bigendian=no
 885     ,AC_MSG_WARN([Could not determine endianness.])))
 886 fi
 887
 888
 889 # check for header files
 890 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 891 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 892 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 893 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 894 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 895 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 896 AC_CHECK_HEADERS([linux/magic.h])
 897 AC_CHECK_HEADERS([sys/prctl.h])
 898
 899 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 900 [#if HAVE_SYS_PARAM_H
 901  #include <sys/param.h>
 902  #endif
 903 ])
 904 AC_CHECK_FUNCS(sysctlbyname)
 905
 906 AC_CHECK_HEADERS([xlocale.h])
 907
 908 # check for structure fields
 909 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 910 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 911 #include <sys/stat.h>
 912 #include <unistd.h>
 913 #ifdef HAVE_SYS_STATFS_H
 914 #include <sys/statfs.h>
 915 #endif
 916 #ifdef HAVE_SYS_PARAM_H
 917 #include <sys/param.h>
 918 #endif
 919 #ifdef HAVE_SYS_MOUNT_H
 920 #include <sys/mount.h>
 921 #endif])
 922 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 923 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 924 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 925 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 926
 927 AC_STRUCT_DIRENT_D_TYPE
 928
 929 # Checks for libcharset
 930 AM_LANGINFO_CODESET
 931 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 932 AC_CHECK_FUNCS(setlocale)
 933
 934 # check additional type sizes
 935 AC_CHECK_SIZEOF(size_t)
 936
 937 dnl Try to figure out whether gsize, gssize should be long or int
 938 AC_MSG_CHECKING([for the appropriate definition for size_t])
 939
 940 case $ac_cv_sizeof_size_t in
 941   $ac_cv_sizeof_short)
 942       glib_size_type=short
 943       ;;
 944   $ac_cv_sizeof_int)
 945       glib_size_type=int
 946       ;;
 947   $ac_cv_sizeof_long)
 948       glib_size_type=long
 949       ;;
 950   $ac_cv_sizeof_long_long)
 951       glib_size_type='long long'
 952       ;;
 953   $ac_cv_sizeof__int64)
 954       glib_size_type='__int64'
 955       ;;
 956   *)  AC_MSG_ERROR([No type matching size_t in size])
 957       ;;
 958 esac
 959
 960 dnl If int/long are the same size, we see which one produces
 961 dnl warnings when used in the location as size_t. (This matters
 962 dnl on AIX with xlc)
 963 dnl
 964 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 965        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 966   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 967 #if defined(_AIX) && !defined(__GNUC__)
 968 #pragma options langlvl=stdc89
 969 #endif
 970 #include <stddef.h>
 971 int main ()
 972 {
 973   size_t s = 1;
 974   unsigned int *size_int = &s;
 975   return (int)*size_int;
 976 }
 977     ]])],glib_size_type=int,
 978       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 979 #if defined(_AIX) && !defined(__GNUC__)
 980 #pragma options langlvl=stdc89
 981 #endif
 982 #include <stddef.h>
 983 int main ()
 984 {
 985    size_t s = 1;
 986    unsigned long *size_long = &s;
 987    return (int)*size_long;
 988 }
 989         ]])],glib_size_type=long)])
 990 ])
 991
 992 AC_MSG_RESULT(unsigned $glib_size_type)
 993
 994 # Check for some functions
 995 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 996 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 997 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 998 # Check for high-resolution sleep functions
 999 AC_CHECK_FUNCS(splice)
1000 AC_CHECK_FUNCS(prlimit)
1001
1002 # To avoid finding a compatibility unusable statfs, which typically
1003 # successfully compiles, but warns to use the newer statvfs interface:
1004 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1005 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1006
1007 AC_MSG_CHECKING([whether to use statfs or statvfs])
1008 # Some systems have both statfs and statvfs, pick the most "native" for these
1009 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1010    [
1011    # on solaris and irix, statfs doesn't even have the f_bavail field
1012    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1013       [ac_cv_func_statfs=no],
1014    # else, at least on linux, statfs is the actual syscall
1015       [ac_cv_func_statvfs=no])
1016    ])
1017
1018 AS_IF([test x$ac_cv_func_statfs = xyes],
1019       [
1020          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1021          AC_MSG_RESULT([statfs])
1022       ],
1023       [test x$ac_cv_func_statvfs = xyes],
1024       [
1025          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1026          AC_MSG_RESULT([statvfs])
1027       ],
1028       [  AC_MSG_RESULT([neither])])
1029
1030 AC_CHECK_HEADERS(crt_externs.h)
1031 AC_CHECK_FUNCS(_NSGetEnviron)
1032
1033 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1034
1035 AC_FUNC_VSNPRINTF_C99
1036 AC_FUNC_PRINTF_UNIX98
1037
1038 # Internet address families
1039 if test $glib_native_win32 = yes; then
1040   glib_inet_includes=["
1041 #include <winsock2.h>
1042   "]
1043 else
1044   glib_inet_includes=["
1045 #include <sys/types.h>
1046 #include <sys/socket.h>
1047   "]
1048 fi
1049
1050 glib_failed=false
1051 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1052 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1053 # winsock defines this even though it doesn't support it
1054 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1055 if $glib_failed ; then
1056   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1057 fi
1058
1059 glib_failed=false
1060 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1061 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1062 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1063 if $glib_failed ; then
1064   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1065 fi
1066
1067 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1068
1069 AS_IF([test $glib_native_win32 = yes], [
1070   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1071   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1072   # they aren't present at run-time (on Windows 2000).
1073   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1074   AC_SUBST(WSPIAPI_INCLUDE)
1075 ], [
1076   AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1077   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <arpa/nameser.h>],
1078                                      [int qclass = C_IN;])],
1079                     [AC_MSG_RESULT([no])],
1080                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <arpa/nameser.h>
1081                                                          #include <arpa/nameser_compat.h>],
1082                                                         [int qclass = C_IN;])],
1083                                        [AC_MSG_RESULT([yes])
1084                                         NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1085                                        [AC_MSG_ERROR([could not compile test program either way])])])
1086   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1087
1088   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1089   NETWORK_LIBS=""
1090   AC_MSG_CHECKING([for res_query])
1091   AC_TRY_LINK([#include <sys/types.h>
1092                #include <netinet/in.h>
1093                #include <arpa/nameser.h>
1094                #include <resolv.h>
1095               ],[
1096                res_query("test", 0, 0, (void *)0, 0);
1097               ],[AC_MSG_RESULT([yes])],
1098               [save_libs="$LIBS"
1099                LIBS="-lresolv $LIBS"
1100                AC_TRY_LINK([#include <sys/types.h>
1101                             #include <netinet/in.h>
1102                             #include <arpa/nameser.h>
1103                             #include <resolv.h>
1104                            ],[
1105                             res_query("test", 0, 0, (void *)0, 0);
1106                            ],[AC_MSG_RESULT([in -lresolv])
1107                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1108                            [LIBS="-lbind $save_libs"
1109                             AC_TRY_LINK([#include <resolv.h>],
1110                                         [res_query("test", 0, 0, (void *)0, 0);],
1111                                         [AC_MSG_RESULT([in -lbind])
1112                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1113                                         [AC_MSG_ERROR(not found)])])
1114                LIBS="$save_libs"])
1115   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1116                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1117                                         [AC_MSG_ERROR(Could not find socket())]))
1118 ])
1119 AC_SUBST(NETWORK_LIBS)
1120
1121 AC_CHECK_HEADER([linux/netlink.h],
1122                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1123                 [#include <sys/socket.h>])
1124 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1125
1126 AC_CHECK_TYPE([struct ip_mreqn], [
1127               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1128               [#include <netinet/in.h>])
1129
1130 case $host in
1131   *-*-solaris* )
1132      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1133      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1134      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1135      ;;
1136 esac
1137
1138 dnl
1139 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1140 dnl
1141 AS_IF([test "$ac_cv_func_statfs" = yes], [
1142   AC_MSG_CHECKING([number of arguments to statfs()])
1143   AC_TRY_COMPILE([#include <unistd.h>
1144   #ifdef HAVE_SYS_PARAM_H
1145   #include <sys/param.h>
1146   #endif
1147   #ifdef HAVE_SYS_VFS_H
1148   #include <sys/vfs.h>
1149   #endif
1150   #ifdef HAVE_SYS_MOUNT_H
1151   #include <sys/mount.h>
1152   #endif
1153   #ifdef HAVE_SYS_STATFS_H
1154   #include <sys/statfs.h>
1155   #endif], [struct statfs st;
1156   statfs(NULL, &st);],[
1157     AC_MSG_RESULT([2])
1158     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1159     AC_TRY_COMPILE([#include <unistd.h>
1160   #ifdef HAVE_SYS_PARAM_H
1161   #include <sys/param.h>
1162   #endif
1163   #ifdef HAVE_SYS_VFS_H
1164   #include <sys/vfs.h>
1165   #endif
1166   #ifdef HAVE_SYS_MOUNT_H
1167   #include <sys/mount.h>
1168   #endif
1169   #ifdef HAVE_SYS_STATFS_H
1170   #include <sys/statfs.h>
1171   #endif], [struct statfs st;
1172   statfs(NULL, &st, sizeof (st), 0);],[
1173       AC_MSG_RESULT([4])
1174       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1175       AC_MSG_RESULT(unknown)
1176       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1177 ])
1178
1179 #
1180 # Check whether to use an included printf
1181 #
1182
1183 AC_ARG_ENABLE(included-printf,
1184               [AS_HELP_STRING([--enable-included-printf],
1185                               [use included printf [default=auto]])],
1186               enable_included_printf="$enableval")
1187
1188 need_included_printf=no
1189 if test "x$enable_included_printf" = "xyes" ; then
1190   need_included_printf=yes
1191 fi
1192 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1193   need_included_printf=yes
1194 fi
1195 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1196   need_included_printf=yes
1197 fi
1198 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1199    test -z "$glib_cv_long_long_format" ; then
1200   need_included_printf=yes
1201 fi
1202
1203 if test "x$enable_included_printf" = "xno" &&
1204    test "x$need_included_printf" = "xyes" ; then
1205   AC_MSG_ERROR([
1206 *** Your C library's printf doesn't appear to have the features that
1207 *** GLib needs, but you specified --enable-included-printf=no.])
1208 fi
1209
1210 enable_included_printf=$need_included_printf
1211
1212 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1213 AS_IF([test "$enable_included_printf" != "yes"], [
1214   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1215 ], [
1216   if test -z "$glib_cv_long_long_format" ; then
1217     glib_cv_long_long_format="ll"
1218   fi
1219   AC_DEFINE(HAVE_VASPRINTF,1)
1220 ])
1221
1222 # Checks needed for gnulib vasnprintf
1223 bh_C_SIGNED
1224 jm_AC_TYPE_LONG_LONG
1225 gt_TYPE_LONGDOUBLE
1226 gt_TYPE_WCHAR_T
1227 gt_TYPE_WINT_T
1228 AC_TYPE_SIZE_T
1229 AC_CHECK_TYPES(ptrdiff_t)
1230 jm_AC_TYPE_INTMAX_T
1231 AC_CHECK_FUNCS([snprintf wcslen])
1232 AC_FUNC_SNPRINTF_C99
1233
1234 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1235 # The check is borrowed from the PERL Configure script.
1236 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1237   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1238     glib_cv_working_bcopy,[AC_TRY_RUN([
1239       int main() {
1240         char buf[128], abc[128], *b;
1241         int len, off, align;
1242         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1243         for (align = 7; align >= 0; align--) {
1244           for (len = 36; len; len--) {
1245             b = buf+align; bcopy(abc, b, len);
1246             for (off = 1; off <= len; off++) {
1247               bcopy(b, b+off, len); bcopy(b+off, b, len);
1248                 if (bcmp(b, abc, len)) return(1);
1249             }
1250           }
1251         }
1252         return(0);
1253       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1254
1255   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1256   if test "$glib_cv_working_bcopy" = "yes"; then
1257     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1258   fi
1259 ])
1260
1261 # Check if <sys/select.h> needs to be included for fd_set
1262 AC_MSG_CHECKING([for fd_set])
1263 AC_TRY_COMPILE([#include <sys/types.h>],
1264         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1265 AS_IF([test "$gtk_ok" = "yes"], [
1266     AC_MSG_RESULT([yes, found in sys/types.h])
1267 ], [
1268     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1269     if test "$gtk_ok" = "yes"; then
1270         # *** FIXME: give it a different name
1271         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1272         AC_MSG_RESULT([yes, found in sys/select.h])
1273     else
1274         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1275         AC_MSG_RESULT(no)
1276     fi
1277 ])
1278
1279 dnl *** check for sane realloc() ***
1280 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1281         AC_TRY_RUN([#include <stdlib.h>
1282         int main() {
1283           return realloc (0, sizeof (int)) == 0;
1284         }],
1285         [glib_cv_sane_realloc=yes],
1286         [glib_cv_sane_realloc=no],
1287         [glib_cv_sane_realloc=yes])
1288 ])
1289 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1290   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1291 ])
1292
1293 dnl Check for nl_langinfo and CODESET
1294 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1295         AC_TRY_COMPILE([#include <langinfo.h>],
1296                 [char *codeset = nl_langinfo (CODESET);],
1297                 [glib_cv_langinfo_codeset=yes],
1298                 [glib_cv_langinfo_codeset=no])])
1299 if test x$glib_cv_langinfo_codeset = xyes; then
1300   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1301 fi
1302
1303 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1304 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1305         AC_TRY_COMPILE([#include <langinfo.h>],
1306                 [char *str;
1307                  str = nl_langinfo (PM_STR);
1308                  str = nl_langinfo (D_T_FMT);
1309                  str = nl_langinfo (D_FMT);
1310                  str = nl_langinfo (T_FMT);
1311                  str = nl_langinfo (T_FMT_AMPM);
1312                  str = nl_langinfo (MON_1);
1313                  str = nl_langinfo (ABMON_12);
1314                  str = nl_langinfo (DAY_1);
1315                  str = nl_langinfo (ABDAY_7);],
1316                 [glib_cv_langinfo_time=yes],
1317                 [glib_cv_langinfo_time=no])])
1318 if test x$glib_cv_langinfo_time = xyes; then
1319   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1320 fi
1321
1322 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1323 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1324         AC_TRY_COMPILE([#include <langinfo.h>],
1325                 [char *str;
1326                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1327                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1328                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1329                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1336                 [glib_cv_langinfo_outdigit=yes],
1337                 [glib_cv_langinfo_outdigit=no])])
1338 if test x$glib_cv_langinfo_outdigit = xyes; then
1339   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1340 fi
1341
1342 dnl ****************************************
1343 dnl *** posix_memalign                   ***
1344 dnl ****************************************
1345 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1346 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1347     glib_cv_compliant_posix_memalign=0
1348     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1349         AC_TRY_RUN([
1350                 #define _XOPEN_SOURCE 600
1351                 #include <stdlib.h> /* posix_memalign() should be defined here */
1352                 /* some systems break if #include <malloc.h> used */
1353                 static void test_memalign (size_t boundary, size_t size) {
1354                     void *mem = 0;
1355                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1356                         exit (1);
1357                     else
1358                       free (mem);
1359                 }
1360                 int main() {
1361                     test_memalign (  128,   128 - 2 * sizeof (void*));
1362                     test_memalign (  256,   256 - 2 * sizeof (void*));
1363                     test_memalign (  512,   512 - 2 * sizeof (void*));
1364                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1365                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1366                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1367                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1368                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1369                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1370                     exit (0); /* success */
1371                 }
1372                 ],
1373             [glib_cv_compliant_posix_memalign=1], [], [:])
1374       :
1375     fi
1376     ])
1377 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1378     AC_MSG_RESULT(yes)
1379     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1380 ], [
1381     AC_MSG_RESULT(no)
1382 ])
1383
1384
1385 dnl ****************************************
1386 dnl *** strlcpy/strlcat                  ***
1387 dnl ****************************************
1388 # Check for strlcpy
1389 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1390 AC_TRY_RUN([#include <stdlib.h>
1391 #include <string.h>
1392 int main() {
1393   char p[10];
1394   (void) strlcpy (p, "hi", 10);
1395   if (strlcat (p, "bye", 0) != 3)
1396     return 1;
1397   return 0;
1398 }], glib_cv_have_strlcpy=yes,
1399     glib_cv_have_strlcpy=no,
1400     glib_cv_have_strlcpy=no)])
1401 if test "$glib_cv_have_strlcpy" = "yes"; then
1402     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1403 fi
1404
1405
1406 dnl **********************
1407 dnl *** va_copy checks ***
1408 dnl **********************
1409 dnl we currently check for all three va_copy possibilities, so we get
1410 dnl all results in config.log for bug reports.
1411 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1412         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1413 #include <stdlib.h>
1414         void f (int i, ...) {
1415         va_list args1, args2;
1416         va_start (args1, i);
1417         va_copy (args2, args1);
1418         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1419           exit (1);
1420         va_end (args1); va_end (args2);
1421         }
1422         int main() {
1423           f (0, 42);
1424           return 0;
1425         }]])],
1426         [glib_cv_va_copy=yes],
1427         [glib_cv_va_copy=no])
1428 ])
1429 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1430         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1431 #include <stdlib.h>
1432         void f (int i, ...) {
1433         va_list args1, args2;
1434         va_start (args1, i);
1435         __va_copy (args2, args1);
1436         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1437           exit (1);
1438         va_end (args1); va_end (args2);
1439         }
1440         int main() {
1441           f (0, 42);
1442           return 0;
1443         }]])],
1444         [glib_cv___va_copy=yes],
1445         [glib_cv___va_copy=no])
1446 ])
1447
1448 if test "x$glib_cv_va_copy" = "xyes"; then
1449   g_va_copy_func=va_copy
1450 else if test "x$glib_cv___va_copy" = "xyes"; then
1451   g_va_copy_func=__va_copy
1452 fi
1453 fi
1454
1455 if test -n "$g_va_copy_func"; then
1456   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1457 fi
1458
1459 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1460         AC_TRY_RUN([#include <stdarg.h>
1461 #include <stdlib.h>
1462         void f (int i, ...) {
1463         va_list args1, args2;
1464         va_start (args1, i);
1465         args2 = args1;
1466         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1467           exit (1);
1468         va_end (args1); va_end (args2);
1469         }
1470         int main() {
1471           f (0, 42);
1472           return 0;
1473         }],
1474         [glib_cv_va_val_copy=yes],
1475         [glib_cv_va_val_copy=no],
1476         [glib_cv_va_val_copy=yes])
1477 ])
1478
1479 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1480   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1481 ])
1482
1483 dnl ***********************
1484 dnl *** g_module checks ***
1485 dnl ***********************
1486 G_MODULE_LIBS=
1487 G_MODULE_LIBS_EXTRA=
1488 G_MODULE_PLUGIN_LIBS=
1489 if test x"$glib_native_win32" = xyes; then
1490   dnl No use for this on Win32
1491   G_MODULE_LDFLAGS=
1492 else
1493   export SED
1494   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1495 fi
1496 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1497 G_MODULE_NEED_USCORE=0
1498 G_MODULE_BROKEN_RTLD_GLOBAL=0
1499 G_MODULE_HAVE_DLERROR=0
1500 dnl *** force native WIN32 shared lib loader
1501 if test -z "$G_MODULE_IMPL"; then
1502   case "$host" in
1503   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1504   esac
1505 fi
1506 dnl *** force native AIX library loader
1507 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1508 if test -z "$G_MODULE_IMPL"; then
1509   case "$host" in
1510   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1511   esac
1512 fi
1513 dnl *** dlopen() and dlsym() in system libraries
1514 AS_IF([ test -z "$G_MODULE_IMPL"], [
1515         AC_CHECK_FUNC(dlopen,
1516                       [AC_CHECK_FUNC(dlsym,
1517                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1518                       [])
1519 ])
1520 dnl *** load_image (BeOS)
1521 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1522   AC_CHECK_LIB(root, load_image,
1523       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1524       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1525       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1526       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1527       [])
1528 ])
1529 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1530 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1531         AC_CHECK_FUNC(NSLinkModule,
1532                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1533                        G_MODULE_NEED_USCORE=1],
1534                       [])
1535 ])
1536 dnl *** dlopen() and dlsym() in libdl
1537 AS_IF([ test -z "$G_MODULE_IMPL"], [
1538         AC_CHECK_LIB(dl, dlopen,
1539                      [AC_CHECK_LIB(dl, dlsym,
1540                                    [G_MODULE_LIBS=-ldl
1541                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1542                      [])
1543 ])
1544 dnl *** shl_load() in libdld (HP-UX)
1545 AS_IF([ test -z "$G_MODULE_IMPL"], [
1546         AC_CHECK_LIB(dld, shl_load,
1547                 [G_MODULE_LIBS=-ldld
1548                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1549                 [])
1550 ])
1551 dnl *** additional checks for G_MODULE_IMPL_DL
1552 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1553         LIBS_orig="$LIBS"
1554         LDFLAGS_orig="$LDFLAGS"
1555         LIBS="$G_MODULE_LIBS $LIBS"
1556         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1557 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1558         echo "void glib_plugin_test(void) { }" > plugin.c
1559         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1560                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1561         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1562                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1563                 -shrext ".o" -avoid-version plugin.lo \
1564                 -rpath /dont/care >/dev/null 2>&1
1565         eval `./libtool --config | grep ^objdir`
1566         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1567                 glib_cv_rtldglobal_broken,[
1568                 AC_TRY_RUN([
1569 #include <dlfcn.h>
1570 #ifndef RTLD_GLOBAL
1571 #  define RTLD_GLOBAL 0
1572 #endif
1573 #ifndef RTLD_LAZY
1574 #  define RTLD_LAZY 0
1575 #endif
1576 int glib_plugin_test;
1577 int main () {
1578     void *handle, *global, *local;
1579     global = &glib_plugin_test;
1580     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1581     if (!handle) return 0;
1582     local = dlsym (handle, "glib_plugin_test");
1583     return global == local;
1584 }                       ],
1585                         [glib_cv_rtldglobal_broken=no],
1586                         [glib_cv_rtldglobal_broken=yes],
1587                         [glib_cv_rtldglobal_broken=no])
1588                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1589                 rmdir ${objdir} 2>/dev/null
1590         ])
1591         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1592                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1593         else
1594                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1595         fi
1596 dnl *** check whether we need preceeding underscores
1597         AC_CACHE_CHECK([for preceeding underscore in symbols],
1598                 glib_cv_uscore,[
1599                 AC_TRY_RUN([#include <dlfcn.h>
1600                 int glib_underscore_test (void) { return 42; }
1601                 int main() {
1602                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1603                   handle = dlopen ((void*)0, 0);
1604                   if (handle) {
1605                     f1 = dlsym (handle, "glib_underscore_test");
1606                     f2 = dlsym (handle, "_glib_underscore_test");
1607                   } return (!f2 || f1);
1608                 }],
1609                         [glib_cv_uscore=yes],
1610                         [glib_cv_uscore=no],
1611                         [])
1612                 rm -f plugin.c plugin.$ac_objext plugin.lo
1613         ])
1614         GLIB_ASSERT_SET(glib_cv_uscore)
1615         if test "x$glib_cv_uscore" = "xyes"; then
1616                 G_MODULE_NEED_USCORE=1
1617         else
1618                 G_MODULE_NEED_USCORE=0
1619         fi
1620
1621         LDFLAGS="$LDFLAGS_orig"
1622 dnl *** check for having dlerror()
1623         AC_CHECK_FUNC(dlerror,
1624                 [G_MODULE_HAVE_DLERROR=1],
1625                 [G_MODULE_HAVE_DLERROR=0])
1626         LIBS="$LIBS_orig"
1627 ])
1628 dnl *** done, have we got an implementation?
1629 if test -z "$G_MODULE_IMPL"; then
1630         G_MODULE_IMPL=0
1631         G_MODULE_SUPPORTED=false
1632 else
1633         G_MODULE_SUPPORTED=true
1634 fi
1635
1636 AC_MSG_CHECKING(for the suffix of module shared libraries)
1637 export SED
1638 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1639 eval $shrext_cmds
1640 module=yes eval std_shrext=$shrext_cmds
1641 # chop the initial dot
1642 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1643 AC_MSG_RESULT(.$glib_gmodule_suffix)
1644 # any reason it may fail?
1645 if test "x$glib_gmodule_suffix" = x; then
1646         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1647 fi
1648
1649 AC_SUBST(G_MODULE_SUPPORTED)
1650 AC_SUBST(G_MODULE_IMPL)
1651 AC_SUBST(G_MODULE_LIBS)
1652 AC_SUBST(G_MODULE_LIBS_EXTRA)
1653 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1654 AC_SUBST(G_MODULE_LDFLAGS)
1655 AC_SUBST(G_MODULE_HAVE_DLERROR)
1656 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1657 AC_SUBST(G_MODULE_NEED_USCORE)
1658 AC_SUBST(GLIB_DEBUG_FLAGS)
1659
1660 dnl **********************
1661 dnl *** g_spawn checks ***
1662 dnl **********************
1663
1664 AC_MSG_CHECKING(for gspawn implementation)
1665 case "$host" in
1666   *-*-mingw*)
1667     GSPAWN=gspawn-win32.lo
1668     ;;
1669   *)
1670     GSPAWN=gspawn.lo
1671     ;;
1672 esac
1673 AC_MSG_RESULT($GSPAWN)
1674 AC_SUBST(GSPAWN)
1675
1676 dnl *************************
1677 dnl *** GIOChannel checks ***
1678 dnl *************************
1679
1680 AC_MSG_CHECKING(for GIOChannel implementation)
1681 case "$host" in
1682   *-*-mingw*)
1683     GIO=giowin32.lo
1684     ;;
1685   *)
1686     GIO=giounix.lo
1687     ;;
1688 esac
1689 AC_MSG_RESULT($GIO)
1690 AC_SUBST(GIO)
1691
1692 dnl *********************************
1693 dnl *** Directory for GIO modules ***
1694 dnl *********************************
1695
1696 AC_ARG_WITH(gio-module-dir,
1697            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1698                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1699            [],
1700            [with_gio_module_dir='${libdir}/gio/modules'])
1701 GIO_MODULE_DIR=$with_gio_module_dir
1702 AC_SUBST(GIO_MODULE_DIR)
1703
1704 dnl **********************************
1705 dnl *** Check for libselinux (GIO) ***
1706 dnl **********************************
1707 AC_ARG_ENABLE(selinux,
1708               AS_HELP_STRING([--disable-selinux],
1709                              [build without selinux support]))
1710 msg_selinux=no
1711 SELINUX_LIBS=
1712 AS_IF([ test "x$enable_selinux" != "xno"], [
1713
1714  AC_CHECK_LIB(selinux, is_selinux_enabled,
1715    [AC_CHECK_HEADERS(selinux/selinux.h,
1716      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1717        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1718         SELINUX_LIBS="-lselinux"
1719         msg_selinux=yes])
1720      ])
1721    ])
1722 ])
1723 AC_SUBST(SELINUX_LIBS)
1724
1725 dnl *****************************
1726 dnl ** Check for inotify (GIO) **
1727 dnl *****************************
1728 inotify_support=no
1729 AC_CHECK_HEADERS([sys/inotify.h],
1730 [
1731         inotify_support=yes
1732         AC_CHECK_FUNCS(inotify_init1)
1733 ])
1734
1735 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1736
1737 dnl ****************************
1738 dnl ** Check for kqueue (GIO) **
1739 dnl ****************************
1740 kqueue_support=no
1741 AC_CHECK_HEADERS([sys/event.h],
1742 [
1743         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1744 ])
1745
1746 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1747
1748 dnl *********************************
1749 dnl ** Check for Solaris FEN (GIO) **
1750 dnl *********************************
1751 fen_support=no
1752 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1753 #include <port.h>
1754 #ifndef PORT_SOURCE_FILE
1755 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1756 #endif
1757 int main() { return 0; } ]])],
1758 [
1759         fen_support=yes
1760 ],)
1761
1762 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1763
1764 dnl ****************************
1765 dnl *** Checks for FAM (GIO) ***
1766 dnl ****************************
1767
1768 should_disable_fam=no
1769
1770 AC_ARG_ENABLE(fam,
1771               AS_HELP_STRING([--disable-fam],
1772                              [don't use fam for file system monitoring]),
1773                          [
1774                                 if test "x$enable_fam" = "xno"; then
1775                                         should_disable_fam=yes
1776                                 fi
1777                          ]
1778                          )
1779 fam_support=no
1780 FAM_LIBS=
1781 if test "x$should_disable_fam" = "xno"; then
1782 AC_CHECK_LIB(fam, FAMOpen,
1783   [AC_CHECK_HEADERS(fam.h,
1784     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1785      AC_CHECK_LIB(fam, FAMNoExists,
1786                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1787      FAM_LIBS="-lfam"]
1788      fam_support=yes,
1789     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1790   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1791 AC_SUBST(FAM_LIBS)
1792 fi
1793 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1794
1795
1796 dnl *****************************
1797 dnl *** Check for xattr (GIO) ***
1798 dnl *****************************
1799 AC_ARG_ENABLE(xattr,
1800               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1801 msg_xattr=no
1802 XATTR_LIBS=
1803 AS_IF([ test "x$enable_xattr" != "xno"], [
1804
1805 dnl either glibc or libattr can provide xattr support
1806
1807 dnl for both of them, we check for getxattr being in
1808 dnl the library and a valid xattr header.
1809
1810 dnl try glibc
1811  AC_CHECK_LIB(c, getxattr,
1812    [AC_CHECK_HEADERS(sys/xattr.h,
1813      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1814       msg_xattr=yes])
1815    ])
1816
1817   AS_IF([ test "x$msg_xattr" != "xyes"], [
1818 dnl   failure. try libattr
1819    AC_CHECK_LIB(attr, getxattr,
1820       [AC_CHECK_HEADERS(attr/xattr.h,
1821        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1822         XATTR_LIBS="-lattr"
1823         msg_xattr=yes])
1824       ])
1825   ])
1826
1827   AS_IF([ test "x$msg_xattr" = "xyes"], [
1828     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1829     AC_TRY_COMPILE([
1830       #include <stdio.h>
1831       #ifdef HAVE_SYS_TYPES_H
1832       #include <sys/types.h>
1833       #endif
1834       #ifdef HAVE_SYS_XATTR_H
1835       #include <sys/xattr.h>
1836       #elif HAVE_ATTR_XATTR_H
1837       #include <attr/xattr.h>
1838       #endif
1839     ],
1840     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1841     [
1842       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1843       AC_MSG_RESULT([yes])
1844     ],
1845     [AC_MSG_RESULT([no])]
1846     )
1847   ])
1848 ])
1849 AC_SUBST(XATTR_LIBS)
1850
1851 dnl ************************
1852 dnl *** check for libelf ***
1853 dnl ************************
1854 AC_ARG_ENABLE(libelf,
1855               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1856 AS_IF([ test "x$enable_libelf" != "xno"],[
1857 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1858 AS_IF([ test $have_libelf = maybe ], [
1859   glib_save_LIBS=$LIBS
1860   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1861   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1862   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1863   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1864   LIBS=$glib_save_LIBS
1865
1866   if test $have_libelf != no; then
1867     LIBELF_LIBS=-lelf
1868     have_libelf=yes
1869   fi
1870 ])
1871 ])
1872
1873 if test x$have_libelf = xyes; then
1874   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1875 fi
1876
1877 dnl ****************************************
1878 dnl *** platform dependent source checks ***
1879 dnl ****************************************
1880
1881 AC_MSG_CHECKING(for platform-dependent source)
1882 case "$host" in
1883   *-*-cygwin*|*-*-mingw*)
1884     PLATFORMDEP=gwin32.lo
1885     ;;
1886   *)
1887     PLATFORMDEP=
1888     ;;
1889 esac
1890 AC_MSG_RESULT($PLATFORMDEP)
1891 AC_SUBST(PLATFORMDEP)
1892
1893 AC_MSG_CHECKING([whether to compile timeloop])
1894 case "$host" in
1895   *-*-cygwin*|*-*-mingw*|*-*-minix)
1896     enable_timeloop=no
1897     ;;
1898   *)
1899     enable_timeloop=yes
1900     ;;
1901 esac
1902 AC_MSG_RESULT($enable_timeloop)
1903 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1904
1905 AC_MSG_CHECKING([if building for some Win32 platform])
1906 case "$host" in
1907   *-*-mingw*|*-*-cygwin*)
1908     platform_win32=yes
1909     ;;
1910   *)
1911     platform_win32=no
1912     ;;
1913 esac
1914 AC_MSG_RESULT($platform_win32)
1915 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1916
1917 dnl ***********************
1918 dnl *** g_thread checks ***
1919 dnl ***********************
1920
1921 AC_ARG_WITH(threads,
1922            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1923                            [specify a thread implementation to use])],
1924            [],
1925            [with_threads=yes])
1926
1927 dnl error and warning message
1928 dnl *************************
1929
1930 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1931
1932 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1933                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1934                 compilation now, but then your programs might not work.
1935                 Please provide information on how it is done on your system."
1936
1937 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1938                  "
1939
1940 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1941                   provide information on your thread implementation."
1942
1943 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1944                 functions will not be MT-safe during their first call because
1945                 there is no working 'getpwuid_r' on your system."
1946
1947 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1948                 because there is no 'localtime_r' on your system."
1949
1950 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1951                 linking threaded applications. As GLib cannot do that
1952                 automatically, you will get an linkg error everytime you are
1953                 not using the right compiler. In that case you have to relink
1954                 with the right compiler. Ususally just '_r' is appended
1955                 to the compiler name."
1956
1957 dnl determination of thread implementation
1958 dnl ***************************************
1959
1960 AC_MSG_CHECKING(for thread implementation)
1961
1962 have_threads=no
1963 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1964         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1965         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1966         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1967         glib_save_CPPFLAGS="$CPPFLAGS"
1968         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1969         AS_IF([ test "x$have_threads" = xno], [
1970                 AC_TRY_COMPILE([#include <pthread.h>],
1971                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1972                         have_threads=posix)
1973         ])
1974         # Tru64Unix requires -pthread to find pthread.h. See #103020
1975         CPPFLAGS="$CPPFLAGS -pthread"
1976         if test "x$have_threads" = xno; then
1977         AC_TRY_COMPILE([#include <pthread.h>],
1978                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1979                        have_threads=posix)
1980         fi
1981         CPPFLAGS="$glib_save_CPPFLAGS"
1982 ])
1983 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1984         case $host in
1985                 *-*-mingw*)
1986                 have_threads=win32
1987                 ;;
1988         esac
1989 fi
1990
1991 if test "x$have_threads" = xno; then
1992         AC_MSG_RESULT(none available)
1993         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1994 else
1995         AC_MSG_RESULT($have_threads)
1996 fi
1997
1998
1999 dnl determination of G_THREAD_CFLAGS
2000 dnl ********************************
2001
2002 G_THREAD_LIBS=
2003 G_THREAD_LIBS_EXTRA=
2004 G_THREAD_CFLAGS=
2005
2006 dnl
2007 dnl Test program for basic POSIX threads functionality
2008 dnl
2009 m4_define([glib_thread_test],[
2010 #include <pthread.h>
2011 int check_me = 0;
2012 void* func(void* data) {check_me = 42; return &check_me;}
2013 int main()
2014  { pthread_t t;
2015    void *ret;
2016    pthread_create (&t, $1, func, 0);
2017    pthread_join (t, &ret);
2018    return (check_me != 42 || ret != &check_me);
2019 }])
2020
2021 AS_IF([ test x"$have_threads" = xposix], [
2022   # First we test for posix, whether -pthread or -pthreads do the trick as
2023   # both CPPFLAG and LIBS.
2024   # One of them does for most gcc versions and some other platforms/compilers
2025   # too and could be considered as the canonical way to go.
2026   case $host in
2027     *-*-cygwin*|*-*-darwin*)
2028        # skip cygwin and darwin -pthread or -pthreads test
2029        ;;
2030     *-solaris*)
2031       # These compiler/linker flags work with both Sun Studio and gcc
2032       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2033       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2034       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2035       G_THREAD_LIBS="-lpthread -lthread"
2036       ;;
2037     *)
2038       for flag in pthread pthreads mt; do
2039         glib_save_CFLAGS="$CFLAGS"
2040         CFLAGS="$CFLAGS -$flag"
2041         AC_TRY_RUN(glib_thread_test(0),
2042                    glib_flag_works=yes,
2043                    glib_flag_works=no,
2044                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2045                                    glib_flag_works=yes,
2046                                    glib_flag_works=no)])
2047         CFLAGS="$glib_save_CFLAGS"
2048         if test $glib_flag_works = yes ; then
2049            G_THREAD_CFLAGS=-$flag
2050         G_THREAD_LIBS=-$flag
2051         break;
2052         fi
2053       done
2054        ;;
2055   esac
2056 ])
2057
2058 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2059
2060   # The canonical -pthread[s] does not work. Try something different.
2061
2062   case $host in
2063         *-aix*)
2064                 if test x"$GCC" = xyes; then
2065                         # GCC 3.0 and above needs -pthread.
2066                         # Should be coverd by the case above.
2067                         # GCC 2.x and below needs -mthreads
2068                         G_THREAD_CFLAGS="-mthreads"
2069                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2070                 else
2071                         # We are probably using the aix compiler. Normaly a
2072                         # program would have to be compiled with the _r variant
2073                         # of the corresponding compiler, but we as GLib cannot
2074                         # do that: but the good news is that for compiling the
2075                         # only difference is the added -D_THREAD_SAFE compile
2076                         # option. This is according to the "C for AIX User's
2077                         # Guide".
2078                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2079                 fi
2080                 ;;
2081         *-dg-dgux*)  # DG/UX
2082                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2083                 ;;
2084         *-sysv5uw7*) # UnixWare 7
2085                 # We are not using gcc with -pthread. Catched above.
2086                 G_THREAD_CFLAGS="-Kthread"
2087                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2088                 ;;
2089         *-mingw*)
2090                 # No flag needed when using MSVCRT.DLL
2091                 G_THREAD_CFLAGS=""
2092                 ;;
2093         *)
2094                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2095                 ;;
2096   esac
2097 ])
2098
2099 # if we are not finding the localtime_r function, then we probably are
2100 # not using the proper multithread flag
2101
2102 glib_save_CPPFLAGS="$CPPFLAGS"
2103 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2104
2105 # First we test, whether localtime_r is declared in time.h
2106 # directly. Then we test whether a macro localtime_r exists, in
2107 # which case localtime_r in the test program is replaced and thus
2108 # if we still find localtime_r in the output, it is not defined as
2109 # a macro.
2110
2111 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2112   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2113                                                            localtime_r(a,b)],
2114                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2115
2116 CPPFLAGS="$glib_save_CPPFLAGS"
2117
2118 AC_MSG_CHECKING(thread related cflags)
2119 AC_MSG_RESULT($G_THREAD_CFLAGS)
2120 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2121
2122 dnl determination of G_THREAD_LIBS
2123 dnl ******************************
2124
2125 AS_IF([test x$have_threads = xposix], [
2126           glib_save_CPPFLAGS="$CPPFLAGS"
2127           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2128           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2129             case $host in
2130               *-aix*)
2131                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2132                 # probably using the aix compiler.
2133                 AC_MSG_WARN($AIX_COMPILE_INFO)
2134                 ;;
2135               *)
2136                 G_THREAD_LIBS=error
2137                 glib_save_LIBS="$LIBS"
2138                 for thread_lib in "" pthread pthread32 pthreads thread; do
2139                         if test x"$thread_lib" = x; then
2140                                 add_thread_lib=""
2141                                 IN=""
2142                         else
2143                                 add_thread_lib="-l$thread_lib"
2144                                 IN=" in -l$thread_lib"
2145                         fi
2146                         if test x"$have_threads" = xposix; then
2147                                 defattr=0
2148                         else
2149                                 defattr=pthread_attr_default
2150                         fi
2151
2152                         LIBS="$add_thread_lib $glib_save_LIBS"
2153
2154                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2155                         AC_TRY_RUN(glib_thread_test($defattr),
2156                                    glib_result=yes,
2157                                    glib_result=no,
2158                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2159                                                    glib_result=yes,
2160                                                    glib_result=no)])
2161                         AC_MSG_RESULT($glib_result)
2162
2163                         if test "$glib_result" = "yes" ; then
2164                           G_THREAD_LIBS="$add_thread_lib"
2165                           break
2166                         fi
2167                 done
2168                 if test "x$G_THREAD_LIBS" = xerror; then
2169                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2170                 fi
2171                 LIBS="$glib_save_LIBS"
2172                 ;;
2173             esac
2174           ])
2175
2176           g_threads_impl="POSIX"
2177           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2178           CPPFLAGS="$glib_save_CPPFLAGS"
2179 ], [test x$have_threads = xwin32], [
2180            g_threads_impl="WIN32"
2181 ], [
2182            g_threads_impl="NONE"
2183            G_THREAD_LIBS=error
2184 ])
2185
2186 if test "x$G_THREAD_LIBS" = xerror; then
2187         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2188 fi
2189
2190 case $host in
2191   *-*-beos*)
2192     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2193     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2194     ;;
2195   *)
2196     ;;
2197 esac
2198
2199 AC_MSG_CHECKING(thread related libraries)
2200 AC_MSG_RESULT($G_THREAD_LIBS)
2201
2202 dnl check for mt safe function variants and some posix functions
2203 dnl ************************************************************
2204
2205 glib_save_LIBS="$LIBS"
2206 # we are not doing the following for now, as this might require glib
2207 # to always be linked with the thread libs on some platforms.
2208 # LIBS="$LIBS $G_THREAD_LIBS"
2209 AC_CHECK_FUNCS(localtime_r gmtime_r)
2210 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2211         AC_CACHE_CHECK([for posix getpwuid_r],
2212                 ac_cv_func_posix_getpwuid_r,
2213                 [AC_TRY_RUN([
2214 #include <errno.h>
2215 #include <pwd.h>
2216 int main () {
2217     char buffer[10000];
2218     struct passwd pwd, *pwptr = &pwd;
2219     int error;
2220     errno = 0;
2221     error = getpwuid_r (0, &pwd, buffer,
2222                         sizeof (buffer), &pwptr);
2223    return (error < 0 && errno == ENOSYS)
2224            || error == ENOSYS;
2225 }                               ],
2226                         [ac_cv_func_posix_getpwuid_r=yes],
2227                         [ac_cv_func_posix_getpwuid_r=no])])
2228         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2229         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2230                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2231                         [Have POSIX function getpwuid_r])
2232         else
2233                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2234                         ac_cv_func_nonposix_getpwuid_r,
2235                         [AC_TRY_LINK([#include <pwd.h>],
2236                                 [char buffer[10000];
2237                                 struct passwd pwd;
2238                                 getpwuid_r (0, &pwd, buffer,
2239                                                 sizeof (buffer));],
2240                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2241                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2242                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2243                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2244                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2245                                 [Have non-POSIX function getpwuid_r])
2246                 fi
2247         fi
2248 ])
2249 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2250         AC_CACHE_CHECK([for posix getgrgid_r],
2251                 ac_cv_func_posix_getgrgid_r,
2252                 [AC_TRY_RUN([
2253 #include <errno.h>
2254 #include <grp.h>
2255 int main () {
2256     char buffer[10000];
2257     struct group grp, *grpptr = &grp;
2258     int error;
2259     errno = 0;
2260     error = getgrgid_r (0, &grp, buffer,
2261                         sizeof (buffer), &grpptr);
2262    return (error < 0 && errno == ENOSYS)
2263            || error == ENOSYS;
2264 }                              ],
2265                        [ac_cv_func_posix_getgrgid_r=yes],
2266                        [ac_cv_func_posix_getgrgid_r=no])])
2267         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2268         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2269                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2270                         [Have POSIX function getgrgid_r])
2271         ], [
2272                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2273                         ac_cv_func_nonposix_getgrgid_r,
2274                         [AC_TRY_LINK([#include <grp.h>],
2275                                 [char buffer[10000];
2276                                 struct group grp;
2277                                 getgrgid_r (0, &grp, buffer,
2278                                 sizeof (buffer));],
2279                         [ac_cv_func_nonposix_getgrgid_r=yes],
2280                         [ac_cv_func_nonposix_getgrgid_r=no])])
2281                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2282                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2283                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2284                                 [Have non-POSIX function getgrgid_r])
2285                 fi
2286         ])
2287 ])
2288 LIBS="$G_THREAD_LIBS $LIBS"
2289 AS_IF([ test x"$have_threads" = xposix], [
2290         glib_save_CPPFLAGS="$CPPFLAGS"
2291         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2292         # This is not AC_CHECK_FUNC to also work with function
2293         # name mangling in header files.
2294         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2295         AC_LINK_IFELSE(
2296             [AC_LANG_PROGRAM(
2297                 [#include <pthread.h>],
2298                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2299             [AC_MSG_RESULT(yes)
2300              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2301                 [Have function pthread_attr_setstacksize])],
2302             [AC_MSG_RESULT(no)])
2303         AC_MSG_CHECKING(for pthread_condattr_setclock)
2304         AC_LINK_IFELSE(
2305             [AC_LANG_PROGRAM(
2306                 [#include <pthread.h>],
2307                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2308             [AC_MSG_RESULT(yes)
2309              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2310                 [Have function pthread_condattr_setclock])],
2311             [AC_MSG_RESULT(no)])
2312         CPPFLAGS="$glib_save_CPPFLAGS"
2313 ])
2314
2315 LIBS="$glib_save_LIBS"
2316
2317 # now spit out all the warnings.
2318 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2319    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2320         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2321 fi
2322 if test "$ac_cv_func_localtime_r" != "yes"; then
2323         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2324 fi
2325
2326 #
2327 # Hack to deal with:
2328 #
2329 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2330 #     building shared libraries with linux.
2331 #  b) FreeBSD doesn't do this either.
2332 #
2333 case $host in
2334   *-*-freebsd*|*-*-linux*)
2335     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2336     ;;
2337   *-*-openbsd*)
2338     LDFLAGS="$LDFLAGS -pthread"
2339     ;;
2340   *)
2341     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2342     ;;
2343 esac
2344
2345 AC_SUBST(G_THREAD_CFLAGS)
2346 AC_SUBST(G_THREAD_LIBS)
2347 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2348 AC_SUBST(G_THREAD_LIBS_EXTRA)
2349
2350 AC_CHECK_FUNCS(clock_gettime, [], [
2351   AC_CHECK_LIB(rt, clock_gettime, [
2352     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2353     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2354     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2355   ])
2356 ])
2357
2358
2359 dnl ************************
2360 dnl *** g_atomic_* tests ***
2361 dnl ************************
2362
2363 dnl We need to decide at configure time if GLib will use real atomic
2364 dnl operations ("lock free") or emulated ones with a mutex.  This is
2365 dnl because we must put this information in glibconfig.h so we know if
2366 dnl it is safe or not to inline using compiler intrinsics directly from
2367 dnl the header.
2368 dnl
2369 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2370 dnl user is interested in knowing if they can use the atomic ops across
2371 dnl processes.
2372 dnl
2373 dnl We can currently support the atomic ops natively when building GLib
2374 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2375 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2376 dnl we are using GCC.
2377 dnl
2378 dnl Note that the atomic ops are only available with GCC on x86 when
2379 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2380 dnl not available but would be available given the right flags, we want
2381 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2382 dnl that then to silently fall back on emulated atomic ops just because
2383 dnl the user had the wrong build environment.
2384
2385 dnl We may add other compilers here in the future...
2386
2387 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2388   AC_TRY_COMPILE([],
2389                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2390                  [glib_cv_g_atomic_lock_free=yes],
2391                  [glib_cv_g_atomic_lock_free=no])])
2392
2393 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2394   SAVE_CFLAGS="${CFLAGS}"
2395   CFLAGS="-march=i486"
2396   AC_TRY_COMPILE([],
2397                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2398                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2399                  [])
2400   CFLAGS="${SAVE_CFLAGS}"
2401 fi
2402
2403 dnl We need a more robust approach here...
2404 case $host_cpu in
2405   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2406     glib_memory_barrier_needed=no
2407     ;;
2408   sparc*|alpha*|powerpc*|ia64)
2409     glib_memory_barrier_needed=yes
2410     ;;
2411   *)
2412     glib_memory_barrier_needed=yes
2413     ;;
2414 esac
2415
2416 dnl ************************
2417 dnl ** Check for futex(2) **
2418 dnl ************************
2419 AC_CACHE_CHECK(for futex(2) system call,
2420     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2421 #include <linux/futex.h>
2422 #include <sys/syscall.h>
2423 #include <unistd.h>
2424 ],[
2425 int
2426 main (void)
2427 {
2428   /* it is not like this actually runs or anything... */
2429   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2430   return 0;
2431 }
2432 ])],glib_cv_futex=yes,glib_cv_futex=no))
2433 if test x"$glib_cv_futex" = xyes; then
2434   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2435 fi
2436
2437 AC_CACHE_CHECK(for eventfd(2) system call,
2438     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2439 #include <sys/eventfd.h>
2440 #include <unistd.h>
2441 ],[
2442 int
2443 main (void)
2444 {
2445   eventfd (0, EFD_CLOEXEC);
2446   return 0;
2447 }
2448 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2449 if test x"$glib_cv_eventfd" = x"yes"; then
2450   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2451 fi
2452 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2453
2454 dnl ****************************************
2455 dnl *** GLib POLL* compatibility defines ***
2456 dnl ****************************************
2457
2458 glib_poll_includes=["
2459 #include <sys/types.h>
2460 #include <sys/poll.h>
2461 "]
2462
2463 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2464    test $ac_cv_header_sys_poll_h = yes ], [
2465   glib_failed=false
2466   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2467   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2468   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2469   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2470   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2471   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2472   if $glib_failed ; then
2473     AC_MSG_ERROR([Could not determine values for POLL* constants])
2474   fi
2475 ], [
2476   glib_cv_value_POLLIN=1
2477   glib_cv_value_POLLOUT=4
2478   glib_cv_value_POLLPRI=2
2479   glib_cv_value_POLLERR=8
2480   glib_cv_value_POLLHUP=16
2481   glib_cv_value_POLLNVAL=32
2482 ])
2483
2484 AC_MSG_CHECKING([for broken poll])
2485 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2486         #include <stdlib.h>
2487         #include <fcntl.h>
2488         #include <poll.h>
2489         #ifdef HAVE_SYS_POLL_H
2490         #include <sys/poll.h>
2491         #endif
2492         int main(void) {
2493           struct pollfd fds[1];
2494           int fd;
2495           fd = open("/dev/null", 1);
2496           fds[0].fd = fd;
2497           fds[0].events = POLLIN;
2498           fds[0].revents = 0;
2499           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2500                 exit(1);  /* Does not work for devices -- fail */
2501           }
2502           exit(0);
2503         }]])],
2504   [broken_poll=no],
2505   [broken_poll=yes
2506    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2507   [broken_poll="no (cross compiling)"])
2508 AC_MSG_RESULT($broken_poll)
2509
2510 dnl *********************
2511 dnl *** GRegex checks ***
2512 dnl *********************
2513
2514 PCRE_REQUIRED_VERSION=8.13
2515
2516 # Check if we should use the internal or the system-supplied pcre
2517 AC_ARG_WITH(pcre,
2518             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2519                             [whether to use system PCRE [default=internal]])])
2520
2521 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2522
2523 AS_IF([ test "x$with_pcre" = xsystem], [
2524   PKG_CHECK_MODULES(PCRE,
2525                     libpcre >= $PCRE_REQUIRED_VERSION)
2526   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2527                   glib_save_CFLAGS="$CFLAGS"
2528                   glib_save_LIBS="$LIBS"
2529                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2530                   AC_TRY_RUN([#include <pcre.h>
2531                               int main () {
2532                                 int support;
2533                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2534                                 if (!support)
2535                                   return 1;
2536                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2537                                 if (!support)
2538                                   return 1;
2539                                 return 0;
2540                               }],
2541                   glib_cv_pcre_has_unicode=yes,
2542                   glib_cv_pcre_has_unicode=no,
2543                   glib_cv_pcre_has_unicode=yes)
2544                   CFLAGS="$glib_save_CFLAGS"
2545                   LIBS="$glib_save_LIBS"
2546       ])
2547   if test "$glib_cv_pcre_has_unicode" = "no"; then
2548     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2549   fi
2550   AC_SUBST(PCRE_CFLAGS)
2551   AC_SUBST(PCRE_LIBS)
2552   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2553   PCRE_REQUIRES=libpcre
2554   AC_SUBST(PCRE_REQUIRES)
2555 ], [
2556   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2557   AS_IF([ test x"$GCC" = xyes], [
2558     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2559     save_CFLAGS="$CFLAGS"
2560     CFLAGS="$CFLAGS -Wno-pointer-sign"
2561     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2562                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2563     CFLAGS="$save_CFLAGS"
2564   ])
2565 ])
2566 AC_SUBST(PCRE_WARN_CFLAGS)
2567
2568 dnl **********************
2569 dnl *** Win32 API libs ***
2570 dnl **********************
2571
2572 case $host in
2573   *-*-cygwin*)
2574         G_LIBS_EXTRA="-luser32 -lkernel32"
2575     ;;
2576   *-*-mingw*)
2577         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2578     ;;
2579   *)
2580         G_LIBS_EXTRA=""
2581     ;;
2582 esac
2583 AC_SUBST(G_LIBS_EXTRA)
2584
2585 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2586 dnl since we need it for g_iconv()
2587
2588 AC_MSG_CHECKING([for EILSEQ])
2589 AC_TRY_COMPILE([
2590 #include <errno.h>
2591 ],
2592 [
2593 int error = EILSEQ;
2594 ], have_eilseq=yes, have_eilseq=no);
2595 AC_MSG_RESULT($have_eilseq)
2596
2597 dnl ******************************************************************
2598 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2599 dnl *** glib-compile-schemas in PATH                               ***
2600 dnl ******************************************************************
2601
2602 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2603
2604 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2605   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2606   if test x$GLIB_GENMARSHAL = xno; then
2607     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2608   fi
2609
2610   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2611   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2612     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2613   fi
2614
2615   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2616   if test x$GLIB_COMPILE_RESOURCES = xno; then
2617     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2618   fi
2619 ])
2620
2621 dnl **************************
2622 dnl *** Checks for gtk-doc ***
2623 dnl **************************
2624 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2625 # it on it's own line.
2626 m4_ifdef([GTK_DOC_CHECK], [
2627 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2628 ],[
2629 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2630 ])
2631
2632 AC_ARG_ENABLE(man,
2633               [AS_HELP_STRING([--enable-man],
2634                               [generate man pages [default=auto]])],,
2635               enable_man=maybe)
2636
2637 AS_IF([test "$enable_man" != no], [
2638   AC_PATH_PROG([XSLTPROC], [xsltproc])
2639   AS_IF([test -z "$XSLTPROC"], [
2640     AS_IF([test "$enable_man" = yes], [
2641       AC_MSG_ERROR([xsltproc is required for --enable-man])
2642     ])
2643     enable_man=no
2644   ])
2645 ])
2646
2647 AS_IF([ test "$enable_man" != no ], [
2648   dnl check for DocBook DTD in the local catalog
2649   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2650      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2651   AS_IF([test "$have_docbook_dtd" != yes], [
2652     AS_IF([test "$enable_man" = yes ], [
2653       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2654     ])
2655     enable_man=no
2656   ])
2657 ])
2658
2659 AS_IF([test "$enable_man" != no], [
2660   dnl check for DocBook XSL stylesheets in the local catalog
2661   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2662      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2663   AS_IF([ test "$have_docbook_dtd" != yes ], [
2664     AS_IF([ test "$enable_man" = yes ], [
2665       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2666     ])
2667     enable_man=no
2668   ])
2669 ])
2670
2671 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2672
2673 AC_MSG_CHECKING([whether to generate man pages])
2674 AS_IF([ test "$enable_man" != no ], [
2675   AC_MSG_RESULT([yes])
2676 ], [
2677   AC_MSG_RESULT([no])
2678 ])
2679
2680 dnl
2681 dnl Tracing
2682 dnl
2683
2684 AC_ARG_ENABLE([dtrace],
2685              [AS_HELP_STRING([--enable-dtrace],
2686                               [include tracing support for dtrace])])
2687 have_dtrace=no
2688 AC_MSG_CHECKING([whether to include dtrace tracing support])
2689 AS_IF([ test "x$enable_dtrace" != xno], [
2690   if test x$glib_have_carbon = xyes; then
2691     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2692   else
2693     AC_MSG_RESULT([yes])
2694     AC_CHECK_PROGS(DTRACE, dtrace)
2695     if test -z "$DTRACE"; then
2696       if test "x$enable_dtrace" = xyes; then
2697         AC_MSG_ERROR([dtrace not found])
2698       fi
2699     else
2700       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2701                       [if test "x$enable_dtrace" = xyes; then
2702                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2703                        fi])
2704     fi
2705   fi
2706 ], [
2707   AC_MSG_RESULT([no])
2708 ])
2709 if test "x$have_dtrace" = xyes; then
2710   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2711 fi
2712 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2713
2714 AC_MSG_CHECKING([whether to include systemtap tracing support])
2715 AC_ARG_ENABLE([systemtap],
2716              [AS_HELP_STRING([--enable-systemtap],
2717                               [include tracing support for systemtap])])
2718 have_systemtap=no
2719 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2720   have_systemtap=yes
2721 fi
2722 AC_MSG_RESULT(${have_systemtap})
2723
2724 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2725
2726 AC_ARG_WITH([tapset-install-dir],
2727             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2728                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2729             [if test "x${withval}" = x; then
2730                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2731              else
2732                ABS_TAPSET_DIR="${withval}"
2733               fi],
2734             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2735 AC_SUBST(ABS_TAPSET_DIR)
2736
2737 dnl ************************************
2738 dnl *** Enable lcov coverage reports ***
2739 dnl ************************************
2740
2741 AC_ARG_ENABLE(gcov,
2742   AS_HELP_STRING([--enable-gcov],
2743                  [enable coverage testing with gcov]),
2744   [use_gcov=$enableval], [use_gcov=no])
2745
2746 AS_IF([ test "x$use_gcov" = "xyes"], [
2747   dnl we need gcc:
2748   if test "$GCC" != "yes"; then
2749     AC_MSG_ERROR([GCC is required for --enable-gcov])
2750   fi
2751
2752   dnl Check if ccache is being used
2753   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2754   case `$SHTOOL path $CC` in
2755     *ccache*[)] gcc_ccache=yes;;
2756     *[)] gcc_ccache=no;;
2757   esac
2758
2759   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2760     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2761   fi
2762
2763   ltp_version_list="1.6 1.7 1.8 1.9"
2764   AC_CHECK_PROG(LTP, lcov, lcov)
2765   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2766
2767   AS_IF([ test "$LTP" ], [
2768     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2769       glib_cv_ltp_version=invalid
2770       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2771       for ltp_check_version in $ltp_version_list; do
2772         if test "$ltp_version" = "$ltp_check_version"; then
2773           glib_cv_ltp_version="$ltp_check_version (ok)"
2774         fi
2775       done
2776     ])
2777   ], [
2778     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2779     AC_MSG_ERROR([$ltp_msg])
2780   ])
2781
2782   case $glib_cv_ltp_version in
2783     ""|invalid[)]
2784       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2785       AC_MSG_ERROR([$ltp_msg])
2786       LTP="exit 0;"
2787       ;;
2788   esac
2789
2790   if test -z "$LTP_GENHTML"; then
2791     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2792   fi
2793
2794   dnl Remove all optimization flags from CFLAGS
2795   changequote({,})
2796   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2797   changequote([,])
2798
2799   dnl Add the special gcc flags
2800   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2801   LDFLAGS="$LDFLAGS -lgcov"
2802 ])
2803
2804 dnl ******************************
2805 dnl *** output the whole stuff ***
2806 dnl ******************************
2807
2808 dnl this section will only be run if config.status is invoked with no
2809 dnl arguments, or with "glib/glibconfig.h" as an argument.
2810 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2811 [
2812         outfile=glib/glibconfig.h-tmp
2813         cat > $outfile <<\_______EOF
2814 /* glibconfig.h
2815  *
2816  * This is a generated file.  Please modify 'configure.ac'
2817  */
2818
2819 #ifndef __GLIBCONFIG_H__
2820 #define __GLIBCONFIG_H__
2821
2822 #include <glib/gmacros.h>
2823
2824 _______EOF
2825
2826         if test x$glib_limits_h = xyes; then
2827           echo '#include <limits.h>' >> $outfile
2828         fi
2829         if test x$glib_float_h = xyes; then
2830           echo '#include <float.h>' >> $outfile
2831         fi
2832         if test x$glib_values_h = xyes; then
2833           echo '#include <values.h>' >> $outfile
2834         fi
2835         if test "$glib_header_alloca_h" = "yes"; then
2836           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2837         fi
2838         if test x$glib_sys_poll_h = xyes; then
2839           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2840         fi
2841         if test x$glib_included_printf != xyes; then
2842           echo "
2843 /* Specifies that GLib's g_print*() functions wrap the
2844  * system printf functions.  This is useful to know, for example,
2845  * when using glibc's register_printf_function().
2846  */" >> $outfile
2847           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2848         fi
2849
2850         cat >> $outfile <<_______EOF
2851
2852 G_BEGIN_DECLS
2853
2854 #define G_MINFLOAT      $glib_mf
2855 #define G_MAXFLOAT      $glib_Mf
2856 #define G_MINDOUBLE     $glib_md
2857 #define G_MAXDOUBLE     $glib_Md
2858 #define G_MINSHORT      $glib_ms
2859 #define G_MAXSHORT      $glib_Ms
2860 #define G_MAXUSHORT     $glib_Mus
2861 #define G_MININT        $glib_mi
2862 #define G_MAXINT        $glib_Mi
2863 #define G_MAXUINT       $glib_Mui
2864 #define G_MINLONG       $glib_ml
2865 #define G_MAXLONG       $glib_Ml
2866 #define G_MAXULONG      $glib_Mul
2867
2868 _______EOF
2869
2870
2871         ### this should always be true in a modern C/C++ compiler
2872         cat >>$outfile <<_______EOF
2873 typedef signed char gint8;
2874 typedef unsigned char guint8;
2875 _______EOF
2876
2877
2878         if test -n "$gint16"; then
2879           cat >>$outfile <<_______EOF
2880 typedef signed $gint16 gint16;
2881 typedef unsigned $gint16 guint16;
2882 #define G_GINT16_MODIFIER $gint16_modifier
2883 #define G_GINT16_FORMAT $gint16_format
2884 #define G_GUINT16_FORMAT $guint16_format
2885 _______EOF
2886         fi
2887
2888
2889         if test -n "$gint32"; then
2890           cat >>$outfile <<_______EOF
2891 typedef signed $gint32 gint32;
2892 typedef unsigned $gint32 guint32;
2893 #define G_GINT32_MODIFIER $gint32_modifier
2894 #define G_GINT32_FORMAT $gint32_format
2895 #define G_GUINT32_FORMAT $guint32_format
2896 _______EOF
2897         fi
2898
2899         cat >>$outfile <<_______EOF
2900 #define G_HAVE_GINT64 1          /* deprecated, always true */
2901
2902 ${glib_extension}typedef signed $gint64 gint64;
2903 ${glib_extension}typedef unsigned $gint64 guint64;
2904
2905 #define G_GINT64_CONSTANT(val)  $gint64_constant
2906 #define G_GUINT64_CONSTANT(val) $guint64_constant
2907 _______EOF
2908
2909         if test x$gint64_format != x ; then
2910           cat >>$outfile <<_______EOF
2911 #define G_GINT64_MODIFIER $gint64_modifier
2912 #define G_GINT64_FORMAT $gint64_format
2913 #define G_GUINT64_FORMAT $guint64_format
2914 _______EOF
2915         else
2916           cat >>$outfile <<_______EOF
2917 #undef G_GINT64_MODIFIER
2918 #undef G_GINT64_FORMAT
2919 #undef G_GUINT64_FORMAT
2920 _______EOF
2921         fi
2922
2923         cat >>$outfile <<_______EOF
2924
2925 #define GLIB_SIZEOF_VOID_P $glib_void_p
2926 #define GLIB_SIZEOF_LONG   $glib_long
2927 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2928
2929 _______EOF
2930
2931         cat >>$outfile <<_______EOF
2932 typedef signed $glib_size_type_define gssize;
2933 typedef unsigned $glib_size_type_define gsize;
2934 #define G_GSIZE_MODIFIER $gsize_modifier
2935 #define G_GSSIZE_FORMAT $gssize_format
2936 #define G_GSIZE_FORMAT $gsize_format
2937
2938 #define G_MAXSIZE       G_MAXU$glib_msize_type
2939 #define G_MINSSIZE      G_MIN$glib_msize_type
2940 #define G_MAXSSIZE      G_MAX$glib_msize_type
2941
2942 typedef gint64 goffset;
2943 #define G_MINOFFSET     G_MININT64
2944 #define G_MAXOFFSET     G_MAXINT64
2945
2946 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2947 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2948 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2949
2950 _______EOF
2951
2952         if test -z "$glib_unknown_void_p"; then
2953           cat >>$outfile <<_______EOF
2954
2955 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2956 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2957
2958 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2959 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2960
2961 typedef signed $glib_intptr_type_define gintptr;
2962 typedef unsigned $glib_intptr_type_define guintptr;
2963
2964 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2965 #define G_GINTPTR_FORMAT        $gintptr_format
2966 #define G_GUINTPTR_FORMAT       $guintptr_format
2967 _______EOF
2968         else
2969           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2970         fi
2971
2972
2973
2974         cat >>$outfile <<_______EOF
2975 $glib_atexit
2976 $glib_memmove
2977 $glib_defines
2978 $glib_os
2979 $glib_static_compilation
2980
2981 $glib_vacopy
2982
2983 #ifdef  __cplusplus
2984 #define G_HAVE_INLINE   1
2985 #else   /* !__cplusplus */
2986 $glib_inline
2987 #endif  /* !__cplusplus */
2988
2989 #ifdef  __cplusplus
2990 #define G_CAN_INLINE    1
2991 _______EOF
2992
2993         if test x$g_can_inline = xyes ; then
2994                 cat >>$outfile <<_______EOF
2995 #else   /* !__cplusplus */
2996 #define G_CAN_INLINE    1
2997 _______EOF
2998         fi
2999
3000         cat >>$outfile <<_______EOF
3001 #endif
3002
3003 _______EOF
3004
3005         if test x$g_have_iso_c_varargs = xyes ; then
3006                 cat >>$outfile <<_______EOF
3007 #ifndef __cplusplus
3008 # define G_HAVE_ISO_VARARGS 1
3009 #endif
3010 _______EOF
3011         fi
3012         if test x$g_have_iso_cxx_varargs = xyes ; then
3013                 cat >>$outfile <<_______EOF
3014 #ifdef __cplusplus
3015 # define G_HAVE_ISO_VARARGS 1
3016 #endif
3017 _______EOF
3018         fi
3019         if test x$g_have_gnuc_varargs = xyes ; then
3020                 cat >>$outfile <<_______EOF
3021
3022 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3023  * is passed ISO vararg support is turned off, and there is no work
3024  * around to turn it on, so we unconditionally turn it off.
3025  */
3026 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3027 #  undef G_HAVE_ISO_VARARGS
3028 #endif
3029
3030 #define G_HAVE_GNUC_VARARGS 1
3031 _______EOF
3032         fi
3033
3034         case x$g_stack_grows in
3035         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3036         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3037         esac
3038
3039
3040         echo >>$outfile
3041         if test x$g_have_eilseq = xno; then
3042                 cat >>$outfile <<_______EOF
3043 #ifndef EILSEQ
3044 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3045  * The correspondence between this and the corresponding definition
3046  * in libiconv is essential.
3047  */
3048 #  define EILSEQ ENOENT
3049 #endif
3050 _______EOF
3051
3052         fi
3053
3054         if test x$g_have_gnuc_visibility = xyes; then
3055                 cat >>$outfile <<_______EOF
3056 #define G_HAVE_GNUC_VISIBILITY 1
3057 _______EOF
3058         fi
3059                 cat >>$outfile <<_______EOF
3060 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3061 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3062 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3063 #define G_GNUC_INTERNAL __hidden
3064 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3065 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3066 #else
3067 #define G_GNUC_INTERNAL
3068 #endif
3069 _______EOF
3070
3071         echo >>$outfile
3072         cat >>$outfile <<_______EOF
3073 #define G_THREADS_ENABLED
3074 #define G_THREADS_IMPL_$g_threads_impl_def
3075 _______EOF
3076
3077         if test x"$g_memory_barrier_needed" != xno; then
3078           echo >>$outfile
3079           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3080         fi
3081         if test x"$g_atomic_lock_free" = xyes; then
3082           echo >>$outfile
3083           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3084         fi
3085         echo >>$outfile
3086         g_bit_sizes="16 32 64"
3087         for bits in $g_bit_sizes; do
3088           cat >>$outfile <<_______EOF
3089 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3090 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3091 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3092 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3093 _______EOF
3094         done
3095
3096         cat >>$outfile <<_______EOF
3097 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3098 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3099 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3100 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3101 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3102 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3103 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3104 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3105 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3106 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3107 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3108 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3109 #define G_BYTE_ORDER $g_byte_order
3110
3111 #define GLIB_SYSDEF_POLLIN =$g_pollin
3112 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3113 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3114 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3115 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3116 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3117
3118 #define G_MODULE_SUFFIX "$g_module_suffix"
3119
3120 typedef $g_pid_type GPid;
3121
3122 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3123 #define GLIB_SYSDEF_AF_INET $g_af_inet
3124 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3125
3126 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3127 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3128 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3129
3130 G_END_DECLS
3131
3132 #endif /* __GLIBCONFIG_H__ */
3133 _______EOF
3134
3135
3136         if cmp -s $outfile glib/glibconfig.h; then
3137           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3138           rm -f $outfile
3139         else
3140           mv $outfile glib/glibconfig.h
3141         fi
3142 ],[
3143
3144 # Note that if two cases are the same, case goes with the first one.
3145 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3146 # on variable expansion in case labels.  Look at the generated config.status
3147 # for a hint.
3148
3149 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3150   glib_header_alloca_h="$ac_cv_working_alloca_h"
3151 else
3152   glib_header_alloca_h="$ac_cv_header_alloca_h"
3153 fi
3154
3155 case xyes in
3156 x$ac_cv_header_float_h)
3157   glib_float_h=yes
3158   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3159   glib_md=DBL_MIN glib_Md=DBL_MAX
3160   ;;
3161 x$ac_cv_header_values_h)
3162   glib_values_h=yes
3163   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3164   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3165   ;;
3166 esac
3167
3168 case xyes in
3169 x$ac_cv_header_limits_h)
3170   glib_limits_h=yes
3171   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3172   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3173   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3174   ;;
3175 x$ac_cv_header_values_h)
3176   glib_values_h=yes
3177   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3178   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3179   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3180   ;;
3181 esac
3182
3183 if test x$ac_cv_header_sys_poll_h = xyes ; then
3184   glib_sys_poll_h=yes
3185 fi
3186
3187 if test x$enable_included_printf = xyes ; then
3188   glib_included_printf=yes
3189 fi
3190
3191 case 2 in
3192 $ac_cv_sizeof_short)
3193   gint16=short
3194   gint16_modifier='"h"'
3195   gint16_format='"hi"'
3196   guint16_format='"hu"'
3197   ;;
3198 $ac_cv_sizeof_int)
3199   gint16=int
3200   gint16_modifier='""'
3201   gint16_format='"i"'
3202   guint16_format='"u"'
3203   ;;
3204 esac
3205 case 4 in
3206 $ac_cv_sizeof_short)
3207   gint32=short
3208   gint32_modifier='"h"'
3209   gint32_format='"hi"'
3210   guint32_format='"hu"'
3211   ;;
3212 $ac_cv_sizeof_int)
3213   gint32=int
3214   gint32_modifier='""'
3215   gint32_format='"i"'
3216   guint32_format='"u"'
3217   ;;
3218 $ac_cv_sizeof_long)
3219   gint32=long
3220   gint32_modifier='"l"'
3221   gint32_format='"li"'
3222   guint32_format='"lu"'
3223   ;;
3224 esac
3225 case 8 in
3226 $ac_cv_sizeof_int)
3227   gint64=int
3228   gint64_modifier='""'
3229   gint64_format='"i"'
3230   guint64_format='"u"'
3231   glib_extension=
3232   gint64_constant='(val)'
3233   guint64_constant='(val)'
3234   ;;
3235 $ac_cv_sizeof_long)
3236   gint64=long
3237   gint64_modifier='"l"'
3238   gint64_format='"li"'
3239   guint64_format='"lu"'
3240   glib_extension=
3241   gint64_constant='(val##L)'
3242   guint64_constant='(val##UL)'
3243   ;;
3244 $ac_cv_sizeof_long_long)
3245   gint64='long long'
3246   if test -n "$glib_cv_long_long_format"; then
3247     gint64_modifier='"'$glib_cv_long_long_format'"'
3248     gint64_format='"'$glib_cv_long_long_format'i"'
3249     guint64_format='"'$glib_cv_long_long_format'u"'
3250   fi
3251   glib_extension='G_GNUC_EXTENSION '
3252   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3253   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3254   ;;
3255 $ac_cv_sizeof___int64)
3256   gint64='__int64'
3257   if test -n "$glib_cv_long_long_format"; then
3258     gint64_modifier='"'$glib_cv_long_long_format'"'
3259     gint64_format='"'$glib_cv_long_long_format'i"'
3260     guint64_format='"'$glib_cv_long_long_format'u"'
3261   fi
3262   glib_extension=
3263   gint64_constant='(val##i64)'
3264   guint64_constant='(val##ui64)'
3265   ;;
3266 esac
3267 glib_size_t=$ac_cv_sizeof_size_t
3268 glib_size_type_define="$glib_size_type"
3269 glib_void_p=$ac_cv_sizeof_void_p
3270 glib_long=$ac_cv_sizeof_long
3271
3272 case "$glib_size_type" in
3273 short)
3274   gsize_modifier='"h"'
3275   gsize_format='"hu"'
3276   gssize_format='"hi"'
3277   glib_msize_type='SHRT'
3278   ;;
3279 int)
3280   gsize_modifier='""'
3281   gsize_format='"u"'
3282   gssize_format='"i"'
3283   glib_msize_type='INT'
3284   ;;
3285 long)
3286   gsize_modifier='"l"'
3287   gsize_format='"lu"'
3288   gssize_format='"li"'
3289   glib_msize_type='LONG'
3290   ;;
3291 "long long"|__int64)
3292   gsize_modifier='"I64"'
3293   gsize_format='"I64u"'
3294   gssize_format='"I64i"'
3295   glib_msize_type='INT64'
3296   ;;
3297 esac
3298
3299 gintbits=`expr $ac_cv_sizeof_int \* 8`
3300 glongbits=`expr $ac_cv_sizeof_long \* 8`
3301 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3302
3303 case $ac_cv_sizeof_void_p in
3304 $ac_cv_sizeof_int)
3305   glib_intptr_type_define=int
3306   gintptr_modifier='""'
3307   gintptr_format='"i"'
3308   guintptr_format='"u"'
3309   glib_gpi_cast='(gint)'
3310   glib_gpui_cast='(guint)'
3311   ;;
3312 $ac_cv_sizeof_long)
3313   glib_intptr_type_define=long
3314   gintptr_modifier='"l"'
3315   gintptr_format='"li"'
3316   guintptr_format='"lu"'
3317   glib_gpi_cast='(glong)'
3318   glib_gpui_cast='(gulong)'
3319   ;;
3320 $ac_cv_sizeof_long_long)
3321   glib_intptr_type_define='long long'
3322   gintptr_modifier='"I64"'
3323   gintptr_format='"I64i"'
3324   guintptr_format='"I64u"'
3325   glib_gpi_cast='(gint64)'
3326   glib_gpui_cast='(guint64)'
3327   ;;
3328 $ac_cv_sizeof___int64)
3329   glib_intptr_type_define=__int64
3330   gintptr_modifier='"I64"'
3331   gintptr_format='"I64i"'
3332   guintptr_format='"I64u"'
3333   glib_gpi_cast='(gint64)'
3334   glib_gpui_cast='(guint64)'
3335   ;;
3336 *)
3337   glib_unknown_void_p=yes
3338   ;;
3339 esac
3340
3341
3342 case xyes in
3343 x$ac_cv_func_atexit)
3344   glib_atexit="
3345 #ifdef NeXT /* @#%@! NeXTStep */
3346 # define g_ATEXIT(proc) (!atexit (proc))
3347 #else
3348 # define g_ATEXIT(proc) (atexit (proc))
3349 #endif"
3350   ;;
3351 x$ac_cv_func_on_exit)
3352   glib_atexit="
3353 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3354   ;;
3355 esac
3356
3357 case xyes in
3358 x$ac_cv_func_memmove)
3359   glib_memmove='
3360 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3361   ;;
3362 x$glib_cv_working_bcopy)
3363   glib_memmove="
3364 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3365 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3366   ;;
3367 *)
3368   glib_memmove="
3369 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3370  * so we have to roll our own copy routine. */
3371 void g_memmove (void* dest, const void * src, unsigned long len);"
3372   ;;
3373 esac
3374
3375 glib_defines="
3376 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3377 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3378 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3379 "
3380
3381 case xyes in
3382 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3383 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3384 *)                      glib_vacopy=''
3385 esac
3386
3387 if test x$glib_cv_va_val_copy = xno; then
3388   glib_vacopy="\$glib_vacopy
3389 #define G_VA_COPY_AS_ARRAY 1"
3390 fi
3391
3392 if test x$glib_cv_hasinline = xyes; then
3393     glib_inline='#define G_HAVE_INLINE 1'
3394 fi
3395 if test x$glib_cv_has__inline = xyes; then
3396     glib_inline="\$glib_inline
3397 #define G_HAVE___INLINE 1"
3398 fi
3399 if test x$glib_cv_has__inline__ = xyes; then
3400     glib_inline="\$glib_inline
3401 #define G_HAVE___INLINE__ 1"
3402 fi
3403
3404 g_have_gnuc_varargs=$g_have_gnuc_varargs
3405 g_have_iso_c_varargs=$g_have_iso_c_varargs
3406 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3407
3408 g_can_inline=$g_can_inline
3409 g_have_gnuc_visibility=$g_have_gnuc_visibility
3410 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3411
3412 if test x$ac_cv_c_bigendian = xyes; then
3413   g_byte_order=G_BIG_ENDIAN
3414   g_bs_native=BE
3415   g_bs_alien=LE
3416 else
3417   g_byte_order=G_LITTLE_ENDIAN
3418   g_bs_native=LE
3419   g_bs_alien=BE
3420 fi
3421
3422 g_pollin=$glib_cv_value_POLLIN
3423 g_pollout=$glib_cv_value_POLLOUT
3424 g_pollpri=$glib_cv_value_POLLPRI
3425 g_pollhup=$glib_cv_value_POLLHUP
3426 g_pollerr=$glib_cv_value_POLLERR
3427 g_pollnval=$glib_cv_value_POLLNVAL
3428
3429 # If a family is not found on the system, define that family to
3430 # a negative value, picking a different one for each undefined
3431 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3432 # This is needed because glib-mkenums doesn't handle optional
3433 # values in enums, and thus we have to have all existing values
3434 # defined in the enum.
3435 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3436   g_af_unix=$glib_cv_value_AF_UNIX
3437 else
3438   g_af_unix=-1
3439 fi
3440 g_af_inet=$glib_cv_value_AF_INET
3441 g_af_inet6=$glib_cv_value_AF_INET6
3442
3443 g_msg_peek=$glib_cv_value_MSG_PEEK
3444 g_msg_oob=$glib_cv_value_MSG_OOB
3445 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3446
3447 g_stack_grows=$glib_cv_stack_grows
3448
3449 g_have_eilseq=$have_eilseq
3450
3451 g_threads_impl_def=$g_threads_impl
3452
3453 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3454 g_memory_barrier_needed="$glib_memory_barrier_needed"
3455 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3456
3457 g_module_suffix="$glib_gmodule_suffix"
3458
3459 g_pid_type="$glib_pid_type"
3460 case $host in
3461   *-*-beos*)
3462     glib_os="#define G_OS_BEOS"
3463     ;;
3464   *-*-cygwin*)
3465     glib_os="#define G_OS_UNIX
3466 #define G_PLATFORM_WIN32
3467 #define G_WITH_CYGWIN"
3468     ;;
3469   *-*-mingw*)
3470     glib_os="#define G_OS_WIN32
3471 #define G_PLATFORM_WIN32"
3472     ;;
3473   *)
3474     glib_os="#define G_OS_UNIX"
3475     ;;
3476 esac
3477 glib_static_compilation=""
3478 if test x$glib_win32_static_compilation = xyes; then
3479   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3480 #define GOBJECT_STATIC_COMPILATION 1"
3481 fi
3482 ])
3483
3484 # Redo enough to get guint32 and guint64 for the alignment checks below
3485 case 4 in
3486 $ac_cv_sizeof_short)
3487   gint32=short
3488   ;;
3489 $ac_cv_sizeof_int)
3490   gint32=int
3491   ;;
3492 $ac_cv_sizeof_long)
3493   gint32=long
3494   ;;
3495 esac
3496 case 8 in
3497 $ac_cv_sizeof_int)
3498   gint64=int
3499   ;;
3500 $ac_cv_sizeof_long)
3501   gint64=long
3502   ;;
3503 $ac_cv_sizeof_long_long)
3504   gint64='long long'
3505   ;;
3506 $ac_cv_sizeof___int64)
3507   gint64='__int64'
3508   ;;
3509 esac
3510
3511 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3512 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3513 typedef unsigned $gint32 guint32;])
3514 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3515 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3516 typedef unsigned $gint64 guint64;])
3517 AC_CHECK_TYPE([unsigned long])
3518 AC_CHECK_ALIGNOF([unsigned long])
3519
3520 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3521 #
3522 # 1.2.14 required for dbus_message_set_serial
3523 AS_IF([ test x$enable_modular_tests = xyes], [
3524    PKG_CHECK_MODULES(DBUS1,
3525                      dbus-1 >= 1.2.14,
3526                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3527                      have_dbus1=no)
3528    AC_SUBST(DBUS1_CFLAGS)
3529    AC_SUBST(DBUS1_LIBS)
3530 ])
3531 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3532
3533 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3534 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3535
3536 dnl
3537 dnl Check for -Bsymbolic-functions linker flag used to avoid
3538 dnl intra-library PLT jumps, if available.
3539 dnl
3540
3541 AC_ARG_ENABLE(Bsymbolic,
3542               [AS_HELP_STRING([--disable-Bsymbolic],
3543                               [avoid linking with -Bsymbolic])],,
3544               [SAVED_LDFLAGS="${LDFLAGS}"
3545                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3546                LDFLAGS=-Wl,-Bsymbolic-functions
3547                AC_TRY_LINK([], [int main (void) { return 0; }],
3548                            AC_MSG_RESULT(yes)
3549                            enable_Bsymbolic=yes,
3550                            AC_MSG_RESULT(no)
3551                            enable_Bsymbolic=no)
3552                LDFLAGS="${SAVED_LDFLAGS}"])
3553
3554 if test "x${enable_Bsymbolic}" = "xyes"; then
3555   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3556 fi
3557
3558 AC_SUBST(GLIB_LINK_FLAGS)
3559
3560 dnl Compiler flags; macro originates from systemd
3561 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3562 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3563    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3564    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3565    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3566    -Werror=format=2 -Werror=missing-include-dirs])
3567 CFLAGS="$CFLAGS $with_cflags"
3568
3569 #
3570 # Define variables corresponding to the correct include paths to use for
3571 # in-tree building.
3572 #
3573
3574 # for config.h:
3575 config_h_INCLUDES='-I$(top_builddir)'
3576 AC_SUBST(config_h_INCLUDES)
3577
3578 # glib:
3579 #   config.h
3580 #   $(top_builddir)/glib: for glibconfig.h
3581 #   $(top_srcdir)/glib:   for glib.h
3582 #   $(top_srcdir):        for everything
3583 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3584 AC_SUBST(glib_INCLUDES)
3585
3586 # gobject:
3587 #   same as glib
3588 gobject_INCLUDES='$(glib_INCLUDES)'
3589 AC_SUBST(gobject_INCLUDES)
3590
3591 # gmodule:
3592 #   glib includes
3593 #   $(top_srcdir)/gmodule: for gmodule.h
3594 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3595 AC_SUBST(gmodule_INCLUDES)
3596
3597 # gio:
3598 #   same as gmodule
3599 gio_INCLUDES='$(gmodule_INCLUDES)'
3600 AC_SUBST(gio_INCLUDES)
3601
3602
3603 AC_CONFIG_FILES([
3604 glib-2.0.pc
3605 gmodule-2.0.pc
3606 gmodule-export-2.0.pc
3607 gmodule-no-export-2.0.pc
3608 gthread-2.0.pc
3609 gobject-2.0.pc
3610 gio-2.0.pc
3611 gio-unix-2.0.pc
3612 gio-windows-2.0.pc
3613 glib-zip
3614 glib-gettextize
3615 Makefile
3616 build/Makefile
3617 build/win32/Makefile
3618 build/win32/dirent/Makefile
3619 build/win32/vs9/Makefile
3620 build/win32/vs10/Makefile
3621 build/win32/vs11/Makefile
3622 glib/Makefile
3623 glib/glib.stp
3624 glib/libcharset/Makefile
3625 glib/gnulib/Makefile
3626 glib/pcre/Makefile
3627 glib/update-pcre/Makefile
3628 glib/tests/Makefile
3629 gmodule/Makefile
3630 gmodule/gmoduleconf.h
3631 gobject/Makefile
3632 gobject/gobject.stp
3633 gobject/glib-mkenums
3634 gobject/tests/Makefile
3635 gthread/Makefile
3636 gio/Makefile
3637 gio/gdbus-2.0/codegen/Makefile
3638 gio/gdbus-2.0/codegen/config.py
3639 gio/gnetworking.h
3640 gio/xdgmime/Makefile
3641 gio/inotify/Makefile
3642 gio/kqueue/Makefile
3643 gio/fen/Makefile
3644 gio/fam/Makefile
3645 gio/win32/Makefile
3646 gio/tests/Makefile
3647 gio/tests/gdbus-object-manager-example/Makefile
3648 po/Makefile.in
3649 docs/Makefile
3650 docs/reference/Makefile
3651 docs/reference/glib/Makefile
3652 docs/reference/glib/version.xml
3653 docs/reference/gobject/Makefile
3654 docs/reference/gobject/version.xml
3655 docs/reference/gio/Makefile
3656 docs/reference/gio/gdbus-object-manager-example/Makefile
3657 docs/reference/gio/version.xml
3658 tests/Makefile
3659 tests/gobject/Makefile
3660 tests/refcount/Makefile
3661 m4macros/Makefile
3662 ])
3663
3664 AC_CONFIG_COMMANDS([chmod-scripts],
3665 [chmod 0755 glib-zip
3666 chmod 0755 glib-gettextize
3667 chmod 0755 gobject/glib-mkenums])
3668
3669 # we want to invoke this macro solely so that the config.status script
3670 # and automake generated makefiles know about these generated files.
3671 # They are only needed to distcheck the package
3672 if false; then
3673   AC_CONFIG_FILES([
3674     INSTALL
3675     README
3676     config.h.win32
3677     glib/glibconfig.h.win32
3678     glib/makefile.msc
3679     glib/glib.rc
3680     gmodule/makefile.msc
3681     gmodule/gmodule.rc
3682     gobject/makefile.msc
3683     gobject/gobject.rc
3684     gthread/makefile.msc
3685     gthread/gthread.rc
3686     gio/gio.rc
3687     tests/makefile.msc
3688   ])
3689 fi
3690
3691 AC_OUTPUT