cmake/OpenCVFindIPP.cmake

   1 #
   2 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   3 # installation/package
   4 #
   5 # This will try to find Intel IPP libraries, and include path by automatic
   6 # search through typical install locations and if failed it will
   7 # examine IPPROOT environment variable.
   8 # Note, IPPROOT is not set by IPP installer, it should be set manually.
   9 #
  10 # On return this will define:
  11 #
  12 # IPP_FOUND        - True if Intel IPP found
  13 # IPP_ROOT_DIR     - root of IPP installation
  14 # IPP_INCLUDE_DIRS - IPP include folder
  15 # IPP_LIBRARY_DIRS - IPP libraries folder
  16 # IPP_LIBRARIES    - IPP libraries names that are used by OpenCV
  17 # IPP_LATEST_VERSION_STR   - string with the newest detected IPP version
  18 # IPP_LATEST_VERSION_MAJOR - numbers of IPP version (MAJOR.MINOR.BUILD)
  19 # IPP_LATEST_VERSION_MINOR
  20 # IPP_LATEST_VERSION_BUILD
  21 #
  22 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  23 #
  24
  25 set(IPP_FOUND)
  26 set(IPP_VERSION_STR "5.3.0.0") # will not detect earlier versions
  27 set(IPP_VERSION_MAJOR 0)
  28 set(IPP_VERSION_MINOR 0)
  29 set(IPP_VERSION_BUILD 0)
  30 set(IPP_ROOT_DIR)
  31 set(IPP_INCLUDE_DIRS)
  32 set(IPP_LIBRARY_DIRS)
  33 set(IPP_LIBRARIES)
  34 set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
  35 set(IPP_LIB_SUFFIX  ${CMAKE_STATIC_LIBRARY_SUFFIX})
  36 set(IPP_PREFIX "ipp")
  37 set(IPP_SUFFIX "_l")
  38 set(IPPCORE    "core") # core functionality
  39 set(IPPS       "s")    # signal processing
  40 set(IPPI       "i")    # image processing
  41 set(IPPCC      "cc")   # color conversion
  42 set(IPPCV      "cv")   # computer vision
  43 set(IPPVM      "vm")   # vector math
  44
  45
  46 set(IPP_X64 0)
  47 if (CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
  48     set(IPP_X64 1)
  49 endif()
  50 if (CMAKE_CL_64)
  51     set(IPP_X64 1)
  52 endif()
  53
  54 # ------------------------------------------------------------------------
  55 # This function detect IPP version by analyzing ippversion.h file
  56 # Note, ippversion.h file was inroduced since IPP 5.3
  57 # ------------------------------------------------------------------------
  58 function(get_ipp_version _ROOT_DIR)
  59     set(_VERSION_STR)
  60     set(_MAJOR)
  61     set(_MINOR)
  62     set(_BUILD)
  63
  64     # read IPP version info from file
  65     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR1 REGEX "IPP_VERSION_MAJOR")
  66     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR2 REGEX "IPP_VERSION_MINOR")
  67     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_BUILD")
  68     if("${STR3}" STREQUAL "")
  69         file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_UPDATE")
  70     endif()
  71     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR4 REGEX "IPP_VERSION_STR")
  72
  73     # extract info and assign to variables
  74     string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  75     string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  76     string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  77     string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  78
  79     # export info to parent scope
  80     set(IPP_VERSION_STR   ${_VERSION_STR} PARENT_SCOPE)
  81     set(IPP_VERSION_MAJOR ${_MAJOR}       PARENT_SCOPE)
  82     set(IPP_VERSION_MINOR ${_MINOR}       PARENT_SCOPE)
  83     set(IPP_VERSION_BUILD ${_BUILD}       PARENT_SCOPE)
  84
  85     message(STATUS "found IPP: ${_MAJOR}.${_MINOR}.${_BUILD} [${_VERSION_STR}]")
  86     message(STATUS "at: ${_ROOT_DIR}")
  87
  88     return()
  89
  90 endfunction()
  91
  92
  93 # ------------------------------------------------------------------------
  94 # This is auxiliary function called from set_ipp_variables()
  95 # to set IPP_LIBRARIES variable in IPP 6.x style (IPP 5.3 should also work)
  96 # ------------------------------------------------------------------------
  97 function(set_ipp_old_libraries)
  98     set(IPP_PREFIX "ipp")
  99     set(IPP_SUFFIX)            # old style static core libs suffix
 100     set(IPP_ARCH)              # architecture suffix
 101     set(IPP_DISP   "emerged")  # old style dipatcher and cpu-specific
 102     set(IPP_MRGD   "merged")   #   static libraries
 103     set(IPPCORE    "core")     # core functionality
 104     set(IPPSP      "s")        # signal processing
 105     set(IPPIP      "i")        # image processing
 106     set(IPPCC      "cc")       # color conversion
 107     set(IPPCV      "cv")       # computer vision
 108     set(IPPVM      "vm")       # vector math
 109
 110     if (IPP_X64)
 111         set(IPP_ARCH "em64t")
 112     endif()
 113
 114     if(WIN32)
 115         set(IPP_SUFFIX "l")
 116     endif()
 117
 118     set(IPP_LIBRARIES
 119         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 120         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 121         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 122         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 123         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 124         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 125         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 126         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 127         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 128         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 129         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_ARCH}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 130         PARENT_SCOPE)
 131
 132     return()
 133
 134 endfunction()
 135
 136
 137 # ------------------------------------------------------------------------
 138 # This is auxiliary function called from set_ipp_variables()
 139 # to set IPP_LIBRARIES variable in IPP 7.x and 8.x style
 140 # ------------------------------------------------------------------------
 141 function(set_ipp_new_libraries _LATEST_VERSION)
 142     set(IPP_PREFIX "ipp")
 143
 144     if(${_LATEST_VERSION} VERSION_LESS "8.0")
 145         set(IPP_SUFFIX "_l")        # static not threaded libs suffix IPP 7.x
 146     else()
 147         if(WIN32)
 148             set(IPP_SUFFIX "mt")    # static not threaded libs suffix IPP 8.x for Windows
 149         else()
 150             set(IPP_SUFFIX "")      # static not threaded libs suffix IPP 8.x for Linux/OS X
 151         endif()
 152     endif()
 153     set(IPPCORE    "core")     # core functionality
 154     set(IPPSP      "s")        # signal processing
 155     set(IPPIP      "i")        # image processing
 156     set(IPPCC      "cc")       # color conversion
 157     set(IPPCV      "cv")       # computer vision
 158     set(IPPVM      "vm")       # vector math
 159
 160     set(IPP_LIBRARIES
 161         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 162         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 163         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 164         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPI}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 165         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPS}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 166         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_SUFFIX}${IPP_LIB_SUFFIX})
 167
 168     if (UNIX)
 169         set(IPP_LIBRARIES
 170             ${IPP_LIBRARIES}
 171             ${IPP_LIB_PREFIX}irc${CMAKE_SHARED_LIBRARY_SUFFIX}
 172             ${IPP_LIB_PREFIX}imf${CMAKE_SHARED_LIBRARY_SUFFIX}
 173             ${IPP_LIB_PREFIX}svml${CMAKE_SHARED_LIBRARY_SUFFIX})
 174     endif()
 175     set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 176     return()
 177
 178 endfunction()
 179
 180
 181 # ------------------------------------------------------------------------
 182 # This function will set
 183 # IPP_INCLUDE_DIRS, IPP_LIBRARY_DIRS and IPP_LIBRARIES variables depending
 184 # on IPP version parameter.
 185 # Since IPP 7.0 version library names and install folder structure
 186 # was changed
 187 # ------------------------------------------------------------------------
 188 function(set_ipp_variables _LATEST_VERSION)
 189     if(${_LATEST_VERSION} VERSION_LESS "7.0")
 190 #        message(STATUS "old")
 191
 192         # set INCLUDE and LIB folders
 193         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 194         set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib     PARENT_SCOPE)
 195
 196         if (IPP_X64)
 197             if(NOT EXISTS ${IPP_ROOT_DIR}/../em64t)
 198                 message(SEND_ERROR "IPP EM64T libraries not found")
 199             endif()
 200         else()
 201             if(NOT EXISTS ${IPP_ROOT_DIR}/../ia32)
 202                 message(SEND_ERROR "IPP IA32 libraries not found")
 203             endif()
 204         endif()
 205
 206         # set IPP_LIBRARIES variable (6.x lib names)
 207         set_ipp_old_libraries()
 208         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 209         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 210
 211     else()
 212 #        message(STATUS "new")
 213
 214         # set INCLUDE and LIB folders
 215         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 216
 217         if (APPLE)
 218             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib)
 219         elseif (IPP_X64)
 220             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/intel64)
 221                 message(SEND_ERROR "IPP EM64T libraries not found")
 222             endif()
 223             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/intel64)
 224         else()
 225             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/ia32)
 226                 message(SEND_ERROR "IPP IA32 libraries not found")
 227             endif()
 228             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/ia32)
 229         endif()
 230
 231         if (UNIX)
 232             get_filename_component(INTEL_COMPILER_LIBRARY_DIR ${IPP_ROOT_DIR}/../lib REALPATH)
 233             if (IPP_X64)
 234                 if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 235                     message(SEND_ERROR "Intel compiler EM64T libraries not found")
 236                 endif()
 237                 set(IPP_LIBRARY_DIRS
 238                     ${IPP_LIBRARY_DIRS}
 239                     ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 240             else()
 241                 if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 242                     message(SEND_ERROR "Intel compiler IA32 libraries not found")
 243                 endif()
 244                 set(IPP_LIBRARY_DIRS
 245                     ${IPP_LIBRARY_DIRS}
 246                     ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 247             endif()
 248         endif()
 249         set(IPP_LIBRARY_DIRS ${IPP_LIBRARY_DIRS} PARENT_SCOPE)
 250
 251         # set IPP_LIBRARIES variable (7.x or 8.x lib names)
 252         set_ipp_new_libraries(${_LATEST_VERSION})
 253         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 254         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 255
 256     endif()
 257
 258     return()
 259
 260 endfunction()
 261
 262
 263 # ------------------------------------------------------------------------
 264 # This section will look for IPP through IPPROOT env variable
 265 # Note, IPPROOT is not set by IPP installer, you may need to set it manually
 266 # ------------------------------------------------------------------------
 267 find_path(
 268     IPP_H_PATH
 269     NAMES ippversion.h
 270     PATHS $ENV{IPPROOT}
 271     PATH_SUFFIXES include
 272     DOC "The path to Intel(R) IPP header files"
 273     NO_DEFAULT_PATH
 274     NO_CMAKE_PATH)
 275
 276 if(IPP_H_PATH)
 277     set(IPP_FOUND 1)
 278
 279     # traverse up to IPPROOT level
 280     get_filename_component(IPP_ROOT_DIR ${IPP_H_PATH} PATH)
 281
 282     # extract IPP version info
 283     get_ipp_version(${IPP_ROOT_DIR})
 284
 285     # keep info in the same vars for auto search and search by IPPROOT
 286     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 287     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 288     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 289     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 290
 291     # set IPP INCLUDE, LIB dirs and library names
 292     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 293 endif()
 294
 295
 296 if(NOT IPP_FOUND)
 297     # reset var from previous search
 298     set(IPP_H_PATH)
 299
 300
 301     # ------------------------------------------------------------------------
 302     # This section will look for IPP through system program folders
 303     # Note, if several IPP installations found the newest version will be
 304     # selected
 305     # ------------------------------------------------------------------------
 306     foreach(curdir ${CMAKE_SYSTEM_PREFIX_PATH})
 307         set(curdir ${curdir}/intel)
 308         file(TO_CMAKE_PATH ${curdir} CURDIR)
 309
 310         if(EXISTS ${curdir})
 311             file(GLOB_RECURSE IPP_H_DIR ${curdir}/ippversion.h)
 312
 313             if(IPP_H_DIR)
 314                 set(IPP_FOUND 1)
 315             endif()
 316
 317             # init IPP_LATEST_VERSION  version with oldest detectable version (5.3.0.0)
 318             #   IPP prior 5.3 did not have ippversion.h file
 319             set(IPP_LATEST_VERSION_STR ${IPP_VERSION_STR})
 320
 321             # look through all dirs where ippversion.h was found
 322             foreach(item ${IPP_H_DIR})
 323
 324                 # traverse up to IPPROOT level
 325                 get_filename_component(_FILE_PATH ${item} PATH)
 326                 get_filename_component(_ROOT_DIR ${_FILE_PATH} PATH)
 327
 328                 # extract IPP version info
 329                 get_ipp_version(${_ROOT_DIR})
 330
 331                 # remember the latest version (if many found)
 332                 if(${IPP_LATEST_VERSION_STR} VERSION_LESS ${IPP_VERSION_STR})
 333                     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 334                     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 335                     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 336                     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 337                     set(IPP_ROOT_DIR ${_ROOT_DIR})
 338                 endif()
 339             endforeach()
 340         endif()
 341     endforeach()
 342 endif()
 343
 344 if(IPP_FOUND)
 345     # set IPP INCLUDE, LIB dirs and library names
 346     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 347
 348     # set CACHE variable IPP_H_PATH,
 349     # path to IPP header files for the latest version
 350     find_path(
 351         IPP_H_PATH
 352         NAMES ippversion.h
 353         PATHS ${IPP_ROOT_DIR}
 354         PATH_SUFFIXES include
 355         DOC "The path to Intel(R) IPP header files"
 356         NO_DEFAULT_PATH
 357         NO_CMAKE_PATH)
 358 endif()
 359
 360 if(WIN32 AND MINGW AND NOT IPP_LATEST_VERSION_MAJOR LESS 7)
 361     # Since IPP built with Microsoft compiler and /GS option
 362     # ======================================================
 363     # From Windows SDK 7.1
 364     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 365     # to avoid undefined reference to __security_cookie and _chkstk:
 366     set(MSV_RUNTMCHK "RunTmChk")
 367     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 368
 369     # To avoid undefined reference to _alldiv and _chkstk
 370     # ===================================================
 371     # NB: it may require a recompilation of w32api (after having modified
 372     #     the file ntdll.def) to export the required functions
 373     #     See http://code.opencv.org/issues/1906 for additional details
 374     set(MSV_NTDLL    "ntdll")
 375     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 376 endif()