cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CMAKE_COMPILER_IS_GNUCXX)
  16
  17     EXEC_PROGRAM(
  18         ${CMAKE_CXX_COMPILER}
  19         ARGS ${CMAKE_CXX_COMPILER_ARG1} -dumpversion
  20         OUTPUT_VARIABLE gcc_compiler_version)
  21     #MESSAGE("GCC Version: ${gcc_compiler_version}")
  22     IF(gcc_compiler_version VERSION_GREATER "4.2.-1")
  23         SET(PCHSupport_FOUND TRUE)
  24     ENDIF()
  25
  26     SET(_PCH_include_prefix "-I")
  27     SET(_PCH_isystem_prefix "-isystem")
  28
  29 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  30     SET(PCHSupport_FOUND TRUE)
  31     SET(_PCH_include_prefix "/I")
  32     SET(_PCH_isystem_prefix "/I")
  33 ELSE()
  34     SET(PCHSupport_FOUND FALSE)
  35 ENDIF()
  36
  37 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  38
  39     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  40     SET(${_out_compile_flags} ${${_flags_var_name}} )
  41
  42     IF(CMAKE_COMPILER_IS_GNUCXX)
  43
  44         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  45         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  46             LIST(APPEND ${_out_compile_flags} "-fPIC")
  47         ENDIF()
  48
  49     ELSE()
  50         ## TODO ... ? or does it work out of the box
  51     ENDIF()
  52
  53     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  54     FOREACH(item ${DIRINC})
  55         if(item MATCHES "^${OpenCV_SOURCE_DIR}/modules/")
  56           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  57         else()
  58           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  59         endif()
  60     ENDFOREACH(item)
  61
  62     GET_DIRECTORY_PROPERTY(_directory_flags DEFINITIONS)
  63     GET_DIRECTORY_PROPERTY(_global_definitions DIRECTORY ${OpenCV_SOURCE_DIR} DEFINITIONS)
  64     #MESSAGE("_directory_flags ${_directory_flags} ${_global_definitions}" )
  65     LIST(APPEND ${_out_compile_flags} ${_directory_flags})
  66     LIST(APPEND ${_out_compile_flags} ${_global_definitions})
  67     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  68
  69     SEPARATE_ARGUMENTS(${_out_compile_flags})
  70
  71 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  72
  73
  74 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  75
  76     SET(${_dephelp} ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx)
  77     IF(CMAKE_HOST_WIN32)
  78         ADD_CUSTOM_COMMAND(
  79           OUTPUT "${${_dephelp}}"
  80           COMMAND ${CMAKE_COMMAND} -E echo "#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  81           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction();"               >> "${${_dephelp}}"
  82           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction()"                >> "${${_dephelp}}"
  83           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  84           COMMAND ${CMAKE_COMMAND} -E echo "    return 0;"                     >> "${${_dephelp}}"
  85           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  86           DEPENDS "${_include_file}"
  87           )
  88     else()
  89         ADD_CUSTOM_COMMAND(
  90           OUTPUT "${${_dephelp}}"
  91           COMMAND ${CMAKE_COMMAND} -E echo "\\#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  92           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)\\;"         >> "${${_dephelp}}"
  93           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)"            >> "${${_dephelp}}"
  94           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  95           COMMAND ${CMAKE_COMMAND} -E echo "    \\return 0\\;"                 >> "${${_dephelp}}"
  96           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  97           DEPENDS "${_include_file}"
  98           )
  99     endif()
 100
 101 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 102
 103 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 104
 105     FILE(TO_NATIVE_PATH ${_input} _native_input)
 106     FILE(TO_NATIVE_PATH ${_output} _native_output)
 107
 108     IF(CMAKE_COMPILER_IS_GNUCXX)
 109         IF(CMAKE_CXX_COMPILER_ARG1)
 110             # remove leading space in compiler argument
 111             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 112
 113             SET(${out_command}
 114               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 115               )
 116         ELSE(CMAKE_CXX_COMPILER_ARG1)
 117             SET(${out_command}
 118               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 119               )
 120         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 121     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 122
 123         SET(_dummy_str "#include <${_input}>")
 124         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 125
 126         SET(${out_command}
 127           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 128           )
 129         #/out:${_output}
 130
 131     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 132
 133 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 134
 135
 136 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 137
 138     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 139
 140     IF(CMAKE_COMPILER_IS_GNUCXX)
 141         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 142         # on all remote machines set
 143         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 144         # if you want warnings for invalid header files (which is very inconvenient
 145         # if you have different versions of the headers for different build types
 146         # you may set _pch_dowarn
 147         IF (_dowarn)
 148             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" -Winvalid-pch " )
 149         ELSE (_dowarn)
 150             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" " )
 151         ENDIF (_dowarn)
 152
 153     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 154
 155         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 156
 157     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 158
 159 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 160
 161
 162 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 163
 164     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 165     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 166     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 167
 168 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 169
 170
 171 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 172
 173     # to do: test whether compiler flags match between target  _targetName
 174     # and _pch_output_to_use
 175     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 176
 177     IF(ARGN STREQUAL "0")
 178         SET(_dowarn 0)
 179     ELSE()
 180         SET(_dowarn 1)
 181     ENDIF()
 182
 183     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 184     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 185
 186     GET_TARGET_PROPERTY(_sources ${_targetName} SOURCES)
 187     FOREACH(src ${_sources})
 188       if(NOT "${src}" MATCHES "\\.mm$")
 189         get_source_file_property(_flags "${src}" COMPILE_FLAGS)
 190         if(_flags)
 191           set(_flags "${_flags} ${_target_cflags}")
 192         else()
 193           set(_flags "${_target_cflags}")
 194         endif()
 195
 196         set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${_flags}")
 197       endif()
 198     ENDFOREACH()
 199
 200     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 201       DEPENDS ${_pch_output_to_use}
 202       )
 203
 204     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 205
 206 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 207
 208 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 209
 210     SET(_PCH_current_target ${_targetName})
 211
 212     IF(NOT CMAKE_BUILD_TYPE)
 213         MESSAGE(FATAL_ERROR
 214           "This is the ADD_PRECOMPILED_HEADER macro. "
 215           "You must set CMAKE_BUILD_TYPE!"
 216           )
 217     ENDIF()
 218
 219     IF(ARGN STREQUAL "0")
 220         SET(_dowarn 0)
 221     ELSE()
 222         SET(_dowarn 1)
 223     ENDIF()
 224
 225     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 226     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 227     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 228
 229     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 230
 231     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 232
 233     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 234       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 235       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 236       )
 237
 238     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 239
 240     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 241     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 242
 243     ADD_CUSTOM_COMMAND(
 244       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 245       COMMAND ${CMAKE_COMMAND} -E copy  "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 246       DEPENDS "${_input}"
 247       )
 248
 249     #message("_command  ${_input} ${_output}")
 250     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 251
 252     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 253     ADD_CUSTOM_COMMAND(
 254       OUTPUT "${_output}"
 255       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 256       COMMAND ${_command}
 257       DEPENDS "${_input}"
 258       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 259       DEPENDS ${_targetName}_pch_dephelp
 260       )
 261
 262     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 263
 264 ENDMACRO(ADD_PRECOMPILED_HEADER)
 265
 266
 267 # Generates the use of precompiled in a target,
 268 # without using depency targets (2 extra for each target)
 269 # Using Visual, must also add ${_targetName}_pch to sources
 270 # Not needed by Xcode
 271
 272 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 273
 274     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 275         SET(_dummy_str "#include \"${_input}\"\n"
 276 "// This is required to suppress LNK4221.  Very annoying.\n"
 277 "void *g_${_targetName}Dummy = 0\;\n")
 278
 279         # Use of cxx extension for generated files (as Qt does)
 280         SET(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cxx)
 281         if(EXISTS ${${_targetName}_pch})
 282             # Check if contents is the same, if not rewrite
 283             # todo
 284         else()
 285             FILE(WRITE ${${_targetName}_pch} ${_dummy_str})
 286         endif()
 287     endif()
 288
 289 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 290
 291
 292 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 293
 294     IF(ARGN STREQUAL "0")
 295         SET(_dowarn 0)
 296     ELSE()
 297         SET(_dowarn 1)
 298     ENDIF()
 299
 300     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 301
 302         # Auto include the precompile (useful for moc processing, since the use of
 303         # precompiled is specified at the target level
 304         # and I don't want to specifiy /F- for each moc/res/ui generated files (using Qt)
 305
 306         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 307         if (oldProps MATCHES NOTFOUND)
 308             SET(oldProps "")
 309         endif()
 310
 311         SET(newProperties "${oldProps} /Yu\"${_input}\" /FI\"${_input}\"")
 312         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES COMPILE_FLAGS "${newProperties}")
 313
 314         #also inlude ${oldProps} to have the same compile options
 315         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 316
 317     elseif (CMAKE_GENERATOR MATCHES Xcode)
 318
 319         # For Xcode, cmake needs my patch to process
 320         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 321
 322         # When buiding out of the tree, precompiled may not be located
 323         # Use full path instead.
 324         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 325
 326         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 327         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 328
 329     else()
 330
 331         #Fallback to the "old" precompiled suppport
 332         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 333
 334     endif()
 335
 336 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 337
 338 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 339   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 340     if(CMAKE_GENERATOR MATCHES Visual)
 341       string(REGEX REPLACE "hpp$" "cpp" ${the_target}_pch "${pch_header}")
 342       add_native_precompiled_header(${the_target} ${pch_header})
 343       unset(${the_target}_pch)
 344     elseif(CMAKE_GENERATOR MATCHES Xcode)
 345       add_native_precompiled_header(${the_target} ${pch_header})
 346     elseif(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 347       add_precompiled_header(${the_target} ${pch_header})
 348     endif()
 349   endif()
 350 endmacro()