cmake/OpenCVFindLibsGUI.cmake

   1 # ----------------------------------------------------------------------------
   2 #  Detect 3rd-party GUI libraries
   3 # ----------------------------------------------------------------------------
   4
   5 #--- Win32 UI ---
   6 ocv_clear_vars(HAVE_WIN32UI)
   7 if(WITH_WIN32UI)
   8   try_compile(HAVE_WIN32UI
   9     "${OpenCV_BINARY_DIR}"
  10     "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
  11     CMAKE_FLAGS "-DLINK_LIBRARIES:STRING=user32;gdi32")
  12 endif()
  13
  14 # --- QT4 ---
  15 ocv_clear_vars(HAVE_QT HAVE_QT5)
  16 if(WITH_QT)
  17   if(NOT CMAKE_VERSION VERSION_LESS 2.8.3 AND NOT WITH_QT EQUAL 4)
  18     find_package(Qt5Core)
  19     find_package(Qt5Gui)
  20     find_package(Qt5Widgets)
  21     find_package(Qt5Test)
  22     find_package(Qt5Concurrent)
  23     if(Qt5Core_FOUND AND Qt5Gui_FOUND AND Qt5Widgets_FOUND AND Qt5Test_FOUND AND Qt5Concurrent_FOUND)
  24       set(HAVE_QT5 ON)
  25       set(HAVE_QT  ON)
  26       find_package(Qt5OpenGL)
  27       if(Qt5OpenGL_FOUND)
  28         set(QT_QTOPENGL_FOUND ON)
  29       endif()
  30     endif()
  31   endif()
  32
  33   if(NOT HAVE_QT)
  34     find_package(Qt4 REQUIRED QtCore QtGui QtTest)
  35     if(QT4_FOUND)
  36       set(HAVE_QT TRUE)
  37     endif()
  38   endif()
  39 endif()
  40
  41 # --- GTK ---
  42 ocv_clear_vars(HAVE_GTK HAVE_GTHREAD HAVE_GTKGLEXT)
  43 if(WITH_GTK AND NOT HAVE_QT)
  44   CHECK_MODULE(gtk+-2.0 HAVE_GTK)
  45   CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
  46   if(WITH_OPENGL)
  47     CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
  48   endif()
  49 endif()
  50
  51 # --- OpenGl ---
  52 ocv_clear_vars(HAVE_OPENGL HAVE_QT_OPENGL)
  53 if(WITH_OPENGL)
  54   if(WITH_WIN32UI OR (HAVE_QT AND QT_QTOPENGL_FOUND) OR HAVE_GTKGLEXT)
  55     find_package (OpenGL QUIET)
  56     if(OPENGL_FOUND)
  57       set(HAVE_OPENGL TRUE)
  58       list(APPEND OPENCV_LINKER_LIBS ${OPENGL_LIBRARIES})
  59       if(QT_QTOPENGL_FOUND)
  60         set(HAVE_QT_OPENGL TRUE)
  61       else()
  62         ocv_include_directories(${OPENGL_INCLUDE_DIR})
  63       endif()
  64     endif()
  65   endif()
  66 endif(WITH_OPENGL)
  67
  68 # --- Carbon & Cocoa ---
  69 if(APPLE)
  70   if(WITH_CARBON)
  71     set(HAVE_CARBON YES)
  72   elseif(NOT IOS)
  73     set(HAVE_COCOA YES)
  74   endif()
  75 endif()