cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CMAKE_COMPILER_IS_GNUCXX)
  16
  17     EXEC_PROGRAM(
  18         ${CMAKE_CXX_COMPILER}
  19         ARGS ${CMAKE_CXX_COMPILER_ARG1} -dumpversion
  20         OUTPUT_VARIABLE gcc_compiler_version)
  21     #MESSAGE("GCC Version: ${gcc_compiler_version}")
  22     IF(gcc_compiler_version MATCHES "4\\.[0,2-9]\\.[0-9]")
  23         SET(PCHSupport_FOUND TRUE)
  24     ENDIF()
  25
  26     SET(_PCH_include_prefix "-I")
  27     SET(_PCH_isystem_prefix "-isystem")
  28
  29 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  30     SET(PCHSupport_FOUND TRUE)
  31     SET(_PCH_include_prefix "/I")
  32     SET(_PCH_isystem_prefix "/I")
  33 ELSE()
  34     SET(PCHSupport_FOUND FALSE)
  35 ENDIF()
  36
  37 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  38
  39     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  40     SET(${_out_compile_flags} ${${_flags_var_name}} )
  41
  42     IF(CMAKE_COMPILER_IS_GNUCXX)
  43
  44         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  45         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  46             LIST(APPEND ${_out_compile_flags} "-fPIC")
  47         ENDIF()
  48
  49     ELSE()
  50         ## TODO ... ? or does it work out of the box
  51     ENDIF()
  52
  53     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  54     FOREACH(item ${DIRINC})
  55         if(item MATCHES "^${OpenCV_SOURCE_DIR}/modules/")
  56           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  57         else()
  58           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  59         endif()
  60     ENDFOREACH(item)
  61
  62     GET_DIRECTORY_PROPERTY(_directory_flags DEFINITIONS)
  63     GET_DIRECTORY_PROPERTY(_global_definitions DIRECTORY ${OpenCV_SOURCE_DIR} DEFINITIONS)
  64     #MESSAGE("_directory_flags ${_directory_flags} ${_global_definitions}" )
  65     LIST(APPEND ${_out_compile_flags} ${_directory_flags})
  66     LIST(APPEND ${_out_compile_flags} ${_global_definitions})
  67     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  68
  69     SEPARATE_ARGUMENTS(${_out_compile_flags})
  70
  71 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  72
  73
  74 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  75
  76     SET(${_dephelp} ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx)
  77     IF(CMAKE_HOST_WIN32)
  78         ADD_CUSTOM_COMMAND(
  79           OUTPUT "${${_dephelp}}"
  80           COMMAND ${CMAKE_COMMAND} -E echo "#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  81           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction();"               >> "${${_dephelp}}"
  82           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction()"                >> "${${_dephelp}}"
  83           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  84           COMMAND ${CMAKE_COMMAND} -E echo "    return 0;"                     >> "${${_dephelp}}"
  85           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  86           DEPENDS "${_include_file}"
  87           )
  88     else()
  89         ADD_CUSTOM_COMMAND(
  90           OUTPUT "${${_dephelp}}"
  91           COMMAND ${CMAKE_COMMAND} -E echo "\\#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  92           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)\\;"         >> "${${_dephelp}}"
  93           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)"            >> "${${_dephelp}}"
  94           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  95           COMMAND ${CMAKE_COMMAND} -E echo "    \\return 0\\;"                 >> "${${_dephelp}}"
  96           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  97           DEPENDS "${_include_file}"
  98           )
  99     endif()
 100
 101 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 102
 103 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 104
 105     FILE(TO_NATIVE_PATH ${_input} _native_input)
 106     FILE(TO_NATIVE_PATH ${_output} _native_output)
 107
 108     IF(CMAKE_COMPILER_IS_GNUCXX)
 109         IF(CMAKE_CXX_COMPILER_ARG1)
 110             # remove leading space in compiler argument
 111             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 112
 113             SET(${out_command}
 114               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 115               )
 116             message("!!!!!!!!!!!!!!!!${${out_command}}!!!!")
 117         ELSE(CMAKE_CXX_COMPILER_ARG1)
 118             SET(${out_command}
 119               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 120               )
 121         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 122     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 123
 124         SET(_dummy_str "#include <${_input}>")
 125         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 126
 127         SET(${out_command}
 128           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 129           )
 130         #/out:${_output}
 131
 132     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 133
 134 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 135
 136
 137 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 138
 139     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 140
 141     IF(CMAKE_COMPILER_IS_GNUCXX)
 142         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 143         # on all remote machines set
 144         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 145         # if you want warnings for invalid header files (which is very inconvenient
 146         # if you have different versions of the headers for different build types
 147         # you may set _pch_dowarn
 148         IF (_dowarn)
 149             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" -Winvalid-pch " )
 150         ELSE (_dowarn)
 151             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" " )
 152         ENDIF (_dowarn)
 153
 154     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 155
 156         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 157
 158     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 159
 160 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 161
 162
 163 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 164
 165     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 166     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 167     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 168
 169 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 170
 171
 172 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 173
 174     # to do: test whether compiler flags match between target  _targetName
 175     # and _pch_output_to_use
 176     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 177
 178     IF(ARGN STREQUAL "0")
 179         SET(_dowarn 0)
 180     ELSE()
 181         SET(_dowarn 1)
 182     ENDIF()
 183
 184     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 185     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 186     SET_TARGET_PROPERTIES(${_targetName}
 187       PROPERTIES
 188       COMPILE_FLAGS ${_target_cflags}
 189       )
 190
 191     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 192       DEPENDS ${_pch_output_to_use}
 193       )
 194
 195     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 196
 197 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 198
 199 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 200
 201     SET(_PCH_current_target ${_targetName})
 202
 203     IF(NOT CMAKE_BUILD_TYPE)
 204         MESSAGE(FATAL_ERROR
 205           "This is the ADD_PRECOMPILED_HEADER macro. "
 206           "You must set CMAKE_BUILD_TYPE!"
 207           )
 208     ENDIF()
 209
 210     IF(ARGN STREQUAL "0")
 211         SET(_dowarn 0)
 212     ELSE()
 213         SET(_dowarn 1)
 214     ENDIF()
 215
 216     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 217     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 218     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 219
 220     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 221
 222     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 223
 224     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 225       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 226       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 227       )
 228
 229     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 230
 231     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 232     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 233
 234     ADD_CUSTOM_COMMAND(
 235       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 236       COMMAND ${CMAKE_COMMAND} -E copy  "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 237       DEPENDS "${_input}"
 238       )
 239
 240     #message("_command  ${_input} ${_output}")
 241     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 242
 243     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 244     ADD_CUSTOM_COMMAND(
 245       OUTPUT "${_output}"
 246       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 247       COMMAND ${_command}
 248       DEPENDS "${_input}"
 249       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 250       DEPENDS ${_targetName}_pch_dephelp
 251       )
 252
 253     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 254
 255 ENDMACRO(ADD_PRECOMPILED_HEADER)
 256
 257
 258 # Generates the use of precompiled in a target,
 259 # without using depency targets (2 extra for each target)
 260 # Using Visual, must also add ${_targetName}_pch to sources
 261 # Not needed by Xcode
 262
 263 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 264
 265     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 266         SET(_dummy_str "#include \"${_input}\"\n"
 267 "// This is required to suppress LNK4221.  Very annoying.\n"
 268 "void *g_${_targetName}Dummy = 0\;\n")
 269
 270         # Use of cxx extension for generated files (as Qt does)
 271         SET(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cxx)
 272         if(EXISTS ${${_targetName}_pch})
 273             # Check if contents is the same, if not rewrite
 274             # todo
 275         else()
 276             FILE(WRITE ${${_targetName}_pch} ${_dummy_str})
 277         endif()
 278     endif()
 279
 280 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 281
 282
 283 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 284
 285     IF(ARGN STREQUAL "0")
 286         SET(_dowarn 0)
 287     ELSE()
 288         SET(_dowarn 1)
 289     ENDIF()
 290
 291     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 292
 293         # Auto include the precompile (useful for moc processing, since the use of
 294         # precompiled is specified at the target level
 295         # and I don't want to specifiy /F- for each moc/res/ui generated files (using Qt)
 296
 297         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 298         if (oldProps MATCHES NOTFOUND)
 299             SET(oldProps "")
 300         endif()
 301
 302         SET(newProperties "${oldProps} /Yu\"${_input}\" /FI\"${_input}\"")
 303         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES COMPILE_FLAGS "${newProperties}")
 304
 305         #also inlude ${oldProps} to have the same compile options
 306         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 307
 308     elseif (CMAKE_GENERATOR MATCHES Xcode)
 309
 310         # For Xcode, cmake needs my patch to process
 311         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 312
 313         # When buiding out of the tree, precompiled may not be located
 314         # Use full path instead.
 315         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 316
 317         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 318         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 319
 320     else()
 321
 322         #Fallback to the "old" precompiled suppport
 323         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 324
 325     endif()
 326
 327 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 328
 329 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 330   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 331     if(CMAKE_GENERATOR MATCHES Visual)
 332       string(REGEX REPLACE "hpp$" "cpp" ${the_target}_pch "${pch_header}")
 333       add_native_precompiled_header(${the_target} ${pch_header})
 334       unset(${the_target}_pch)
 335     elseif(CMAKE_GENERATOR MATCHES Xcode)
 336       add_native_precompiled_header(${the_target} ${pch_header})
 337     elseif(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 338       add_precompiled_header(${the_target} ${pch_header})
 339     endif()
 340   endif()
 341 endmacro()