cmake/OpenCVGenPkgconfig.cmake

   1 # --------------------------------------------------------------------------------------------
   2 # according to man pkg-config
   3 #  The package name specified on the pkg-config command line is defined to
   4 #      be the name of the metadata file, minus the .pc extension. If a library
   5 #      can install multiple versions simultaneously, it must give each version
   6 #      its own name (for example, GTK 1.2 might have the package  name  "gtk+"
   7 #      while GTK 2.0 has "gtk+-2.0").
   8 #
   9 # ${BIN_DIR}/unix-install/opencv.pc -> For use *with* "make install"
  10 # -------------------------------------------------------------------------------------------
  11 set(prefix      "${CMAKE_INSTALL_PREFIX}")
  12 set(exec_prefix "\${prefix}")
  13 set(libdir      "") #TODO: need link paths for OpenCV_EXTRA_COMPONENTS
  14 set(includedir  "\${prefix}/${OPENCV_INCLUDE_INSTALL_PATH}")
  15 set(VERSION     ${OPENCV_VERSION})
  16
  17 if(CMAKE_BUILD_TYPE MATCHES "Release")
  18   set(ocv_optkind OPT)
  19 else()
  20   set(ocv_optkind DBG)
  21 endif()
  22
  23 #build the list of opencv libs and dependencies for all modules
  24 set(OpenCV_LIB_COMPONENTS "")
  25 set(OpenCV_EXTRA_COMPONENTS "")
  26 foreach(m ${OPENCV_MODULES_PUBLIC})
  27   list(INSERT OpenCV_LIB_COMPONENTS 0 ${${m}_MODULE_DEPS_${ocv_optkind}} ${m})
  28   if(${m}_EXTRA_DEPS_${ocv_optkind})
  29     list(INSERT OpenCV_EXTRA_COMPONENTS 0 ${${m}_EXTRA_DEPS_${ocv_optkind}})
  30   endif()
  31 endforeach()
  32
  33 ocv_list_unique(OpenCV_LIB_COMPONENTS)
  34 ocv_list_unique(OpenCV_EXTRA_COMPONENTS)
  35 ocv_list_reverse(OpenCV_LIB_COMPONENTS)
  36 ocv_list_reverse(OpenCV_EXTRA_COMPONENTS)
  37
  38 #build the list of components
  39 set(OpenCV_LIB_COMPONENTS_ "")
  40 foreach(CVLib ${OpenCV_LIB_COMPONENTS})
  41   get_target_property(libpath ${CVLib} LOCATION_${CMAKE_BUILD_TYPE})
  42   get_filename_component(libname "${libpath}" NAME)
  43
  44   if(INSTALL_TO_MANGLED_PATHS)
  45     set(libname "${libname}.${OPENCV_VERSION}")
  46   endif()
  47
  48   #need better solution....
  49   if(libpath MATCHES "3rdparty")
  50     set(installDir "share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH}")
  51   else()
  52     set(installDir "${OPENCV_LIB_INSTALL_PATH}")
  53   endif()
  54
  55   set(OpenCV_LIB_COMPONENTS_ "${OpenCV_LIB_COMPONENTS_} \${exec_prefix}/${installDir}/${libname}")
  56 endforeach()
  57
  58 # add extra dependencies required for OpenCV
  59 set(OpenCV_LIB_COMPONENTS ${OpenCV_LIB_COMPONENTS_})
  60 if(OpenCV_EXTRA_COMPONENTS)
  61   string(REPLACE ";" " " OpenCV_EXTRA_COMPONENTS "${OpenCV_EXTRA_COMPONENTS}")
  62   set(OpenCV_LIB_COMPONENTS "${OpenCV_LIB_COMPONENTS} ${OpenCV_EXTRA_COMPONENTS}")
  63 endif()
  64
  65 #generate the .pc file
  66 if(INSTALL_TO_MANGLED_PATHS)
  67   set(OPENCV_PC_FILE_NAME "opencv-${OPENCV_VERSION}.pc")
  68 else()
  69   set(OPENCV_PC_FILE_NAME opencv.pc)
  70 endif()
  71 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/opencv-XXX.pc.cmake.in" "${CMAKE_BINARY_DIR}/unix-install/${OPENCV_PC_FILE_NAME}" @ONLY IMMEDIATE)
  72
  73 if(UNIX AND NOT ANDROID)
  74   install(FILES ${CMAKE_BINARY_DIR}/unix-install/${OPENCV_PC_FILE_NAME} DESTINATION ${OPENCV_LIB_INSTALL_PATH}/pkgconfig)
  75 endif()