cmake/OpenCVDetectHalide.cmake

   1 cmake_minimum_required(VERSION ${MIN_VER_CMAKE})
   2
   3 if(" ${HALIDE_ROOT_DIR}" STREQUAL " ")
   4   unset(HALIDE_ROOT_DIR CACHE)
   5 endif()
   6 ocv_check_environment_variables(HALIDE_ROOT_DIR)
   7 set(HALIDE_ROOT_DIR "${HALIDE_ROOT_DIR}" CACHE PATH "Halide root directory")
   8
   9 if(NOT HAVE_HALIDE)
  10   find_package(Halide QUIET) # Try CMake-based config files
  11   if(Halide_FOUND)
  12     if(TARGET Halide::Halide)  # modern Halide scripts defines imported target
  13       set(HALIDE_INCLUDE_DIRS "")
  14       set(HALIDE_LIBRARIES "Halide::Halide")
  15       set(HAVE_HALIDE TRUE)
  16     else()
  17       # using HALIDE_INCLUDE_DIRS / Halide_LIBRARIES
  18       set(HAVE_HALIDE TRUE)
  19     endif()
  20   endif()
  21 endif()
  22
  23 if(NOT HAVE_HALIDE AND HALIDE_ROOT_DIR)
  24   # Try manual search
  25   find_library(HALIDE_LIBRARY
  26       NAMES Halide
  27       HINTS ${HALIDE_ROOT_DIR}/lib          # Unix
  28       HINTS ${HALIDE_ROOT_DIR}/lib/Release  # Win32
  29   )
  30   find_path(HALIDE_INCLUDE_DIR
  31       NAMES Halide.h HalideRuntime.h
  32       HINTS ${HALIDE_ROOT_DIR}/include
  33   )
  34   if(HALIDE_LIBRARY AND HALIDE_INCLUDE_DIR)
  35     # TODO try_compile
  36     set(HALIDE_INCLUDE_DIRS "${HALIDE_INCLUDE_DIR}")
  37     set(HALIDE_LIBRARIES "${HALIDE_LIBRARY}")
  38     set(HAVE_HALIDE TRUE)
  39   endif()
  40 endif()
  41
  42 if(HAVE_HALIDE)
  43   if(HALIDE_INCLUDE_DIRS)
  44     include_directories(${HALIDE_INCLUDE_DIRS})
  45   endif()
  46   list(APPEND OPENCV_LINKER_LIBS ${HALIDE_LIBRARIES})
  47 endif()