compiler/record-minmax-conversion-test/CMakeLists.txt

   1 if(NOT ENABLE_TEST)
   2   return()
   3 endif(NOT ENABLE_TEST)
   4
   5 unset(RECORD_MINMAX_CONVERSION_TEST)
   6
   7 macro(addTest NAME)
   8   list(APPEND RECORD_MINMAX_CONVERSION_TEST ${NAME})
   9 endmacro(addTest)
  10
  11 # Read "test.lst"
  12 include("test.lst")
  13 # Read "test.local.lst" if exists
  14 include("test.local.lst" OPTIONAL)
  15
  16 unset(TEST_DEPS)
  17
  18 get_target_property(ARTIFACTS_BIN_PATH testDataGenerator BINARY_DIR)
  19
  20 ###
  21 ### Generate test.config
  22 ###
  23 set(TEST_CONFIG "${CMAKE_CURRENT_BINARY_DIR}/test.config")
  24
  25 add_custom_command(
  26   OUTPUT ${TEST_CONFIG}
  27   COMMAND ${CMAKE_COMMAND} -E remove -f ${TEST_CONFIG}
  28   COMMAND ${CMAKE_COMMAND} -E echo 'RECORD_MINMAX_PATH=\"$<TARGET_FILE:record-minmax>\"' >> ${TEST_CONFIG}
  29   DEPENDS record-minmax
  30   COMMENT "Generate test configuration"
  31 )
  32
  33 list(APPEND TEST_DEPS "${TEST_CONFIG}")
  34
  35 # This enforces CMake to generate all the dependencies during "build" phase
  36 add_custom_target(record_minmax_conversion_test_deps ALL DEPENDS ${TEST_DEPS})
  37
  38 # Run tests
  39 add_test(
  40   NAME record_minmax_conversion_test
  41   COMMAND "${CMAKE_CURRENT_SOURCE_DIR}/testall.sh"
  42           "${TEST_CONFIG}"
  43           "${ARTIFACTS_BIN_PATH}"
  44           "${NNCC_OVERLAY_DIR}/venv_2_12_1"
  45           ${RECORD_MINMAX_CONVERSION_TEST}
  46 )