cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CMAKE_COMPILER_IS_GNUCXX)
  16
  17     IF(NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.2.0")
  18         SET(PCHSupport_FOUND TRUE)
  19     ENDIF()
  20
  21     SET(_PCH_include_prefix "-I")
  22     SET(_PCH_isystem_prefix "-isystem")
  23     SET(_PCH_define_prefix "-D")
  24
  25 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  26     SET(PCHSupport_FOUND TRUE)
  27     SET(_PCH_include_prefix "/I")
  28     SET(_PCH_isystem_prefix "/I")
  29     SET(_PCH_define_prefix "/D")
  30 ELSE()
  31     SET(PCHSupport_FOUND FALSE)
  32 ENDIF()
  33
  34 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  35
  36     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  37     SET(${_out_compile_flags} ${${_flags_var_name}} )
  38
  39     IF(CMAKE_COMPILER_IS_GNUCXX)
  40
  41         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  42         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  43             LIST(APPEND ${_out_compile_flags} "-fPIC")
  44         ENDIF()
  45
  46         GET_PROPERTY(_definitions DIRECTORY PROPERTY COMPILE_DEFINITIONS)
  47         if(_definitions)
  48           foreach(_def ${_definitions})
  49             LIST(APPEND ${_out_compile_flags} "\"-D${_def}\"")
  50           endforeach()
  51         endif()
  52         GET_TARGET_PROPERTY(_target_definitions ${_PCH_current_target} COMPILE_DEFINITIONS)
  53         if(_target_definitions)
  54           foreach(_def ${_target_definitions})
  55             LIST(APPEND ${_out_compile_flags} "\"-D${_def}\"")
  56           endforeach()
  57         endif()
  58
  59     ELSE()
  60         ## TODO ... ? or does it work out of the box
  61     ENDIF()
  62
  63     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  64     FOREACH(item ${DIRINC})
  65         ocv_is_opencv_directory(__result ${item})
  66         if(__result)
  67           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  68         else()
  69           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  70         endif()
  71     ENDFOREACH(item)
  72
  73     get_target_property(DIRINC ${_PCH_current_target} INCLUDE_DIRECTORIES )
  74     FOREACH(item ${DIRINC})
  75         ocv_is_opencv_directory(__result ${item})
  76         if(__result)
  77           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  78         else()
  79           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  80         endif()
  81     ENDFOREACH(item)
  82
  83     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  84
  85     SEPARATE_ARGUMENTS(${_out_compile_flags})
  86
  87 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  88
  89
  90 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  91
  92     set(${_dephelp} "${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx")
  93     set(_content "")
  94     if(EXISTS "${_dephelp}")
  95       file(READ "${_dephelp}" _content)
  96     endif()
  97     set(_dummy_str
  98 "#include \"${_include_file}\"
  99 int testfunction();
 100 int testfunction()
 101 {
 102     return 0;
 103 }
 104 ")
 105     if(NOT _content STREQUAL _dummy_str)
 106       file(WRITE "${${_dephelp}}" "${_dummy_str}")
 107     endif()
 108
 109 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 110
 111 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 112
 113     FILE(TO_NATIVE_PATH ${_input} _native_input)
 114     FILE(TO_NATIVE_PATH ${_output} _native_output)
 115
 116     IF(CMAKE_COMPILER_IS_GNUCXX)
 117         IF(CMAKE_CXX_COMPILER_ARG1)
 118             # remove leading space in compiler argument
 119             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 120
 121             SET(${out_command}
 122               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 123               )
 124         ELSE(CMAKE_CXX_COMPILER_ARG1)
 125             SET(${out_command}
 126               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 127               )
 128         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 129     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 130
 131         SET(_dummy_str "#include <${_input}>")
 132         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 133
 134         SET(${out_command}
 135           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 136           )
 137         #/out:${_output}
 138
 139     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 140
 141 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 142
 143
 144 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 145
 146     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 147
 148     IF(CMAKE_COMPILER_IS_GNUCXX)
 149         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 150         # on all remote machines set
 151         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 152         # if you want warnings for invalid header files (which is very inconvenient
 153         # if you have different versions of the headers for different build types
 154         # you may set _pch_dowarn
 155         IF (_dowarn)
 156             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -Winvalid-pch " )
 157         ELSE (_dowarn)
 158             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} " )
 159         ENDIF (_dowarn)
 160
 161     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 162
 163         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 164
 165     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 166
 167 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 168
 169
 170 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 171
 172     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 173     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 174     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 175
 176 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 177
 178
 179 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 180
 181     # to do: test whether compiler flags match between target  _targetName
 182     # and _pch_output_to_use
 183     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 184
 185     IF(ARGN STREQUAL "0")
 186         SET(_dowarn 0)
 187     ELSE()
 188         SET(_dowarn 1)
 189     ENDIF()
 190
 191     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 192     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 193
 194     GET_TARGET_PROPERTY(_sources ${_targetName} SOURCES)
 195     FOREACH(src ${_sources})
 196       if(NOT "${src}" MATCHES "\\.mm$")
 197         get_source_file_property(_flags "${src}" COMPILE_FLAGS)
 198         if(_flags)
 199           set(_flags "${_flags} ${_target_cflags}")
 200         else()
 201           set(_flags "${_target_cflags}")
 202         endif()
 203
 204         set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${_flags}")
 205       endif()
 206     ENDFOREACH()
 207
 208     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 209       DEPENDS ${_pch_output_to_use}
 210       )
 211
 212     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 213
 214 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 215
 216 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 217
 218     SET(_PCH_current_target ${_targetName})
 219
 220     IF(NOT CMAKE_BUILD_TYPE)
 221         MESSAGE(FATAL_ERROR
 222           "This is the ADD_PRECOMPILED_HEADER macro. "
 223           "You must set CMAKE_BUILD_TYPE!"
 224           )
 225     ENDIF()
 226
 227     IF(ARGN STREQUAL "0")
 228         SET(_dowarn 0)
 229     ELSE()
 230         SET(_dowarn 1)
 231     ENDIF()
 232
 233     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 234     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 235     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 236
 237     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 238
 239     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 240
 241     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 242       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 243       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 244       )
 245
 246     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 247
 248     get_target_property(type ${_targetName} TYPE)
 249     if(type STREQUAL "SHARED_LIBRARY")
 250         get_target_property(__DEFINES ${_targetName} DEFINE_SYMBOL)
 251         if(NOT __DEFINES MATCHES __DEFINES-NOTFOUND)
 252             list(APPEND _compile_FLAGS "${_PCH_define_prefix}${__DEFINES}")
 253         endif()
 254     endif()
 255
 256     get_target_property(DIRINC ${_targetName} INCLUDE_DIRECTORIES)
 257     set_target_properties(${_targetName}_pch_dephelp PROPERTIES INCLUDE_DIRECTORIES "${DIRINC}")
 258
 259     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 260     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 261
 262     ADD_CUSTOM_COMMAND(
 263       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 264       COMMAND ${CMAKE_COMMAND} -E copy_if_different "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 265       DEPENDS "${_input}"
 266       )
 267
 268     #message("_command  ${_input} ${_output}")
 269     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 270
 271     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 272     ADD_CUSTOM_COMMAND(
 273       OUTPUT "${_output}"
 274       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 275       COMMAND ${_command}
 276       DEPENDS "${_input}"
 277       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 278       DEPENDS ${_targetName}_pch_dephelp
 279       )
 280
 281     get_target_property(_sources ${_targetName} SOURCES)
 282     foreach(src ${_sources})
 283       if(NOT "${src}" MATCHES "\\.mm$")
 284         get_source_file_property(oldProps "${src}" COMPILE_FLAGS)
 285         if(NOT oldProps)
 286           set(newProperties "-include \"${CMAKE_CURRENT_BINARY_DIR}/${_name}\"")
 287           set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${newProperties}")
 288         else()
 289           ocv_debug_message("Skip PCH, flags: ${oldProps} , file: ${src}")
 290         endif()
 291       endif()
 292     endforeach()
 293
 294     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 295
 296 ENDMACRO(ADD_PRECOMPILED_HEADER)
 297
 298
 299 # Generates the use of precompiled in a target,
 300 # without using depency targets (2 extra for each target)
 301 # Using Visual, must also add ${_targetName}_pch to sources
 302 # Not needed by Xcode
 303
 304 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 305
 306   if(ENABLE_PRECOMPILED_HEADERS)
 307     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 308         set(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cpp)
 309     endif()
 310   endif()
 311
 312 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 313
 314
 315 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 316
 317     IF(ARGN STREQUAL "0")
 318         SET(_dowarn 0)
 319     ELSE()
 320         SET(_dowarn 1)
 321     ENDIF()
 322
 323     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 324
 325         # Auto include the precompile (useful for moc processing, since the use of
 326         # precompiled is specified at the target level
 327         # and I don't want to specifiy /F- for each moc/res/ui generated files (using Qt)
 328
 329         get_target_property(_sources ${_targetName} SOURCES)
 330         foreach(src ${_sources})
 331           if(NOT "${src}" MATCHES "\\.mm$")
 332             get_source_file_property(oldProps "${src}" COMPILE_FLAGS)
 333             if(NOT oldProps)
 334               set(newProperties "/Yu\"${_input}\" /FI\"${_input}\"")
 335               set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${newProperties}")
 336             else()
 337               ocv_debug_message("Skip PCH, flags: ${oldProps} , file: ${src}")
 338             endif()
 339           endif()
 340         endforeach()
 341
 342         #also inlude ${oldProps} to have the same compile options
 343         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 344         if (oldProps MATCHES NOTFOUND)
 345             SET(oldProps "")
 346         endif()
 347         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 348
 349         set(_dummy_str "#include \"${_input}\"\n")
 350         set(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cpp)
 351         if(EXISTS ${${_targetName}_pch})
 352             file(READ "${${_targetName}_pch}" _contents)
 353         endif()
 354         if(NOT _dummy_str STREQUAL "${_contents}")
 355             file(WRITE ${${_targetName}_pch} ${_dummy_str})
 356         endif()
 357
 358     elseif (CMAKE_GENERATOR MATCHES Xcode)
 359
 360         # For Xcode, cmake needs my patch to process
 361         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 362
 363         # When buiding out of the tree, precompiled may not be located
 364         # Use full path instead.
 365         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 366
 367         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 368         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 369
 370     else()
 371
 372         #Fallback to the "old" precompiled suppport
 373         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 374
 375     endif()
 376
 377 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 378
 379 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 380   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 381     if(CMAKE_GENERATOR MATCHES "^Visual" OR CMAKE_GENERATOR MATCHES Xcode)
 382       add_native_precompiled_header(${the_target} ${pch_header})
 383     elseif(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 384       add_precompiled_header(${the_target} ${pch_header})
 385     endif()
 386   endif()
 387 endmacro()