cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CMAKE_COMPILER_IS_GNUCXX)
  16
  17     EXEC_PROGRAM(
  18         ${CMAKE_CXX_COMPILER}
  19         ARGS ${CMAKE_CXX_COMPILER_ARG1} -dumpversion
  20         OUTPUT_VARIABLE gcc_compiler_version)
  21     #MESSAGE("GCC Version: ${gcc_compiler_version}")
  22     IF(gcc_compiler_version MATCHES "4\\.[0,2-9]\\.[0-9]")
  23         SET(PCHSupport_FOUND TRUE)
  24     ENDIF()
  25
  26     SET(_PCH_include_prefix "-I")
  27     SET(_PCH_isystem_prefix "-isystem")
  28
  29 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  30     SET(PCHSupport_FOUND TRUE)
  31     SET(_PCH_include_prefix "/I")
  32     SET(_PCH_isystem_prefix "/I")
  33 ELSE()
  34     SET(PCHSupport_FOUND FALSE)
  35 ENDIF()
  36
  37 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  38
  39     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  40     SET(${_out_compile_flags} ${${_flags_var_name}} )
  41
  42     IF(CMAKE_COMPILER_IS_GNUCXX)
  43
  44         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  45         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  46             LIST(APPEND ${_out_compile_flags} "-fPIC")
  47         ENDIF()
  48
  49     ELSE()
  50         ## TODO ... ? or does it work out of the box
  51     ENDIF()
  52
  53     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  54     FOREACH(item ${DIRINC})
  55         if(item MATCHES "^${OpenCV_SOURCE_DIR}/modules/")
  56           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  57         else()
  58           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  59         endif()
  60     ENDFOREACH(item)
  61
  62     GET_DIRECTORY_PROPERTY(_directory_flags DEFINITIONS)
  63     GET_DIRECTORY_PROPERTY(_global_definitions DIRECTORY ${OpenCV_SOURCE_DIR} DEFINITIONS)
  64     #MESSAGE("_directory_flags ${_directory_flags} ${_global_definitions}" )
  65     LIST(APPEND ${_out_compile_flags} ${_directory_flags})
  66     LIST(APPEND ${_out_compile_flags} ${_global_definitions})
  67     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  68
  69     SEPARATE_ARGUMENTS(${_out_compile_flags})
  70
  71 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  72
  73
  74 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  75
  76     SET(${_dephelp} ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx)
  77     IF(CMAKE_HOST_WIN32)
  78         ADD_CUSTOM_COMMAND(
  79           OUTPUT "${${_dephelp}}"
  80           COMMAND ${CMAKE_COMMAND} -E echo "#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  81           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction();"               >> "${${_dephelp}}"
  82           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction()"                >> "${${_dephelp}}"
  83           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  84           COMMAND ${CMAKE_COMMAND} -E echo "    return 0;"                     >> "${${_dephelp}}"
  85           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  86           DEPENDS "${_include_file}"
  87           )
  88     else()
  89         ADD_CUSTOM_COMMAND(
  90           OUTPUT "${${_dephelp}}"
  91           COMMAND ${CMAKE_COMMAND} -E echo "\\#include \\\"${_include_file}\\\"" >  "${${_dephelp}}"
  92           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)\\;"         >> "${${_dephelp}}"
  93           COMMAND ${CMAKE_COMMAND} -E echo "int testfunction\\(\\)"            >> "${${_dephelp}}"
  94           COMMAND ${CMAKE_COMMAND} -E echo "{"                                 >> "${${_dephelp}}"
  95           COMMAND ${CMAKE_COMMAND} -E echo "    \\return 0\\;"                 >> "${${_dephelp}}"
  96           COMMAND ${CMAKE_COMMAND} -E echo "}"                                 >> "${${_dephelp}}"
  97           DEPENDS "${_include_file}"
  98           )
  99     endif()
 100
 101 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 102
 103 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 104
 105     FILE(TO_NATIVE_PATH ${_input} _native_input)
 106     FILE(TO_NATIVE_PATH ${_output} _native_output)
 107
 108     IF(CMAKE_COMPILER_IS_GNUCXX)
 109         IF(CMAKE_CXX_COMPILER_ARG1)
 110             # remove leading space in compiler argument
 111             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 112
 113             SET(${out_command}
 114               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 115               )
 116         ELSE(CMAKE_CXX_COMPILER_ARG1)
 117             SET(${out_command}
 118               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}
 119               )
 120         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 121     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 122
 123         SET(_dummy_str "#include <${_input}>")
 124         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 125
 126         SET(${out_command}
 127           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 128           )
 129         #/out:${_output}
 130
 131     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 132
 133 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 134
 135
 136 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 137
 138     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 139
 140     IF(CMAKE_COMPILER_IS_GNUCXX)
 141         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 142         # on all remote machines set
 143         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 144         # if you want warnings for invalid header files (which is very inconvenient
 145         # if you have different versions of the headers for different build types
 146         # you may set _pch_dowarn
 147         IF (_dowarn)
 148             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" -Winvalid-pch " )
 149         ELSE (_dowarn)
 150             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_header_name}\" " )
 151         ENDIF (_dowarn)
 152
 153     ELSE(CMAKE_COMPILER_IS_GNUCXX)
 154
 155         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 156
 157     ENDIF(CMAKE_COMPILER_IS_GNUCXX)
 158
 159 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 160
 161
 162 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 163
 164     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 165     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 166     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 167
 168 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 169
 170
 171 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 172
 173     # to do: test whether compiler flags match between target  _targetName
 174     # and _pch_output_to_use
 175     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 176
 177     IF(ARGN STREQUAL "0")
 178         SET(_dowarn 0)
 179     ELSE()
 180         SET(_dowarn 1)
 181     ENDIF()
 182
 183     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 184     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 185     SET_TARGET_PROPERTIES(${_targetName}
 186       PROPERTIES
 187       COMPILE_FLAGS ${_target_cflags}
 188       )
 189
 190     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 191       DEPENDS ${_pch_output_to_use}
 192       )
 193
 194     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 195
 196 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 197
 198 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 199
 200     SET(_PCH_current_target ${_targetName})
 201
 202     IF(NOT CMAKE_BUILD_TYPE)
 203         MESSAGE(FATAL_ERROR
 204           "This is the ADD_PRECOMPILED_HEADER macro. "
 205           "You must set CMAKE_BUILD_TYPE!"
 206           )
 207     ENDIF()
 208
 209     IF(ARGN STREQUAL "0")
 210         SET(_dowarn 0)
 211     ELSE()
 212         SET(_dowarn 1)
 213     ENDIF()
 214
 215     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 216     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 217     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 218
 219     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 220
 221     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 222
 223     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 224       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 225       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 226       )
 227
 228     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 229
 230     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 231     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 232
 233     ADD_CUSTOM_COMMAND(
 234       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 235       COMMAND ${CMAKE_COMMAND} -E copy  "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 236       DEPENDS "${_input}"
 237       )
 238
 239     #message("_command  ${_input} ${_output}")
 240     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 241
 242     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 243     ADD_CUSTOM_COMMAND(
 244       OUTPUT "${_output}"
 245       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 246       COMMAND ${_command}
 247       DEPENDS "${_input}"
 248       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 249       DEPENDS ${_targetName}_pch_dephelp
 250       )
 251
 252     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 253
 254 ENDMACRO(ADD_PRECOMPILED_HEADER)
 255
 256
 257 # Generates the use of precompiled in a target,
 258 # without using depency targets (2 extra for each target)
 259 # Using Visual, must also add ${_targetName}_pch to sources
 260 # Not needed by Xcode
 261
 262 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 263
 264     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 265         SET(_dummy_str "#include \"${_input}\"\n"
 266 "// This is required to suppress LNK4221.  Very annoying.\n"
 267 "void *g_${_targetName}Dummy = 0\;\n")
 268
 269         # Use of cxx extension for generated files (as Qt does)
 270         SET(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cxx)
 271         if(EXISTS ${${_targetName}_pch})
 272             # Check if contents is the same, if not rewrite
 273             # todo
 274         else()
 275             FILE(WRITE ${${_targetName}_pch} ${_dummy_str})
 276         endif()
 277     endif()
 278
 279 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 280
 281
 282 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 283
 284     IF(ARGN STREQUAL "0")
 285         SET(_dowarn 0)
 286     ELSE()
 287         SET(_dowarn 1)
 288     ENDIF()
 289
 290     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 291
 292         # Auto include the precompile (useful for moc processing, since the use of
 293         # precompiled is specified at the target level
 294         # and I don't want to specifiy /F- for each moc/res/ui generated files (using Qt)
 295
 296         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 297         if (oldProps MATCHES NOTFOUND)
 298             SET(oldProps "")
 299         endif()
 300
 301         SET(newProperties "${oldProps} /Yu\"${_input}\" /FI\"${_input}\"")
 302         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES COMPILE_FLAGS "${newProperties}")
 303
 304         #also inlude ${oldProps} to have the same compile options
 305         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 306
 307     elseif (CMAKE_GENERATOR MATCHES Xcode)
 308
 309         # For Xcode, cmake needs my patch to process
 310         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 311
 312         # When buiding out of the tree, precompiled may not be located
 313         # Use full path instead.
 314         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 315
 316         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 317         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 318
 319     else()
 320
 321         #Fallback to the "old" precompiled suppport
 322         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 323
 324     endif()
 325
 326 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 327
 328 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 329   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 330     if(CMAKE_GENERATOR MATCHES Visual)
 331       string(REGEX REPLACE "hpp$" "cpp" ${the_target}_pch "${pch_header}")
 332       add_native_precompiled_header(${the_target} ${pch_header})
 333       unset(${the_target}_pch)
 334     elseif(CMAKE_GENERATOR MATCHES Xcode)
 335       add_native_precompiled_header(${the_target} ${pch_header})
 336     elseif(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 337       add_precompiled_header(${the_target} ${pch_header})
 338     endif()
 339   endif()
 340 endmacro()