cmake/OpenCVDetectCXXCompiler.cmake

   1 # Compilers:
   2 # - CV_GCC - GNU compiler (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
   3 # - CV_CLANG - Clang-compatible compiler (CMAKE_CXX_COMPILER_ID MATCHES "Clang" - Clang or AppleClang, see CMP0025)
   4 # - CV_ICC - Intel compiler
   5 # - MSVC - Microsoft Visual Compiler (CMake variable)
   6 # - MSVC64 - additional flag, 64-bit
   7 # - MINGW / CYGWIN / CMAKE_COMPILER_IS_MINGW / CMAKE_COMPILER_IS_CYGWIN (CMake original variables)
   8 # - MINGW64 - 64-bit
   9 #
  10 # CPU Platforms:
  11 # - X86 / X86_64
  12 # - ARM - ARM CPU, not defined for AArch64
  13 # - AARCH64 - ARMv8+ (64-bit)
  14 # - PPC64 / PPC64LE - PowerPC
  15 #
  16 # OS:
  17 # - WIN32 - Windows | MINGW
  18 # - UNIX - Linux | MacOSX | ANDROID
  19 # - ANDROID
  20 # - IOS
  21 # - APPLE - MacOSX | iOS
  22 # ----------------------------------------------------------------------------
  23
  24 if(CMAKE_CL_64)
  25     set(MSVC64 1)
  26 endif()
  27
  28 if(NOT DEFINED CV_GCC AND CMAKE_CXX_COMPILER_ID MATCHES "GNU")
  29   set(CV_GCC 1)
  30 endif()
  31 if(NOT DEFINED CV_CLANG AND CMAKE_CXX_COMPILER_ID MATCHES "Clang")  # Clang or AppleClang (see CMP0025)
  32   set(CV_CLANG 1)
  33   set(CMAKE_COMPILER_IS_CLANGCXX 1)  # TODO next release: remove this
  34   set(CMAKE_COMPILER_IS_CLANGCC 1)   # TODO next release: remove this
  35 endif()
  36
  37 function(access_CMAKE_COMPILER_IS_CLANGCXX)
  38   if(NOT OPENCV_SUPPRESS_DEPRECATIONS)
  39     message(WARNING "DEPRECATED: CMAKE_COMPILER_IS_CLANGCXX support is deprecated in OpenCV.
  40     Consider using:
  41     - CV_GCC    # GCC
  42     - CV_CLANG  # Clang or AppleClang (see CMP0025)
  43 ")
  44   endif()
  45 endfunction()
  46 variable_watch(CMAKE_COMPILER_IS_CLANGCXX access_CMAKE_COMPILER_IS_CLANGCXX)
  47 variable_watch(CMAKE_COMPILER_IS_CLANGCC access_CMAKE_COMPILER_IS_CLANGCXX)
  48
  49
  50 # ----------------------------------------------------------------------------
  51 # Detect Intel ICC compiler
  52 # ----------------------------------------------------------------------------
  53 if(UNIX)
  54   if  (__ICL)
  55     set(CV_ICC   __ICL)
  56   elseif(__ICC)
  57     set(CV_ICC   __ICC)
  58   elseif(__ECL)
  59     set(CV_ICC   __ECL)
  60   elseif(__ECC)
  61     set(CV_ICC   __ECC)
  62   elseif(__INTEL_COMPILER)
  63     set(CV_ICC   __INTEL_COMPILER)
  64   elseif(CMAKE_C_COMPILER MATCHES "icc")
  65     set(CV_ICC   icc_matches_c_compiler)
  66   endif()
  67 endif()
  68
  69 if(MSVC AND CMAKE_C_COMPILER MATCHES "icc|icl")
  70   set(CV_ICC   __INTEL_COMPILER_FOR_WINDOWS)
  71 endif()
  72
  73 if(NOT DEFINED CMAKE_CXX_COMPILER_VERSION)
  74   message(WARNING "Compiler version is not available: CMAKE_CXX_COMPILER_VERSION is not set")
  75 endif()
  76
  77 if(WIN32 AND CV_GCC)
  78   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpmachine
  79                   OUTPUT_VARIABLE OPENCV_GCC_TARGET_MACHINE
  80                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  81   if(OPENCV_GCC_TARGET_MACHINE MATCHES "amd64|x86_64|AMD64")
  82     set(MINGW64 1)
  83   endif()
  84 endif()
  85
  86 message(STATUS "Detected processor: ${CMAKE_SYSTEM_PROCESSOR}")
  87 if(MSVC64 OR MINGW64)
  88   set(X86_64 1)
  89 elseif(MINGW OR (MSVC AND NOT CMAKE_CROSSCOMPILING))
  90   set(X86 1)
  91 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  92   set(X86_64 1)
  93 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "i686.*|i386.*|x86.*|amd64.*|AMD64.*")
  94   set(X86 1)
  95 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(arm.*|ARM.*)")
  96   set(ARM 1)
  97 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  98   set(AARCH64 1)
  99 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(powerpc|ppc)64le")
 100   set(PPC64LE 1)
 101 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(powerpc|ppc)64")
 102   set(PPC64 1)
 103 endif()
 104
 105 # Workaround for 32-bit operating systems on x86_64/aarch64 processor
 106 if(CMAKE_SIZEOF_VOID_P EQUAL 4 AND NOT FORCE_X86_64)
 107   message(STATUS "sizeof(void) = 4 on 64 bit processor. Assume 32-bit compilation mode")
 108   if (X86_64)
 109     unset(X86_64)
 110     set(X86 1)
 111   endif()
 112   if (AARCH64)
 113     unset(AARCH64)
 114     set(ARM 1)
 115   endif()
 116 endif()
 117
 118 # Similar code exists in OpenCVConfig.cmake
 119 if(NOT DEFINED OpenCV_STATIC)
 120   # look for global setting
 121   if(NOT DEFINED BUILD_SHARED_LIBS OR BUILD_SHARED_LIBS)
 122     set(OpenCV_STATIC OFF)
 123   else()
 124     set(OpenCV_STATIC ON)
 125   endif()
 126 endif()
 127
 128 if(DEFINED OpenCV_ARCH AND DEFINED OpenCV_RUNTIME)
 129   # custom overridden values
 130 elseif(MSVC)
 131   if(CMAKE_CL_64)
 132     set(OpenCV_ARCH x64)
 133   elseif((CMAKE_GENERATOR MATCHES "ARM") OR ("${arch_hint}" STREQUAL "ARM") OR (CMAKE_VS_EFFECTIVE_PLATFORMS MATCHES "ARM|arm"))
 134     # see Modules/CmakeGenericSystem.cmake
 135     set(OpenCV_ARCH ARM)
 136   else()
 137     set(OpenCV_ARCH x86)
 138   endif()
 139   if(MSVC_VERSION EQUAL 1400)
 140     set(OpenCV_RUNTIME vc8)
 141   elseif(MSVC_VERSION EQUAL 1500)
 142     set(OpenCV_RUNTIME vc9)
 143   elseif(MSVC_VERSION EQUAL 1600)
 144     set(OpenCV_RUNTIME vc10)
 145   elseif(MSVC_VERSION EQUAL 1700)
 146     set(OpenCV_RUNTIME vc11)
 147   elseif(MSVC_VERSION EQUAL 1800)
 148     set(OpenCV_RUNTIME vc12)
 149   elseif(MSVC_VERSION EQUAL 1900)
 150     set(OpenCV_RUNTIME vc14)
 151   elseif(MSVC_VERSION MATCHES "^191[0-9]$")
 152     set(OpenCV_RUNTIME vc15)
 153   elseif(MSVC_VERSION MATCHES "^192[0-9]$")
 154     set(OpenCV_RUNTIME vc16)
 155   else()
 156     message(WARNING "OpenCV does not recognize MSVC_VERSION \"${MSVC_VERSION}\". Cannot set OpenCV_RUNTIME")
 157   endif()
 158 elseif(MINGW)
 159   set(OpenCV_RUNTIME mingw)
 160
 161   if(MINGW64)
 162     set(OpenCV_ARCH x64)
 163   else()
 164     set(OpenCV_ARCH x86)
 165   endif()
 166 endif()
 167
 168 # Fix handling of duplicated files in the same static library:
 169 # https://public.kitware.com/Bug/view.php?id=14874
 170 if(CMAKE_VERSION VERSION_LESS "3.1")
 171   foreach(var CMAKE_C_ARCHIVE_APPEND CMAKE_CXX_ARCHIVE_APPEND)
 172     if(${var} MATCHES "^<CMAKE_AR> r")
 173       string(REPLACE "<CMAKE_AR> r" "<CMAKE_AR> q" ${var} "${${var}}")
 174     endif()
 175   endforeach()
 176 endif()
 177
 178 set(CMAKE_CXX_STANDARD 11)
 179 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 180 set(CMAKE_CXX_EXTENSIONS OFF) # use -std=c++11 instead of -std=gnu++11
 181 if(CMAKE_CXX11_COMPILE_FEATURES)
 182   set(HAVE_CXX11 ON)
 183 endif()
 184 if(NOT HAVE_CXX11)
 185   ocv_check_compiler_flag(CXX "" HAVE_CXX11 "${OpenCV_SOURCE_DIR}/cmake/checks/cxx11.cpp")
 186   if(NOT HAVE_CXX11)
 187     ocv_check_compiler_flag(CXX "-std=c++11" HAVE_STD_CXX11 "${OpenCV_SOURCE_DIR}/cmake/checks/cxx11.cpp")
 188     if(HAVE_STD_CXX11)
 189       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 190       set(HAVE_CXX11 ON)
 191     endif()
 192   endif()
 193 endif()
 194 if(NOT HAVE_CXX11)
 195   message(FATAL_ERROR "OpenCV 4.x requires C++11")
 196 endif()