cmake/lint.cmake

   1
   2 set(CMAKE_SOURCE_DIR ..)
   3 set(LINT_COMMAND ${CMAKE_SOURCE_DIR}/scripts/cpp_lint.py)
   4 set(SRC_FILE_EXTENSIONS h hpp hu c cpp cu cc)
   5 set(EXCLUDE_FILE_EXTENSTIONS pb.h pb.cc)
   6 set(LINT_DIRS include src/caffe examples tools python matlab)
   7
   8 cmake_policy(SET CMP0009 NEW)  # suppress cmake warning
   9
  10 # find all files of interest
  11 foreach(ext ${SRC_FILE_EXTENSIONS})
  12     foreach(dir ${LINT_DIRS})
  13         file(GLOB_RECURSE FOUND_FILES ${CMAKE_SOURCE_DIR}/${dir}/*.${ext})
  14         set(LINT_SOURCES ${LINT_SOURCES} ${FOUND_FILES})
  15     endforeach()
  16 endforeach()
  17
  18 # find all files that should be excluded
  19 foreach(ext ${EXCLUDE_FILE_EXTENSTIONS})
  20     file(GLOB_RECURSE FOUND_FILES ${CMAKE_SOURCE_DIR}/*.${ext})
  21     set(EXCLUDED_FILES ${EXCLUDED_FILES} ${FOUND_FILES})
  22 endforeach()
  23
  24 # exclude generated pb files
  25 list(REMOVE_ITEM LINT_SOURCES ${EXCLUDED_FILES})
  26
  27 execute_process(
  28     COMMAND ${LINT_COMMAND} ${LINT_SOURCES}
  29     ERROR_VARIABLE LINT_OUTPUT
  30     ERROR_STRIP_TRAILING_WHITESPACE
  31 )
  32
  33 string(REPLACE "\n" ";" LINT_OUTPUT ${LINT_OUTPUT})
  34
  35 list(GET LINT_OUTPUT -1 LINT_RESULT)
  36 list(REMOVE_AT LINT_OUTPUT -1)
  37 string(REPLACE " " ";" LINT_RESULT ${LINT_RESULT})
  38 list(GET LINT_RESULT -1 NUM_ERRORS)
  39 if(NUM_ERRORS GREATER 0)
  40     foreach(msg ${LINT_OUTPUT})
  41         string(FIND ${msg} "Done" result)
  42         if(result LESS 0)
  43             message(STATUS ${msg})
  44         endif()
  45     endforeach()
  46     message(FATAL_ERROR "Lint found ${NUM_ERRORS} errors!")
  47 else()
  48     message(STATUS "Lint did not find any errors!")
  49 endif()
  50