cmake/OpenCVDetectMediaSDK.cmake

   1 set(root "$ENV{MFX_HOME}")
   2
   3 find_path(MFX_INCLUDE mfxdefs.h PATHS "${root}/include" NO_DEFAULT_PATH)
   4
   5 # TODO: ICC? MINGW? ARM? IOS?
   6 if(WIN32)
   7     if(X86_64)
   8         set(arch "x64")
   9     else()
  10         set(arch "win32")
  11     endif()
  12 elseif(UNIX)
  13     set(arch "lin_x64")
  14 else()
  15     # ???
  16 endif()
  17
  18 find_library(MFX_LIBRARY mfx PATHS "${root}/lib/${arch}" NO_DEFAULT_PATH)
  19 find_library(MFX_VA_LIBRARY va)
  20 find_library(MFX_VA_DRM_LIBRARY va-drm)
  21
  22 if(MFX_INCLUDE AND MFX_LIBRARY AND MFX_VA_LIBRARY AND MFX_VA_DRM_LIBRARY)
  23     add_library(mfx-va UNKNOWN IMPORTED)
  24     set_target_properties(mfx-va PROPERTIES IMPORTED_LOCATION "${MFX_VA_LIBRARY}")
  25
  26     add_library(mfx-va-drm UNKNOWN IMPORTED)
  27     set_target_properties(mfx-va-drm PROPERTIES IMPORTED_LOCATION "${MFX_VA_DRM_LIBRARY}")
  28
  29     add_library(mfx UNKNOWN IMPORTED)
  30     set_target_properties(mfx PROPERTIES
  31       IMPORTED_LOCATION "${MFX_LIBRARY}"
  32       INTERFACE_INCLUDE_DIRECTORIES "${MFX_INCLUDE}"
  33       INTERFACE_LINK_LIBRARIES "mfx-va;mfx-va-drm;-Wl,--exclude-libs=libmfx"
  34     )
  35     set(HAVE_MFX 1)
  36 else()
  37     set(HAVE_MFX 0)
  38 endif()