cmake/OpenCVFindIPP.cmake

   1 #
   2 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   3 # installation/package
   4 #
   5 # This will try to find Intel IPP libraries, and include path by automatic
   6 # search through typical install locations and if failed it will
   7 # examine IPPROOT environment variable.
   8 # Note, IPPROOT is not set by IPP installer, it should be set manually.
   9 #
  10 # On return this will define:
  11 #
  12 # IPP_FOUND        - True if Intel IPP found
  13 # IPP_ROOT_DIR     - root of IPP installation
  14 # IPP_INCLUDE_DIRS - IPP include folder
  15 # IPP_LIBRARY_DIRS - IPP libraries folder
  16 # IPP_LIBRARIES    - IPP libraries names that are used by OpenCV
  17 # IPP_LATEST_VERSION_STR   - string with the newest detected IPP version
  18 # IPP_LATEST_VERSION_MAJOR - numbers of IPP version (MAJOR.MINOR.BUILD)
  19 # IPP_LATEST_VERSION_MINOR
  20 # IPP_LATEST_VERSION_BUILD
  21 #
  22 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  23 #
  24
  25 set(IPP_FOUND)
  26 set(IPP_VERSION_STR "5.3.0.0") # will not detect earlier versions
  27 set(IPP_VERSION_MAJOR 0)
  28 set(IPP_VERSION_MINOR 0)
  29 set(IPP_VERSION_BUILD 0)
  30 set(IPP_ROOT_DIR)
  31 set(IPP_INCLUDE_DIRS)
  32 set(IPP_LIBRARY_DIRS)
  33 set(IPP_LIBRARIES)
  34 set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
  35 set(IPP_LIB_SUFFIX  ${CMAKE_STATIC_LIBRARY_SUFFIX})
  36 set(IPP_PREFIX "ipp")
  37 set(IPP_SUFFIX "_l")
  38 set(IPPCORE    "core") # core functionality
  39 set(IPPS       "s")    # signal processing
  40 set(IPPI       "i")    # image processing
  41 set(IPPCC      "cc")   # color conversion
  42 set(IPPCV      "cv")   # computer vision
  43 set(IPPVM      "vm")   # vector math
  44
  45
  46 set(IPP_X64 0)
  47 if (CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
  48     set(IPP_X64 1)
  49 endif()
  50 if (CMAKE_CL_64)
  51     set(IPP_X64 1)
  52 endif()
  53
  54 # ------------------------------------------------------------------------
  55 # This function detect IPP version by analyzing ippversion.h file
  56 # Note, ippversion.h file was inroduced since IPP 5.3
  57 # ------------------------------------------------------------------------
  58 function(get_ipp_version _ROOT_DIR)
  59     set(_VERSION_STR)
  60     set(_MAJOR)
  61     set(_MINOR)
  62     set(_BUILD)
  63
  64     # read IPP version info from file
  65     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR1 REGEX "IPP_VERSION_MAJOR")
  66     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR2 REGEX "IPP_VERSION_MINOR")
  67     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_BUILD")
  68     if("${STR3}" STREQUAL "")
  69         file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_UPDATE")
  70     endif()
  71     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR4 REGEX "IPP_VERSION_STR")
  72
  73     # extract info and assign to variables
  74     string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  75     string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  76     string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  77     string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  78
  79     # export info to parent scope
  80     set(IPP_VERSION_STR   ${_VERSION_STR} PARENT_SCOPE)
  81     set(IPP_VERSION_MAJOR ${_MAJOR}       PARENT_SCOPE)
  82     set(IPP_VERSION_MINOR ${_MINOR}       PARENT_SCOPE)
  83     set(IPP_VERSION_BUILD ${_BUILD}       PARENT_SCOPE)
  84
  85     message(STATUS "found IPP: ${_MAJOR}.${_MINOR}.${_BUILD} [${_VERSION_STR}]")
  86     message(STATUS "at: ${_ROOT_DIR}")
  87
  88     return()
  89
  90 endfunction()
  91
  92
  93 # ------------------------------------------------------------------------
  94 # This is auxiliary function called from set_ipp_variables()
  95 # to set IPP_LIBRARIES variable in IPP 6.x style (IPP 5.3 should also work)
  96 # ------------------------------------------------------------------------
  97 function(set_ipp_old_libraries)
  98     set(IPP_PREFIX "ipp")
  99     set(IPP_SUFFIX)            # old style static core libs suffix
 100     set(IPP_ARCH)              # architecture suffix
 101     set(IPP_DISP   "emerged")  # old style dipatcher and cpu-specific
 102     set(IPP_MRGD   "merged")   #   static libraries
 103     set(IPPCORE    "core")     # core functionality
 104     set(IPPSP      "s")        # signal processing
 105     set(IPPIP      "i")        # image processing
 106     set(IPPCC      "cc")       # color conversion
 107     set(IPPCV      "cv")       # computer vision
 108     set(IPPVM      "vm")       # vector math
 109
 110     if (IPP_X64)
 111         set(IPP_ARCH "em64t")
 112     endif()
 113
 114     if(WIN32)
 115         set(IPP_SUFFIX "l")
 116     endif()
 117
 118     set(IPP_LIBRARIES
 119         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 120         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 121         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 122         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 123         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 124         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 125         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 126         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 127         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 128         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 129         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_ARCH}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 130         PARENT_SCOPE)
 131
 132     return()
 133
 134 endfunction()
 135
 136
 137 # ------------------------------------------------------------------------
 138 # This is auxiliary function called from set_ipp_variables()
 139 # to set IPP_LIBRARIES variable in IPP 7.x style
 140 # ------------------------------------------------------------------------
 141 function(set_ipp_new_libraries _LATEST_VERSION)
 142     set(IPP_PREFIX "ipp")
 143
 144     if(${_LATEST_VERSION} VERSION_LESS "8.0")
 145         set(IPP_SUFFIX "_l")       # static not threaded libs suffix
 146     else()
 147         set(IPP_SUFFIX "")       # static not threaded libs suffix
 148     endif()
 149     set(IPP_THRD   "_t")       # static threaded libs suffix
 150     set(IPPCORE    "core")     # core functionality
 151     set(IPPSP      "s")        # signal processing
 152     set(IPPIP      "i")        # image processing
 153     set(IPPCC      "cc")       # color conversion
 154     set(IPPCV      "cv")       # computer vision
 155     set(IPPVM      "vm")       # vector math
 156
 157     set(IPP_LIBRARIES
 158         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 159         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 160         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 161         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPI}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 162         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPS}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 163         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 164         PARENT_SCOPE)
 165
 166     return()
 167
 168 endfunction()
 169
 170
 171 # ------------------------------------------------------------------------
 172 # This function will set
 173 # IPP_INCLUDE_DIRS, IPP_LIBRARY_DIRS and IPP_LIBRARIES variables depending
 174 # on IPP version parameter.
 175 # Since IPP 7.0 version library names and install folder structure
 176 # was changed
 177 # ------------------------------------------------------------------------
 178 function(set_ipp_variables _LATEST_VERSION)
 179     if(${_LATEST_VERSION} VERSION_LESS "7.0")
 180 #        message(STATUS "old")
 181
 182         # set INCLUDE and LIB folders
 183         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 184         set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib     PARENT_SCOPE)
 185
 186         if (IPP_X64)
 187             if(NOT EXISTS ${IPP_ROOT_DIR}/../em64t)
 188                 message(SEND_ERROR "IPP EM64T libraries not found")
 189             endif()
 190         else()
 191             if(NOT EXISTS ${IPP_ROOT_DIR}/../ia32)
 192                 message(SEND_ERROR "IPP IA32 libraries not found")
 193             endif()
 194         endif()
 195
 196         # set IPP_LIBRARIES variable (6.x lib names)
 197         set_ipp_old_libraries()
 198         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 199         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 200
 201     else()
 202 #        message(STATUS "new")
 203
 204         # set INCLUDE and LIB folders
 205         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 206
 207         if (APPLE)
 208             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib PARENT_SCOPE)
 209         elseif (IPP_X64)
 210             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/intel64)
 211                 message(SEND_ERROR "IPP EM64T libraries not found")
 212             endif()
 213             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/intel64 PARENT_SCOPE)
 214         else()
 215             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/ia32)
 216                 message(SEND_ERROR "IPP IA32 libraries not found")
 217             endif()
 218             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/ia32 PARENT_SCOPE)
 219         endif()
 220
 221         # set IPP_LIBRARIES variable (7.x lib names)
 222         set_ipp_new_libraries(${_LATEST_VERSION})
 223         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 224         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 225
 226     endif()
 227
 228     return()
 229
 230 endfunction()
 231
 232
 233 # ------------------------------------------------------------------------
 234 # This section will look for IPP through IPPROOT env variable
 235 # Note, IPPROOT is not set by IPP installer, you may need to set it manually
 236 # ------------------------------------------------------------------------
 237 find_path(
 238     IPP_H_PATH
 239     NAMES ippversion.h
 240     PATHS $ENV{IPPROOT}
 241     PATH_SUFFIXES include
 242     DOC "The path to Intel(R) IPP header files"
 243     NO_DEFAULT_PATH
 244     NO_CMAKE_PATH)
 245
 246 if(IPP_H_PATH)
 247     set(IPP_FOUND 1)
 248
 249     # traverse up to IPPROOT level
 250     get_filename_component(IPP_ROOT_DIR ${IPP_H_PATH} PATH)
 251
 252     # extract IPP version info
 253     get_ipp_version(${IPP_ROOT_DIR})
 254
 255     # keep info in the same vars for auto search and search by IPPROOT
 256     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 257     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 258     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 259     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 260
 261     # set IPP INCLUDE, LIB dirs and library names
 262     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 263 endif()
 264
 265
 266 if(NOT IPP_FOUND)
 267     # reset var from previous search
 268     set(IPP_H_PATH)
 269
 270
 271     # ------------------------------------------------------------------------
 272     # This section will look for IPP through system program folders
 273     # Note, if several IPP installations found the newest version will be
 274     # selected
 275     # ------------------------------------------------------------------------
 276     foreach(curdir ${CMAKE_SYSTEM_PREFIX_PATH})
 277         set(curdir ${curdir}/intel)
 278         file(TO_CMAKE_PATH ${curdir} CURDIR)
 279
 280         if(EXISTS ${curdir})
 281             file(GLOB_RECURSE IPP_H_DIR ${curdir}/ippversion.h)
 282
 283             if(IPP_H_DIR)
 284                 set(IPP_FOUND 1)
 285             endif()
 286
 287             # init IPP_LATEST_VERSION  version with oldest detectable version (5.3.0.0)
 288             #   IPP prior 5.3 did not have ippversion.h file
 289             set(IPP_LATEST_VERSION_STR ${IPP_VERSION_STR})
 290
 291             # look through all dirs where ippversion.h was found
 292             foreach(item ${IPP_H_DIR})
 293
 294                 # traverse up to IPPROOT level
 295                 get_filename_component(_FILE_PATH ${item} PATH)
 296                 get_filename_component(_ROOT_DIR ${_FILE_PATH} PATH)
 297
 298                 # extract IPP version info
 299                 get_ipp_version(${_ROOT_DIR})
 300
 301                 # remember the latest version (if many found)
 302                 if(${IPP_LATEST_VERSION_STR} VERSION_LESS ${IPP_VERSION_STR})
 303                     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 304                     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 305                     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 306                     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 307                     set(IPP_ROOT_DIR ${_ROOT_DIR})
 308                 endif()
 309             endforeach()
 310         endif()
 311     endforeach()
 312 endif()
 313
 314 if(IPP_FOUND)
 315     # set IPP INCLUDE, LIB dirs and library names
 316     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 317
 318     # set CACHE variable IPP_H_PATH,
 319     # path to IPP header files for the latest version
 320     find_path(
 321         IPP_H_PATH
 322         NAMES ippversion.h
 323         PATHS ${IPP_ROOT_DIR}
 324         PATH_SUFFIXES include
 325         DOC "The path to Intel(R) IPP header files"
 326         NO_DEFAULT_PATH
 327         NO_CMAKE_PATH)
 328 endif()
 329
 330 if(WIN32 AND MINGW AND NOT IPP_LATEST_VERSION_MAJOR LESS 7)
 331     # Since IPP built with Microsoft compiler and /GS option
 332     # ======================================================
 333     # From Windows SDK 7.1
 334     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 335     # to avoid undefined reference to __security_cookie and _chkstk:
 336     set(MSV_RUNTMCHK "RunTmChk")
 337     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 338
 339     # To avoid undefined reference to _alldiv and _chkstk
 340     # ===================================================
 341     # NB: it may require a recompilation of w32api (after having modified
 342     #     the file ntdll.def) to export the required functions
 343     #     See http://code.opencv.org/issues/1906 for additional details
 344     set(MSV_NTDLL    "ntdll")
 345     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 346 endif()