cmake/OpenCVFindLibsGUI.cmake

   1 # ----------------------------------------------------------------------------
   2 #  Detect 3rd-party GUI libraries
   3 # ----------------------------------------------------------------------------
   4
   5 #--- Win32 UI ---
   6 ocv_clear_vars(HAVE_WIN32UI)
   7 if(WITH_WIN32UI)
   8   try_compile(HAVE_WIN32UI
   9     "${OpenCV_BINARY_DIR}"
  10     "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
  11     CMAKE_FLAGS "-DLINK_LIBRARIES:STRING=user32;gdi32")
  12 endif()
  13
  14 # --- QT4 ---
  15 ocv_clear_vars(HAVE_QT HAVE_QT5)
  16 if(WITH_QT)
  17   if(NOT WITH_QT EQUAL 4)
  18     find_package(Qt5Core)
  19     find_package(Qt5Gui)
  20     find_package(Qt5Widgets)
  21     find_package(Qt5Test)
  22     find_package(Qt5Concurrent)
  23     if(Qt5Core_FOUND AND Qt5Gui_FOUND AND Qt5Widgets_FOUND AND Qt5Test_FOUND AND Qt5Concurrent_FOUND)
  24       set(HAVE_QT5 ON)
  25       set(HAVE_QT  ON)
  26       find_package(Qt5OpenGL)
  27       if(Qt5OpenGL_FOUND)
  28         set(QT_QTOPENGL_FOUND ON)
  29       endif()
  30     endif()
  31   endif()
  32
  33   if(NOT HAVE_QT)
  34     find_package(Qt4 REQUIRED QtCore QtGui QtTest)
  35     if(QT4_FOUND)
  36       set(HAVE_QT TRUE)
  37     endif()
  38   endif()
  39 endif()
  40
  41 # --- GTK ---
  42 ocv_clear_vars(HAVE_GTK HAVE_GTK3 HAVE_GTHREAD HAVE_GTKGLEXT)
  43 if(WITH_GTK AND NOT HAVE_QT)
  44   if(WITH_GTK_2_X)
  45     CHECK_MODULE(gtk+-2.0 HAVE_GTK)
  46     if(HAVE_GTK AND (ALIASOF_gtk+-2.0_VERSION VERSION_LESS MIN_VER_GTK))
  47       message (FATAL_ERROR "Gtk support requires a minimum gtk+ version of ${MIN_VER_GTK} (${ALIASOF_gtk+-2.0_VERSION} found)")
  48     endif()
  49   else()
  50     CHECK_MODULE(gtk+-3.0 HAVE_GTK3)
  51     if(NOT HAVE_GTK3)
  52       message(WARNING "Unable to locate Gtk3 development libraries")
  53     endif()
  54   endif()
  55   CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
  56   if(HAVE_GTK OR HAVE_GTK3 AND NOT HAVE_GTHREAD)
  57     message(FATAL_ERROR "gthread not found. This library is required when building with Gtk support")
  58   endif()
  59   if(WITH_OPENGL AND NOT HAVE_GTK3)
  60     CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
  61   endif()
  62 endif()
  63
  64 # --- OpenGl ---
  65 ocv_clear_vars(HAVE_OPENGL HAVE_QT_OPENGL)
  66 if(WITH_OPENGL)
  67   if(WITH_WIN32UI OR (HAVE_QT AND QT_QTOPENGL_FOUND) OR HAVE_GTKGLEXT)
  68     find_package (OpenGL QUIET)
  69     if(OPENGL_FOUND)
  70       set(HAVE_OPENGL TRUE)
  71       list(APPEND OPENCV_LINKER_LIBS ${OPENGL_LIBRARIES})
  72       if(QT_QTOPENGL_FOUND)
  73         set(HAVE_QT_OPENGL TRUE)
  74       else()
  75         ocv_include_directories(${OPENGL_INCLUDE_DIR})
  76       endif()
  77     endif()
  78   endif()
  79 endif(WITH_OPENGL)
  80
  81 # --- Carbon & Cocoa ---
  82 if(APPLE)
  83   if(WITH_CARBON)
  84     set(HAVE_CARBON YES)
  85   elseif(NOT IOS AND CMAKE_COMPILER_IS_CLANGCXX)
  86     set(HAVE_COCOA YES)
  87   endif()
  88 endif()