cmake/OpenCVFindIPP.cmake

   1 #
   2 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   3 # installation/package
   4 #
   5 # By default, ICV version will be used.
   6 # To use standalone IPP update cmake command line:
   7 # cmake ... -DIPPROOT=<path> ...
   8 #
   9 # Note: Backward compatibility is broken, IPPROOT environment path is ignored
  10 #
  11 #
  12 # On return this will define:
  13 #
  14 # HAVE_IPP          - True if Intel IPP found
  15 # HAVE_IPP_ICV_ONLY - True if Intel IPP ICV version is available
  16 # IPP_ROOT_DIR      - root of IPP installation
  17 # IPP_INCLUDE_DIRS  - IPP include folder
  18 # IPP_LIBRARIES     - IPP libraries that are used by OpenCV
  19 # IPP_VERSION_STR   - string with the newest detected IPP version
  20 # IPP_VERSION_MAJOR - numbers of IPP version (MAJOR.MINOR.BUILD)
  21 # IPP_VERSION_MINOR
  22 # IPP_VERSION_BUILD
  23 #
  24 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  25 #
  26
  27 unset(HAVE_IPP CACHE)
  28 unset(HAVE_IPP_ICV_ONLY)
  29 unset(IPP_ROOT_DIR)
  30 unset(IPP_INCLUDE_DIRS)
  31 unset(IPP_LIBRARIES)
  32 unset(IPP_VERSION_STR)
  33 unset(IPP_VERSION_MAJOR)
  34 unset(IPP_VERSION_MINOR)
  35 unset(IPP_VERSION_BUILD)
  36
  37 set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
  38 set(IPP_LIB_SUFFIX  ${CMAKE_STATIC_LIBRARY_SUFFIX})
  39
  40 set(IPP_X64 0)
  41 if(CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
  42     set(IPP_X64 1)
  43 endif()
  44 if(CMAKE_CL_64)
  45     set(IPP_X64 1)
  46 endif()
  47
  48 # This function detects IPP version by analyzing .h file
  49 macro(ipp_get_version VERSION_FILE)
  50   unset(_VERSION_STR)
  51   unset(_MAJOR)
  52   unset(_MINOR)
  53   unset(_BUILD)
  54
  55   # read IPP version info from file
  56   file(STRINGS ${VERSION_FILE} STR1 REGEX "IPP_VERSION_MAJOR")
  57   file(STRINGS ${VERSION_FILE} STR2 REGEX "IPP_VERSION_MINOR")
  58   file(STRINGS ${VERSION_FILE} STR3 REGEX "IPP_VERSION_BUILD")
  59   if("${STR3}" STREQUAL "")
  60     file(STRINGS ${VERSION_FILE} STR3 REGEX "IPP_VERSION_UPDATE")
  61   endif()
  62   file(STRINGS ${VERSION_FILE} STR4 REGEX "IPP_VERSION_STR")
  63
  64   # extract info and assign to variables
  65   string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  66   string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  67   string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  68   string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  69
  70   # export info to parent scope
  71   set(IPP_VERSION_STR   ${_VERSION_STR})
  72   set(IPP_VERSION_MAJOR ${_MAJOR})
  73   set(IPP_VERSION_MINOR ${_MINOR})
  74   set(IPP_VERSION_BUILD ${_BUILD})
  75 endmacro()
  76
  77 macro(_ipp_not_supported)
  78   message(STATUS ${ARGN})
  79   unset(HAVE_IPP)
  80   unset(HAVE_IPP_ICV_ONLY)
  81   unset(IPP_VERSION_STR)
  82   return()
  83 endmacro()
  84
  85 # This macro uses IPP_ROOT_DIR variable
  86 # TODO Cleanup code after ICV package stabilization
  87 macro(ipp_detect_version)
  88   set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include)
  89
  90   set(__msg)
  91   if(EXISTS ${IPP_ROOT_DIR}/ippicv.h)
  92     set(__msg " (ICV version)")
  93     set(HAVE_IPP_ICV_ONLY 1)
  94     if(EXISTS ${IPP_ROOT_DIR}/ippversion.h)
  95       _ipp_not_supported("Can't resolve IPP directory: ${IPP_ROOT_DIR}")
  96     else()
  97       ipp_get_version(${IPP_ROOT_DIR}/ippicv.h)
  98     endif()
  99     ocv_assert(IPP_VERSION_STR VERSION_GREATER "8.0")
 100     set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/)
 101   elseif(EXISTS ${IPP_ROOT_DIR}/include/ipp.h)
 102     ipp_get_version(${IPP_ROOT_DIR}/include/ippversion.h)
 103     ocv_assert(IPP_VERSION_STR VERSION_GREATER "1.0")
 104   else()
 105     _ipp_not_supported("Can't resolve IPP directory: ${IPP_ROOT_DIR}")
 106   endif()
 107
 108   message(STATUS "found IPP${__msg}: ${_MAJOR}.${_MINOR}.${_BUILD} [${IPP_VERSION_STR}]")
 109   message(STATUS "at: ${IPP_ROOT_DIR}")
 110
 111   if(${IPP_VERSION_STR} VERSION_LESS "7.0")
 112     _ipp_not_supported("IPP ${IPP_VERSION_STR} is not supported")
 113   endif()
 114
 115   set(HAVE_IPP 1)
 116   if(EXISTS ${IPP_INCLUDE_DIRS}/ipp_redefine.h)
 117     set(HAVE_IPP_REDEFINE 1)
 118   else()
 119     unset(HAVE_IPP_REDEFINE)
 120   endif()
 121
 122   macro(_ipp_set_library_dir DIR)
 123     if(NOT EXISTS ${DIR})
 124       _ipp_not_supported("IPP library directory not found")
 125     endif()
 126     set(IPP_LIBRARY_DIR ${DIR})
 127   endmacro()
 128
 129   if(NOT HAVE_IPP_ICV_ONLY)
 130     if(APPLE)
 131       _ipp_set_library_dir(${IPP_ROOT_DIR}/lib)
 132     elseif(IPP_X64)
 133       _ipp_set_library_dir(${IPP_ROOT_DIR}/lib/intel64)
 134     else()
 135       _ipp_set_library_dir(${IPP_ROOT_DIR}/lib/ia32)
 136     endif()
 137   else()
 138     if(EXISTS ${IPP_ROOT_DIR}/lib)
 139       set(IPP_LIBRARY_DIR ${IPP_ROOT_DIR}/lib)
 140     else()
 141       _ipp_not_supported("IPP ${IPP_VERSION_STR} at ${IPP_ROOT_DIR} is not supported")
 142     endif()
 143     if(IPP_X64)
 144       _ipp_set_library_dir(${IPP_LIBRARY_DIR}/intel64)
 145     else()
 146       _ipp_set_library_dir(${IPP_LIBRARY_DIR}/ia32)
 147     endif()
 148   endif()
 149
 150   macro(_ipp_add_library name)
 151     if (EXISTS ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX})
 152       list(APPEND IPP_LIBRARIES ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX})
 153     else()
 154       message(STATUS "Can't find IPP library: ${name}")
 155     endif()
 156   endmacro()
 157
 158   set(IPP_PREFIX "ipp")
 159   if(${IPP_VERSION_STR} VERSION_LESS "8.0")
 160     set(IPP_SUFFIX "_l")      # static not threaded libs suffix IPP 7.x
 161   else()
 162     if(WIN32)
 163       set(IPP_SUFFIX "mt")    # static not threaded libs suffix IPP 8.x for Windows
 164     else()
 165       set(IPP_SUFFIX "")      # static not threaded libs suffix IPP 8.x for Linux/OS X
 166     endif()
 167   endif()
 168
 169   if(HAVE_IPP_ICV_ONLY)
 170     _ipp_add_library(icv)
 171   else()
 172     _ipp_add_library(core)
 173     _ipp_add_library(s)
 174     _ipp_add_library(i)
 175     _ipp_add_library(cc)
 176     _ipp_add_library(cv)
 177     _ipp_add_library(vm)
 178     _ipp_add_library(m)
 179
 180     if(UNIX)
 181       get_filename_component(INTEL_COMPILER_LIBRARY_DIR ${IPP_ROOT_DIR}/../lib REALPATH)
 182       if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR})
 183         get_filename_component(INTEL_COMPILER_LIBRARY_DIR ${IPP_ROOT_DIR}/../compiler/lib REALPATH)
 184       endif()
 185       if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR})
 186         _ipp_not_supported("IPP configuration error: can't find Intel compiler library dir ${INTEL_COMPILER_LIBRARY_DIR}")
 187       endif()
 188       if(NOT APPLE)
 189         if(IPP_X64)
 190           if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 191             message(SEND_ERROR "Intel compiler EM64T libraries not found")
 192           endif()
 193           set(INTEL_COMPILER_LIBRARY_DIR ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 194         else()
 195           if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 196             message(SEND_ERROR "Intel compiler IA32 libraries not found")
 197           endif()
 198           set(INTEL_COMPILER_LIBRARY_DIR ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 199         endif()
 200       endif()
 201
 202       macro(_ipp_add_compiler_library name)
 203         if (EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/${IPP_LIB_PREFIX}${name}${CMAKE_SHARED_LIBRARY_SUFFIX})
 204           list(APPEND IPP_LIBRARIES ${INTEL_COMPILER_LIBRARY_DIR}/${IPP_LIB_PREFIX}${name}${CMAKE_SHARED_LIBRARY_SUFFIX})
 205         else()
 206           message(STATUS "Can't find compiler library: ${name}")
 207         endif()
 208       endmacro()
 209
 210       _ipp_add_compiler_library(irc)
 211       _ipp_add_compiler_library(imf)
 212       _ipp_add_compiler_library(svml)
 213     endif(UNIX)
 214   endif()
 215
 216   #message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 217 endmacro()
 218
 219 # OPENCV_IPP_PATH is an environment variable for internal usage only, do not use it
 220 if(DEFINED ENV{OPENCV_IPP_PATH} AND NOT DEFINED IPPROOT)
 221   set(IPPROOT "$ENV{OPENCV_IPP_PATH}")
 222 endif()
 223 if(NOT DEFINED IPPROOT)
 224   include("${OpenCV_SOURCE_DIR}/3rdparty/ippicv/downloader.cmake")
 225   if(DEFINED OPENCV_ICV_PATH)
 226     set(IPPROOT "${OPENCV_ICV_PATH}")
 227   else()
 228     return()
 229   endif()
 230 endif()
 231
 232 # Try ICV
 233 find_path(
 234     IPP_ICV_H_PATH
 235     NAMES ippicv.h
 236     PATHS ${IPPROOT}
 237     DOC "The path to Intel(R) IPP ICV header files"
 238     NO_DEFAULT_PATH
 239     NO_CMAKE_PATH)
 240 set(IPP_ROOT_DIR ${IPP_ICV_H_PATH})
 241
 242 if(NOT IPP_ICV_H_PATH)
 243   # Try standalone IPP
 244   find_path(
 245       IPP_H_PATH
 246       NAMES ippversion.h
 247       PATHS ${IPPROOT}
 248       PATH_SUFFIXES include
 249       DOC "The path to Intel(R) IPP header files"
 250       NO_DEFAULT_PATH
 251       NO_CMAKE_PATH)
 252   if(IPP_H_PATH)
 253     get_filename_component(IPP_ROOT_DIR ${IPP_H_PATH} PATH)
 254   endif()
 255 endif()
 256
 257 if(IPP_ROOT_DIR)
 258   ipp_detect_version()
 259 endif()
 260
 261
 262 if(WIN32 AND MINGW AND NOT IPP_VERSION_MAJOR LESS 7)
 263     # Since IPP built with Microsoft compiler and /GS option
 264     # ======================================================
 265     # From Windows SDK 7.1
 266     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 267     # to avoid undefined reference to __security_cookie and _chkstk:
 268     set(MSV_RUNTMCHK "RunTmChk")
 269     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 270
 271     # To avoid undefined reference to _alldiv and _chkstk
 272     # ===================================================
 273     # NB: it may require a recompilation of w32api (after having modified
 274     #     the file ntdll.def) to export the required functions
 275     #     See http://code.opencv.org/issues/1906 for additional details
 276     set(MSV_NTDLL    "ntdll")
 277     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 278 endif()