cmake/iOSToolchain.cmake

   1 # This file is based off of the Platform/Darwin.cmake and Platform/UnixPaths.cmake
   2 # files which are included with CMake 2.8.4
   3 # It has been altered for iOS development
   4
   5 # Options:
   6 #
   7 # IOS_PLATFORM = OS (default) or SIMULATOR
   8 #   This decides if SDKS will be selected from the iPhoneOS.platform or iPhoneSimulator.platform folders
   9 #   OS - the default, used to build for iPhone and iPad physical devices, which have an arm arch.
  10 #   SIMULATOR - used to build for the Simulator platforms, which have an x86 arch.
  11 #
  12 # CMAKE_IOS_DEVELOPER_ROOT = automatic(default) or /path/to/platform/Developer folder
  13 #   By default this location is automatcially chosen based on the IOS_PLATFORM value above.
  14 #   If set manually, it will override the default location and force the user of a particular Developer Platform
  15 #
  16 # CMAKE_IOS_SDK_ROOT = automatic(default) or /path/to/platform/Developer/SDKs/SDK folder
  17 #   By default this location is automatcially chosen based on the CMAKE_IOS_DEVELOPER_ROOT value.
  18 #   In this case it will always be the most up-to-date SDK found in the CMAKE_IOS_DEVELOPER_ROOT path.
  19 #   If set manually, this will force the use of a specific SDK version
  20
  21 # Macros:
  22 #
  23 # set_xcode_property (TARGET XCODE_PROPERTY XCODE_VALUE)
  24 #  A convenience macro for setting xcode specific properties on targets
  25 #  example: set_xcode_property (myioslib IPHONEOS_DEPLOYMENT_TARGET "3.1")
  26 #
  27 # find_host_package (PROGRAM ARGS)
  28 #  A macro used to find executable programs on the host system, not within the iOS environment.
  29 #  Thanks to the android-cmake project for providing the command
  30
  31
  32 # Standard settings
  33 set (CMAKE_SYSTEM_NAME Darwin)
  34 set (CMAKE_SYSTEM_VERSION 1)
  35 set (UNIX True)
  36 set (APPLE True)
  37 set (IOS True)
  38
  39 # Required as of cmake 2.8.10
  40 set (CMAKE_OSX_DEPLOYMENT_TARGET "" CACHE STRING "Force unset of the deployment target for iOS" FORCE)
  41
  42 # Determine the cmake host system version so we know where to find the iOS SDKs
  43 find_program (CMAKE_UNAME uname /bin /usr/bin /usr/local/bin)
  44 if (CMAKE_UNAME)
  45         exec_program(uname ARGS -r OUTPUT_VARIABLE CMAKE_HOST_SYSTEM_VERSION)
  46         string (REGEX REPLACE "^([0-9]+)\\.([0-9]+).*$" "\\1" DARWIN_MAJOR_VERSION "${CMAKE_HOST_SYSTEM_VERSION}")
  47 endif (CMAKE_UNAME)
  48
  49 # Force the compilers to gcc for iOS
  50 if(NOT CMAKE_C_COMPILER)
  51         include (CMakeForceCompiler)
  52         CMAKE_FORCE_C_COMPILER (gcc GNU)
  53         CMAKE_FORCE_CXX_COMPILER (g++ GNU)
  54 endif()
  55
  56 # Skip the platform compiler checks for cross compiling
  57 #set (CMAKE_CXX_COMPILER_WORKS TRUE)
  58 #set (CMAKE_C_COMPILER_WORKS TRUE)
  59
  60 # All iOS/Darwin specific settings - some may be redundant
  61 set (CMAKE_SHARED_LIBRARY_PREFIX "lib")
  62 set (CMAKE_SHARED_LIBRARY_SUFFIX ".dylib")
  63 set (CMAKE_SHARED_MODULE_PREFIX "lib")
  64 set (CMAKE_SHARED_MODULE_SUFFIX ".so")
  65 set (CMAKE_MODULE_EXISTS 1)
  66 set (CMAKE_DL_LIBS "")
  67
  68 set (CMAKE_C_OSX_COMPATIBILITY_VERSION_FLAG "-compatibility_version ")
  69 set (CMAKE_C_OSX_CURRENT_VERSION_FLAG "-current_version ")
  70 set (CMAKE_CXX_OSX_COMPATIBILITY_VERSION_FLAG "${CMAKE_C_OSX_COMPATIBILITY_VERSION_FLAG}")
  71 set (CMAKE_CXX_OSX_CURRENT_VERSION_FLAG "${CMAKE_C_OSX_CURRENT_VERSION_FLAG}")
  72
  73 # Hidden visibilty is required for cxx on iOS
  74 set (CMAKE_C_FLAGS_INIT "")
  75 set (CMAKE_CXX_FLAGS_INIT "-headerpad_max_install_names -fvisibility=hidden -fvisibility-inlines-hidden")
  76
  77 set (CMAKE_C_LINK_FLAGS "-Wl,-search_paths_first ${CMAKE_C_LINK_FLAGS}")
  78 set (CMAKE_CXX_LINK_FLAGS "-Wl,-search_paths_first ${CMAKE_CXX_LINK_FLAGS}")
  79
  80 set (CMAKE_PLATFORM_HAS_INSTALLNAME 1)
  81 set (CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "-dynamiclib -headerpad_max_install_names")
  82 set (CMAKE_SHARED_MODULE_CREATE_C_FLAGS "-bundle -headerpad_max_install_names")
  83 set (CMAKE_SHARED_MODULE_LOADER_C_FLAG "-Wl,-bundle_loader,")
  84 set (CMAKE_SHARED_MODULE_LOADER_CXX_FLAG "-Wl,-bundle_loader,")
  85 set (CMAKE_FIND_LIBRARY_SUFFIXES ".dylib" ".so" ".a")
  86
  87 # hack: if a new cmake (which uses CMAKE_INSTALL_NAME_TOOL) runs on an old build tree
  88 # (where install_name_tool was hardcoded) and where CMAKE_INSTALL_NAME_TOOL isn't in the cache
  89 # and still cmake didn't fail in CMakeFindBinUtils.cmake (because it isn't rerun)
  90 # hardcode CMAKE_INSTALL_NAME_TOOL here to install_name_tool, so it behaves as it did before, Alex
  91 if (NOT DEFINED CMAKE_INSTALL_NAME_TOOL)
  92         find_program(CMAKE_INSTALL_NAME_TOOL install_name_tool)
  93 endif (NOT DEFINED CMAKE_INSTALL_NAME_TOOL)
  94
  95 # Setup iOS platform unless specified manually with IOS_PLATFORM
  96 if (NOT DEFINED IOS_PLATFORM)
  97         set (IOS_PLATFORM "OS")
  98 endif (NOT DEFINED IOS_PLATFORM)
  99 set (IOS_PLATFORM ${IOS_PLATFORM} CACHE STRING "Type of iOS Platform")
 100
 101 # Check the platform selection and setup for developer root
 102 if (${IOS_PLATFORM} STREQUAL "OS")
 103         set (IOS_PLATFORM_LOCATION "iPhoneOS.platform")
 104
 105         # This causes the installers to properly locate the output libraries
 106         set (CMAKE_XCODE_EFFECTIVE_PLATFORMS "-iphoneos")
 107 elseif (${IOS_PLATFORM} STREQUAL "SIMULATOR")
 108         set (IOS_PLATFORM_LOCATION "iPhoneSimulator.platform")
 109
 110         # This causes the installers to properly locate the output libraries
 111         set (CMAKE_XCODE_EFFECTIVE_PLATFORMS "-iphonesimulator")
 112 else (${IOS_PLATFORM} STREQUAL "OS")
 113         message (FATAL_ERROR "Unsupported IOS_PLATFORM value selected. Please choose OS or SIMULATOR")
 114 endif (${IOS_PLATFORM} STREQUAL "OS")
 115
 116 # Setup iOS developer location unless specified manually with CMAKE_IOS_DEVELOPER_ROOT
 117 # Note Xcode 4.3 changed the installation location, choose the most recent one available
 118 set (XCODE_POST_43_ROOT "/Applications/Xcode.app/Contents/Developer/Platforms/${IOS_PLATFORM_LOCATION}/Developer")
 119 set (XCODE_PRE_43_ROOT "/Developer/Platforms/${IOS_PLATFORM_LOCATION}/Developer")
 120 if (NOT DEFINED CMAKE_IOS_DEVELOPER_ROOT)
 121         if (EXISTS ${XCODE_POST_43_ROOT})
 122                 set (CMAKE_IOS_DEVELOPER_ROOT ${XCODE_POST_43_ROOT})
 123         elseif(EXISTS ${XCODE_PRE_43_ROOT})
 124                 set (CMAKE_IOS_DEVELOPER_ROOT ${XCODE_PRE_43_ROOT})
 125         endif (EXISTS ${XCODE_POST_43_ROOT})
 126 endif (NOT DEFINED CMAKE_IOS_DEVELOPER_ROOT)
 127 set (CMAKE_IOS_DEVELOPER_ROOT ${CMAKE_IOS_DEVELOPER_ROOT} CACHE PATH "Location of iOS Platform")
 128
 129 # Find and use the most recent iOS sdk unless specified manually with CMAKE_IOS_SDK_ROOT
 130 if (NOT DEFINED CMAKE_IOS_SDK_ROOT)
 131         file (GLOB _CMAKE_IOS_SDKS "${CMAKE_IOS_DEVELOPER_ROOT}/SDKs/*")
 132         if (_CMAKE_IOS_SDKS)
 133                 list (SORT _CMAKE_IOS_SDKS)
 134                 list (REVERSE _CMAKE_IOS_SDKS)
 135                 list (GET _CMAKE_IOS_SDKS 0 CMAKE_IOS_SDK_ROOT)
 136         else (_CMAKE_IOS_SDKS)
 137                 message (FATAL_ERROR "No iOS SDK's found in default search path ${CMAKE_IOS_DEVELOPER_ROOT}. Manually set CMAKE_IOS_SDK_ROOT or install the iOS SDK.")
 138         endif (_CMAKE_IOS_SDKS)
 139         message (STATUS "Toolchain using default iOS SDK: ${CMAKE_IOS_SDK_ROOT}")
 140 endif (NOT DEFINED CMAKE_IOS_SDK_ROOT)
 141 set (CMAKE_IOS_SDK_ROOT ${CMAKE_IOS_SDK_ROOT} CACHE PATH "Location of the selected iOS SDK")
 142
 143 # Set the sysroot default to the most recent SDK
 144 set (CMAKE_OSX_SYSROOT ${CMAKE_IOS_SDK_ROOT} CACHE PATH "Sysroot used for iOS support")
 145
 146 # set the architecture for iOS
 147 # NOTE: Currently both ARCHS_STANDARD_32_BIT and ARCHS_UNIVERSAL_IPHONE_OS set armv7 only, so set both manually
 148 if (${IOS_PLATFORM} STREQUAL "OS")
 149         set (IOS_ARCH armv7 armv7s)
 150         set (CMAKE_SYSTEM_PROCESSOR armv7)
 151 else (${IOS_PLATFORM} STREQUAL "OS")
 152         set (IOS_ARCH i386)
 153         set (CMAKE_SYSTEM_PROCESSOR i386)
 154 endif (${IOS_PLATFORM} STREQUAL "OS")
 155
 156 set (CMAKE_OSX_ARCHITECTURES ${IOS_ARCH} CACHE string  "Build architecture for iOS")
 157
 158 # Set the find root to the iOS developer roots and to user defined paths
 159 set (CMAKE_FIND_ROOT_PATH ${CMAKE_IOS_DEVELOPER_ROOT} ${CMAKE_IOS_SDK_ROOT} ${CMAKE_PREFIX_PATH} CACHE string  "iOS find search path root")
 160
 161 # default to searching for frameworks first
 162 set (CMAKE_FIND_FRAMEWORK FIRST)
 163
 164 # set up the default search directories for frameworks
 165 set (CMAKE_SYSTEM_FRAMEWORK_PATH
 166         ${CMAKE_IOS_SDK_ROOT}/System/Library/Frameworks
 167         ${CMAKE_IOS_SDK_ROOT}/System/Library/PrivateFrameworks
 168         ${CMAKE_IOS_SDK_ROOT}/Developer/Library/Frameworks
 169 )
 170
 171 # only search the iOS sdks, not the remainder of the host filesystem
 172 set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY)
 173 set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
 174 set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
 175
 176
 177 # This little macro lets you set any XCode specific property
 178 macro (set_xcode_property TARGET XCODE_PROPERTY XCODE_VALUE)
 179         set_property (TARGET ${TARGET} PROPERTY XCODE_ATTRIBUTE_${XCODE_PROPERTY} ${XCODE_VALUE})
 180 endmacro (set_xcode_property)
 181
 182
 183 # This macro lets you find executable programs on the host system
 184 macro (find_host_package)
 185         set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
 186         set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER)
 187         set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER)
 188         set (IOS FALSE)
 189
 190         find_package(${ARGN})
 191
 192         set (IOS TRUE)
 193         set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY)
 194         set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
 195         set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
 196 endmacro (find_host_package)
 197