cmake/OpenCVFindIPP.cmake

   1 #
   2 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   3 # installation/package
   4 #
   5 # This will try to find Intel IPP libraries, and include path by automatic
   6 # search through typical install locations and if failed it will
   7 # examine IPPROOT environment variable.
   8 # Note, IPPROOT is not set by IPP installer, it should be set manually.
   9 #
  10 # On return this will define:
  11 #
  12 # IPP_FOUND        - True if Intel IPP found
  13 # IPP_ROOT_DIR     - root of IPP installation
  14 # IPP_INCLUDE_DIRS - IPP include folder
  15 # IPP_LIBRARY_DIRS - IPP libraries folder
  16 # IPP_LIBRARIES    - IPP libraries names that are used by OpenCV
  17 # IPP_LATEST_VERSION_STR   - string with the newest detected IPP version
  18 # IPP_LATEST_VERSION_MAJOR - numbers of IPP version (MAJOR.MINOR.BUILD)
  19 # IPP_LATEST_VERSION_MINOR
  20 # IPP_LATEST_VERSION_BUILD
  21 #
  22 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  23 #
  24
  25 set(IPP_FOUND)
  26 set(IPP_VERSION_STR "5.3.0.0") # will not detect earlier versions
  27 set(IPP_VERSION_MAJOR 0)
  28 set(IPP_VERSION_MINOR 0)
  29 set(IPP_VERSION_BUILD 0)
  30 set(IPP_ROOT_DIR)
  31 set(IPP_INCLUDE_DIRS)
  32 set(IPP_LIBRARY_DIRS)
  33 set(IPP_LIBRARIES)
  34 set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
  35 set(IPP_LIB_SUFFIX  ${CMAKE_STATIC_LIBRARY_SUFFIX})
  36 set(IPP_PREFIX "ipp")
  37 set(IPP_SUFFIX "_l")
  38 set(IPPCORE    "core") # core functionality
  39 set(IPPS       "s")    # signal processing
  40 set(IPPI       "i")    # image processing
  41 set(IPPCC      "cc")   # color conversion
  42 set(IPPCV      "cv")   # computer vision
  43 set(IPPVM      "vm")   # vector math
  44
  45
  46 set(IPP_X64 0)
  47 if (CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
  48     set(IPP_X64 1)
  49 endif()
  50 if (CMAKE_CL_64)
  51     set(IPP_X64 1)
  52 endif()
  53
  54 # ------------------------------------------------------------------------
  55 # This function detect IPP version by analyzing ippversion.h file
  56 # Note, ippversion.h file was inroduced since IPP 5.3
  57 # ------------------------------------------------------------------------
  58 function(get_ipp_version _ROOT_DIR)
  59     set(_VERSION_STR)
  60     set(_MAJOR)
  61     set(_MINOR)
  62     set(_BUILD)
  63
  64     # read IPP version info from file
  65     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR1 REGEX "IPP_VERSION_MAJOR")
  66     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR2 REGEX "IPP_VERSION_MINOR")
  67     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_BUILD")
  68     if("${STR3}" STREQUAL "")
  69         file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR3 REGEX "IPP_VERSION_UPDATE")
  70     endif()
  71     file(STRINGS ${_ROOT_DIR}/include/ippversion.h STR4 REGEX "IPP_VERSION_STR")
  72
  73     # extract info and assign to variables
  74     string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  75     string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  76     string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  77     string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  78
  79     # export info to parent scope
  80     set(IPP_VERSION_STR   ${_VERSION_STR} PARENT_SCOPE)
  81     set(IPP_VERSION_MAJOR ${_MAJOR}       PARENT_SCOPE)
  82     set(IPP_VERSION_MINOR ${_MINOR}       PARENT_SCOPE)
  83     set(IPP_VERSION_BUILD ${_BUILD}       PARENT_SCOPE)
  84
  85     message(STATUS "found IPP: ${_MAJOR}.${_MINOR}.${_BUILD} [${_VERSION_STR}]")
  86     message(STATUS "at: ${_ROOT_DIR}")
  87
  88     return()
  89
  90 endfunction()
  91
  92
  93 # ------------------------------------------------------------------------
  94 # This is auxiliary function called from set_ipp_variables()
  95 # to set IPP_LIBRARIES variable in IPP 6.x style (IPP 5.3 should also work)
  96 # ------------------------------------------------------------------------
  97 function(set_ipp_old_libraries)
  98     set(IPP_PREFIX "ipp")
  99     set(IPP_SUFFIX)            # old style static core libs suffix
 100     set(IPP_ARCH)              # architecture suffix
 101     set(IPP_DISP   "emerged")  # old style dipatcher and cpu-specific
 102     set(IPP_MRGD   "merged")   #   static libraries
 103     set(IPPCORE    "core")     # core functionality
 104     set(IPPSP      "s")        # signal processing
 105     set(IPPIP      "i")        # image processing
 106     set(IPPCC      "cc")       # color conversion
 107     set(IPPCV      "cv")       # computer vision
 108     set(IPPVM      "vm")       # vector math
 109
 110     if (IPP_X64)
 111         set(IPP_ARCH "em64t")
 112     endif()
 113
 114     if(WIN32)
 115         set(IPP_SUFFIX "l")
 116     endif()
 117
 118     set(IPP_LIBRARIES
 119         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 120         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 121         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 122         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 123         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 124         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 125         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 126         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPIP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 127         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_MRGD}${IPP_ARCH}${IPP_LIB_SUFFIX}
 128         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPSP}${IPP_DISP}${IPP_ARCH}${IPP_LIB_SUFFIX}
 129         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_ARCH}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 130         PARENT_SCOPE)
 131
 132     return()
 133
 134 endfunction()
 135
 136
 137 # ------------------------------------------------------------------------
 138 # This is auxiliary function called from set_ipp_variables()
 139 # to set IPP_LIBRARIES variable in IPP 7.x and 8.x style
 140 # ------------------------------------------------------------------------
 141 function(set_ipp_new_libraries _LATEST_VERSION)
 142     set(IPP_PREFIX "ipp")
 143
 144     if(${_LATEST_VERSION} VERSION_LESS "8.0")
 145         set(IPP_SUFFIX "_l")        # static not threaded libs suffix IPP 7.x
 146     else()
 147         if(WIN32)
 148             set(IPP_SUFFIX "mt")    # static not threaded libs suffix IPP 8.x for Windows
 149         else()
 150             set(IPP_SUFFIX "")      # static not threaded libs suffix IPP 8.x for Linux/OS X
 151         endif()
 152     endif()
 153     set(IPPCORE    "core")     # core functionality
 154     set(IPPSP      "s")        # signal processing
 155     set(IPPIP      "i")        # image processing
 156     set(IPPCC      "cc")       # color conversion
 157     set(IPPCV      "cv")       # computer vision
 158     set(IPPVM      "vm")       # vector math
 159
 160     set(IPP_LIBRARIES
 161         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPVM}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 162         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCC}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 163         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCV}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 164         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPI}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 165         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPS}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 166         ${IPP_LIB_PREFIX}${IPP_PREFIX}${IPPCORE}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 167         PARENT_SCOPE)
 168
 169     return()
 170
 171 endfunction()
 172
 173
 174 # ------------------------------------------------------------------------
 175 # This function will set
 176 # IPP_INCLUDE_DIRS, IPP_LIBRARY_DIRS and IPP_LIBRARIES variables depending
 177 # on IPP version parameter.
 178 # Since IPP 7.0 version library names and install folder structure
 179 # was changed
 180 # ------------------------------------------------------------------------
 181 function(set_ipp_variables _LATEST_VERSION)
 182     if(${_LATEST_VERSION} VERSION_LESS "7.0")
 183 #        message(STATUS "old")
 184
 185         # set INCLUDE and LIB folders
 186         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 187         set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib     PARENT_SCOPE)
 188
 189         if (IPP_X64)
 190             if(NOT EXISTS ${IPP_ROOT_DIR}/../em64t)
 191                 message(SEND_ERROR "IPP EM64T libraries not found")
 192             endif()
 193         else()
 194             if(NOT EXISTS ${IPP_ROOT_DIR}/../ia32)
 195                 message(SEND_ERROR "IPP IA32 libraries not found")
 196             endif()
 197         endif()
 198
 199         # set IPP_LIBRARIES variable (6.x lib names)
 200         set_ipp_old_libraries()
 201         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 202         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 203
 204     else()
 205 #        message(STATUS "new")
 206
 207         # set INCLUDE and LIB folders
 208         set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include PARENT_SCOPE)
 209
 210         if (APPLE)
 211             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib PARENT_SCOPE)
 212         elseif (IPP_X64)
 213             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/intel64)
 214                 message(SEND_ERROR "IPP EM64T libraries not found")
 215             endif()
 216             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/intel64 PARENT_SCOPE)
 217         else()
 218             if(NOT EXISTS ${IPP_ROOT_DIR}/lib/ia32)
 219                 message(SEND_ERROR "IPP IA32 libraries not found")
 220             endif()
 221             set(IPP_LIBRARY_DIRS ${IPP_ROOT_DIR}/lib/ia32 PARENT_SCOPE)
 222         endif()
 223
 224         # set IPP_LIBRARIES variable (7.x or 8.x lib names)
 225         set_ipp_new_libraries(${_LATEST_VERSION})
 226         set(IPP_LIBRARIES ${IPP_LIBRARIES} PARENT_SCOPE)
 227         message(STATUS "IPP libs: ${IPP_LIBRARIES}")
 228
 229     endif()
 230
 231     return()
 232
 233 endfunction()
 234
 235
 236 # ------------------------------------------------------------------------
 237 # This section will look for IPP through IPPROOT env variable
 238 # Note, IPPROOT is not set by IPP installer, you may need to set it manually
 239 # ------------------------------------------------------------------------
 240 find_path(
 241     IPP_H_PATH
 242     NAMES ippversion.h
 243     PATHS $ENV{IPPROOT}
 244     PATH_SUFFIXES include
 245     DOC "The path to Intel(R) IPP header files"
 246     NO_DEFAULT_PATH
 247     NO_CMAKE_PATH)
 248
 249 if(IPP_H_PATH)
 250     set(IPP_FOUND 1)
 251
 252     # traverse up to IPPROOT level
 253     get_filename_component(IPP_ROOT_DIR ${IPP_H_PATH} PATH)
 254
 255     # extract IPP version info
 256     get_ipp_version(${IPP_ROOT_DIR})
 257
 258     # keep info in the same vars for auto search and search by IPPROOT
 259     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 260     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 261     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 262     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 263
 264     # set IPP INCLUDE, LIB dirs and library names
 265     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 266 endif()
 267
 268
 269 if(NOT IPP_FOUND)
 270     # reset var from previous search
 271     set(IPP_H_PATH)
 272
 273
 274     # ------------------------------------------------------------------------
 275     # This section will look for IPP through system program folders
 276     # Note, if several IPP installations found the newest version will be
 277     # selected
 278     # ------------------------------------------------------------------------
 279     foreach(curdir ${CMAKE_SYSTEM_PREFIX_PATH})
 280         set(curdir ${curdir}/intel)
 281         file(TO_CMAKE_PATH ${curdir} CURDIR)
 282
 283         if(EXISTS ${curdir})
 284             file(GLOB_RECURSE IPP_H_DIR ${curdir}/ippversion.h)
 285
 286             if(IPP_H_DIR)
 287                 set(IPP_FOUND 1)
 288             endif()
 289
 290             # init IPP_LATEST_VERSION  version with oldest detectable version (5.3.0.0)
 291             #   IPP prior 5.3 did not have ippversion.h file
 292             set(IPP_LATEST_VERSION_STR ${IPP_VERSION_STR})
 293
 294             # look through all dirs where ippversion.h was found
 295             foreach(item ${IPP_H_DIR})
 296
 297                 # traverse up to IPPROOT level
 298                 get_filename_component(_FILE_PATH ${item} PATH)
 299                 get_filename_component(_ROOT_DIR ${_FILE_PATH} PATH)
 300
 301                 # extract IPP version info
 302                 get_ipp_version(${_ROOT_DIR})
 303
 304                 # remember the latest version (if many found)
 305                 if(${IPP_LATEST_VERSION_STR} VERSION_LESS ${IPP_VERSION_STR})
 306                     set(IPP_LATEST_VERSION_STR   ${IPP_VERSION_STR})
 307                     set(IPP_LATEST_VERSION_MAJOR ${IPP_VERSION_MAJOR})
 308                     set(IPP_LATEST_VERSION_MINOR ${IPP_VERSION_MINOR})
 309                     set(IPP_LATEST_VERSION_BUILD ${IPP_VERSION_BUILD})
 310                     set(IPP_ROOT_DIR ${_ROOT_DIR})
 311                 endif()
 312             endforeach()
 313         endif()
 314     endforeach()
 315 endif()
 316
 317 if(IPP_FOUND)
 318     # set IPP INCLUDE, LIB dirs and library names
 319     set_ipp_variables(${IPP_LATEST_VERSION_STR})
 320
 321     # set CACHE variable IPP_H_PATH,
 322     # path to IPP header files for the latest version
 323     find_path(
 324         IPP_H_PATH
 325         NAMES ippversion.h
 326         PATHS ${IPP_ROOT_DIR}
 327         PATH_SUFFIXES include
 328         DOC "The path to Intel(R) IPP header files"
 329         NO_DEFAULT_PATH
 330         NO_CMAKE_PATH)
 331 endif()
 332
 333 if(WIN32 AND MINGW AND NOT IPP_LATEST_VERSION_MAJOR LESS 7)
 334     # Since IPP built with Microsoft compiler and /GS option
 335     # ======================================================
 336     # From Windows SDK 7.1
 337     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 338     # to avoid undefined reference to __security_cookie and _chkstk:
 339     set(MSV_RUNTMCHK "RunTmChk")
 340     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 341
 342     # To avoid undefined reference to _alldiv and _chkstk
 343     # ===================================================
 344     # NB: it may require a recompilation of w32api (after having modified
 345     #     the file ntdll.def) to export the required functions
 346     #     See http://code.opencv.org/issues/1906 for additional details
 347     set(MSV_NTDLL    "ntdll")
 348     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 349 endif()