cmake/templates/OpenCVConfig.cmake.in

   1 # ===================================================================================
   2 #  The OpenCV CMake configuration file
   3 #
   4 #             ** File generated automatically, do not modify **
   5 #
   6 #  Usage from an external project:
   7 #    In your CMakeLists.txt, add these lines:
   8 #
   9 #    FIND_PACKAGE(OpenCV REQUIRED)
  10 #    TARGET_LINK_LIBRARIES(MY_TARGET_NAME ${OpenCV_LIBS})
  11 #
  12 #    Or you can search for specific OpenCV modules:
  13 #
  14 #    FIND_PACKAGE(OpenCV REQUIRED core highgui)
  15 #
  16 #    If the module is found then OPENCV_<MODULE>_FOUND is set to TRUE.
  17 #
  18 #    This file will define the following variables:
  19 #      - OpenCV_LIBS                     : The list of all imported targets for OpenCV modules.
  20 #      - OpenCV_INCLUDE_DIRS             : The OpenCV include directories.
  21 #      - OpenCV_COMPUTE_CAPABILITIES     : The version of compute capability
  22 #      - OpenCV_ANDROID_NATIVE_API_LEVEL : Minimum required level of Android API
  23 #      - OpenCV_VERSION                  : The version of this OpenCV build: "@OPENCV_VERSION_PLAIN@"
  24 #      - OpenCV_VERSION_MAJOR            : Major version part of OpenCV_VERSION: "@OPENCV_VERSION_MAJOR@"
  25 #      - OpenCV_VERSION_MINOR            : Minor version part of OpenCV_VERSION: "@OPENCV_VERSION_MINOR@"
  26 #      - OpenCV_VERSION_PATCH            : Patch version part of OpenCV_VERSION: "@OPENCV_VERSION_PATCH@"
  27 #      - OpenCV_VERSION_TWEAK            : Tweak version part of OpenCV_VERSION: "@OPENCV_VERSION_TWEAK@"
  28 #      - OpenCV_VERSION_STATUS           : Development status of this build: "@OPENCV_VERSION_STATUS@"
  29 #
  30 #    Advanced variables:
  31 #      - OpenCV_SHARED
  32 #      - OpenCV_CONFIG_PATH
  33 #      - OpenCV_INSTALL_PATH  (not set on Windows)
  34 #      - OpenCV_LIB_COMPONENTS
  35 #      - OpenCV_USE_MANGLED_PATHS
  36 #      - OpenCV_HAVE_ANDROID_CAMERA
  37 #
  38 # ===================================================================================
  39
  40 set(modules_file_suffix "")
  41 if(ANDROID)
  42   string(REPLACE - _ modules_file_suffix "_${ANDROID_NDK_ABI_NAME}")
  43 endif()
  44
  45 if(NOT TARGET opencv_core)
  46   include(${CMAKE_CURRENT_LIST_DIR}/OpenCVModules${modules_file_suffix}.cmake)
  47 endif()
  48
  49 # TODO All things below should be reviewed. What is about of moving this code into related modules (special vars/hooks/files)
  50
  51 # Version Compute Capability from which OpenCV has been compiled is remembered
  52 set(OpenCV_COMPUTE_CAPABILITIES @OpenCV_CUDA_CC_CONFIGCMAKE@)
  53
  54 set(OpenCV_CUDA_VERSION @OpenCV_CUDA_VERSION@)
  55 set(OpenCV_USE_CUBLAS   @HAVE_CUBLAS@)
  56 set(OpenCV_USE_CUFFT    @HAVE_CUFFT@)
  57 set(OpenCV_USE_NVCUVID  @HAVE_NVCUVID@)
  58
  59 # Android API level from which OpenCV has been compiled is remembered
  60 set(OpenCV_ANDROID_NATIVE_API_LEVEL @OpenCV_ANDROID_NATIVE_API_LEVEL_CONFIGCMAKE@)
  61
  62 # Some additional settings are required if OpenCV is built as static libs
  63 set(OpenCV_SHARED @BUILD_SHARED_LIBS@)
  64
  65 # Enables mangled install paths, that help with side by side installs
  66 set(OpenCV_USE_MANGLED_PATHS @OpenCV_USE_MANGLED_PATHS_CONFIGCMAKE@)
  67
  68 # Extract the directory where *this* file has been installed (determined at cmake run-time)
  69 get_filename_component(OpenCV_CONFIG_PATH "${CMAKE_CURRENT_LIST_FILE}" PATH CACHE)
  70
  71 if(NOT WIN32 OR OpenCV_ANDROID_NATIVE_API_LEVEL GREATER 0)
  72   if(OpenCV_ANDROID_NATIVE_API_LEVEL GREATER 0)
  73     set(OpenCV_INSTALL_PATH "${OpenCV_CONFIG_PATH}/../../..")
  74   else()
  75     set(OpenCV_INSTALL_PATH "${OpenCV_CONFIG_PATH}/../..")
  76   endif()
  77   # Get the absolute path with no ../.. relative marks, to eliminate implicit linker warnings
  78   if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 2.8)
  79     get_filename_component(OpenCV_INSTALL_PATH "${OpenCV_INSTALL_PATH}" ABSOLUTE)
  80   else()
  81     get_filename_component(OpenCV_INSTALL_PATH "${OpenCV_INSTALL_PATH}" REALPATH)
  82   endif()
  83 endif()
  84
  85 # Presence of Android native camera wrappers
  86 set(OpenCV_HAVE_ANDROID_CAMERA @HAVE_opencv_androidcamera@)
  87
  88 # ======================================================
  89 # Include directories to add to the user project:
  90 # ======================================================
  91
  92 # Provide the include directories to the caller
  93 set(OpenCV_INCLUDE_DIRS @OpenCV_INCLUDE_DIRS_CONFIGCMAKE@)
  94
  95 # ======================================================
  96 # Link directories to add to the user project:
  97 # ======================================================
  98
  99 # Provide the libs directories to the caller
 100 set(OpenCV_LIB_DIR_OPT @OpenCV_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where release OpenCV libraries are located")
 101 set(OpenCV_LIB_DIR_DBG @OpenCV_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where debug OpenCV libraries are located")
 102 set(OpenCV_3RDPARTY_LIB_DIR_OPT @OpenCV_3RDPARTY_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where release 3rdpaty OpenCV dependencies are located")
 103 set(OpenCV_3RDPARTY_LIB_DIR_DBG @OpenCV_3RDPARTY_LIB_DIRS_CONFIGCMAKE@ CACHE PATH "Path where debug 3rdpaty OpenCV dependencies are located")
 104 mark_as_advanced(FORCE OpenCV_LIB_DIR_OPT OpenCV_LIB_DIR_DBG OpenCV_3RDPARTY_LIB_DIR_OPT OpenCV_3RDPARTY_LIB_DIR_DBG OpenCV_CONFIG_PATH)
 105
 106 # ======================================================
 107 #  Version variables:
 108 # ======================================================
 109 SET(OpenCV_VERSION @OPENCV_VERSION_PLAIN@)
 110 SET(OpenCV_VERSION_MAJOR  @OPENCV_VERSION_MAJOR@)
 111 SET(OpenCV_VERSION_MINOR  @OPENCV_VERSION_MINOR@)
 112 SET(OpenCV_VERSION_PATCH  @OPENCV_VERSION_PATCH@)
 113 SET(OpenCV_VERSION_TWEAK  @OPENCV_VERSION_TWEAK@)
 114 SET(OpenCV_VERSION_STATUS "@OPENCV_VERSION_STATUS@")
 115
 116 # ====================================================================
 117 # Link libraries: e.g. opencv_core;opencv_imgproc; etc...
 118 # ====================================================================
 119
 120 SET(OpenCV_LIB_COMPONENTS @OPENCV_MODULES_CONFIGCMAKE@)
 121
 122 # ==============================================================
 123 #  Extra include directories, needed by OpenCV 2 new structure
 124 # ==============================================================
 125 SET(OpenCV2_INCLUDE_DIRS @OpenCV2_INCLUDE_DIRS_CONFIGCMAKE@)
 126 if(OpenCV2_INCLUDE_DIRS)
 127   list(APPEND OpenCV_INCLUDE_DIRS ${OpenCV2_INCLUDE_DIRS})
 128
 129   set(OpenCV_ADD_DEBUG_RELEASE @OpenCV_ADD_DEBUG_RELEASE_CONFIGCMAKE@)
 130   if(OpenCV_ADD_DEBUG_RELEASE)
 131     set(OpenCV_LIB_DIR_OPT "${OpenCV_LIB_DIR_OPT}/Release")
 132     set(OpenCV_LIB_DIR_DBG "${OpenCV_LIB_DIR_DBG}/Debug")
 133     set(OpenCV_3RDPARTY_LIB_DIR_OPT "${OpenCV_3RDPARTY_LIB_DIR_OPT}/Release")
 134     set(OpenCV_3RDPARTY_LIB_DIR_DBG "${OpenCV_3RDPARTY_LIB_DIR_DBG}/Debug")
 135   endif()
 136 endif()
 137
 138 # ==============================================================
 139 #  Check OpenCV availability
 140 # ==============================================================
 141 if(ANDROID AND OpenCV_ANDROID_NATIVE_API_LEVEL GREATER ANDROID_NATIVE_API_LEVEL)
 142   message(FATAL_ERROR "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 143   #always FATAL_ERROR because we can't say to the caller that OpenCV is not found
 144   #http://www.mail-archive.com/cmake@cmake.org/msg37831.html
 145   if(OpenCV_FIND_REQUIRED)
 146     message(FATAL_ERROR "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 147   elseif(NOT OpenCV_FIND_QUIETLY)
 148     message(WARNING "Minimum required by OpenCV API level is android-${OpenCV_ANDROID_NATIVE_API_LEVEL}")
 149   endif()
 150   set(OpenCV_FOUND "OpenCV_FOUND-NOTFOUND")
 151   return()#Android toolchain requires CMake > 2.6
 152 endif()
 153
 154 # ==============================================================
 155 #  Form list of modules (components) to find
 156 # ==============================================================
 157 if(NOT OpenCV_FIND_COMPONENTS)
 158   set(OpenCV_FIND_COMPONENTS ${OpenCV_LIB_COMPONENTS})
 159   list(REMOVE_ITEM OpenCV_FIND_COMPONENTS opencv_java)
 160   if(GTest_FOUND OR GTEST_FOUND)
 161     list(REMOVE_ITEM OpenCV_FIND_COMPONENTS opencv_ts)
 162   endif()
 163 endif()
 164
 165 # expand short module names and see if requested components exist
 166 set(OpenCV_FIND_COMPONENTS_ "")
 167 foreach(__cvcomponent ${OpenCV_FIND_COMPONENTS})
 168   if(NOT __cvcomponent MATCHES "^opencv_")
 169     set(__cvcomponent opencv_${__cvcomponent})
 170   endif()
 171   list(FIND OpenCV_LIB_COMPONENTS ${__cvcomponent} __cvcomponentIdx)
 172   if(__cvcomponentIdx LESS 0)
 173     #requested component is not found...
 174     if(OpenCV_FIND_REQUIRED)
 175       message(FATAL_ERROR "${__cvcomponent} is required but was not found")
 176     elseif(NOT OpenCV_FIND_QUIETLY)
 177       message(WARNING "${__cvcomponent} is required but was not found")
 178     endif()
 179     #indicate that module is NOT found
 180     string(TOUPPER "${__cvcomponent}" __cvcomponent)
 181     set(${__cvcomponent}_FOUND "${__cvcomponent}_FOUND-NOTFOUND")
 182   else()
 183     list(APPEND OpenCV_FIND_COMPONENTS_ ${__cvcomponent})
 184     #indicate that module is found
 185     string(TOUPPER "${__cvcomponent}" __cvcomponent)
 186     set(${__cvcomponent}_FOUND 1)
 187   endif()
 188 endforeach()
 189 set(OpenCV_FIND_COMPONENTS ${OpenCV_FIND_COMPONENTS_})
 190
 191 # ==============================================================
 192 #  Resolve dependencies
 193 # ==============================================================
 194 if(OpenCV_USE_MANGLED_PATHS)
 195   set(OpenCV_LIB_SUFFIX ".${OpenCV_VERSION_MAJOR}.${OpenCV_VERSION_MINOR}.${OpenCV_VERSION_PATCH}")
 196 else()
 197   set(OpenCV_LIB_SUFFIX "")
 198 endif()
 199
 200 SET(OpenCV_LIBS "${OpenCV_LIB_COMPONENTS}")
 201
 202 foreach(__opttype OPT DBG)
 203   SET(OpenCV_LIBS_${__opttype} "${OpenCV_LIBS}")
 204   SET(OpenCV_EXTRA_LIBS_${__opttype} "")
 205
 206   # CUDA
 207   if(OpenCV_CUDA_VERSION AND (CMAKE_CROSSCOMPILING OR (WIN32 AND NOT OpenCV_SHARED)))
 208     if(NOT CUDA_FOUND)
 209       find_package(CUDA ${OpenCV_CUDA_VERSION} EXACT REQUIRED)
 210     else()
 211       if(NOT CUDA_VERSION_STRING VERSION_EQUAL OpenCV_CUDA_VERSION)
 212         message(FATAL_ERROR "OpenCV static library was compiled with CUDA ${OpenCV_CUDA_VERSION} support. Please, use the same version or rebuild OpenCV with CUDA ${CUDA_VERSION_STRING}")
 213       endif()
 214     endif()
 215
 216     list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_LIBRARIES})
 217
 218     if(${CUDA_VERSION} VERSION_LESS "5.5")
 219       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_npp_LIBRARY})
 220     else()
 221       find_cuda_helper_libs(nppc)
 222       find_cuda_helper_libs(nppi)
 223       find_cuda_helper_libs(npps)
 224       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_nppc_LIBRARY} ${CUDA_nppi_LIBRARY} ${CUDA_npps_LIBRARY})
 225     endif()
 226
 227     if(OpenCV_USE_CUBLAS)
 228       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_CUBLAS_LIBRARIES})
 229     endif()
 230
 231     if(OpenCV_USE_CUFFT)
 232       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_CUFFT_LIBRARIES})
 233     endif()
 234
 235     if(OpenCV_USE_NVCUVID)
 236       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_nvcuvid_LIBRARIES})
 237     endif()
 238
 239     if(WIN32)
 240       list(APPEND OpenCV_EXTRA_LIBS_${__opttype} ${CUDA_nvcuvenc_LIBRARIES})
 241     endif()
 242   endif()
 243 endforeach()
 244
 245 # ==============================================================
 246 #  Android camera helper macro
 247 # ==============================================================
 248 if(OpenCV_HAVE_ANDROID_CAMERA)
 249   macro(COPY_NATIVE_CAMERA_LIBS target)
 250     get_target_property(target_location ${target} LOCATION)
 251     get_filename_component(target_location "${target_location}" PATH)
 252     file(GLOB camera_wrappers "${OpenCV_LIB_DIR_OPT}/libnative_camera_r*.so")
 253     foreach(wrapper ${camera_wrappers})
 254       add_custom_command(
 255         TARGET ${target}
 256         POST_BUILD
 257         COMMAND ${CMAKE_COMMAND} -E copy "${wrapper}" "${target_location}"
 258       )
 259     endforeach()
 260   endmacro()
 261 endif()
 262
 263 # ==============================================================
 264 # Compatibility stuff
 265 # ==============================================================
 266 if(CMAKE_BUILD_TYPE MATCHES "Debug")
 267   SET(OpenCV_LIB_DIR ${OpenCV_LIB_DIR_DBG} ${OpenCV_3RDPARTY_LIB_DIR_DBG})
 268 else()
 269   SET(OpenCV_LIB_DIR ${OpenCV_LIB_DIR_OPT} ${OpenCV_3RDPARTY_LIB_DIR_OPT})
 270 endif()
 271 set(OpenCV_LIBRARIES ${OpenCV_LIBS})
 272
 273 if(CMAKE_CROSSCOMPILING AND OpenCV_SHARED AND (CMAKE_SYSTEM_NAME MATCHES "Linux"))
 274   foreach(dir ${OpenCV_LIB_DIR})
 275     set(CMAKE_EXE_LINKER_FLAGS    "${CMAKE_EXE_LINKER_FLAGS}    -Wl,-rpath-link,${dir}")
 276     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-rpath-link,${dir}")
 277     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-rpath-link,${dir}")
 278   endforeach()
 279 endif()
 280
 281
 282
 283 #
 284 # Some macroses for samples
 285 #
 286 macro(ocv_check_dependencies)
 287   set(OCV_DEPENDENCIES_FOUND TRUE)
 288   foreach(d ${ARGN})
 289     if(NOT TARGET ${d})
 290       set(OCV_DEPENDENCIES_FOUND FALSE)
 291       break()
 292     endif()
 293   endforeach()
 294 endmacro()
 295
 296 # adds include directories in such way that directories from the OpenCV source tree go first
 297 function(ocv_include_directories)
 298   set(__add_before "")
 299   file(TO_CMAKE_PATH "${OpenCV_DIR}" __baseDir)
 300   foreach(dir ${ARGN})
 301     get_filename_component(__abs_dir "${dir}" ABSOLUTE)
 302     if("${__abs_dir}" MATCHES "^${__baseDir}")
 303       list(APPEND __add_before "${dir}")
 304     else()
 305       include_directories(AFTER SYSTEM "${dir}")
 306     endif()
 307   endforeach()
 308   include_directories(BEFORE ${__add_before})
 309 endfunction()
 310
 311 macro(ocv_include_modules)
 312   include_directories(BEFORE "${OpenCV_INCLUDE_DIRS}")
 313 endmacro()
 314
 315 # remove all matching elements from the list
 316 macro(ocv_list_filterout lst regex)
 317   foreach(item ${${lst}})
 318     if(item MATCHES "${regex}")
 319       list(REMOVE_ITEM ${lst} "${item}")
 320     endif()
 321   endforeach()
 322 endmacro()