cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CMAKE_COMPILER_IS_GNUCXX)
  16
  17     EXEC_PROGRAM(
  18         ${CMAKE_CXX_COMPILER}
  19         ARGS ${CMAKE_CXX_COMPILER_ARG1} -dumpversion
  20         OUTPUT_VARIABLE gcc_compiler_version)
  21     #MESSAGE("GCC Version: ${gcc_compiler_version}")
  22     IF(gcc_compiler_version VERSION_GREATER "4.2.-1")
  23         SET(PCHSupport_FOUND TRUE)
  24     ENDIF()
  25
  26     SET(_PCH_include_prefix "-I")
  27     SET(_PCH_isystem_prefix "-isystem")
  28     SET(_PCH_define_prefix "-D")
  29
  30 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  31     SET(PCHSupport_FOUND TRUE)
  32     SET(_PCH_include_prefix "/I")
  33     SET(_PCH_isystem_prefix "/I")
  34     SET(_PCH_define_prefix "/D")
  35 ELSE()
  36     SET(PCHSupport_FOUND FALSE)
  37 ENDIF()
  38
  39 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  40
  41     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  42     SET(${_out_compile_flags} ${${_flags_var_name}} )
  43
  44     IF(CMAKE_COMPILER_IS_GNUCXX)
  45
  46         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  47         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  48             LIST(APPEND ${_out_compile_flags} "-fPIC")
  49         ENDIF()
  50
  51         GET_TARGET_PROPERTY(_target_definitions ${_PCH_current_target} COMPILE_DEFINITIONS)
  52         if(_target_definitions)
  53           foreach(_def ${_target_definitions})
  54             LIST(APPEND ${_out_compile_flags} "-D${_def}")
  55           endforeach()
  56         endif()
  57
  58     ELSE()
  59         ## TODO ... ? or does it work out of the box
  60     ENDIF()
  61
  62     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  63     FOREACH(item ${DIRINC})
  64         if(item MATCHES "^${OpenCV_SOURCE_DIR}/modules/")
  65           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  66         else()
  67           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  68         endif()
  69     ENDFOREACH(item)
  70
  71     GET_DIRECTORY_PROPERTY(_directory_flags DEFINITIONS)
  72     GET_DIRECTORY_PROPERTY(_global_definitions DIRECTORY ${OpenCV_SOURCE_DIR} DEFINITIONS)
  73     #MESSAGE("_directory_flags ${_directory_flags} ${_global_definitions}" )
  74     LIST(APPEND ${_out_compile_flags} ${_directory_flags})
  75     LIST(APPEND ${_out_compile_flags} ${_global_definitions})
  76     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  77
  78     SEPARATE_ARGUMENTS(${_out_compile_flags})
  79
  80 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  81
  82
  83 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  84
  85     SET(${_dephelp} ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx)
  86     IF(CMAKE_HOST_WIN32)
  87         ADD_CUSTOM_COMMAND(
  88           OUTPUT "${${_dephelp}}"
  89           COMMAND ${CMAKE_COMMAND} -E echo "#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  90           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction();"               >> "${${_dephelp}}"
  91           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction()"                >> "${${_dephelp}}"
  92           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  93           COMMAND ${CMAKE_COMMAND} -E echo "    return 0;"                     >> "${${_dephelp}}"
  94           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  95           DEPENDS "${_include_file}"
  96           )
  97     else()
  98         ADD_CUSTOM_COMMAND(
  99           OUTPUT "${${_dephelp}}"
 100           COMMAND ${CMAKE_COMMAND} -E echo "\\#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
 101           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)\\;"         >> "${${_dephelp}}"
 102           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)"            >> "${${_dephelp}}"
 103           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
 104           COMMAND ${CMAKE_COMMAND} -E echo "    \\return 0\\;"                 >> "${${_dephelp}}"
 105           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
 106           DEPENDS "${_include_file}"
 107           )
 108     endif()
 109
 110 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 111
 112 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 113
 114     FILE(TO_NATIVE_PATH ${_input} _native_input)
 115     FILE(TO_NATIVE_PATH ${_output} _native_output)
 116
 117     IF(CMAKE_COMPILER_IS_GNUCXX)
 118         IF(CMAKE_CXX_COMPILER_ARG1)
 119             # remove leading space in compiler argument
 120             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 121
 122             SET(${out_command}
 123               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 124               )
 125         ELSE(CMAKE_CXX_COMPILER_ARG1)
 126             SET(${out_command}
 127               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 128               )
 129         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 130     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 131
 132         SET(_dummy_str "#include <${_input}>")
 133         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 134
 135         SET(${out_command}
 136           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 137           )
 138         #/out:${_output}
 139
 140     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 141
 142 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 143
 144
 145 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 146
 147     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 148
 149     IF(CMAKE_COMPILER_IS_GNUCXX)
 150         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 151         # on all remote machines set
 152         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 153         # if you want warnings for invalid header files (which is very inconvenient
 154         # if you have different versions of the headers for different build types
 155         # you may set _pch_dowarn
 156         IF (_dowarn)
 157             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" -Winvalid-pch " )
 158         ELSE (_dowarn)
 159             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" " )
 160         ENDIF (_dowarn)
 161
 162     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 163
 164         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 165
 166     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 167
 168 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 169
 170
 171 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 172
 173     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 174     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 175     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 176
 177 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 178
 179
 180 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 181
 182     # to do: test whether compiler flags match between target  _targetName
 183     # and _pch_output_to_use
 184     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 185
 186     IF(ARGN STREQUAL "0")
 187         SET(_dowarn 0)
 188     ELSE()
 189         SET(_dowarn 1)
 190     ENDIF()
 191
 192     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 193     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 194
 195     GET_TARGET_PROPERTY(_sources ${_targetName} SOURCES)
 196     FOREACH(src ${_sources})
 197       if(NOT "${src}" MATCHES "\\.mm$")
 198         get_source_file_property(_flags "${src}" COMPILE_FLAGS)
 199         if(_flags)
 200           set(_flags "${_flags} ${_target_cflags}")
 201         else()
 202           set(_flags "${_target_cflags}")
 203         endif()
 204
 205         set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${_flags}")
 206       endif()
 207     ENDFOREACH()
 208
 209     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 210       DEPENDS ${_pch_output_to_use}
 211       )
 212
 213     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 214
 215 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 216
 217 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 218
 219     SET(_PCH_current_target ${_targetName})
 220
 221     IF(NOT CMAKE_BUILD_TYPE)
 222         MESSAGE(FATAL_ERROR
 223           "This is the ADD_PRECOMPILED_HEADER macro. "
 224           "You must set CMAKE_BUILD_TYPE!"
 225           )
 226     ENDIF()
 227
 228     IF(ARGN STREQUAL "0")
 229         SET(_dowarn 0)
 230     ELSE()
 231         SET(_dowarn 1)
 232     ENDIF()
 233
 234     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 235     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 236     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 237
 238     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 239
 240     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 241
 242     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 243       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 244       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 245       )
 246
 247     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 248
 249     get_target_property(type ${_targetName} TYPE)
 250     if(type STREQUAL "SHARED_LIBRARY")
 251         get_target_property(__DEFINES ${_targetName} DEFINE_SYMBOL)
 252         if(NOT __DEFINES MATCHES __DEFINES-NOTFOUND)
 253             list(APPEND _compile_FLAGS "${_PCH_define_prefix}${__DEFINES}")
 254         endif()
 255     endif()
 256
 257     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 258     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 259
 260     ADD_CUSTOM_COMMAND(
 261       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 262       COMMAND ${CMAKE_COMMAND} -E copy  "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 263       DEPENDS "${_input}"
 264       )
 265
 266     #message("_command  ${_input} ${_output}")
 267     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 268
 269     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 270     ADD_CUSTOM_COMMAND(
 271       OUTPUT "${_output}"
 272       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 273       COMMAND ${_command}
 274       DEPENDS "${_input}"
 275       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 276       DEPENDS ${_targetName}_pch_dephelp
 277       )
 278
 279     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 280
 281 ENDMACRO(ADD_PRECOMPILED_HEADER)
 282
 283
 284 # Generates the use of precompiled in a target,
 285 # without using depency targets (2 extra for each target)
 286 # Using Visual, must also add ${_targetName}_pch to sources
 287 # Not needed by Xcode
 288
 289 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 290
 291     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 292         set(_dummy_str "#include \"${_input}\"\n")
 293
 294         set(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cpp)
 295         if(EXISTS ${${_targetName}_pch})
 296             # Check if contents is the same, if not rewrite
 297             # todo
 298         else()
 299             FILE(WRITE ${${_targetName}_pch} ${_dummy_str})
 300         endif()
 301     endif()
 302
 303 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 304
 305
 306 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 307
 308     IF(ARGN STREQUAL "0")
 309         SET(_dowarn 0)
 310     ELSE()
 311         SET(_dowarn 1)
 312     ENDIF()
 313
 314     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 315
 316         # Auto include the precompile (useful for moc processing, since the use of
 317         # precompiled is specified at the target level
 318         # and I don't want to specifiy /F- for each moc/res/ui generated files (using Qt)
 319
 320         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 321         if (oldProps MATCHES NOTFOUND)
 322             SET(oldProps "")
 323         endif()
 324
 325         SET(newProperties "${oldProps} /Yu\"${_input}\" /FI\"${_input}\"")
 326         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES COMPILE_FLAGS "${newProperties}")
 327
 328         #also inlude ${oldProps} to have the same compile options
 329         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 330
 331     elseif (CMAKE_GENERATOR MATCHES Xcode)
 332
 333         # For Xcode, cmake needs my patch to process
 334         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 335
 336         # When buiding out of the tree, precompiled may not be located
 337         # Use full path instead.
 338         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 339
 340         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 341         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 342
 343     else()
 344
 345         #Fallback to the "old" precompiled suppport
 346         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 347
 348     endif()
 349
 350 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 351
 352 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 353   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 354     if(CMAKE_GENERATOR MATCHES "^Visual" OR CMAKE_GENERATOR MATCHES Xcode)
 355       add_native_precompiled_header(${the_target} ${pch_header})
 356     elseif(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 357       add_precompiled_header(${the_target} ${pch_header})
 358     endif()
 359   endif()
 360 endmacro()