cmake/OpenCVDetectPython.cmake

   1 if(WIN32 AND NOT PYTHON_EXECUTABLE)
   2   # search for executable with the same bitness as resulting binaries
   3   # standard FindPythonInterp always prefers executable from system path
   4   # this is really important because we are using the interpreter for numpy search and for choosing the install location
   5   foreach(_CURRENT_VERSION ${Python_ADDITIONAL_VERSIONS} 2.7 "${MIN_VER_PYTHON}")
   6     find_host_program(PYTHON_EXECUTABLE
   7       NAMES python${_CURRENT_VERSION} python
   8       PATHS
   9         [HKEY_LOCAL_MACHINE\\\\SOFTWARE\\\\Python\\\\PythonCore\\\\${_CURRENT_VERSION}\\\\InstallPath]
  10         [HKEY_CURRENT_USER\\\\SOFTWARE\\\\Python\\\\PythonCore\\\\${_CURRENT_VERSION}\\\\InstallPath]
  11       NO_SYSTEM_ENVIRONMENT_PATH
  12     )
  13   endforeach()
  14 endif()
  15 find_host_package(PythonInterp "${MIN_VER_PYTHON}")
  16
  17 unset(HAVE_SPHINX CACHE)
  18
  19 if(PYTHONINTERP_FOUND)
  20   set(PYTHON_VERSION_MAJOR_MINOR "${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR}")
  21
  22   if(NOT ANDROID AND NOT IOS)
  23     ocv_check_environment_variables(PYTHON_LIBRARY PYTHON_INCLUDE_DIR)
  24     find_host_package(PythonLibs "${PYTHON_VERSION_STRING}" EXACT)
  25   endif()
  26
  27   if(NOT ANDROID AND NOT IOS)
  28     if(CMAKE_HOST_UNIX)
  29       execute_process(COMMAND ${PYTHON_EXECUTABLE} -c "from distutils.sysconfig import *; print(get_python_lib())"
  30                       RESULT_VARIABLE PYTHON_CVPY_PROCESS
  31                       OUTPUT_VARIABLE PYTHON_STD_PACKAGES_PATH
  32                       OUTPUT_STRIP_TRAILING_WHITESPACE)
  33       if("${PYTHON_STD_PACKAGES_PATH}" MATCHES "site-packages")
  34         set(_PYTHON_PACKAGES_PATH "python${PYTHON_VERSION_MAJOR_MINOR}/site-packages")
  35       else() #debian based assumed, install to the dist-packages.
  36         set(_PYTHON_PACKAGES_PATH "python${PYTHON_VERSION_MAJOR_MINOR}/dist-packages")
  37       endif()
  38       if(EXISTS "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}/${PYTHON_PACKAGES_PATH}")
  39         set(_PYTHON_PACKAGES_PATH "lib${LIB_SUFFIX}/${_PYTHON_PACKAGES_PATH}")
  40       else()
  41         set(_PYTHON_PACKAGES_PATH "lib/${_PYTHON_PACKAGES_PATH}")
  42       endif()
  43     elseif(CMAKE_HOST_WIN32)
  44       get_filename_component(PYTHON_PATH "${PYTHON_EXECUTABLE}" PATH)
  45       file(TO_CMAKE_PATH "${PYTHON_PATH}" PYTHON_PATH)
  46       if(NOT EXISTS "${PYTHON_PATH}/Lib/site-packages")
  47         unset(PYTHON_PATH)
  48         get_filename_component(PYTHON_PATH "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Python\\PythonCore\\${PYTHON_VERSION_MAJOR_MINOR}\\InstallPath]" ABSOLUTE)
  49         if(NOT PYTHON_PATH)
  50            get_filename_component(PYTHON_PATH "[HKEY_CURRENT_USER\\SOFTWARE\\Python\\PythonCore\\${PYTHON_VERSION_MAJOR_MINOR}\\InstallPath]" ABSOLUTE)
  51         endif()
  52         file(TO_CMAKE_PATH "${PYTHON_PATH}" PYTHON_PATH)
  53       endif()
  54       set(_PYTHON_PACKAGES_PATH "${PYTHON_PATH}/Lib/site-packages")
  55     endif()
  56     SET(PYTHON_PACKAGES_PATH "${_PYTHON_PACKAGES_PATH}" CACHE PATH "Where to install the python packages.")
  57
  58     if(NOT PYTHON_NUMPY_INCLUDE_DIRS)
  59       # Attempt to discover the NumPy include directory. If this succeeds, then build python API with NumPy
  60       execute_process(COMMAND "${PYTHON_EXECUTABLE}" -c
  61                         "import os; os.environ['DISTUTILS_USE_SDK']='1'; import numpy.distutils; print(os.pathsep.join(numpy.distutils.misc_util.get_numpy_include_dirs()))"
  62                       RESULT_VARIABLE PYTHON_NUMPY_PROCESS
  63                       OUTPUT_VARIABLE PYTHON_NUMPY_INCLUDE_DIRS
  64                       OUTPUT_STRIP_TRAILING_WHITESPACE)
  65
  66       if(PYTHON_NUMPY_PROCESS EQUAL 0)
  67         file(TO_CMAKE_PATH "${PYTHON_NUMPY_INCLUDE_DIRS}" _PYTHON_NUMPY_INCLUDE_DIRS)
  68         set(PYTHON_NUMPY_INCLUDE_DIRS "${_PYTHON_NUMPY_INCLUDE_DIRS}" CACHE PATH "Path to numpy headers")
  69       endif()
  70     endif()
  71
  72     if(PYTHON_NUMPY_INCLUDE_DIRS)
  73       execute_process(COMMAND "${PYTHON_EXECUTABLE}" -c "import numpy; print(numpy.version.version)"
  74                       OUTPUT_VARIABLE PYTHON_NUMPY_VERSION
  75                       OUTPUT_STRIP_TRAILING_WHITESPACE)
  76     endif()
  77   endif(NOT ANDROID AND NOT IOS)
  78 endif()
  79
  80 if(BUILD_DOCS)
  81   find_host_program(SPHINX_BUILD sphinx-build)
  82   find_host_program(PLANTUML plantuml)
  83   if(SPHINX_BUILD)
  84       execute_process(COMMAND "${SPHINX_BUILD}"
  85                       OUTPUT_QUIET
  86                       ERROR_VARIABLE SPHINX_OUTPUT
  87                       OUTPUT_STRIP_TRAILING_WHITESPACE)
  88       if(SPHINX_OUTPUT MATCHES "Sphinx v([0-9][^ \n]*)")
  89         set(SPHINX_VERSION "${CMAKE_MATCH_1}")
  90         set(HAVE_SPHINX 1)
  91         message(STATUS "Found Sphinx ${SPHINX_VERSION}: ${SPHINX_BUILD}")
  92       endif()
  93   endif()
  94 endif(BUILD_DOCS)