cmake/ReadCeresVersionFromSource.cmake

   1 # Ceres Solver - A fast non-linear least squares minimizer
   2 # Copyright 2015 Google Inc. All rights reserved.
   3 # http://ceres-solver.org/
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions are met:
   7 #
   8 # * Redistributions of source code must retain the above copyright notice,
   9 #   this list of conditions and the following disclaimer.
  10 # * Redistributions in binary form must reproduce the above copyright notice,
  11 #   this list of conditions and the following disclaimer in the documentation
  12 #   and/or other materials provided with the distribution.
  13 # * Neither the name of Google Inc. nor the names of its contributors may be
  14 #   used to endorse or promote products derived from this software without
  15 #   specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  18 # AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20 # ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
  21 # LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22 # CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  23 # SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24 # INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  25 # CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  26 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  27 # POSSIBILITY OF SUCH DAMAGE.
  28 #
  29 # Author: alexs.mac@gmail.com (Alex Stewart)
  30 #
  31
  32 # Extract Ceres version from <CERES_SOURCE_ROOT>/include/ceres/version.h
  33 # so that we only have a single definition of the Ceres version, not two
  34 # one in the source and one in the CMakeLists.txt.
  35 macro(read_ceres_version_from_source CERES_SOURCE_ROOT)
  36   set(CERES_VERSION_FILE ${CERES_SOURCE_ROOT}/include/ceres/version.h)
  37   if (NOT EXISTS ${CERES_VERSION_FILE})
  38     message(FATAL_ERROR "Cannot find Ceres version.h file in specified "
  39       "Ceres source directory: ${CERES_SOURCE_ROOT}, it is not here: "
  40       "${CERES_VERSION_FILE}")
  41   endif()
  42
  43   file(READ ${CERES_VERSION_FILE} CERES_VERSION_FILE_CONTENTS)
  44
  45   string(REGEX MATCH "#define CERES_VERSION_MAJOR [0-9]+"
  46     CERES_VERSION_MAJOR "${CERES_VERSION_FILE_CONTENTS}")
  47   string(REGEX REPLACE "#define CERES_VERSION_MAJOR ([0-9]+)" "\\1"
  48     CERES_VERSION_MAJOR "${CERES_VERSION_MAJOR}")
  49   # NOTE: if (VAR) is FALSE if VAR is numeric and <= 0, as such we cannot use
  50   #       it for testing version numbers, which might well be zero, at least
  51   #       for the patch version, hence check for empty string explicitly.
  52   if ("${CERES_VERSION_MAJOR}" STREQUAL "")
  53     message(FATAL_ERROR "Failed to extract Ceres major version from "
  54       "${CERES_VERSION_FILE}")
  55   endif()
  56
  57   string(REGEX MATCH "#define CERES_VERSION_MINOR [0-9]+"
  58     CERES_VERSION_MINOR "${CERES_VERSION_FILE_CONTENTS}")
  59   string(REGEX REPLACE "#define CERES_VERSION_MINOR ([0-9]+)" "\\1"
  60     CERES_VERSION_MINOR "${CERES_VERSION_MINOR}")
  61   if ("${CERES_VERSION_MINOR}" STREQUAL "")
  62     message(FATAL_ERROR "Failed to extract Ceres minor version from "
  63       "${CERES_VERSION_FILE}")
  64   endif()
  65
  66   string(REGEX MATCH "#define CERES_VERSION_REVISION [0-9]+"
  67     CERES_VERSION_PATCH "${CERES_VERSION_FILE_CONTENTS}")
  68   string(REGEX REPLACE "#define CERES_VERSION_REVISION ([0-9]+)" "\\1"
  69     CERES_VERSION_PATCH "${CERES_VERSION_PATCH}")
  70   if ("${CERES_VERSION_PATCH}" STREQUAL "")
  71     message(FATAL_ERROR "Failed to extract Ceres patch version from "
  72       "${CERES_VERSION_FILE}")
  73   endif()
  74
  75   # This is on a single line s/t CMake does not interpret it as a list of
  76   # elements and insert ';' separators which would result in 3.;2.;0 nonsense.
  77   set(CERES_VERSION "${CERES_VERSION_MAJOR}.${CERES_VERSION_MINOR}.${CERES_VERSION_PATCH}")
  78
  79   message(STATUS "Detected Ceres version: ${CERES_VERSION} from "
  80     "${CERES_VERSION_FILE}")
  81 endmacro()