cmake/OpenCVFindLibsGUI.cmake

   1 # ----------------------------------------------------------------------------
   2 #  Detect 3rd-party GUI libraries
   3 # ----------------------------------------------------------------------------
   4
   5 #--- Win32 UI ---
   6 ocv_clear_vars(HAVE_WIN32UI)
   7 if(WITH_WIN32UI)
   8   TRY_COMPILE(HAVE_WIN32UI
   9     "${OPENCV_BINARY_DIR}/CMakeFiles/CMakeTmp"
  10     "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
  11     CMAKE_FLAGS "\"user32.lib\" \"gdi32.lib\""
  12     OUTPUT_VARIABLE OUTPUT)
  13 endif(WITH_WIN32UI)
  14
  15 # --- QT4 ---
  16 ocv_clear_vars(HAVE_QT HAVE_QT5)
  17 if(WITH_QT)
  18   if(NOT CMAKE_VERSION VERSION_LESS 2.8.3 AND NOT WITH_QT EQUAL 4)
  19     find_package(Qt5Core)
  20     find_package(Qt5Gui)
  21     find_package(Qt5Widgets)
  22     find_package(Qt5Test)
  23     find_package(Qt5Concurrent)
  24     if(Qt5Core_FOUND AND Qt5Gui_FOUND AND Qt5Widgets_FOUND AND Qt5Test_FOUND AND Qt5Concurrent_FOUND)
  25       set(HAVE_QT5 ON)
  26       set(HAVE_QT  ON)
  27       add_definitions(-DHAVE_QT)
  28       find_package(Qt5OpenGL)
  29       if(Qt5OpenGL_FOUND)
  30         set(QT_QTOPENGL_FOUND ON)
  31       endif()
  32     endif()
  33   endif()
  34
  35   if(NOT HAVE_QT)
  36     find_package(Qt4 REQUIRED QtCore QtGui QtTest)
  37     if(QT4_FOUND)
  38       set(HAVE_QT TRUE)
  39       add_definitions(-DHAVE_QT) # We need to define the macro this way, using cvconfig.h does not work
  40     endif()
  41   endif()
  42 endif()
  43
  44 # --- GTK ---
  45 ocv_clear_vars(HAVE_GTK HAVE_GTHREAD HAVE_GTKGLEXT)
  46 if(WITH_GTK AND NOT HAVE_QT)
  47   CHECK_MODULE(gtk+-2.0 HAVE_GTK)
  48   CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
  49   if(WITH_OPENGL)
  50     CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
  51   endif()
  52 endif()
  53
  54 # --- OpenGl ---
  55 ocv_clear_vars(HAVE_OPENGL HAVE_QT_OPENGL)
  56 if(WITH_OPENGL)
  57   if(WITH_WIN32UI OR (HAVE_QT AND QT_QTOPENGL_FOUND) OR HAVE_GTKGLEXT)
  58     find_package (OpenGL QUIET)
  59     if(OPENGL_FOUND)
  60       set(HAVE_OPENGL TRUE)
  61       list(APPEND OPENCV_LINKER_LIBS ${OPENGL_LIBRARIES})
  62       if(QT_QTOPENGL_FOUND)
  63         set(HAVE_QT_OPENGL TRUE)
  64         add_definitions(-DHAVE_QT_OPENGL)
  65       else()
  66         ocv_include_directories(${OPENGL_INCLUDE_DIR})
  67       endif()
  68     endif()
  69   endif()
  70 endif(WITH_OPENGL)