cmake/OpenCVPCHSupport.cmake

   1 # taken from http://public.kitware.com/Bug/view.php?id=1260 and slightly adjusted
   2
   3 # - Try to find precompiled headers support for GCC 3.4 and 4.x
   4 # Once done this will define:
   5 #
   6 # Variable:
   7 #   PCHSupport_FOUND
   8 #
   9 # Macro:
  10 #   ADD_PRECOMPILED_HEADER  _targetName _input  _dowarn
  11 #   ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use _dowarn
  12 #   ADD_NATIVE_PRECOMPILED_HEADER _targetName _input _dowarn
  13 #   GET_NATIVE_PRECOMPILED_HEADER _targetName _input
  14
  15 IF(CV_GCC)
  16
  17     IF(NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.2.0")
  18         SET(PCHSupport_FOUND TRUE)
  19     ENDIF()
  20
  21     SET(_PCH_include_prefix "-I")
  22     SET(_PCH_isystem_prefix "-isystem")
  23     SET(_PCH_define_prefix "-D")
  24
  25 ELSEIF(CMAKE_GENERATOR MATCHES "^Visual.*$")
  26     SET(PCHSupport_FOUND TRUE)
  27     SET(_PCH_include_prefix "/I")
  28     SET(_PCH_isystem_prefix "/I")
  29     SET(_PCH_define_prefix "/D")
  30 ELSE()
  31     SET(PCHSupport_FOUND FALSE)
  32 ENDIF()
  33
  34 MACRO(_PCH_GET_COMPILE_FLAGS _out_compile_flags)
  35
  36     STRING(TOUPPER "CMAKE_CXX_FLAGS_${CMAKE_BUILD_TYPE}" _flags_var_name)
  37     SET(${_out_compile_flags} ${${_flags_var_name}} )
  38
  39     IF(CV_GCC)
  40
  41         GET_TARGET_PROPERTY(_targetType ${_PCH_current_target} TYPE)
  42         IF(${_targetType} STREQUAL SHARED_LIBRARY AND NOT WIN32)
  43             LIST(APPEND ${_out_compile_flags} "-fPIC")
  44         ENDIF()
  45
  46         # Processed via $<TARGET_PROPERTY:target,COMPILE_DEFINITIONS>
  47         #GET_PROPERTY(_definitions DIRECTORY PROPERTY COMPILE_DEFINITIONS)
  48         #GET_TARGET_PROPERTY(_target_definitions ${_PCH_current_target} COMPILE_DEFINITIONS)
  49
  50         GET_TARGET_PROPERTY(_cxx_standard ${_PCH_current_target} CXX_STANDARD)
  51         if (_cxx_standard)
  52             GET_TARGET_PROPERTY(_cxx_extensions ${_PCH_current_target} CXX_EXTENSIONS)
  53             if (_cxx_extensions)
  54                 LIST(APPEND ${_out_compile_flags} "${CMAKE_CXX${_cxx_standard}_EXTENSION_COMPILE_OPTION}")
  55             else()
  56                 LIST(APPEND ${_out_compile_flags} "${CMAKE_CXX${_cxx_standard}_STANDARD_COMPILE_OPTION}")
  57             endif()
  58         endif()
  59     ELSE()
  60         ## TODO ... ? or does it work out of the box
  61     ENDIF()
  62
  63     GET_DIRECTORY_PROPERTY(DIRINC INCLUDE_DIRECTORIES )
  64     FOREACH(item ${DIRINC})
  65         ocv_is_opencv_directory(__result ${item})
  66         if(__result)
  67           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  68         elseif(CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0" AND
  69                item MATCHES "/usr/include$")
  70           # workaround for GCC 6.x bug
  71         else()
  72           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  73         endif()
  74     ENDFOREACH(item)
  75
  76     get_target_property(DIRINC ${_PCH_current_target} INCLUDE_DIRECTORIES )
  77     FOREACH(item ${DIRINC})
  78         ocv_is_opencv_directory(__result ${item})
  79         if(__result)
  80           LIST(APPEND ${_out_compile_flags} "${_PCH_include_prefix}\"${item}\"")
  81         elseif(CV_GCC AND NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "6.0" AND
  82                item MATCHES "/usr/include$")
  83           # workaround for GCC 6.x bug
  84         else()
  85           LIST(APPEND ${_out_compile_flags} "${_PCH_isystem_prefix}\"${item}\"")
  86         endif()
  87     ENDFOREACH(item)
  88
  89     LIST(APPEND ${_out_compile_flags} ${CMAKE_CXX_FLAGS})
  90
  91     SEPARATE_ARGUMENTS(${_out_compile_flags})
  92
  93 ENDMACRO(_PCH_GET_COMPILE_FLAGS)
  94
  95
  96 MACRO(_PCH_WRITE_PCHDEP_CXX _targetName _include_file _dephelp)
  97
  98     set(${_dephelp} "${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch_dephelp.cxx")
  99     set(_content "")
 100     if(EXISTS "${${_dephelp}}")
 101       file(READ "${${_dephelp}}" _content)
 102     endif()
 103     set(_dummy_str
 104 "#include \"${_include_file}\"
 105 int testfunction();
 106 int testfunction()
 107 {
 108     return 0;
 109 }
 110 ")
 111     if(NOT _content STREQUAL _dummy_str)
 112       file(WRITE "${${_dephelp}}" "${_dummy_str}")
 113     endif()
 114
 115 ENDMACRO(_PCH_WRITE_PCHDEP_CXX )
 116
 117 MACRO(_PCH_GET_COMPILE_COMMAND out_command _input _output)
 118
 119     FILE(TO_NATIVE_PATH ${_input} _native_input)
 120     FILE(TO_NATIVE_PATH ${_output} _native_output)
 121
 122     if(CV_GCC)
 123         IF(CMAKE_CXX_COMPILER_ARG1)
 124             # remove leading space in compiler argument
 125             STRING(REGEX REPLACE "^ +" "" pchsupport_compiler_cxx_arg1 ${CMAKE_CXX_COMPILER_ARG1})
 126
 127             SET(${out_command}
 128               ${CMAKE_CXX_COMPILER} ${pchsupport_compiler_cxx_arg1} ${_compile_FLAGS} -x c++-header -o ${_output} -c ${_input}
 129               )
 130         ELSE(CMAKE_CXX_COMPILER_ARG1)
 131             SET(${out_command}
 132               ${CMAKE_CXX_COMPILER}  ${_compile_FLAGS} -x c++-header -o ${_output} -c ${_input}
 133               )
 134         ENDIF(CMAKE_CXX_COMPILER_ARG1)
 135     ELSE()
 136
 137         SET(_dummy_str "#include <${_input}>")
 138         FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/pch_dummy.cpp ${_dummy_str})
 139
 140         SET(${out_command}
 141           ${CMAKE_CXX_COMPILER} ${_compile_FLAGS} /c /Fp${_native_output} /Yc${_native_input} pch_dummy.cpp
 142           )
 143         #/out:${_output}
 144
 145     ENDIF()
 146
 147 ENDMACRO(_PCH_GET_COMPILE_COMMAND )
 148
 149
 150 MACRO(_PCH_GET_TARGET_COMPILE_FLAGS _cflags  _header_name _pch_path _dowarn )
 151
 152     FILE(TO_NATIVE_PATH ${_pch_path} _native_pch_path)
 153
 154     IF(CV_GCC)
 155         # for use with distcc and gcc >4.0.1 if preprocessed files are accessible
 156         # on all remote machines set
 157         # PCH_ADDITIONAL_COMPILER_FLAGS to -fpch-preprocess
 158         # if you want warnings for invalid header files (which is very inconvenient
 159         # if you have different versions of the headers for different build types
 160         # you may set _pch_dowarn
 161         IF (_dowarn)
 162             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} -Winvalid-pch " )
 163         ELSE (_dowarn)
 164             SET(${_cflags} "${PCH_ADDITIONAL_COMPILER_FLAGS} " )
 165         ENDIF (_dowarn)
 166
 167     ELSE()
 168
 169         set(${_cflags} "/Fp${_native_pch_path} /Yu${_header_name}" )
 170
 171     ENDIF()
 172
 173 ENDMACRO(_PCH_GET_TARGET_COMPILE_FLAGS )
 174
 175
 176 MACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input _output)
 177
 178     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 179     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 180     SET(${_output} "${CMAKE_CURRENT_BINARY_DIR}/${_name}.gch/${_targetName}_${CMAKE_BUILD_TYPE}.gch")
 181
 182 ENDMACRO(GET_PRECOMPILED_HEADER_OUTPUT _targetName _input)
 183
 184
 185 MACRO(ADD_PRECOMPILED_HEADER_TO_TARGET _targetName _input _pch_output_to_use )
 186
 187     # to do: test whether compiler flags match between target  _targetName
 188     # and _pch_output_to_use
 189     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 190
 191     IF(ARGN STREQUAL "0")
 192         SET(_dowarn 0)
 193     ELSE()
 194         SET(_dowarn 1)
 195     ENDIF()
 196
 197     _PCH_GET_TARGET_COMPILE_FLAGS(_target_cflags ${_name} ${_pch_output_to_use} ${_dowarn})
 198     #MESSAGE("Add flags ${_target_cflags} to ${_targetName} " )
 199     if(CV_GCC)
 200       set(_target_cflags "${_target_cflags} -include \"${CMAKE_CURRENT_BINARY_DIR}/${_name}\"")
 201     endif()
 202
 203     GET_TARGET_PROPERTY(_sources ${_targetName} SOURCES)
 204     FOREACH(src ${_sources})
 205       if(NOT "${src}" MATCHES "\\.mm$" AND NOT "${src}" MATCHES "\\.rc$")
 206         get_source_file_property(_flags "${src}" COMPILE_FLAGS)
 207         get_source_file_property(_flags2 "${src}" COMPILE_DEFINITIONS)
 208         if(NOT _flags AND NOT _flags2)
 209           set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${_target_cflags}")
 210         else()
 211           #ocv_debug_message("Skip PCH, flags: ${oldProps} defines: ${oldProps2}, file: ${src}")
 212         endif()
 213       endif()
 214     ENDFOREACH()
 215
 216     ADD_CUSTOM_TARGET(pch_Generate_${_targetName}
 217       DEPENDS ${_pch_output_to_use}
 218       )
 219
 220     ADD_DEPENDENCIES(${_targetName} pch_Generate_${_targetName} )
 221
 222 ENDMACRO(ADD_PRECOMPILED_HEADER_TO_TARGET)
 223
 224 MACRO(ADD_PRECOMPILED_HEADER _targetName _input)
 225
 226     SET(_PCH_current_target ${_targetName})
 227
 228     IF(NOT CMAKE_BUILD_TYPE)
 229         MESSAGE(FATAL_ERROR
 230           "This is the ADD_PRECOMPILED_HEADER macro. "
 231           "You must set CMAKE_BUILD_TYPE!"
 232           )
 233     ENDIF()
 234
 235     IF(ARGN STREQUAL "0")
 236         SET(_dowarn 0)
 237     ELSE()
 238         SET(_dowarn 1)
 239     ENDIF()
 240
 241     GET_FILENAME_COMPONENT(_name ${_input} NAME)
 242     GET_FILENAME_COMPONENT(_path ${_input} PATH)
 243     GET_PRECOMPILED_HEADER_OUTPUT( ${_targetName} ${_input} _output)
 244
 245     _PCH_WRITE_PCHDEP_CXX(${_targetName} "${_input}" _pch_dephelp_cxx)
 246
 247     ADD_LIBRARY(${_targetName}_pch_dephelp STATIC "${_pch_dephelp_cxx}" "${_input}" )
 248
 249     set_target_properties(${_targetName}_pch_dephelp PROPERTIES
 250       DEBUG_POSTFIX "${OPENCV_DEBUG_POSTFIX}"
 251       ARCHIVE_OUTPUT_DIRECTORY "${LIBRARY_OUTPUT_PATH}"
 252       )
 253
 254     _PCH_GET_COMPILE_FLAGS(_compile_FLAGS)
 255     list(APPEND _compile_FLAGS "${_PCH_include_prefix}\"${_path}\"")
 256
 257     get_target_property(type ${_targetName} TYPE)
 258     if(type STREQUAL "SHARED_LIBRARY")
 259         get_target_property(__DEFINES ${_targetName} DEFINE_SYMBOL)
 260         if(NOT __DEFINES MATCHES __DEFINES-NOTFOUND)
 261             list(APPEND _compile_FLAGS "${_PCH_define_prefix}${__DEFINES}")
 262         endif()
 263     endif()
 264
 265     if(type STREQUAL "SHARED_LIBRARY" OR type STREQUAL "STATIC_LIBRARY")
 266       get_target_property(__pic ${_targetName} POSITION_INDEPENDENT_CODE)
 267       if(__pic AND CMAKE_CXX_COMPILE_OPTIONS_PIC
 268           AND NOT OPENCV_SKIP_PCH_PIC_HANDLING
 269           AND NOT OPENCV_SKIP_PCH_PIC_HANDLING_${_targetName}
 270       )
 271         list(APPEND _compile_FLAGS "${CMAKE_CXX_COMPILE_OPTIONS_PIC}")
 272       endif()
 273     elseif(type STREQUAL "EXECUTABLE")
 274       get_target_property(__pie ${_targetName} POSITION_INDEPENDENT_CODE)
 275       if(__pie AND CMAKE_CXX_COMPILE_OPTIONS_PIE
 276           AND NOT OPENCV_SKIP_PCH_PIE_HANDLING
 277           AND NOT OPENCV_SKIP_PCH_PIE_HANDLING_${_targetName}
 278       )
 279         list(APPEND _compile_FLAGS "${CMAKE_CXX_COMPILE_OPTIONS_PIE}")
 280       endif()
 281     endif()
 282
 283     get_target_property(DIRINC ${_targetName} INCLUDE_DIRECTORIES)
 284     set_target_properties(${_targetName}_pch_dephelp PROPERTIES INCLUDE_DIRECTORIES "${DIRINC}")
 285
 286     #MESSAGE("_compile_FLAGS: ${_compile_FLAGS}")
 287     #message("COMMAND ${CMAKE_CXX_COMPILER}     ${_compile_FLAGS} -x c++-header -o ${_output} ${_input}")
 288
 289     ADD_CUSTOM_COMMAND(
 290       OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 291       COMMAND ${CMAKE_COMMAND} -E copy_if_different "${_input}" "${CMAKE_CURRENT_BINARY_DIR}/${_name}" # ensure same directory! Required by gcc
 292       DEPENDS "${_input}"
 293       )
 294
 295     #message("_command  ${_input} ${_output}")
 296     _PCH_GET_COMPILE_COMMAND(_command  ${CMAKE_CURRENT_BINARY_DIR}/${_name} ${_output} )
 297
 298     set(_pch_generate_file_cmd "${CMAKE_CURRENT_BINARY_DIR}/${_name}.command.sh")
 299     string(REPLACE " " "\\ " _command "${_command}")
 300     string(REPLACE ";" " " _command "${_command}")
 301     file(GENERATE OUTPUT "${_pch_generate_file_cmd}" CONTENT "#!/bin/sh
 302 if [ -n \"$VERBOSE\" ]; then
 303   tail -n1 \$0
 304 fi
 305 ${_command} '-D$<JOIN:$<TARGET_PROPERTY:${_targetName},COMPILE_DEFINITIONS>,' '-D>'
 306 ")
 307     GET_FILENAME_COMPONENT(_outdir ${_output} PATH)
 308     if(NOT CMAKE_HOST_WIN32)  # chmod may be not available on Win32/MinGW (and it is not required)
 309       set(_pch_prepare_command COMMAND chmod +x "${_pch_generate_file_cmd}")
 310     endif()
 311     ADD_CUSTOM_COMMAND(
 312       OUTPUT "${_output}"
 313       COMMAND ${CMAKE_COMMAND} -E make_directory "${_outdir}"
 314       ${_pch_prepare_command}
 315       COMMAND "${_pch_generate_file_cmd}"
 316       DEPENDS "${_input}" "${_pch_generate_file_cmd}"
 317       DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${_name}"
 318       DEPENDS ${_targetName}_pch_dephelp
 319       )
 320
 321     ADD_PRECOMPILED_HEADER_TO_TARGET(${_targetName} ${_input}  ${_output} ${_dowarn})
 322
 323 ENDMACRO(ADD_PRECOMPILED_HEADER)
 324
 325
 326 # Generates the use of precompiled in a target,
 327 # without using dependency targets (2 extra for each target)
 328 # Using Visual, must also add ${_targetName}_pch to sources
 329 # Not needed by Xcode
 330
 331 MACRO(GET_NATIVE_PRECOMPILED_HEADER _targetName _input)
 332
 333   if(ENABLE_PRECOMPILED_HEADERS)
 334     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 335         set(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cpp)
 336     endif()
 337   endif()
 338
 339 ENDMACRO(GET_NATIVE_PRECOMPILED_HEADER)
 340
 341
 342 MACRO(ADD_NATIVE_PRECOMPILED_HEADER _targetName _input)
 343
 344     IF(ARGN STREQUAL "0")
 345         SET(_dowarn 0)
 346     ELSE()
 347         SET(_dowarn 1)
 348     ENDIF()
 349
 350     if(CMAKE_GENERATOR MATCHES "^Visual.*$")
 351
 352         # Auto include the precompile (useful for moc processing, since the use of
 353         # precompiled is specified at the target level
 354         # and I don't want to specify /F- for each moc/res/ui generated files (using Qt)
 355
 356         get_target_property(_sources ${_targetName} SOURCES)
 357         foreach(src ${_sources})
 358           if("${src}" MATCHES "\\.c(pp|xx)?$")
 359             get_source_file_property(oldProps "${src}" COMPILE_FLAGS)
 360             get_source_file_property(oldProps2 "${src}" COMPILE_DEFINITIONS)
 361             if(NOT oldProps AND NOT oldProps2)
 362               set(newProperties "/Yu\"${_input}\" /FI\"${_input}\"")
 363               set_source_files_properties("${src}" PROPERTIES COMPILE_FLAGS "${newProperties}")
 364             else()
 365               ocv_debug_message("Skip PCH, flags: ${oldProps} defines: ${oldProps2}, file: ${src}")
 366             endif()
 367           endif()
 368         endforeach()
 369
 370         #also include ${oldProps} to have the same compile options
 371         GET_TARGET_PROPERTY(oldProps ${_targetName} COMPILE_FLAGS)
 372         if (oldProps MATCHES NOTFOUND)
 373             SET(oldProps "")
 374         endif()
 375         SET_SOURCE_FILES_PROPERTIES(${${_targetName}_pch} PROPERTIES COMPILE_FLAGS "${oldProps} /Yc\"${_input}\"")
 376
 377         set(_dummy_str "#include \"${_input}\"\n")
 378         set(${_targetName}_pch ${CMAKE_CURRENT_BINARY_DIR}/${_targetName}_pch.cpp)
 379         if(EXISTS ${${_targetName}_pch})
 380             file(READ "${${_targetName}_pch}" _contents)
 381         endif()
 382         if(NOT _dummy_str STREQUAL "${_contents}")
 383             file(WRITE ${${_targetName}_pch} ${_dummy_str})
 384         endif()
 385
 386     elseif (CMAKE_GENERATOR MATCHES Xcode)
 387
 388         # For Xcode, cmake needs my patch to process
 389         # GCC_PREFIX_HEADER and GCC_PRECOMPILE_PREFIX_HEADER as target properties
 390
 391         # When building out of the tree, precompiled may not be located
 392         # Use full path instead.
 393         GET_FILENAME_COMPONENT(fullPath ${_input} ABSOLUTE)
 394
 395         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PREFIX_HEADER "${fullPath}")
 396         SET_TARGET_PROPERTIES(${_targetName} PROPERTIES XCODE_ATTRIBUTE_GCC_PRECOMPILE_PREFIX_HEADER "YES")
 397
 398     else()
 399
 400         #Fallback to the "old" precompiled support
 401         #ADD_PRECOMPILED_HEADER(${_targetName} ${_input} ${_dowarn})
 402
 403     endif()
 404
 405 ENDMACRO(ADD_NATIVE_PRECOMPILED_HEADER)
 406
 407 macro(ocv_add_precompiled_header_to_target the_target pch_header)
 408   if(PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS AND EXISTS "${pch_header}")
 409     if(CMAKE_GENERATOR MATCHES "^Visual" OR CMAKE_GENERATOR MATCHES Xcode)
 410       add_native_precompiled_header(${the_target} ${pch_header})
 411     elseif(CV_GCC AND CMAKE_GENERATOR MATCHES "Makefiles|Ninja")
 412       add_precompiled_header(${the_target} ${pch_header})
 413     endif()
 414   endif()
 415 endmacro()