cmake/OpenCVFindLAPACK.cmake

   1 macro(_find_header_file_in_dirs VAR NAME)
   2   unset(${VAR})
   3   unset(${VAR} CACHE)
   4   if(" ${ARGN}" STREQUAL " ")
   5     check_include_file("${NAME}" HAVE_${VAR})
   6     if(HAVE_${VAR})
   7       set(${VAR} "${NAME}") # fallback
   8     else()
   9       set(${VAR} "")
  10     endif()
  11   else()
  12     find_path(${VAR} "${NAME}" ${ARGN} NO_DEFAULT_PATH)
  13     if(${VAR})
  14       set(${VAR} "${${VAR}}/${NAME}")
  15       unset(${VAR} CACHE)
  16     else()
  17       unset(${VAR} CACHE)
  18       set(${VAR} "")
  19     endif()
  20   endif()
  21 endmacro()
  22
  23 macro(ocv_lapack_check)
  24   string(REGEX REPLACE "[^a-zA-Z0-9_]" "_" _lapack_impl "${LAPACK_IMPL}")
  25   message(STATUS "LAPACK(${LAPACK_IMPL}): LAPACK_LIBRARIES: ${LAPACK_LIBRARIES}")
  26   _find_header_file_in_dirs(OPENCV_CBLAS_H_PATH_${_lapack_impl} "${LAPACK_CBLAS_H}" "${LAPACK_INCLUDE_DIR}")
  27   _find_header_file_in_dirs(OPENCV_LAPACKE_H_PATH_${_lapack_impl} "${LAPACK_LAPACKE_H}" "${LAPACK_INCLUDE_DIR}")
  28   if(NOT OPENCV_CBLAS_H_PATH_${_lapack_impl} OR NOT OPENCV_LAPACKE_H_PATH_${_lapack_impl})
  29     message(WARNING "LAPACK(${LAPACK_IMPL}): CBLAS/LAPACK headers are not found in '${LAPACK_INCLUDE_DIR}'")
  30     unset(LAPACK_LIBRARIES)
  31   else()
  32     # adding proxy opencv_lapack.h header
  33     set(CBLAS_H_PROXY_PATH ${CMAKE_BINARY_DIR}/opencv_lapack.h)
  34     set(_lapack_include_str "extern \"C\" {\n\#include \"${OPENCV_CBLAS_H_PATH_${_lapack_impl}}\"")
  35     if(NOT "${OPENCV_CBLAS_H_PATH_${_lapack_impl}}" STREQUAL "${OPENCV_LAPACKE_H_PATH_${_lapack_impl}}")
  36       set(_lapack_include_str "${_lapack_include_str}\n#include \"${OPENCV_LAPACKE_H_PATH_${_lapack_impl}}\"")
  37     endif()
  38     set(_lapack_include_str "${_lapack_include_str}\n}\n")
  39     # update file contents (if required)
  40     set(__content_str "")
  41     if(EXISTS "${CBLAS_H_PROXY_PATH}")
  42       file(READ "${CBLAS_H_PROXY_PATH}" __content_str)
  43     endif()
  44     if(NOT " ${__content_str}" STREQUAL " ${_lapack_include_str}")
  45       file(WRITE "${CBLAS_H_PROXY_PATH}" "${_lapack_include_str}")
  46     endif()
  47
  48     try_compile(__VALID_LAPACK
  49         "${OpenCV_BINARY_DIR}"
  50         "${OpenCV_SOURCE_DIR}/cmake/checks/lapack_check.cpp"
  51         CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${LAPACK_INCLUDE_DIR}\;${CMAKE_BINARY_DIR}"
  52                     "-DLINK_DIRECTORIES:STRING=${LAPACK_LINK_LIBRARIES}"
  53                     "-DLINK_LIBRARIES:STRING=${LAPACK_LIBRARIES}"
  54         OUTPUT_VARIABLE TRY_OUT
  55     )
  56     if(NOT __VALID_LAPACK)
  57       #message(FATAL_ERROR "LAPACK: check build log:\n${TRY_OUT}")
  58       message(STATUS "LAPACK(${LAPACK_IMPL}): Can't build LAPACK check code. This LAPACK version is not supported.")
  59       unset(LAPACK_LIBRARIES)
  60     else()
  61       message(STATUS "LAPACK(${LAPACK_IMPL}): Support is enabled.")
  62       ocv_include_directories(${LAPACK_INCLUDE_DIR})
  63       set(HAVE_LAPACK 1)
  64     endif()
  65   endif()
  66 endmacro()
  67
  68 if(WITH_LAPACK)
  69   ocv_update(LAPACK_IMPL "Unknown")
  70   if(NOT OPENCV_LAPACK_FIND_PACKAGE_ONLY)
  71     if(NOT LAPACK_LIBRARIES AND NOT OPENCV_LAPACK_DISABLE_MKL)
  72       include(cmake/OpenCVFindMKL.cmake)
  73       if(HAVE_MKL)
  74         set(LAPACK_INCLUDE_DIR  ${MKL_INCLUDE_DIRS})
  75         set(LAPACK_LIBRARIES    ${MKL_LIBRARIES})
  76         set(LAPACK_CBLAS_H      "mkl_cblas.h")
  77         set(LAPACK_LAPACKE_H    "mkl_lapack.h")
  78         set(LAPACK_IMPL         "MKL")
  79         ocv_lapack_check()
  80       endif()
  81     endif()
  82     if(NOT LAPACK_LIBRARIES)
  83       include(cmake/OpenCVFindOpenBLAS.cmake)
  84       if(OpenBLAS_FOUND)
  85         set(LAPACK_INCLUDE_DIR  ${OpenBLAS_INCLUDE_DIR})
  86         set(LAPACK_LIBRARIES    ${OpenBLAS_LIB})
  87         set(LAPACK_CBLAS_H      "cblas.h")
  88         set(LAPACK_LAPACKE_H    "lapacke.h")
  89         set(LAPACK_IMPL         "OpenBLAS")
  90         ocv_lapack_check()
  91       endif()
  92     endif()
  93     if(NOT LAPACK_LIBRARIES AND UNIX)
  94       include(cmake/OpenCVFindAtlas.cmake)
  95       if(ATLAS_FOUND)
  96         set(LAPACK_INCLUDE_DIR  ${Atlas_INCLUDE_DIR})
  97         set(LAPACK_LIBRARIES    ${Atlas_LIBRARIES})
  98         set(LAPACK_CBLAS_H      "cblas.h")
  99         set(LAPACK_LAPACKE_H    "lapacke.h")
 100         set(LAPACK_IMPL         "Atlas")
 101         ocv_lapack_check()
 102       endif()
 103     endif()
 104   endif()
 105
 106   if(NOT LAPACK_LIBRARIES)
 107     if(WIN32 AND NOT OPENCV_LAPACK_SHARED_LIBS)
 108       set(BLA_STATIC 1)
 109     endif()
 110     find_package(LAPACK)
 111     if(LAPACK_FOUND)
 112       if(NOT DEFINED LAPACKE_INCLUDE_DIR)
 113         find_path(LAPACKE_INCLUDE_DIR "lapacke.h")
 114       endif()
 115       if(NOT DEFINED MKL_LAPACKE_INCLUDE_DIR)
 116         find_path(MKL_LAPACKE_INCLUDE_DIR "mkl_lapack.h")
 117       endif()
 118       if(MKL_LAPACKE_INCLUDE_DIR AND NOT OPENCV_LAPACK_DISABLE_MKL)
 119         set(LAPACK_INCLUDE_DIR  ${MKL_LAPACKE_INCLUDE_DIR})
 120         set(LAPACK_CBLAS_H      "mkl_cblas.h")
 121         set(LAPACK_LAPACKE_H    "mkl_lapack.h")
 122         set(LAPACK_IMPL         "LAPACK/MKL")
 123         ocv_lapack_check()
 124       endif()
 125       if(NOT HAVE_LAPACK)
 126         if(LAPACKE_INCLUDE_DIR)
 127           set(LAPACK_INCLUDE_DIR  ${LAPACKE_INCLUDE_DIR})
 128           set(LAPACK_CBLAS_H      "cblas.h")
 129           set(LAPACK_LAPACKE_H    "lapacke.h")
 130           set(LAPACK_IMPL         "LAPACK/Generic")
 131           ocv_lapack_check()
 132         elseif(APPLE)
 133           set(LAPACK_CBLAS_H      "Accelerate/Accelerate.h")
 134           set(LAPACK_LAPACKE_H    "Accelerate/Accelerate.h")
 135           set(LAPACK_IMPL         "LAPACK/Apple")
 136           ocv_lapack_check()
 137         endif()
 138       endif()
 139     endif()
 140     if(NOT HAVE_LAPACK)
 141       unset(LAPACK_LIBRARIES)
 142       unset(LAPACK_LIBRARIES CACHE)
 143     endif()
 144   endif()
 145
 146   if(NOT LAPACK_LIBRARIES AND APPLE AND NOT OPENCV_LAPACK_FIND_PACKAGE_ONLY)
 147     set(LAPACK_INCLUDE_DIR  "")
 148     set(LAPACK_LIBRARIES    "-framework Accelerate")
 149     set(LAPACK_CBLAS_H      "Accelerate/Accelerate.h")
 150     set(LAPACK_LAPACKE_H    "Accelerate/Accelerate.h")
 151     set(LAPACK_IMPL         "Apple")
 152     ocv_lapack_check()
 153   endif()
 154
 155   if(NOT HAVE_LAPACK AND LAPACK_LIBRARIES AND LAPACK_CBLAS_H AND LAPACK_LAPACKE_H)
 156     ocv_lapack_check()
 157   endif()
 158
 159   set(LAPACK_INCLUDE_DIR ${LAPACK_INCLUDE_DIR} CACHE PATH   "Path to BLAS include dir" FORCE)
 160   set(LAPACK_CBLAS_H     ${LAPACK_CBLAS_H}     CACHE STRING "Alternative name of cblas.h" FORCE)
 161   set(LAPACK_LAPACKE_H   ${LAPACK_LAPACKE_H}   CACHE STRING "Alternative name of lapacke.h" FORCE)
 162   set(LAPACK_LIBRARIES   ${LAPACK_LIBRARIES}   CACHE STRING "Names of BLAS & LAPACK binaries (.so, .dll, .a, .lib)" FORCE)
 163   set(LAPACK_IMPL        ${LAPACK_IMPL}        CACHE STRING "Lapack implementation id" FORCE)
 164 endif()