cmake/OpenCVFindLibsGUI.cmake

   1 # ----------------------------------------------------------------------------
   2 #  Detect 3rd-party GUI libraries
   3 # ----------------------------------------------------------------------------
   4
   5 #--- Win32 UI ---
   6 ocv_clear_vars(HAVE_WIN32UI)
   7 if(WITH_WIN32UI)
   8   TRY_COMPILE(HAVE_WIN32UI
   9     "${OPENCV_BINARY_DIR}/CMakeFiles/CMakeTmp"
  10     "${OpenCV_SOURCE_DIR}/cmake/checks/win32uitest.cpp"
  11     CMAKE_FLAGS "\"user32.lib\" \"gdi32.lib\""
  12     OUTPUT_VARIABLE OUTPUT)
  13 endif(WITH_WIN32UI)
  14
  15 # --- QT4 ---
  16 ocv_clear_vars(HAVE_QT HAVE_QT5)
  17 if(WITH_QT)
  18   if(NOT CMAKE_VERSION VERSION_LESS 2.8.3 AND NOT WITH_QT EQUAL 4)
  19     find_package(Qt5Core)
  20     find_package(Qt5Gui)
  21     find_package(Qt5Widgets)
  22     find_package(Qt5Test)
  23     find_package(Qt5Concurrent)
  24     if(Qt5Core_FOUND AND Qt5Gui_FOUND AND Qt5Widgets_FOUND AND Qt5Test_FOUND AND Qt5Concurrent_FOUND)
  25       set(HAVE_QT5 ON)
  26       set(HAVE_QT  ON)
  27       find_package(Qt5OpenGL)
  28       if(Qt5OpenGL_FOUND)
  29         set(QT_QTOPENGL_FOUND ON)
  30       endif()
  31     endif()
  32   endif()
  33
  34   if(NOT HAVE_QT)
  35     find_package(Qt4 REQUIRED QtCore QtGui QtTest)
  36     if(QT4_FOUND)
  37       set(HAVE_QT TRUE)
  38     endif()
  39   endif()
  40 endif()
  41
  42 # --- GTK ---
  43 ocv_clear_vars(HAVE_GTK HAVE_GTHREAD HAVE_GTKGLEXT)
  44 if(WITH_GTK AND NOT HAVE_QT)
  45   CHECK_MODULE(gtk+-2.0 HAVE_GTK)
  46   CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
  47   if(WITH_OPENGL)
  48     CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
  49   endif()
  50 endif()
  51
  52 # --- OpenGl ---
  53 ocv_clear_vars(HAVE_OPENGL HAVE_QT_OPENGL)
  54 if(WITH_OPENGL)
  55   if(WITH_WIN32UI OR (HAVE_QT AND QT_QTOPENGL_FOUND) OR HAVE_GTKGLEXT)
  56     find_package (OpenGL QUIET)
  57     if(OPENGL_FOUND)
  58       set(HAVE_OPENGL TRUE)
  59       list(APPEND OPENCV_LINKER_LIBS ${OPENGL_LIBRARIES})
  60       if(QT_QTOPENGL_FOUND)
  61         set(HAVE_QT_OPENGL TRUE)
  62       else()
  63         ocv_include_directories(${OPENGL_INCLUDE_DIR})
  64       endif()
  65     endif()
  66   endif()
  67 endif(WITH_OPENGL)
  68
  69 # --- Carbon & Cocoa ---
  70 if(APPLE)
  71   if(WITH_CARBON)
  72     set(HAVE_CARBON YES)
  73   elseif(NOT IOS)
  74     set(HAVE_COCOA YES)
  75   endif()
  76 endif()