cmake/OpenCVFindIPP.cmake

   1 #
   2 # The script to detect Intel(R) Integrated Performance Primitives (IPP)
   3 # installation/package
   4 #
   5 # By default, ICV version will be used.
   6 # To use standalone IPP update cmake command line:
   7 # cmake ... -DIPPROOT=<path> ...
   8 #
   9 # Note: Backward compatibility is broken, IPPROOT environment path is ignored
  10 #
  11 #
  12 # On return this will define:
  13 #
  14 # HAVE_IPP            - True if Intel IPP found
  15 # HAVE_IPP_ICV        - True if Intel IPP ICV version is available
  16 # IPP_ROOT_DIR        - root of IPP installation
  17 # IPP_INCLUDE_DIRS    - IPP include folder
  18 # IPP_LIBRARIES       - IPP libraries that are used by OpenCV
  19 # IPP_VERSION_STR     - string with the newest detected IPP version
  20 # IPP_VERSION_MAJOR   - numbers of IPP version (MAJOR.MINOR.BUILD)
  21 # IPP_VERSION_MINOR
  22 # IPP_VERSION_BUILD
  23 #
  24 # Created: 30 Dec 2010 by Vladimir Dudnik (vladimir.dudnik@intel.com)
  25 #
  26
  27 unset(HAVE_IPP CACHE)
  28 unset(HAVE_IPP_ICV)
  29 unset(IPP_ROOT_DIR)
  30 unset(IPP_INCLUDE_DIRS)
  31 unset(IPP_LIBRARIES)
  32 unset(IPP_VERSION_STR)
  33 unset(IPP_VERSION_MAJOR)
  34 unset(IPP_VERSION_MINOR)
  35 unset(IPP_VERSION_BUILD)
  36
  37 if (X86 AND UNIX AND NOT APPLE AND NOT ANDROID AND BUILD_SHARED_LIBS)
  38     message(STATUS "On 32-bit Linux Intel IPP can not currently be used with dynamic libs because of linker errors. Set BUILD_SHARED_LIBS=OFF")
  39     return()
  40 endif()
  41
  42 set(IPP_X64 0)
  43 if(CMAKE_CXX_SIZEOF_DATA_PTR EQUAL 8)
  44     set(IPP_X64 1)
  45 endif()
  46 if(CMAKE_CL_64)
  47     set(IPP_X64 1)
  48 endif()
  49
  50 # This function detects Intel IPP version by analyzing .h file
  51 macro(ipp_get_version VERSION_FILE)
  52   unset(_VERSION_STR)
  53   unset(_MAJOR)
  54   unset(_MINOR)
  55   unset(_BUILD)
  56
  57   # read Intel IPP version info from file
  58   file(STRINGS ${VERSION_FILE} STR1 REGEX "IPP_VERSION_MAJOR")
  59   file(STRINGS ${VERSION_FILE} STR2 REGEX "IPP_VERSION_MINOR")
  60   file(STRINGS ${VERSION_FILE} STR3 REGEX "IPP_VERSION_BUILD")
  61   if("${STR3}" STREQUAL "")
  62     file(STRINGS ${VERSION_FILE} STR3 REGEX "IPP_VERSION_UPDATE")
  63   endif()
  64   file(STRINGS ${VERSION_FILE} STR4 REGEX "IPP_VERSION_STR")
  65
  66   # extract info and assign to variables
  67   string(REGEX MATCHALL "[0-9]+" _MAJOR ${STR1})
  68   string(REGEX MATCHALL "[0-9]+" _MINOR ${STR2})
  69   string(REGEX MATCHALL "[0-9]+" _BUILD ${STR3})
  70   string(REGEX MATCHALL "[0-9]+[.]+[0-9]+[^\"]+|[0-9]+[.]+[0-9]+" _VERSION_STR ${STR4})
  71
  72   # export info to parent scope
  73   set(IPP_VERSION_STR   ${_VERSION_STR})
  74   set(IPP_VERSION_MAJOR ${_MAJOR})
  75   set(IPP_VERSION_MINOR ${_MINOR})
  76   set(IPP_VERSION_BUILD ${_BUILD})
  77 endmacro()
  78
  79 macro(_ipp_not_supported)
  80   message(STATUS ${ARGN})
  81   unset(HAVE_IPP)
  82   unset(HAVE_IPP_ICV)
  83   unset(IPP_VERSION_STR)
  84   return()
  85 endmacro()
  86
  87 # This macro uses IPP_ROOT_DIR variable
  88 # TODO Cleanup code after ICV package stabilization
  89 macro(ipp_detect_version)
  90   set(IPP_INCLUDE_DIRS ${IPP_ROOT_DIR}/include)
  91
  92   set(__msg)
  93   if(EXISTS ${IPP_ROOT_DIR}/include/ippicv_redefs.h)
  94     set(__msg " (ICV version)")
  95     set(HAVE_IPP_ICV 1)
  96   elseif(EXISTS ${IPP_ROOT_DIR}/include/ipp.h)
  97     # nothing
  98   else()
  99     _ipp_not_supported("Can't resolve Intel IPP directory: ${IPP_ROOT_DIR}")
 100   endif()
 101
 102   ipp_get_version(${IPP_INCLUDE_DIRS}/ippversion.h)
 103   ocv_assert(IPP_VERSION_STR VERSION_GREATER "1.0")
 104
 105   message(STATUS "found Intel IPP${__msg}: ${_MAJOR}.${_MINOR}.${_BUILD} [${IPP_VERSION_STR}]")
 106   message(STATUS "at: ${IPP_ROOT_DIR}")
 107
 108   if(${IPP_VERSION_STR} VERSION_LESS "7.0")
 109     _ipp_not_supported("Intel IPP ${IPP_VERSION_STR} is not supported")
 110   endif()
 111
 112   set(HAVE_IPP 1)
 113
 114   macro(_ipp_set_library_dir DIR)
 115     if(NOT EXISTS ${DIR})
 116       _ipp_not_supported("Intel IPP library directory not found")
 117     endif()
 118     set(IPP_LIBRARY_DIR ${DIR})
 119   endmacro()
 120
 121   if(APPLE AND NOT HAVE_IPP_ICV)
 122     _ipp_set_library_dir(${IPP_ROOT_DIR}/lib)
 123   elseif(IPP_X64)
 124     _ipp_set_library_dir(${IPP_ROOT_DIR}/lib/intel64)
 125   else()
 126     _ipp_set_library_dir(${IPP_ROOT_DIR}/lib/ia32)
 127   endif()
 128
 129   macro(_ipp_add_library name)
 130     # dynamic linking is only supported for standalone version of Intel IPP
 131     if (BUILD_WITH_DYNAMIC_IPP AND NOT HAVE_IPP_ICV)
 132       if (WIN32)
 133         set(IPP_LIB_PREFIX ${CMAKE_IMPORT_LIBRARY_PREFIX})
 134         set(IPP_LIB_SUFFIX ${CMAKE_IMPORT_LIBRARY_SUFFIX})
 135       else (WIN32)
 136         set(IPP_LIB_PREFIX ${CMAKE_SHARED_LIBRARY_PREFIX})
 137         set(IPP_LIB_SUFFIX ${CMAKE_SHARED_LIBRARY_SUFFIX})
 138       endif (WIN32)
 139     else ()
 140       set(IPP_LIB_PREFIX ${CMAKE_STATIC_LIBRARY_PREFIX})
 141       set(IPP_LIB_SUFFIX ${CMAKE_STATIC_LIBRARY_SUFFIX})
 142     endif ()
 143     if (EXISTS ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX})
 144       if (BUILD_WITH_DYNAMIC_IPP AND NOT HAVE_IPP_ICV)
 145         # When using dynamic libraries from standalone Intel IPP it is your responsibility to install those on the target system
 146         list(APPEND IPP_LIBRARIES ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX})
 147       else ()
 148         add_library(ipp${name} STATIC IMPORTED)
 149         set_target_properties(ipp${name} PROPERTIES
 150           IMPORTED_LINK_INTERFACE_LIBRARIES ""
 151           IMPORTED_LOCATION ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 152         )
 153         list(APPEND IPP_LIBRARIES ipp${name})
 154         if (NOT BUILD_SHARED_LIBS)
 155           # CMake doesn't support "install(TARGETS ${IPP_PREFIX}${name} " command with imported targets
 156           install(FILES ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX}
 157                   DESTINATION ${OPENCV_3P_LIB_INSTALL_PATH} COMPONENT dev)
 158           string(TOUPPER ${name} uname)
 159           set(IPP${uname}_INSTALL_PATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_3P_LIB_INSTALL_PATH}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX}" CACHE INTERNAL "" FORCE)
 160           set(IPP${uname}_LOCATION_PATH "${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX}" CACHE INTERNAL "" FORCE)
 161         endif()
 162       endif()
 163     else()
 164       message(STATUS "Can't find Intel IPP library: ${name} at ${IPP_LIBRARY_DIR}/${IPP_LIB_PREFIX}${IPP_PREFIX}${name}${IPP_SUFFIX}${IPP_LIB_SUFFIX}")
 165     endif()
 166   endmacro()
 167
 168   set(IPP_PREFIX "ipp")
 169   if(${IPP_VERSION_STR} VERSION_LESS "8.0")
 170     if (BUILD_WITH_DYNAMIC_IPP AND NOT HAVE_IPP_ICV)
 171       set(IPP_SUFFIX "")      # dynamic not threaded libs suffix Intel IPP 7.x
 172     else ()
 173       set(IPP_SUFFIX "_l")    # static not threaded libs suffix Intel IPP 7.x
 174     endif ()
 175   else ()
 176     if(WIN32)
 177       if (BUILD_WITH_DYNAMIC_IPP AND NOT HAVE_IPP_ICV)
 178         set(IPP_SUFFIX "")    # dynamic not threaded libs suffix Intel IPP 8.x for Windows
 179       else ()
 180         set(IPP_SUFFIX "mt")  # static not threaded libs suffix Intel IPP 8.x for Windows
 181       endif ()
 182     else()
 183       set(IPP_SUFFIX "")      # static not threaded libs suffix Intel IPP 8.x for Linux/OS X
 184     endif()
 185   endif()
 186
 187   if(HAVE_IPP_ICV)
 188     _ipp_add_library(icv)
 189   else()
 190     _ipp_add_library(cv)
 191     _ipp_add_library(i)
 192     _ipp_add_library(cc)
 193     _ipp_add_library(s)
 194     _ipp_add_library(vm)
 195     _ipp_add_library(core)
 196
 197     if(UNIX AND IPP_VERSION_MAJOR LESS 2017)
 198       get_filename_component(INTEL_COMPILER_LIBRARY_DIR ${IPP_ROOT_DIR}/../lib REALPATH)
 199       if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR})
 200         get_filename_component(INTEL_COMPILER_LIBRARY_DIR ${IPP_ROOT_DIR}/../compiler/lib REALPATH)
 201       endif()
 202       if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR})
 203         _ipp_not_supported("Intel IPP configuration error: can't find Intel compiler library dir ${INTEL_COMPILER_LIBRARY_DIR}")
 204       endif()
 205       if(NOT APPLE)
 206         if(IPP_X64)
 207           if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 208             message(SEND_ERROR "Intel compiler EM64T libraries not found")
 209           endif()
 210           set(INTEL_COMPILER_LIBRARY_DIR ${INTEL_COMPILER_LIBRARY_DIR}/intel64)
 211         else()
 212           if(NOT EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 213             message(SEND_ERROR "Intel compiler IA32 libraries not found")
 214           endif()
 215           set(INTEL_COMPILER_LIBRARY_DIR ${INTEL_COMPILER_LIBRARY_DIR}/ia32)
 216         endif()
 217       endif()
 218
 219       macro(_ipp_add_compiler_library name)
 220         if (EXISTS ${INTEL_COMPILER_LIBRARY_DIR}/${IPP_LIB_PREFIX}${name}${CMAKE_SHARED_LIBRARY_SUFFIX})
 221           list(APPEND IPP_LIBRARIES ${INTEL_COMPILER_LIBRARY_DIR}/${IPP_LIB_PREFIX}${name}${CMAKE_SHARED_LIBRARY_SUFFIX})
 222         else()
 223           message(STATUS "Can't find compiler library: ${name} at ${INTEL_COMPILER_LIBRARY_DIR}/${IPP_LIB_PREFIX}${name}${CMAKE_SHARED_LIBRARY_SUFFIX}")
 224         endif()
 225       endmacro()
 226
 227       _ipp_add_compiler_library(irc)
 228       _ipp_add_compiler_library(imf)
 229       _ipp_add_compiler_library(svml)
 230     endif()
 231   endif()
 232
 233   #message(STATUS "Intel IPP libs: ${IPP_LIBRARIES}")
 234 endmacro()
 235
 236 # OPENCV_IPP_PATH is an environment variable for internal usage only, do not use it
 237 if(DEFINED ENV{OPENCV_IPP_PATH} AND NOT DEFINED IPPROOT)
 238   set(IPPROOT "$ENV{OPENCV_IPP_PATH}")
 239 endif()
 240
 241 if(NOT DEFINED IPPROOT)
 242   include("${OpenCV_SOURCE_DIR}/3rdparty/ippicv/ippicv.cmake")
 243   download_ippicv(IPPROOT)
 244   if(NOT IPPROOT)
 245     return()
 246   endif()
 247   ocv_install_3rdparty_licenses(ippicv "${IPPROOT}/readme.htm" "${IPPROOT}/license/ippEULA.txt")
 248 endif()
 249
 250 file(TO_CMAKE_PATH "${IPPROOT}" __IPPROOT)
 251 if(EXISTS "${__IPPROOT}/include/ippversion.h")
 252   set(IPP_ROOT_DIR ${__IPPROOT})
 253   ipp_detect_version()
 254 endif()
 255
 256
 257 if(WIN32 AND MINGW AND NOT IPP_VERSION_MAJOR LESS 7)
 258     # Since Intel IPP built with Microsoft compiler and /GS option
 259     # ======================================================
 260     # From Windows SDK 7.1
 261     #   (usually in "C:\Program Files\Microsoft Visual Studio 10.0\VC\lib"),
 262     # to avoid undefined reference to __security_cookie and _chkstk:
 263     set(MSV_RUNTMCHK "RunTmChk")
 264     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_RUNTMCHK}${IPP_LIB_SUFFIX})
 265
 266     # To avoid undefined reference to _alldiv and _chkstk
 267     # ===================================================
 268     # NB: it may require a recompilation of w32api (after having modified
 269     #     the file ntdll.def) to export the required functions
 270     #     See http://code.opencv.org/issues/1906 for additional details
 271     set(MSV_NTDLL    "ntdll")
 272     set(IPP_LIBRARIES ${IPP_LIBRARIES} ${MSV_NTDLL}${IPP_LIB_SUFFIX})
 273 endif()