compileoptions.cmake

   1 if (CLR_CMAKE_PLATFORM_UNIX)
   2   # Disable frame pointer optimizations so profilers can get better call stacks
   3   add_compile_options(-fno-omit-frame-pointer)
   4
   5   # The -fms-extensions enable the stuff like __if_exists, __declspec(uuid()), etc.
   6   add_compile_options(-fms-extensions )
   7   #-fms-compatibility      Enable full Microsoft Visual C++ compatibility
   8   #-fms-extensions         Accept some non-standard constructs supported by the Microsoft compiler
   9
  10   # Make signed arithmetic overflow of addition, subtraction, and multiplication wrap around
  11   # using twos-complement representation (this is normally undefined according to the C++ spec).
  12   add_compile_options(-fwrapv)
  13
  14   if(CLR_CMAKE_PLATFORM_DARWIN)
  15     # We cannot enable "stack-protector-strong" on OS X due to a bug in clang compiler (current version 7.0.2)
  16     add_compile_options(-fstack-protector)
  17   else()
  18     add_compile_options(-fstack-protector-strong)
  19   endif(CLR_CMAKE_PLATFORM_DARWIN)
  20
  21   add_definitions(-DDISABLE_CONTRACTS)
  22   # The -ferror-limit is helpful during the porting, it makes sure the compiler doesn't stop
  23   # after hitting just about 20 errors.
  24   add_compile_options(-ferror-limit=4096)
  25
  26   # All warnings that are not explicitly disabled are reported as errors
  27   add_compile_options(-Werror)
  28
  29   # Disabled warnings
  30   add_compile_options(-Wno-unused-private-field)
  31   add_compile_options(-Wno-unused-variable)
  32   # Explicit constructor calls are not supported by clang (this->ClassName::ClassName())
  33   add_compile_options(-Wno-microsoft)
  34   # This warning is caused by comparing 'this' to NULL
  35   add_compile_options(-Wno-tautological-compare)
  36   # There are constants of type BOOL used in a condition. But BOOL is defined as int
  37   # and so the compiler thinks that there is a mistake.
  38   add_compile_options(-Wno-constant-logical-operand)
  39
  40   add_compile_options(-Wno-unknown-warning-option)
  41
  42   #These seem to indicate real issues
  43   add_compile_options(-Wno-invalid-offsetof)
  44   # The following warning indicates that an attribute __attribute__((__ms_struct__)) was applied
  45   # to a struct or a class that has virtual members or a base class. In that case, clang
  46   # may not generate the same object layout as MSVC.
  47   add_compile_options(-Wno-incompatible-ms-struct)
  48
  49   # Some architectures (e.g., ARM) assume char type is unsigned while CoreCLR assumes char is signed
  50   # as x64 does. It has been causing issues in ARM (https://github.com/dotnet/coreclr/issues/4746)
  51   add_compile_options(-fsigned-char)
  52 endif(CLR_CMAKE_PLATFORM_UNIX)
  53
  54 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
  55    # Because we don't use CMAKE_C_COMPILER/CMAKE_CXX_COMPILER to use clang
  56    # we have to set the triple by adding a compiler argument
  57    add_compile_options(-mthumb)
  58    add_compile_options(-mfpu=vfpv3)
  59    if(ARM_SOFTFP)
  60      add_definitions(-DARM_SOFTFP)
  61      add_compile_options(-mfloat-abi=softfp)
  62      add_compile_options(-target armv7-linux-gnueabi)
  63    else()
  64      add_compile_options(-target armv7-linux-gnueabihf)
  65    endif(ARM_SOFTFP)
  66 endif(CLR_CMAKE_PLATFORM_UNIX_ARM)
  67
  68 if (WIN32)
  69   # Compile options for targeting windows
  70
  71   # The following options are set by the razzle build
  72   add_compile_options(/TP) # compile all files as C++
  73   add_compile_options(/d2Zi+) # make optimized builds debugging easier
  74   add_compile_options(/nologo) # Suppress Startup Banner
  75   add_compile_options(/W3) # set warning level to 3
  76   add_compile_options(/WX) # treat warnings as errors
  77   add_compile_options(/Oi) # enable intrinsics
  78   add_compile_options(/Oy-) # disable suppressing of the creation of frame pointers on the call stack for quicker function calls
  79   add_compile_options(/U_MT) # undefine the predefined _MT macro
  80   add_compile_options(/GF) # enable read-only string pooling
  81   add_compile_options(/Gm-) # disable minimal rebuild
  82   add_compile_options(/EHa) # enable C++ EH (w/ SEH exceptions)
  83   add_compile_options(/Zp8) # pack structs on 8-byte boundary
  84   add_compile_options(/Gy) # separate functions for linker
  85   add_compile_options(/Zc:wchar_t-) # C++ language conformance: wchar_t is NOT the native type, but a typedef
  86   add_compile_options(/Zc:forScope) # C++ language conformance: enforce Standard C++ for scoping rules
  87   add_compile_options(/GR-) # disable C++ RTTI
  88   add_compile_options(/FC) # use full pathnames in diagnostics
  89   add_compile_options(/MP) # Build with Multiple Processes (number of processes equal to the number of processors)
  90   add_compile_options(/GS) # Buffer Security Check
  91   add_compile_options(/Zm200) # Specify Precompiled Header Memory Allocation Limit of 150MB
  92   add_compile_options(/wd4960 /wd4961 /wd4603 /wd4627 /wd4838 /wd4456 /wd4457 /wd4458 /wd4459 /wd4091 /we4640)
  93   add_compile_options(/Zi) # enable debugging information
  94   add_compile_options(/ZH:SHA_256) # use SHA256 for generating hashes of compiler processed source files.
  95
  96   if (CLR_CMAKE_PLATFORM_ARCH_I386)
  97     add_compile_options(/Gz)
  98   endif (CLR_CMAKE_PLATFORM_ARCH_I386)
  99
 100   add_compile_options($<$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>:/GL>)
 101   add_compile_options($<$<OR:$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>,$<CONFIG:Checked>>:/O1>)
 102
 103   if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 104   # The generator expression in the following command means that the /homeparams option is added only for debug builds
 105   add_compile_options($<$<CONFIG:Debug>:/homeparams>) # Force parameters passed in registers to be written to the stack
 106   endif (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 107
 108   # enable control-flow-guard support for native components for non-Arm64 builds
 109   add_compile_options(/guard:cf)
 110
 111   # Statically linked CRT (libcmt[d].lib, libvcruntime[d].lib and libucrt[d].lib) by default. This is done to avoid
 112   # linking in VCRUNTIME140.DLL for a simplified xcopy experience by reducing the dependency on VC REDIST.
 113   #
 114   # For Release builds, we shall dynamically link into uCRT [ucrtbase.dll] (which is pushed down as a Windows Update on downlevel OS) but
 115   # wont do the same for debug/checked builds since ucrtbased.dll is not redistributable and Debug/Checked builds are not
 116   # production-time scenarios.
 117   add_compile_options($<$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>:/MT>)
 118   add_compile_options($<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:/MTd>)
 119
 120   set(CMAKE_ASM_MASM_FLAGS "${CMAKE_ASM_MASM_FLAGS} /ZH:SHA_256")
 121
 122 endif (WIN32)
 123
 124 if(CMAKE_ENABLE_CODE_COVERAGE)
 125
 126   if(CLR_CMAKE_PLATFORM_UNIX)
 127     string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 128     if(NOT UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 129       message( WARNING "Code coverage results with an optimised (non-Debug) build may be misleading" )
 130     endif(NOT UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 131
 132     add_compile_options(-fprofile-arcs)
 133     add_compile_options(-ftest-coverage)
 134     set(CLANG_COVERAGE_LINK_FLAGS  "--coverage")
 135     set(CMAKE_SHARED_LINKER_FLAGS  "${CMAKE_SHARED_LINKER_FLAGS} ${CLANG_COVERAGE_LINK_FLAGS}")
 136     set(CMAKE_EXE_LINKER_FLAGS     "${CMAKE_EXE_LINKER_FLAGS} ${CLANG_COVERAGE_LINK_FLAGS}")
 137   else()
 138     message(FATAL_ERROR "Code coverage builds not supported on current platform")
 139   endif(CLR_CMAKE_PLATFORM_UNIX)
 140
 141 endif(CMAKE_ENABLE_CODE_COVERAGE)