cmake/modules/FindRuby.cmake

   1 # - Find Ruby
   2 # This module finds if Ruby is installed and determines where the include files
   3 # and libraries are. Ruby 1.8 and 1.9 are supported.
   4 #
   5 # The minimum required version of Ruby can be specified using the
   6 # standard syntax, e.g. FIND_PACKAGE(Ruby 1.8)
   7 #
   8 # It also determines what the name of the library is. This
   9 # code sets the following variables:
  10 #
  11 #  RUBY_EXECUTABLE   = full path to the ruby binary
  12 #  RUBY_INCLUDE_DIRS = include dirs to be used when using the ruby library
  13 #  RUBY_LIBRARY      = full path to the ruby library
  14 #  RUBY_VERSION      = the version of ruby which was found, e.g. "1.8.7"
  15 #  RUBY_FOUND        = set to true if ruby ws found successfully
  16 #
  17 #  RUBY_INCLUDE_PATH = same as RUBY_INCLUDE_DIRS, only provided for compatibility reasons, don't use it
  18
  19 #=============================================================================
  20 # Copyright 2004-2009 Kitware, Inc.
  21 # Copyright 2008-2009 Alexander Neundorf <neundorf@kde.org>
  22 #
  23 # Redistribution and use in source and binary forms, with or without
  24 # modification, are permitted provided that the following conditions
  25 # are met:
  26 #
  27 # * Redistributions of source code must retain the above copyright
  28 #   notice, this list of conditions and the following disclaimer.
  29 #
  30 # * Redistributions in binary form must reproduce the above copyright
  31 #   notice, this list of conditions and the following disclaimer in the
  32 #   documentation and/or other materials provided with the distribution.
  33 #
  34 # * Neither the names of Kitware, Inc., the Insight Software Consortium,
  35 #   nor the names of their contributors may be used to endorse or promote
  36 #   products derived from this software without specific prior written
  37 #   permission.
  38 #
  39 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  40 # "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  41 # LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  42 # A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  43 # HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  44 # SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  45 # LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  46 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  47 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  48 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  49 # OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  50 #=============================================================================
  51
  52 #   RUBY_ARCHDIR=`$RUBY -r rbconfig -e 'printf("%s",Config::CONFIG@<:@"archdir"@:>@)'`
  53 #   RUBY_SITEARCHDIR=`$RUBY -r rbconfig -e 'printf("%s",Config::CONFIG@<:@"sitearchdir"@:>@)'`
  54 #   RUBY_SITEDIR=`$RUBY -r rbconfig -e 'printf("%s",Config::CONFIG@<:@"sitelibdir"@:>@)'`
  55 #   RUBY_LIBDIR=`$RUBY -r rbconfig -e 'printf("%s",Config::CONFIG@<:@"libdir"@:>@)'`
  56 #   RUBY_LIBRUBYARG=`$RUBY -r rbconfig -e 'printf("%s",Config::CONFIG@<:@"LIBRUBYARG_SHARED"@:>@)'`
  57
  58 # uncomment the following line to get debug output for this file
  59 # SET(_RUBY_DEBUG_OUTPUT TRUE)
  60
  61 # Determine the list of possible names of the ruby executable depending
  62 # on which version of ruby is required
  63 SET(_RUBY_POSSIBLE_EXECUTABLE_NAMES ruby)
  64
  65 # if 1.9 is required, don't look for ruby18 and ruby1.8, default to version 1.8
  66 IF(Ruby_FIND_VERSION_MAJOR  AND  Ruby_FIND_VERSION_MINOR)
  67    SET(Ruby_FIND_VERSION_SHORT_NODOT "${Ruby_FIND_VERSION_MAJOR}${RUBY_FIND_VERSION_MINOR}")
  68 ELSE(Ruby_FIND_VERSION_MAJOR  AND  Ruby_FIND_VERSION_MINOR)
  69    SET(Ruby_FIND_VERSION_SHORT_NODOT "18")
  70 ENDIF(Ruby_FIND_VERSION_MAJOR  AND  Ruby_FIND_VERSION_MINOR)
  71
  72 SET(_RUBY_POSSIBLE_EXECUTABLE_NAMES ${_RUBY_POSSIBLE_EXECUTABLE_NAMES} ruby1.9 ruby19)
  73
  74 # if we want a version below 1.9, also look for ruby 1.8
  75 IF("${Ruby_FIND_VERSION_SHORT_NODOT}" VERSION_LESS "19")
  76    SET(_RUBY_POSSIBLE_EXECUTABLE_NAMES ${_RUBY_POSSIBLE_EXECUTABLE_NAMES} ruby1.8 ruby18)
  77 ENDIF("${Ruby_FIND_VERSION_SHORT_NODOT}" VERSION_LESS "19")
  78
  79 FIND_PROGRAM(RUBY_EXECUTABLE NAMES ${_RUBY_POSSIBLE_EXECUTABLE_NAMES})
  80
  81
  82 IF(RUBY_EXECUTABLE  AND NOT  RUBY_VERSION_MAJOR)
  83   FUNCTION(_RUBY_CONFIG_VAR RBVAR OUTVAR)
  84     EXECUTE_PROCESS(COMMAND ${RUBY_EXECUTABLE} -r rbconfig -e "print RbConfig::CONFIG['${RBVAR}']"
  85       RESULT_VARIABLE _RUBY_SUCCESS
  86       OUTPUT_VARIABLE _RUBY_OUTPUT
  87       ERROR_QUIET)
  88     IF(_RUBY_SUCCESS OR NOT _RUBY_OUTPUT)
  89       EXECUTE_PROCESS(COMMAND ${RUBY_EXECUTABLE} -r rbconfig -e "print Config::CONFIG['${RBVAR}']"
  90         RESULT_VARIABLE _RUBY_SUCCESS
  91         OUTPUT_VARIABLE _RUBY_OUTPUT
  92         ERROR_QUIET)
  93     ENDIF(_RUBY_SUCCESS OR NOT _RUBY_OUTPUT)
  94     SET(${OUTVAR} "${_RUBY_OUTPUT}" PARENT_SCOPE)
  95   ENDFUNCTION(_RUBY_CONFIG_VAR)
  96
  97
  98   # query the ruby version
  99    _RUBY_CONFIG_VAR("MAJOR" RUBY_VERSION_MAJOR)
 100    _RUBY_CONFIG_VAR("MINOR" RUBY_VERSION_MINOR)
 101    _RUBY_CONFIG_VAR("TEENY" RUBY_VERSION_PATCH)
 102
 103    # query the different directories
 104    _RUBY_CONFIG_VAR("archdir" RUBY_ARCH_DIR)
 105    _RUBY_CONFIG_VAR("arch" RUBY_ARCH)
 106    _RUBY_CONFIG_VAR("rubyhdrdir" RUBY_HDR_DIR)
 107    _RUBY_CONFIG_VAR("libdir" RUBY_POSSIBLE_LIB_DIR)
 108    _RUBY_CONFIG_VAR("rubylibdir" RUBY_RUBY_LIB_DIR)
 109
 110    # site_ruby
 111    _RUBY_CONFIG_VAR("sitearchdir" RUBY_SITEARCH_DIR)
 112    _RUBY_CONFIG_VAR("sitelibdir" RUBY_SITELIB_DIR)
 113
 114    # vendor_ruby available ?
 115    EXECUTE_PROCESS(COMMAND ${RUBY_EXECUTABLE} -r rbconfig -e "print 'true' unless Config::CONFIG['vendorarchdir'].nil?"
 116       OUTPUT_VARIABLE RUBY_HAS_VENDOR_RUBY  ERROR_QUIET)
 117
 118    IF(RUBY_HAS_VENDOR_RUBY)
 119       _RUBY_CONFIG_VAR("vendorlibdir" RUBY_VENDORLIB_DIR)
 120       _RUBY_CONFIG_VAR("vendorarchdir" RUBY_VENDORARCH_DIR)
 121    ENDIF(RUBY_HAS_VENDOR_RUBY)
 122
 123    # save the results in the cache so we don't have to run ruby the next time again
 124    SET(RUBY_VERSION_MAJOR    ${RUBY_VERSION_MAJOR}    CACHE PATH "The Ruby major version" FORCE)
 125    SET(RUBY_VERSION_MINOR    ${RUBY_VERSION_MINOR}    CACHE PATH "The Ruby minor version" FORCE)
 126    SET(RUBY_VERSION_PATCH    ${RUBY_VERSION_PATCH}    CACHE PATH "The Ruby patch version" FORCE)
 127    SET(RUBY_ARCH_DIR         ${RUBY_ARCH_DIR}         CACHE PATH "The Ruby arch dir" FORCE)
 128    SET(RUBY_HDR_DIR          ${RUBY_HDR_DIR}          CACHE PATH "The Ruby header dir (1.9)" FORCE)
 129    SET(RUBY_POSSIBLE_LIB_DIR ${RUBY_POSSIBLE_LIB_DIR} CACHE PATH "The Ruby lib dir" FORCE)
 130    SET(RUBY_RUBY_LIB_DIR     ${RUBY_RUBY_LIB_DIR}     CACHE PATH "The Ruby ruby-lib dir" FORCE)
 131    SET(RUBY_SITEARCH_DIR     ${RUBY_SITEARCH_DIR}     CACHE PATH "The Ruby site arch dir" FORCE)
 132    SET(RUBY_SITELIB_DIR      ${RUBY_SITELIB_DIR}      CACHE PATH "The Ruby site lib dir" FORCE)
 133    SET(RUBY_HAS_VENDOR_RUBY  ${RUBY_HAS_VENDOR_RUBY}  CACHE BOOL "Vendor Ruby is available" FORCE)
 134    SET(RUBY_VENDORARCH_DIR   ${RUBY_VENDORARCH_DIR}   CACHE PATH "The Ruby vendor arch dir" FORCE)
 135    SET(RUBY_VENDORLIB_DIR    ${RUBY_VENDORLIB_DIR}    CACHE PATH "The Ruby vendor lib dir" FORCE)
 136
 137    MARK_AS_ADVANCED(
 138      RUBY_ARCH_DIR
 139      RUBY_ARCH
 140      RUBY_HDR_DIR
 141      RUBY_POSSIBLE_LIB_DIR
 142      RUBY_RUBY_LIB_DIR
 143      RUBY_SITEARCH_DIR
 144      RUBY_SITELIB_DIR
 145      RUBY_HAS_VENDOR_RUBY
 146      RUBY_VENDORARCH_DIR
 147      RUBY_VENDORLIB_DIR
 148      RUBY_VERSION_MAJOR
 149      RUBY_VERSION_MINOR
 150      RUBY_VERSION_PATCH
 151      )
 152 ENDIF(RUBY_EXECUTABLE  AND NOT  RUBY_VERSION_MAJOR)
 153
 154 # In case RUBY_EXECUTABLE could not be executed (e.g. cross compiling)
 155 # try to detect which version we found. This is not too good.
 156 IF(RUBY_EXECUTABLE AND NOT RUBY_VERSION_MAJOR)
 157    # by default assume 1.8.0
 158    SET(RUBY_VERSION_MAJOR 1)
 159    SET(RUBY_VERSION_MINOR 8)
 160    SET(RUBY_VERSION_PATCH 0)
 161    # check whether we found 1.9.x
 162    IF(${RUBY_EXECUTABLE} MATCHES "ruby1.?9"  OR  RUBY_HDR_DIR)
 163       SET(RUBY_VERSION_MAJOR 1)
 164       SET(RUBY_VERSION_MINOR 9)
 165    ENDIF(${RUBY_EXECUTABLE} MATCHES "ruby1.?9"  OR  RUBY_HDR_DIR)
 166 ENDIF(RUBY_EXECUTABLE AND NOT RUBY_VERSION_MAJOR)
 167
 168 IF(RUBY_VERSION_MAJOR)
 169    SET(RUBY_VERSION "${RUBY_VERSION_MAJOR}.${RUBY_VERSION_MINOR}.${RUBY_VERSION_PATCH}")
 170    SET(_RUBY_VERSION_SHORT "${RUBY_VERSION_MAJOR}.${RUBY_VERSION_MINOR}")
 171    SET(_RUBY_VERSION_SHORT_NODOT "${RUBY_VERSION_MAJOR}${RUBY_VERSION_MINOR}")
 172    SET(_RUBY_NODOT_VERSION "${RUBY_VERSION_MAJOR}${RUBY_VERSION_MINOR}${RUBY_VERSION_PATCH}")
 173 ENDIF(RUBY_VERSION_MAJOR)
 174
 175 FIND_PATH(RUBY_INCLUDE_DIR
 176    NAMES ruby.h
 177    HINTS
 178    ${RUBY_HDR_DIR}
 179    ${RUBY_ARCH_DIR}
 180    /usr/lib/ruby/${_RUBY_VERSION_SHORT}/i586-linux-gnu/ )
 181
 182 SET(RUBY_INCLUDE_DIRS ${RUBY_INCLUDE_DIR} )
 183
 184 # if ruby > 1.8 is required or if ruby > 1.8 was found, search for the config.h dir
 185 IF( "${Ruby_FIND_VERSION_SHORT_NODOT}" GREATER 18  OR  "${_RUBY_VERSION_SHORT_NODOT}" GREATER 18  OR  RUBY_HDR_DIR)
 186    FIND_PATH(RUBY_CONFIG_INCLUDE_DIR
 187      NAMES ruby/config.h  config.h
 188      HINTS
 189      ${RUBY_HDR_DIR}/${RUBY_ARCH}
 190      ${RUBY_ARCH_DIR}
 191      )
 192
 193    SET(RUBY_INCLUDE_DIRS ${RUBY_INCLUDE_DIRS} ${RUBY_CONFIG_INCLUDE_DIR} )
 194 ENDIF( "${Ruby_FIND_VERSION_SHORT_NODOT}" GREATER 18  OR  "${_RUBY_VERSION_SHORT_NODOT}" GREATER 18  OR  RUBY_HDR_DIR)
 195
 196
 197 # Determine the list of possible names for the ruby library
 198 SET(_RUBY_POSSIBLE_LIB_NAMES ruby ruby-static ruby${_RUBY_VERSION_SHORT} ruby${_RUBY_VERSION_SHORT_NODOT} ruby-${_RUBY_VERSION_SHORT} ruby-${RUBY_VERSION})
 199
 200 IF(WIN32)
 201    SET( _RUBY_MSVC_RUNTIME "" )
 202    IF( MSVC60 )
 203      SET( _RUBY_MSVC_RUNTIME "60" )
 204    ENDIF( MSVC60 )
 205    IF( MSVC70 )
 206      SET( _RUBY_MSVC_RUNTIME "70" )
 207    ENDIF( MSVC70 )
 208    IF( MSVC71 )
 209      SET( _RUBY_MSVC_RUNTIME "71" )
 210    ENDIF( MSVC71 )
 211    IF( MSVC80 )
 212      SET( _RUBY_MSVC_RUNTIME "80" )
 213    ENDIF( MSVC80 )
 214    IF( MSVC90 )
 215      SET( _RUBY_MSVC_RUNTIME "90" )
 216    ENDIF( MSVC90 )
 217
 218    LIST(APPEND _RUBY_POSSIBLE_LIB_NAMES
 219                "msvcr${_RUBY_MSVC_RUNTIME}-ruby${_RUBY_NODOT_VERSION}"
 220                "msvcr${_RUBY_MSVC_RUNTIME}-ruby${_RUBY_NODOT_VERSION}-static"
 221                "msvcrt-ruby${_RUBY_NODOT_VERSION}"
 222                "msvcrt-ruby${_RUBY_NODOT_VERSION}-static" )
 223 ENDIF(WIN32)
 224
 225 FIND_LIBRARY(RUBY_LIBRARY NAMES ${_RUBY_POSSIBLE_LIB_NAMES} HINTS ${RUBY_POSSIBLE_LIB_DIR} )
 226
 227 INCLUDE(FindPackageHandleStandardArgs)
 228 SET(_RUBY_REQUIRED_VARS RUBY_EXECUTABLE RUBY_INCLUDE_DIR RUBY_LIBRARY)
 229 IF(_RUBY_VERSION_SHORT_NODOT GREATER 18)
 230    LIST(APPEND _RUBY_REQUIRED_VARS RUBY_CONFIG_INCLUDE_DIR)
 231 ENDIF(_RUBY_VERSION_SHORT_NODOT GREATER 18)
 232
 233 IF(_RUBY_DEBUG_OUTPUT)
 234    MESSAGE(STATUS "--------FindRuby.cmake debug------------")
 235    MESSAGE(STATUS "_RUBY_POSSIBLE_EXECUTABLE_NAMES: ${_RUBY_POSSIBLE_EXECUTABLE_NAMES}")
 236    MESSAGE(STATUS "_RUBY_POSSIBLE_LIB_NAMES: ${_RUBY_POSSIBLE_LIB_NAMES}")
 237    MESSAGE(STATUS "RUBY_ARCH_DIR: ${RUBY_ARCH_DIR}")
 238    MESSAGE(STATUS "RUBY_HDR_DIR: ${RUBY_HDR_DIR}")
 239    MESSAGE(STATUS "RUBY_POSSIBLE_LIB_DIR: ${RUBY_POSSIBLE_LIB_DIR}")
 240    MESSAGE(STATUS "Found RUBY_VERSION: \"${RUBY_VERSION}\" , short: \"${_RUBY_VERSION_SHORT}\", nodot: \"${_RUBY_VERSION_SHORT_NODOT}\"")
 241    MESSAGE(STATUS "_RUBY_REQUIRED_VARS: ${_RUBY_REQUIRED_VARS}")
 242    MESSAGE(STATUS "RUBY_EXECUTABLE: ${RUBY_EXECUTABLE}")
 243    MESSAGE(STATUS "RUBY_LIBRARY: ${RUBY_LIBRARY}")
 244    MESSAGE(STATUS "RUBY_INCLUDE_DIR: ${RUBY_INCLUDE_DIR}")
 245    MESSAGE(STATUS "RUBY_CONFIG_INCLUDE_DIR: ${RUBY_CONFIG_INCLUDE_DIR}")
 246    MESSAGE(STATUS "--------------------")
 247 ENDIF(_RUBY_DEBUG_OUTPUT)
 248
 249 FIND_PACKAGE_HANDLE_STANDARD_ARGS(Ruby  REQUIRED_VARS  ${_RUBY_REQUIRED_VARS}
 250                                         VERSION_VAR RUBY_VERSION )
 251
 252 MARK_AS_ADVANCED(
 253   RUBY_EXECUTABLE
 254   RUBY_LIBRARY
 255   RUBY_INCLUDE_DIR
 256   RUBY_CONFIG_INCLUDE_DIR
 257   )
 258
 259 # Set some variables for compatibility with previous version of this file
 260 SET(RUBY_POSSIBLE_LIB_PATH ${RUBY_POSSIBLE_LIB_DIR})
 261 SET(RUBY_RUBY_LIB_PATH ${RUBY_RUBY_LIB_DIR})
 262 SET(RUBY_INCLUDE_PATH ${RUBY_INCLUDE_DIRS})