cmake/OpenCVFindLibsGUI.cmake

   1 # ----------------------------------------------------------------------------
   2 #  Detect 3rd-party GUI libraries
   3 # ----------------------------------------------------------------------------
   4
   5 #--- Win32 UI ---
   6 ocv_clear_vars(HAVE_WIN32UI)
   7 if(WITH_WIN32UI)
   8   try_compile(HAVE_WIN32UI
   9     "${OpenCV_BINARY_DIR}"
  10     "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
  11     CMAKE_FLAGS "-DLINK_LIBRARIES:STRING=user32;gdi32")
  12 endif()
  13
  14 # --- QT4 ---
  15 ocv_clear_vars(HAVE_QT HAVE_QT5)
  16 if(WITH_QT)
  17   if(NOT WITH_QT EQUAL 4)
  18     find_package(Qt5Core)
  19     find_package(Qt5Gui)
  20     find_package(Qt5Widgets)
  21     find_package(Qt5Test)
  22     find_package(Qt5Concurrent)
  23     if(Qt5Core_FOUND AND Qt5Gui_FOUND AND Qt5Widgets_FOUND AND Qt5Test_FOUND AND Qt5Concurrent_FOUND)
  24       set(HAVE_QT5 ON)
  25       set(HAVE_QT  ON)
  26       find_package(Qt5OpenGL)
  27       if(Qt5OpenGL_FOUND)
  28         set(QT_QTOPENGL_FOUND ON)
  29       endif()
  30     endif()
  31   endif()
  32
  33   if(NOT HAVE_QT)
  34     find_package(Qt4 REQUIRED QtCore QtGui QtTest)
  35     if(QT4_FOUND)
  36       set(HAVE_QT TRUE)
  37     endif()
  38   endif()
  39 endif()
  40
  41 # --- GTK ---
  42 ocv_clear_vars(HAVE_GTK HAVE_GTK3 HAVE_GTHREAD HAVE_GTKGLEXT)
  43 if(WITH_GTK AND NOT HAVE_QT)
  44   if(NOT WITH_GTK_2_X)
  45     CHECK_MODULE(gtk+-3.0 HAVE_GTK3)
  46     set(HAVE_GTK TRUE)
  47   elseif(NOT HAVE_GTK3)
  48     CHECK_MODULE(gtk+-2.0 HAVE_GTK)
  49     if(HAVE_GTK AND (ALIASOF_gtk+-2.0_VERSION VERSION_LESS MIN_VER_GTK))
  50       message (FATAL_ERROR "GTK support requires a minimum version of ${MIN_VER_GTK} (${ALIASOF_gtk+-2.0_VERSION} found)")
  51     endif()
  52   endif()
  53   CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
  54   if(HAVE_GTK OR HAVE_GTK3 AND NOT HAVE_GTHREAD)
  55     message(FATAL_ERROR "gthread not found. This library is required when building with GTK support")
  56   endif()
  57   if(WITH_OPENGL AND NOT HAVE_GTK3)
  58     CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
  59   endif()
  60 endif()
  61
  62 # --- OpenGl ---
  63 ocv_clear_vars(HAVE_OPENGL HAVE_QT_OPENGL)
  64 if(WITH_OPENGL)
  65   if(WITH_WIN32UI OR (HAVE_QT AND QT_QTOPENGL_FOUND) OR HAVE_GTKGLEXT)
  66     find_package (OpenGL QUIET)
  67     if(OPENGL_FOUND)
  68       set(HAVE_OPENGL TRUE)
  69       list(APPEND OPENCV_LINKER_LIBS ${OPENGL_LIBRARIES})
  70       if(QT_QTOPENGL_FOUND)
  71         set(HAVE_QT_OPENGL TRUE)
  72       else()
  73         ocv_include_directories(${OPENGL_INCLUDE_DIR})
  74       endif()
  75     endif()
  76   endif()
  77 endif(WITH_OPENGL)
  78
  79 # --- Carbon & Cocoa ---
  80 if(APPLE)
  81   if(WITH_CARBON)
  82     set(HAVE_CARBON YES)
  83   elseif(NOT IOS)
  84     set(HAVE_COCOA YES)
  85   endif()
  86 endif()