cmake/OpenCVPluginStandalone.cmake

   1 # Standalone OpenCV plugins build scripts
   2 #
   3 # Useful OpenCV common build variables:
   4 # - CMAKE_BUILD_TYPE=Release/Debug
   5 # - BUILD_WITH_DEBUG_INFO=ON
   6 # - ENABLE_BUILD_HARDENING=ON
   7 #
   8 # Plugin configuration variables:
   9 # - OPENCV_PLUGIN_DEPS - set of extra dependencies (modules), used for include dirs, target_link_libraries
  10 # - OPENCV_PLUGIN_SUFFIX
  11 # - OPENCV_PLUGIN_NAME
  12 # - OPENCV_PLUGIN_OUTPUT_NAME_FULL (overrides both OPENCV_PLUGIN_NAME / OPENCV_PLUGIN_SUFFIX)
  13 #
  14 #=============================================
  15
  16 if(NOT OpenCV_SOURCE_DIR)
  17   message(FATAL_ERROR "OpenCV_SOURCE_DIR must be set to build the plugin!")
  18 endif()
  19
  20 if(NOT DEFINED CMAKE_BUILD_TYPE)
  21   set(CMAKE_BUILD_TYPE "Release")
  22 endif()
  23 message(STATUS "CMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}")
  24
  25 set(BUILD_SHARED_LIBS ON CACHE BOOL "")
  26 if(NOT BUILD_SHARED_LIBS)
  27   message(FATAL_ERROR "Static plugin build does not make sense")
  28 endif()
  29
  30 # re-use OpenCV build scripts
  31 include("${OpenCV_SOURCE_DIR}/cmake/OpenCVUtils.cmake")
  32 include("${OpenCV_SOURCE_DIR}/cmake/OpenCVDetectCXXCompiler.cmake")
  33 include("${OpenCV_SOURCE_DIR}/cmake/OpenCVCompilerOptions.cmake")
  34
  35 function(ocv_create_plugin module default_name dependency_target dependency_target_desc)
  36
  37   set(OPENCV_PLUGIN_NAME ${default_name} CACHE STRING "")
  38   set(OPENCV_PLUGIN_DESTINATION "" CACHE PATH "")
  39   project(${OPENCV_PLUGIN_NAME} LANGUAGES CXX)
  40
  41   if(NOT TARGET ${dependency_target})
  42     message(FATAL_ERROR "${dependency_target_desc} was not found! (missing target ${dependency_target})")
  43   endif()
  44
  45   set(modules_ROOT "${OpenCV_SOURCE_DIR}/modules")
  46   set(module_ROOT "${modules_ROOT}/${module}")
  47
  48   foreach(src ${ARGN})
  49     list(APPEND sources "${module_ROOT}/${src}")
  50   endforeach()
  51
  52   add_library(${OPENCV_PLUGIN_NAME} MODULE
  53       "${sources}"
  54       ${OPENCV_PLUGIN_EXTRA_SRC_FILES}
  55   )
  56
  57   if(OPENCV_PLUGIN_DEPS)
  58     foreach(d ${OPENCV_PLUGIN_DEPS})
  59       list(APPEND OPENCV_PLUGIN_EXTRA_INCLUDES "${modules_ROOT}/${d}/include")
  60     endforeach()
  61   endif()
  62
  63   target_include_directories(${OPENCV_PLUGIN_NAME} PRIVATE
  64       "${CMAKE_CURRENT_BINARY_DIR}"
  65       "${module_ROOT}/src"
  66       "${module_ROOT}/include"
  67       ${OPENCV_PLUGIN_EXTRA_INCLUDES}
  68   )
  69   target_compile_definitions(${OPENCV_PLUGIN_NAME} PRIVATE "BUILD_PLUGIN=1")
  70
  71   target_link_libraries(${OPENCV_PLUGIN_NAME} PRIVATE ${dependency_target})
  72   set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES
  73     CXX_STANDARD 11
  74     CXX_VISIBILITY_PRESET hidden
  75   )
  76
  77   if(DEFINED OPENCV_PLUGIN_MODULE_PREFIX)
  78     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES PREFIX "${OPENCV_PLUGIN_MODULE_PREFIX}")
  79   endif()
  80
  81   if(APPLE)
  82     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup")
  83   elseif(WIN32)
  84     # Hack for Windows only, Linux/MacOS uses global symbol table (without exact .so binding)
  85     find_package(OpenCV REQUIRED ${module} ${OPENCV_PLUGIN_DEPS})
  86     target_link_libraries(${OPENCV_PLUGIN_NAME} PRIVATE ${OpenCV_LIBRARIES})
  87   endif()
  88
  89   if(NOT OpenCV_FOUND)  # build against sources (Linux)
  90     file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/opencv2/opencv_modules.hpp" "#pragma once")
  91   endif()
  92
  93   if(WIN32)
  94     ocv_update(OPENCV_DEBUG_POSTFIX d)
  95   endif()
  96   set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}")
  97
  98   if(DEFINED OPENCV_PLUGIN_SUFFIX)
  99     # custom value
 100   else()
 101     if(WIN32)
 102       ocv_update(OPENCV_PLUGIN_VERSION "${OpenCV_VERSION_MAJOR}${OpenCV_VERSION_MINOR}${OpenCV_VERSION_PATCH}")
 103       if(CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
 104         ocv_update(OPENCV_PLUGIN_ARCH "_64")
 105       else()
 106         ocv_update(OPENCV_PLUGIN_ARCH "")
 107       endif()
 108     else()
 109       # empty
 110     endif()
 111     ocv_update(OPENCV_PLUGIN_SUFFIX "${OPENCV_PLUGIN_VERSION}${OPENCV_PLUGIN_ARCH}")
 112   endif()
 113
 114   if(OPENCV_PLUGIN_DESTINATION)
 115     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY "${OPENCV_PLUGIN_DESTINATION}")
 116     message(STATUS "Output destination: ${OPENCV_PLUGIN_DESTINATION}")
 117   endif()
 118
 119   if(OPENCV_PLUGIN_OUTPUT_NAME_FULL)
 120     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES OUTPUT_NAME "${OPENCV_PLUGIN_OUTPUT_NAME_FULL}")
 121   elseif(OPENCV_PLUGIN_OUTPUT_NAME)
 122     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES OUTPUT_NAME "${OPENCV_PLUGIN_OUTPUT_NAME}${OPENCV_PLUGIN_SUFFIX}")
 123   else()
 124     set_target_properties(${OPENCV_PLUGIN_NAME} PROPERTIES OUTPUT_NAME "${OPENCV_PLUGIN_NAME}${OPENCV_PLUGIN_SUFFIX}")
 125   endif()
 126
 127   install(TARGETS ${OPENCV_PLUGIN_NAME} LIBRARY DESTINATION . COMPONENT plugins)
 128
 129   message(STATUS "Library name: ${OPENCV_PLUGIN_NAME}")
 130
 131 endfunction()