cmake/templates/OpenCVConfig.cmake.in

   1 # ===================================================================================
   2 #  The OpenCV CMake configuration file
   3 #
   4 #             ** File generated automatically, do not modify **
   5 #
   6 #  Usage from an external project:
   7 #    In your CMakeLists.txt, add these lines:
   8 #
   9 #    FIND_PACKAGE(OpenCV REQUIRED)
  10 #    TARGET_LINK_LIBRARIES(MY_TARGET_NAME ${OpenCV_LIBS})
  11 #
  12 #    Or you can search for specific OpenCV modules:
  13 #
  14 #    FIND_PACKAGE(OpenCV REQUIRED core highgui)
  15 #
  16 #    If the module is found then OPENCV_<MODULE>_FOUND is set to TRUE.
  17 #
  18 #    This file will define the following variables:
  19 #      - OpenCV_LIBS                     : The list of libraries to links against.
  20 #      - OpenCV_LIB_DIR                  : The directory(es) where lib files are. Calling LINK_DIRECTORIES
  21 #                                          with this path is NOT needed.
  22 #      - OpenCV_INCLUDE_DIRS             : The OpenCV include directories.
  23 #      - OpenCV_COMPUTE_CAPABILITIES     : The version of compute capability
  24 #      - OpenCV_ANDROID_NATIVE_API_LEVEL : Minimum required level of Android API
  25 #      - OpenCV_VERSION                  : The version of this OpenCV build: "@OPENCV_VERSION@"
  26 #      - OpenCV_VERSION_MAJOR            : Major version part of OpenCV_VERSION: "@OPENCV_VERSION_MAJOR@"
  27 #      - OpenCV_VERSION_MINOR            : Minor version part of OpenCV_VERSION: "@OPENCV_VERSION_MINOR@"
  28 #      - OpenCV_VERSION_PATCH            : Patch version part of OpenCV_VERSION: "@OPENCV_VERSION_PATCH@"
  29 #      - OpenCV_VERSION_TWEAK            : Tweak version part of OpenCV_VERSION: "@OPENCV_VERSION_TWEAK@"
  30 #
  31 #    Advanced variables:
  32 #      - OpenCV_SHARED
  33 #      - OpenCV_CONFIG_PATH
  34 #      - OpenCV_INSTALL_PATH  (not set on Windows)
  35 #      - OpenCV_LIB_COMPONENTS
  36 #      - OpenCV_USE_MANGLED_PATHS
  37 #      - OpenCV_HAVE_ANDROID_CAMERA
  38 #
  39 # ===================================================================================
  40
  41 # Version Compute Capability from which OpenCV has been compiled is remembered
  42 set(OpenCV_COMPUTE_CAPABILITIES @OpenCV_CUDA_CC_CONFIGCMAKE@)
  43
  44 set(OpenCV_CUDA_VERSION @OpenCV_CUDA_VERSION@)
  45 set(OpenCV_USE_CUBLAS   @HAVE_CUBLAS@)
  46 set(OpenCV_USE_CUFFT    @HAVE_CUFFT@)
  47 set(OpenCV_USE_NVCUVID  @HAVE_NVCUVID@)
  48
  49 # Android API level from which OpenCV has been compiled is remembered
  50 set(OpenCV_ANDROID_NATIVE_API_LEVEL @OpenCV_ANDROID_NATIVE_API_LEVEL_CONFIGCMAKE@)
  51
  52 # Some additional settings are required if OpenCV is built as static libs
  53 set(OpenCV_SHARED @BUILD_SHARED_LIBS@)
  54
  55 # Enables mangled install paths, that help with side by side installs
  56 set(OpenCV_USE_MANGLED_PATHS @OpenCV_USE_MANGLED_PATHS_CONFIGCMAKE@)
  57
  58 # Extract the directory where *this* file has been installed (determined at cmake run-time)
  59 get_filename_component(OpenCV_CONFIG_PATH "${CMAKE_CURRENT_LIST_FILE}" PATH CACHE)
  60
  61 if(NOT WIN32 OR OpenCV_ANDROID_NATIVE_API_LEVEL GREATER 0)
  62   if(OpenCV_ANDROID_NATIVE_API_LEVEL GREATER 0)
  63     set(OpenCV_INSTALL_PATH "${OpenCV_CONFIG_PATH}/../../..")
  64   else()
  65     set(OpenCV_INSTALL_PATH "${OpenCV_CONFIG_PATH}/../..")
  66   endif()
  67   # Get the absolute path with no ../.. relative marks, to eliminate implicit linker warnings
  68   if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 2.8)
  69     get_filename_component(OpenCV_INSTALL_PATH "${OpenCV_INSTALL_PATH}" ABSOLUTE)
  70   else()
  71     get_filename_component(OpenCV_INSTALL_PATH "${OpenCV_INSTALL_PATH}" REALPATH)
  72   endif()
  73 endif()
  74
  75 # Presence of Android native camera wrappers
  76 set(OpenCV_HAVE_ANDROID_CAMERA @HAVE_opencv_androidcamera@)
  77
  78 # ======================================================
  79 # Include directories to add to the user project:
  80 # ======================================================
  81
  82 # Provide the include directories to the caller
  83 set(OpenCV_INCLUDE_DIRS @OpenCV_INCLUDE_DIRS_CONFIGCMAKE@)
  84 include_directories(${OpenCV_INCLUDE_DIRS})
  85
  86 # ======================================================
  87 # Link directories to add to the user project:
  88 # ======================================================
  89
  90 # Provide the libs directories to the caller
  91 set(OpenCV_LIB_DIR_OPT @OpenCV_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where release OpenCV libraries are located")
  92 set(OpenCV_LIB_DIR_DBG @OpenCV_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where debug OpenCV libraries are located")
  93 set(OpenCV_3RDPARTY_LIB_DIR_OPT @OpenCV_3RDPARTY_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where release 3rdpaty OpenCV dependencies are located")
  94 set(OpenCV_3RDPARTY_LIB_DIR_DBG @OpenCV_3RDPARTY_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where debug 3rdpaty OpenCV dependencies are located")
  95 mark_as_advanced(FORCE OpenCV_LIB_DIR_OPT OpenCV_LIB_DIR_DBG OpenCV_3RDPARTY_LIB_DIR_OPT OpenCV_3RDPARTY_LIB_DIR_DBG OpenCV_CONFIG_PATH)
  96
  97 # ======================================================
  98 #  Version variables:
  99 # ======================================================
 100 SET(OpenCV_VERSION @OPENCV_VERSION@)
 101 SET(OpenCV_VERSION_MAJOR  @OPENCV_VERSION_MAJOR@)
 102 SET(OpenCV_VERSION_MINOR  @OPENCV_VERSION_MINOR@)
 103 SET(OpenCV_VERSION_PATCH  @OPENCV_VERSION_PATCH@)
 104 SET(OpenCV_VERSION_TWEAK  @OPENCV_VERSION_TWEAK@)
 105
 106 # ====================================================================
 107 # Link libraries: e.g.   libopencv_core.so, opencv_imgproc220d.lib, etc...
 108 # ====================================================================
 109
 110 SET(OpenCV_LIB_COMPONENTS @OPENCV_MODULES_CONFIGCMAKE@)
 111
 112 @OPENCV_DEPENDENCIES_MAP_OPT@
 113
 114 @OPENCV_DEPENDENCIES_MAP_DBG@
 115
 116 # ==============================================================
 117 #  Extra include directories, needed by OpenCV 2 new structure
 118 # ==============================================================
 119 SET(OpenCV2_INCLUDE_DIRS @OpenCV2_INCLUDE_DIRS_CONFIGCMAKE@)
 120 if(OpenCV2_INCLUDE_DIRS)
 121   include_directories(${OpenCV2_INCLUDE_DIRS})
 122   list(APPEND OpenCV_INCLUDE_DIRS ${OpenCV2_INCLUDE_DIRS})
 123
 124   set(OpenCV_ADD_DEBUG_RELEASE @OpenCV_ADD_DEBUG_RELEASE_CONFIGCMAKE@)
 125   if(OpenCV_ADD_DEBUG_RELEASE)
 126     set(OpenCV_LIB_DIR_OPT "${OpenCV_LIB_DIR_OPT}/Release")
 127     set(OpenCV_LIB_DIR_DBG "${OpenCV_LIB_DIR_DBG}/Debug")
 128     set(OpenCV_3RDPARTY_LIB_DIR_OPT "${OpenCV_3RDPARTY_LIB_DIR_OPT}/Release")
 129     set(OpenCV_3RDPARTY_LIB_DIR_DBG "${OpenCV_3RDPARTY_LIB_DIR_DBG}/Debug")
 130   endif()
 131 endif()
 132
 133 # ==============================================================
 134 #  Check OpenCV availability
 135 # ==============================================================
 136 if(ANDROID AND OpenCV_ANDROID_NATIVE_API_LEVEL GREATER ANDROID_NATIVE_API_LEVEL)
 137   message(FATAL_ERROR "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 138   #always FATAL_ERROR because we can't say to the caller that OpenCV is not found
 139   #http://www.mail-archive.com/cmake@cmake.org/msg37831.html
 140   if(OpenCV_FIND_REQUIRED)
 141     message(FATAL_ERROR "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 142   elseif(NOT OpenCV_FIND_QUIETLY)
 143     message(WARNING "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 144   endif()
 145   set(OpenCV_FOUND "OpenCV_FOUND-NOTFOUND")
 146   return()#Android toolchain requires CMake > 2.6
 147 endif()
 148
 149 # ==============================================================
 150 #  Form list of modules (components) to find
 151 # ==============================================================
 152 if(NOT OpenCV_FIND_COMPONENTS)
 153   set(OpenCV_FIND_COMPONENTS ${OpenCV_LIB_COMPONENTS})
 154   if(GTest_FOUND OR GTEST_FOUND)
 155     list(REMOVE_ITEM OpenCV_FIND_COMPONENTS opencv_ts)
 156   endif()
 157 endif()
 158
 159 # expand short module names and see if requested components exist
 160 set(OpenCV_FIND_COMPONENTS_ "")
 161 foreach(__cvcomponent ${OpenCV_FIND_COMPONENTS})
 162   if(NOT __cvcomponent MATCHES "^opencv_")
 163     set(__cvcomponent opencv_${__cvcomponent})
 164   endif()
 165   list(FIND OpenCV_LIB_COMPONENTS ${__cvcomponent} __cvcomponentIdx)
 166   if(__cvcomponentIdx LESS 0)
 167     #requested component is not found...
 168     if(OpenCV_FIND_REQUIRED)
 169       message(FATAL_ERROR "${__cvcomponent} is required but was not found")
 170     elseif(NOT OpenCV_FIND_QUIETLY)
 171       message(WARNING "${__cvcomponent} is required but was not found")
 172     endif()
 173     #indicate that module is NOT found
 174     string(TOUPPER "${__cvcomponent}" __cvcomponent)
 175     set(${__cvcomponent}_FOUND "${__cvcomponent}_FOUND-NOTFOUND")
 176   else()
 177     list(APPEND OpenCV_FIND_COMPONENTS_ ${__cvcomponent})
 178     #indicate that module is found
 179     string(TOUPPER "${__cvcomponent}" __cvcomponent)
 180     set(${__cvcomponent}_FOUND 1)
 181   endif()
 182 endforeach()
 183 set(OpenCV_FIND_COMPONENTS ${OpenCV_FIND_COMPONENTS_})
 184
 185 # ==============================================================
 186 #  Resolve dependencies
 187 # ==============================================================
 188 if(OpenCV_USE_MANGLED_PATHS)
 189   set(OpenCV_LIB_SUFFIX ".${OpenCV_VERSION_MAJOR}.${OpenCV_VERSION_MINOR}.${OpenCV_VERSION_PATCH}")
 190 else()
 191   set(OpenCV_LIB_SUFFIX "")
 192 endif()
 193
 194 foreach(__opttype OPT DBG)
 195   SET(OpenCV_LIBS_${__opttype} "")
 196   SET(OpenCV_EXTRA_LIBS_${__opttype} "")
 197   foreach(__cvlib ${OpenCV_FIND_COMPONENTS})
 198     foreach(__cvdep ${OpenCV_${__cvlib}_DEPS_${__opttype}})
 199       if(__cvdep MATCHES "^opencv_")
 200         list(APPEND OpenCV_LIBS_${__opttype} "${OpenCV_LIB_DIR_${__opttype}}/${OpenCV_${__cvdep}_LIBNAME_${__opttype}}${OpenCV_LIB_SUFFIX}")
 201         #indicate that this module is also found
 202         string(TOUPPER "${__cvdep}" __cvdep)
 203         set(${__cvdep}_FOUND 1)
 204       else()
 205         list(APPEND OpenCV_LIBS_${__opttype} "${OpenCV_3RDPARTY_LIB_DIR_${__opttype}}/${OpenCV_${__cvdep}_LIBNAME_${__opttype}}")
 206       endif()
 207     endforeach()
 208     list(APPEND OpenCV_LIBS_${__opttype} "${OpenCV_LIB_DIR_${__opttype}}/${OpenCV_${__cvlib}_LIBNAME_${__opttype}}${OpenCV_LIB_SUFFIX}")
 209     list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${OpenCV_${__cvlib}_EXTRA_DEPS_${__opttype}})
 210   endforeach()
 211
 212   if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_GREATER 2.4)
 213     if(OpenCV_LIBS_${__opttype})
 214       list(REMOVE_DUPLICATES OpenCV_LIBS_${__opttype})
 215     endif()
 216     if(OpenCV_EXTRA_LIBS_${__opttype})
 217       list(REMOVE_DUPLICATES OpenCV_EXTRA_LIBS_${__opttype})
 218     endif()
 219   else()
 220     #TODO: duplicates are annoying but they should not be the problem
 221   endif()
 222
 223   # CUDA
 224   if(OpenCV_CUDA_VERSION AND WIN32 AND NOT OpenCV_SHARED)
 225     if(NOT CUDA_FOUND)
 226       find_package(CUDA ${OpenCV_CUDA_VERSION} EXACT REQUIRED)
 227     else()
 228       if(NOT CUDA_VERSION_STRING VERSION_EQUAL OpenCV_CUDA_VERSION)
 229         message(FATAL_ERROR "OpenCV static library was compiled with CUDA ${OpenCV_CUDA_VERSION} support. Please, use the same version or rebuild OpenCV with CUDA ${CUDA_VERSION_STRING}")
 230       endif()
 231     endif()
 232
 233     list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 234
 235     if(OpenCV_USE_CUBLAS)
 236       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_CUBLAS_LIBRARIES})
 237     endif()
 238
 239     if(OpenCV_USE_CUFFT)
 240       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_CUFFT_LIBRARIES})
 241     endif()
 242
 243     if(OpenCV_USE_NVCUVID)
 244       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_nvcuvid_LIBRARIES})
 245     endif()
 246
 247     if(WIN32)
 248       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_nvcuvenc_LIBRARIES})
 249     endif()
 250   endif()
 251 endforeach()
 252
 253 if(OpenCV_LIBS_DBG)
 254   list(REVERSE OpenCV_LIBS_DBG)
 255 endif()
 256
 257 if(OpenCV_LIBS_OPT)
 258   list(REVERSE OpenCV_LIBS_OPT)
 259 endif()
 260
 261 # CMake>=2.6 supports the notation "debug XXd optimized XX"
 262 if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_GREATER 2.4)
 263   # Modern CMake:
 264   SET(OpenCV_LIBS "")
 265   foreach(__cvlib ${OpenCV_LIBS_DBG} ${OpenCV_EXTRA_LIBS_DBG})
 266     list(APPEND OpenCV_LIBS debug "${__cvlib}")
 267   endforeach()
 268   foreach(__cvlib ${OpenCV_LIBS_OPT} ${OpenCV_EXTRA_LIBS_OPT})
 269     list(APPEND OpenCV_LIBS optimized "${__cvlib}")
 270   endforeach()
 271 else()
 272   # Old CMake:
 273   if(CMAKE_BUILD_TYPE MATCHES "Debug")
 274     SET(OpenCV_LIBS ${OpenCV_LIBS_DBG} ${OpenCV_EXTRA_LIBS_DBG})
 275   else()
 276     SET(OpenCV_LIBS ${OpenCV_LIBS_OPT} ${OpenCV_EXTRA_LIBS_OPT})
 277   endif()
 278 endif()
 279
 280 # ==============================================================
 281 #  Android camera helper macro
 282 # ==============================================================
 283 if(OpenCV_HAVE_ANDROID_CAMERA)
 284   macro(COPY_NATIVE_CAMERA_LIBS target)
 285     get_target_property(target_location ${target} LOCATION)
 286     get_filename_component(target_location "${target_location}" PATH)
 287     file(GLOB camera_wrappers "${OpenCV_LIB_DIR_OPT}/libnative_camera_r*.so")
 288     foreach(wrapper ${camera_wrappers})
 289       add_custom_command(
 290         TARGET ${target}
 291         POST_BUILD
 292         COMMAND ${CMAKE_COMMAND} -E copy "${wrapper}" "${target_location}"
 293       )
 294     endforeach()
 295   endmacro()
 296 endif()
 297
 298 # ==============================================================
 299 # Compatibility stuff
 300 # ==============================================================
 301 if(CMAKE_BUILD_TYPE MATCHES "Debug")
 302   SET(OpenCV_LIB_DIR ${OpenCV_LIB_DIR_DBG} ${OpenCV_3RDPARTY_LIB_DIR_DBG})
 303 else()
 304   SET(OpenCV_LIB_DIR ${OpenCV_LIB_DIR_OPT} ${OpenCV_3RDPARTY_LIB_DIR_OPT})
 305 endif()
 306 set(OpenCV_LIBRARIES ${OpenCV_LIBS})