cmake/OpenCVDetectCXXCompiler.cmake

   1 # Compilers:
   2 # - CV_GCC - GNU compiler (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
   3 # - CV_CLANG - Clang-compatible compiler (CMAKE_CXX_COMPILER_ID MATCHES "Clang" - Clang or AppleClang, see CMP0025)
   4 # - CV_ICC - Intel compiler
   5 # - MSVC - Microsoft Visual Compiler (CMake variable)
   6 # - MSVC64 - additional flag, 64-bit
   7 # - MINGW / CYGWIN / CMAKE_COMPILER_IS_MINGW / CMAKE_COMPILER_IS_CYGWIN (CMake original variables)
   8 # - MINGW64 - 64-bit
   9 #
  10 # CPU Platforms:
  11 # - X86 / X86_64
  12 # - ARM - ARM CPU, not defined for AArch64
  13 # - AARCH64 - ARMv8+ (64-bit)
  14 # - PPC64 / PPC64LE - PowerPC
  15 #
  16 # OS:
  17 # - WIN32 - Windows | MINGW
  18 # - UNIX - Linux | MacOSX | ANDROID
  19 # - ANDROID
  20 # - IOS
  21 # - APPLE - MacOSX | iOS
  22 # ----------------------------------------------------------------------------
  23
  24 if(CMAKE_CL_64)
  25     set(MSVC64 1)
  26 endif()
  27
  28 if(NOT DEFINED CV_GCC AND CMAKE_CXX_COMPILER_ID MATCHES "GNU")
  29   set(CV_GCC 1)
  30 endif()
  31 if(NOT DEFINED CV_CLANG AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")  # Clang or AppleClang (see CMP0025)
  32   set(CV_CLANG 1)
  33   set(CMAKE_COMPILER_IS_CLANGCXX 1)  # TODO next release: remove this
  34   set(CMAKE_COMPILER_IS_CLANGCC 1)   # TODO next release: remove this
  35 endif()
  36
  37 function(access_CMAKE_COMPILER_IS_CLANGCXX)
  38   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
  39     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CLANGCXX support is deprecated in OpenCV.
  40     Consider using:
  41     - CV_GCC    # GCC
  42     - CV_CLANG  # Clang or AppleClang (see CMP0025)
  43 ")
  44   endif()
  45 endfunction()
  46 variable_watch(CMAKE_COMPILER_IS_CLANGCXX access_CMAKE_COMPILER_IS_CLANGCXX)
  47 variable_watch(CMAKE_COMPILER_IS_CLANGCC access_CMAKE_COMPILER_IS_CLANGCXX)
  48
  49
  50 # ----------------------------------------------------------------------------
  51 # Detect Intel ICC compiler
  52 # ----------------------------------------------------------------------------
  53 if(UNIX)
  54   if  (__ICL)
  55     set(CV_ICC   __ICL)
  56   elseif(__ICC)
  57     set(CV_ICC   __ICC)
  58   elseif(__ECL)
  59     set(CV_ICC   __ECL)
  60   elseif(__ECC)
  61     set(CV_ICC   __ECC)
  62   elseif(__INTEL_COMPILER)
  63     set(CV_ICC   __INTEL_COMPILER)
  64   elseif(CMAKE_C_COMPILER MATCHES "icc")
  65     set(CV_ICC   icc_matches_c_compiler)
  66   endif()
  67 endif()
  68
  69 if(MSVC AND CMAKE_C_COMPILER MATCHES "icc|icl")
  70   set(CV_ICC   __INTEL_COMPILER_FOR_WINDOWS)
  71 endif()
  72
  73 if(NOT DEFINED CMAKE_CXX_COMPILER_VERSION)
  74   message(WARNING "Compiler version is not available: CMAKE_CXX_COMPILER_VERSION is not set")
  75 endif()
  76
  77 if(WIN32 AND CV_GCC)
  78   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpmachine
  79                   OUTPUT_VARIABLE OPENCV_GCC_TARGET_MACHINE
  80                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  81   if(OPENCV_GCC_TARGET_MACHINE MATCHES "amd64|x86_64|AMD64")
  82     set(MINGW64 1)
  83   endif()
  84 endif()
  85
  86 if(MSVC64 OR MINGW64)
  87   set(X86_64 1)
  88 elseif(MINGW OR (MSVC AND NOT CMAKE_CROSSCOMPILING))
  89   set(X86 1)
  90 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  91   set(X86_64 1)
  92 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "i686.*|i386.*|x86.*|amd64.*|AMD64.*")
  93   set(X86 1)
  94 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(arm.*|ARM.*)")
  95   set(ARM 1)
  96 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  97   set(AARCH64 1)
  98 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(powerpc|ppc)64le")
  99   set(PPC64LE 1)
 100 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(powerpc|ppc)64")
 101   set(PPC64 1)
 102 endif()
 103
 104 # Workaround for 32-bit operating systems on 64-bit x86_64 processor
 105 if(X86_64 AND CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT FORCE_X86_64)
 106   message(STATUS "sizeof(void) = 4 on x86 / x86_64 processor. Assume 32-bit compilation mode (X86=1)")
 107   unset(X86_64)
 108   set(X86 1)
 109 endif()
 110
 111 # Similar code exists in OpenCVConfig.cmake
 112 if(NOT DEFINED OpenCV_STATIC)
 113   # look for global setting
 114   if(NOT DEFINED BUILD_SHARED_LIBS OR BUILD_SHARED_LIBS)
 115     set(OpenCV_STATIC OFF)
 116   else()
 117     set(OpenCV_STATIC ON)
 118   endif()
 119 endif()
 120
 121 if(DEFINED OpenCV_ARCH AND DEFINED OpenCV_RUNTIME)
 122   # custom overridden values
 123 elseif(MSVC)
 124   if(CMAKE_CL_64)
 125     set(OpenCV_ARCH x64)
 126   elseif((CMAKE_GENERATOR MATCHES "ARM") OR ("${arch_hint}" STREQUAL "ARM") OR (CMAKE_VS_EFFECTIVE_PLATFORMS MATCHES "ARM|arm"))
 127     # see Modules/CmakeGenericSystem.cmake
 128     set(OpenCV_ARCH ARM)
 129   else()
 130     set(OpenCV_ARCH x86)
 131   endif()
 132   if(MSVC_VERSION EQUAL 1400)
 133     set(OpenCV_RUNTIME vc8)
 134   elseif(MSVC_VERSION EQUAL 1500)
 135     set(OpenCV_RUNTIME vc9)
 136   elseif(MSVC_VERSION EQUAL 1600)
 137     set(OpenCV_RUNTIME vc10)
 138   elseif(MSVC_VERSION EQUAL 1700)
 139     set(OpenCV_RUNTIME vc11)
 140   elseif(MSVC_VERSION EQUAL 1800)
 141     set(OpenCV_RUNTIME vc12)
 142   elseif(MSVC_VERSION EQUAL 1900)
 143     set(OpenCV_RUNTIME vc14)
 144   elseif(MSVC_VERSION MATCHES "^191[0-9]$")
 145     set(OpenCV_RUNTIME vc15)
 146   else()
 147     message(WARNING "OpenCV does not recognize MSVC_VERSION \"${MSVC_VERSION}\". Cannot set OpenCV_RUNTIME")
 148   endif()
 149 elseif(MINGW)
 150   set(OpenCV_RUNTIME mingw)
 151
 152   if(MINGW64)
 153     set(OpenCV_ARCH x64)
 154   else()
 155     set(OpenCV_ARCH x86)
 156   endif()
 157 endif()
 158
 159 # Fix handling of duplicated files in the same static library:
 160 # https://public.kitware.com/Bug/view.php?id=14874
 161 if(CMAKE_VERSION VERSION_LESS "3.1")
 162   foreach(var CMAKE_C_ARCHIVE_APPEND CMAKE_CXX_ARCHIVE_APPEND)
 163     if(${var} MATCHES "^<CMAKE_AR> r")
 164       string(REPLACE "<CMAKE_AR> r" "<CMAKE_AR> q" ${var} "${${var}}")
 165     endif()
 166   endforeach()
 167 endif()
 168
 169 if(ENABLE_CXX11)
 170   #cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
 171   set(CMAKE_CXX_STANDARD 11)
 172   set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 173   set(CMAKE_CXX_EXTENSIONS OFF) # use -std=c++11 instead of -std=gnu++11
 174   if(CMAKE_CXX11_COMPILE_FEATURES)
 175     set(HAVE_CXX11 ON)
 176   endif()
 177 endif()
 178 if(NOT HAVE_CXX11)
 179   ocv_check_compiler_flag(CXX "" HAVE_CXX11 "${OpenCV_SOURCE_DIR}/cmake/checks/cxx11.cpp")
 180   if(NOT HAVE_CXX11 AND ENABLE_CXX11)
 181     ocv_check_compiler_flag(CXX "-std=c++11" HAVE_STD_CXX11 "${OpenCV_SOURCE_DIR}/cmake/checks/cxx11.cpp")
 182     if(HAVE_STD_CXX11)
 183       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 184       set(HAVE_CXX11 ON)
 185     endif()
 186   endif()
 187 endif()