configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2013 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.13.1a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([-Wall -Werror dist-xz filename-length-max=99
  43                   no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2013
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # Our build system is bootstrapped with the bleeding-edge versions of
  67 # aclocal and automake, hence the remake rules must use those versions
  68 # as well.  The extra quoting is to cater to cases when the build
  69 # directory contains whitespace or shell metacharacters.
  70 ACLOCAL="\"`pwd`/t/wrap/aclocal-$APIVERSION\""
  71 AUTOMAKE="\"`pwd`/t/wrap/automake-$APIVERSION\""
  72
  73 AC_PROG_LN_S
  74
  75 AC_PATH_PROG([PERL], [perl])
  76 if test -z "$PERL"; then
  77    AC_MSG_ERROR([perl not found])
  78 fi
  79 # Save details about the selected perl interpreter in config.log.
  80 AM_RUN_LOG([$PERL --version])
  81 $PERL -e 'require 5.006;' || {
  82    AC_MSG_ERROR(
  83 [perl 5.6 or better is required; perl 5.8.2 or better
  84 is recommended.  If you have several perl versions
  85 installed, select the one Automake should use using
  86   ./configure PERL=/path/to/perl])
  87 }
  88
  89 # The test suite will skip some tests if tex is absent.
  90 AC_CHECK_PROG([TEX], [tex], [tex])
  91 # Save details about the selected TeX program in config.log.
  92 # Redirect input from /dev/null, as TeX might otherwise hang waiting
  93 # for input from the terminal.
  94 AM_RUN_LOG([$TEX --version </dev/null])
  95
  96 # The test suite will skip some tests if no lex or yacc program is
  97 # available.
  98 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
  99 #  1. we don't want flex (resp. bison) to be preferred to system lex
 100 #     (resp. system yacc);
 101 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 102 #     by default;
 103 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 104 #     LEXLIB to be calculated and/or AC_SUBST'd;
 105 #  4. we prefer that the YACC and LEX variables are not reported in the
 106 #     configure help screen.
 107 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 108 AC_CHECK_PROGS([LEX], [lex flex], [false])
 109
 110 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 111 # deletion of any files created (such as those added to
 112 # autom4te.cache).  We used to perform only the last of the three
 113 # following tests, but some users were unable to figure out that their
 114 # installation was broken since --version appeared to work.
 115
 116 required_autoconf_version=2.65
 117 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 118 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 119 then
 120   am_cv_autoconf_installed=yes
 121 else
 122   am_cv_autoconf_installed=no
 123 fi])
 124 if test "$am_cv_autoconf_installed" = no; then
 125   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 126     Please make sure it is installed and in your PATH.])
 127 fi
 128
 129 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 130 [mkdir conftest
 131 echo 'AC''_INIT' > conftest/conftest.ac
 132 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 133 then
 134   am_cv_autoconf_works=yes
 135 else
 136   am_cv_autoconf_works=no
 137 fi
 138 rm -rf conftest])
 139 if test "$am_cv_autoconf_works" = no; then
 140   AC_MSG_ERROR([The installed version of autoconf does not work.
 141     Please check config.log for error messages before this one.])
 142 fi
 143
 144 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 145 [mkdir conftest
 146 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 147 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 148 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 149 then
 150   am_cv_autoconf_version=yes
 151 else
 152   am_cv_autoconf_version=no
 153 fi
 154 rm -rf conftest])
 155 if test "$am_cv_autoconf_version" = no; then
 156   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 157 fi
 158
 159 # Test for ln.  We need use it to install the versioned binaries.
 160 AC_MSG_CHECKING([whether ln works])
 161 AC_CACHE_VAL([am_cv_prog_ln], [
 162 rm -f conftest conftest.file
 163 : >conftest.file
 164 if ln conftest.file conftest 2>/dev/null; then
 165   am_cv_prog_ln=ln
 166 else
 167   am_cv_prog_ln='cp -p'
 168 fi
 169 rm -f conftest conftest.file])
 170 AC_SUBST([LN], [$am_cv_prog_ln])
 171 result=no
 172 test "x$am_cv_prog_ln" = xln && result=yes
 173 AC_MSG_RESULT([$result])
 174
 175 # The amount we should wait after modifying files depends on the platform.
 176 # On Windows '95, '98 and ME, files modifications have 2-seconds
 177 # granularity and can be up to 3 seconds in the future w.r.t. the
 178 # system clock.  When it is important to ensure one file is older
 179 # than another we wait at least 5 seconds between creations.
 180 case $build in
 181   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 182   *)               MODIFICATION_DELAY=2;;
 183 esac
 184 AC_SUBST([MODIFICATION_DELAY])
 185
 186 ## ------------------------------------------- ##
 187 ##  Test for things needed by the test suite.  ##
 188 ## ------------------------------------------- ##
 189
 190 AC_PROG_EGREP
 191 AC_PROG_FGREP
 192
 193 dnl FIXME: could we extract this in a simpler way through autoconf
 194 dnl FIXME: idioms or internals?
 195 AC_DEFUN(
 196   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 197   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 198
 199 dnl
 200 dnl Arguments to this macro:
 201 dnl
 202 dnl   $1 - shell to test
 203 dnl   $2 - description of the tested feature
 204 dnl   $3 - shell code used to check the feature; to indicate success,
 205 dnl        it can either exit with status 77, or have the last command
 206 dnl        returning with exit status of zero
 207 dnl   $4 - shell code to execute if the check on the shell is successful
 208 dnl        (defaults to nothing)
 209 dnl   $5 - shell code to execute if the check on the shell is not
 210 dnl        successful (defaults to nothing)
 211 dnl
 212 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 213   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 214   AC_MSG_CHECKING([whether $1 $2])
 215   if { $1 -c "$am_bourne_compatible
 216 AS_ESCAPE([$3])
 217 test \$? -eq 0 || exit 1
 218 # Use 77 to indicate success (rather than 0), in case some shell
 219 # acts like Solaris 10's /bin/sh, exiting successfully on some
 220 # syntax errors.
 221 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 222   then
 223     AC_MSG_RESULT([yes])
 224     $4
 225   else
 226     AC_MSG_RESULT([no])
 227     $5
 228   fi])
 229
 230 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 231 # -----------------------------------------
 232 #
 233 # Check if the given shell is good enough to run our test scripts.
 234 # Inspired to gnulib's 'tests/init.sh'.
 235 #
 236 # We require POSIX and XSI features (e.g., '$(...)' for command
 237 # substitutions, '$((...))' for shell arithmetic, and support for
 238 # '${var#...}' and '${var%...}' parameter expansions).
 239 #
 240 # We require that the shell can correctly trap EXIT when 'set -e' is in
 241 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 242 #
 243 # We want to able to define shell aliases with the same name of shell
 244 # builtins.
 245 #
 246 # We also prefer shells that, when 'set -x' is in effect, do not also
 247 # redirect traces upon stderr redirections.  For example,
 248 #  $ set -x; echo x 2>file
 249 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 250 #   $ set -x; P=1 true 2>file
 251 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 252 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 253 #
 254 # Finally, we look for weird bugs and portability problems mentioned in
 255 # the Autoconf manual, and reject shells that suffers from them. (TODO)
 256 #
 257 # Use '$am_score' to indicate the degree of acceptability of the shell.
 258 # A score of "10" means that the shell is good enough for our needs;
 259 # a score of "9" means that the shell has some minor bugs or limitation,
 260 # but is still (barely) acceptable for our uses.  Any other score means
 261 # that the shell is broken or unfit.
 262 #
 263 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 264   [am_score=10
 265   while :; do
 266
 267     _AM_CHECK_SHELL_FEATURE([$1],
 268       [supports \$(cmd)],
 269       [test "$(echo x)" = x],
 270       [], [am_score=1; break])
 271
 272     _AM_CHECK_SHELL_FEATURE([$1],
 273       [supports \$((expr))],
 274       [test $((1 + 2 * 3)) = 7],
 275       [], [am_score=1; break])
 276
 277     _AM_CHECK_SHELL_FEATURE([$1],
 278       [supports \${@%:@var}],
 279       [zero='' one='x' twelve=' foobar baz!' \
 280         && test ${@%:@zero} -eq 0 \
 281         && test ${@%:@one} -eq 1 \
 282         && test ${@%:@twelve} -eq 12],
 283       [], [am_score=1; break])
 284
 285     _AM_CHECK_SHELL_FEATURE([$1],
 286       [supports \${var@%:@glob} and \${var%glob}],
 287       [v=a/b/c \
 288         && test ${v@%:@*/} = b/c \
 289         && test ${v@%:@@%:@*/} = c \
 290         && test ${v%/*} = a/b \
 291         && test ${v%%/*} = a],
 292       [], [am_score=1; break])
 293
 294     _AM_CHECK_SHELL_FEATURE([$1],
 295       [preserves exit traps with "set -e"],
 296       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 297       [], [am_score=1; break])
 298
 299     _AM_CHECK_SHELL_FEATURE([$1],
 300       [can define exit traps in a shell function],
 301       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 302       [], [am_score=1; break])
 303
 304     _AM_CHECK_SHELL_FEATURE([$1],
 305       [corrupts stderr with "set -x"],
 306       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 307       [am_score=9], [])
 308
 309     echo 'return 34' > conftest-return.sh
 310     echo 'ok=no' >> conftest-return.sh
 311     _AM_CHECK_SHELL_FEATURE([$1],
 312       [can return early from "dot-sourced" files],
 313       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 314       [rm -f conftest-return.sh],
 315       [rm -f conftest-return.sh; am_score=1; break])
 316
 317     echo 'alias false=echo' > conftest-alias.sh
 318     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 319     _AM_CHECK_SHELL_FEATURE([$1],
 320       [supports alias named like shell builtins],
 321       [. ./conftest-alias.sh],
 322       [rm -f conftest-alias.sh],
 323       [rm -f conftest-alias.sh; am_score=1; break])
 324
 325     _AM_CHECK_SHELL_FEATURE([$1],
 326       [supports "test -e"],
 327       [test -e config.log && test -e . && test ! -e nonesuch],
 328       [], [am_score=1; break])
 329
 330     break
 331   done])
 332
 333 # These messages only goes to the config.log file.
 334 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 335
 336 AC_CACHE_VAL(
 337   [ac_cv_AM_TEST_RUNNER_SHELL],
 338   [if test "$AM_TEST_RUNNER_SHELL"; then
 339     # Let the user override it.
 340     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 341   else
 342     ac_cv_AM_TEST_RUNNER_SHELL=no
 343     am_candidate_shells=${CONFIG_SHELL-}
 344     # For the benefit of Solaris.
 345     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 346     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 347       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 348       if test -n "$am_candidate_sh"; then
 349         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 350       fi
 351       AM_SUBST_NOTMAKE([am_candidate_sh])
 352       # Must nullify these in order not to interfere with the checks in
 353       # the next loop.
 354       AS_UNSET([am_candidate_sh])
 355       AS_UNSET([ac_cv_path_am_candidate_sh])
 356     done
 357     AS_UNSET([am_PATH]) # Not required anymore
 358     for am_sh in $am_candidate_shells; do
 359       am_score=0
 360       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 361       if test $am_score -eq 9; then
 362         # The shell is barely acceptable for our needs.  We might
 363         # still find one that is even better, so continue looking.
 364         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 365         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 366       elif test $am_score -eq 10; then
 367         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 368         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 369         break
 370       fi
 371     done
 372   fi
 373   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 374
 375 if test $AM_TEST_RUNNER_SHELL = no; then
 376   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 377                                 enough to be used in our testsuite])])
 378 else
 379   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 380 fi
 381
 382 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 383            [a sturdy POSIX shell for our testsuite])
 384
 385
 386 ###########################################################################
 387
 388 # Look for C, C++ and fortran compilers to be used in the testsuite.
 389
 390 dnl We don't want to abort our configuration script if no C compiler is
 391 dnl available, as such a compiler is only required to run part of the
 392 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 393 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 394 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 395
 396 dnl We want the body of this macro to expand as a single shell statement,
 397 dnl thus we wrap it into { ... } brackets.
 398 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 399   AC_MSG_WARN([$1])
 400   am__failed=yes
 401   break
 402 } ])
 403
 404 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 405   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 406   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 407   am__failed=no
 408   while :; do
 409      $1
 410      break
 411   done
 412   AS_IF([test $am__failed = yes], [$2])
 413   # We have to clear these cache variables, so that future checks on
 414   # compilers for different languages won't be confused.
 415   unset ac_cv_objext ac_cv_exeext
 416   # We also need to meddle with the autoconf internals to ensure that
 417   # checks to find object and executable extensions will be run anew.
 418   # FIXME: In the long run, the better thing to do would be to fix
 419   # FIXME: autoconf instead ...
 420   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 421   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 422   m4_popdef([AC_MSG_FAILURE])
 423   m4_popdef([AC_MSG_ERROR])
 424 ])
 425
 426 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 427   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 428
 429 # Prefer generic compilers to GNU ones when possible.  This will ensure
 430 # more testsuite coverage "in the wild".
 431 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 432 # deliberate; for more discussion and rationale, see:
 433 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 434
 435 AC_MSG_NOTICE([will now look for generic compilers])
 436
 437 # C compiler.
 438 _AM_COMPILER_CAN_FAIL(dnl
 439   [AC_PROG_CC([cc gcc])],
 440   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 441
 442 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 443
 444 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 445 # we must avoid looking for 'CC', because that would be the same as
 446 # 'cc', and could cause $CXX to point to the C compiler, instead of
 447 # to a C++ compiler as expected (see automake bugs #11893 and #10766).
 448 # Similarly, we must avoid looking for 'RCC', as that can point to the
 449 # Qt4 "Resource Compiler": <http://doc.qt.digia.com/4.2/rcc.html>
 450 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 451   # Case-insensitive file system, don't look for CC.
 452   am_CC= am_RCC=
 453 else
 454   am_CC=CC am_RCC=RCC
 455 fi
 456
 457 # The list of C++ compilers here has been copied, pasted and edited
 458 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 459 # Keep it in sync, or better again, find out a way to avoid this code
 460 # duplication.
 461 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 462   [aCC $am_CC FCC KCC $am_RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 463   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 464
 465 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 466
 467 # The lists of Fortran compilers here has been copied, pasted and edited
 468 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 469 # Keep it in sync, or better again, find out a way to avoid this code
 470 # duplication.
 471
 472 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 473   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 474   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 475   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 476
 477 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 478
 479 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 480   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 481   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 482
 483 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 484
 485 # Some tests will need the GNU compilers.  Searching for them here would
 486 # be overkill, since our testsuite already handles their search and setup
 487 # pretty well.  But in case the compilers already found are the GNU ones,
 488 # we want to use them in the testsuite where GNU compilers are required.
 489 # Also, in case the compilers detected above (at configure time) are not
 490 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 491 # FFLAGS detected for them with the GNU compilers too, since it's likely
 492 # they won't be compatible.  So we allow the user to define variants of
 493 # these variables for the GNU compilers separately.
 494
 495 AC_MSG_NOTICE([will now look for GNU compilers])
 496
 497 # GNU C compiler.
 498 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 499 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 500 if test $am_CC_is_GNU = yes; then
 501   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 502   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 503 else
 504   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 505 fi
 506 if test "$GNU_CC" != false; then
 507   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 508         [AC_MSG_WARN([botched installation for GNU C compiler])
 509          _AM_SKIP_COMP_TESTS([GNU C])])
 510 fi
 511
 512 # GNU C++ compiler.
 513 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 514 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 515 if test $am_CXX_is_GNU = yes; then
 516   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 517   GNU_CXX=$CXX
 518   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 519 else
 520   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 521 fi
 522 if test "$GNU_CXX" != false; then
 523   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 524         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 525          _AM_SKIP_COMP_TESTS([GNU C++])])
 526 fi
 527
 528 # GNU Fortran compiler.
 529 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 530 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 531 if test $am_FC_is_GNU = yes; then
 532   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 533   GNU_FC=$FC
 534   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 535 else
 536   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 537 fi
 538 if test "$GNU_FC" != false; then
 539   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 540         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 541          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 542 fi
 543
 544 # GNU Fortran 77 compiler.
 545 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 546 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 547 if test $am_F77_is_GNU = yes; then
 548   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 549   GNU_F77=$F77
 550   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 551 else
 552   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 553 fi
 554 if test "$GNU_F77" != false; then
 555   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 556         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 557         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 558 fi
 559
 560 # GNU Java compiler.
 561 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 562 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 563 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 564 if test "$GNU_GCJ" != false; then
 565   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 566         [AC_MSG_WARN([botched installation for GNU Java compiler])
 567         _AM_SKIP_COMP_TESTS([GNU Java])])
 568 fi
 569
 570 # If we have been able to find at least a working compiler above, we
 571 # know what the object and executable extensions for this platform are.
 572 OBJEXT=${ac_cv_objext-UNKNOWN}
 573 EXEEXT=${ac_cv_exeext-UNKNOWN}
 574 AC_SUBST([OBJEXT])
 575 AC_SUBST([EXEEXT])
 576
 577 ###########################################################################
 578
 579 ## ---------------------- ##
 580 ##  Create output files.  ##
 581 ## ---------------------- ##
 582
 583 AC_CONFIG_FILES([Makefile])
 584 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 585
 586 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 587                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 588                 [APIVERSION=$APIVERSION])
 589 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 590                 [chmod +x t/wrap/automake-${APIVERSION}],
 591                 [APIVERSION=$APIVERSION])
 592
 593 AC_OUTPUT
 594
 595 # Inform the user if this version of automake is a beta release or
 596 # a development snapshot.
 597 # According to HACKING, the version of a development snapshot should
 598 # end with an "odd" letter (a, c, ...), the version of a test release
 599 # should end wit an "even" letter (b, d, ...).
 600
 601 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 602 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 603
 604 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 605   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 606   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 607   { print \"development snapshot\"; }"]`
 608
 609 # '$silent' is set to yes if configure is passed the '--quiet' option.
 610 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 611
 612 WARNING: You are about to use a $am_release_type of automake.
 613 WARNING: It might easily suffer from new bugs or regressions.
 614 WARNING: You are strongly advised not to use it in production code.
 615
 616 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 617 EOF
 618
 619 AS_EXIT([0])