cmake/OpenCVDetectCUDA.cmake

   1 if(WIN32 AND NOT MSVC)
   2   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   3   return()
   4 endif()
   5
   6 if(NOT UNIX AND CV_CLANG)
   7   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
   8   return()
   9 endif()
  10
  11
  12 if(((NOT CMAKE_VERSION VERSION_LESS "3.9.0")  # requires https://gitlab.kitware.com/cmake/cmake/merge_requests/663
  13       OR OPENCV_CUDA_FORCE_EXTERNAL_CMAKE_MODULE)
  14     AND NOT OPENCV_CUDA_FORCE_BUILTIN_CMAKE_MODULE)
  15   ocv_update(CUDA_LINK_LIBRARIES_KEYWORD "LINK_PRIVATE")
  16   find_host_package(CUDA "${MIN_VER_CUDA}" QUIET)
  17 else()
  18   # Use OpenCV's patched "FindCUDA" module
  19   set(CMAKE_MODULE_PATH "${OpenCV_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
  20
  21   if(ANDROID)
  22     set(CUDA_TARGET_OS_VARIANT "Android")
  23   endif()
  24   find_host_package(CUDA "${MIN_VER_CUDA}" QUIET)
  25
  26   list(REMOVE_AT CMAKE_MODULE_PATH 0)
  27 endif()
  28
  29 if(CUDA_FOUND)
  30   set(HAVE_CUDA 1)
  31
  32   if(WITH_CUFFT)
  33     set(HAVE_CUFFT 1)
  34   endif()
  35
  36   if(WITH_CUBLAS)
  37     set(HAVE_CUBLAS 1)
  38   endif()
  39
  40   if(WITH_NVCUVID)
  41     find_cuda_helper_libs(nvcuvid)
  42     if(WIN32)
  43       find_cuda_helper_libs(nvcuvenc)
  44     endif()
  45     if(CUDA_nvcuvid_LIBRARY)
  46       set(HAVE_NVCUVID 1)
  47     endif()
  48     if(CUDA_nvcuvenc_LIBRARY)
  49       set(HAVE_NVCUVENC 1)
  50     endif()
  51   endif()
  52
  53   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  54
  55   set(_generations "Fermi" "Kepler" "Maxwell" "Pascal" "Volta" "Turing")
  56   if(NOT CMAKE_CROSSCOMPILING)
  57     list(APPEND _generations "Auto")
  58   endif()
  59   set(CUDA_GENERATION "" CACHE STRING "Build CUDA device code only for specific GPU architecture. Leave empty to build for all architectures.")
  60   if( CMAKE_VERSION VERSION_GREATER "2.8" )
  61     set_property( CACHE CUDA_GENERATION PROPERTY STRINGS "" ${_generations} )
  62   endif()
  63
  64   if(CUDA_GENERATION)
  65     if(NOT ";${_generations};" MATCHES ";${CUDA_GENERATION};")
  66       string(REPLACE ";" ", " _generations "${_generations}")
  67       message(FATAL_ERROR "ERROR: ${_generations} Generations are suppered.")
  68     endif()
  69     unset(CUDA_ARCH_BIN CACHE)
  70     unset(CUDA_ARCH_PTX CACHE)
  71   endif()
  72
  73   SET(DETECT_ARCHS_COMMAND "${CUDA_NVCC_EXECUTABLE}" ${CUDA_NVCC_FLAGS} "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" "--run")
  74   if(WIN32 AND CMAKE_LINKER) #Workaround for VS cl.exe not being in the env. path
  75     get_filename_component(host_compiler_bindir ${CMAKE_LINKER} DIRECTORY)
  76     SET(DETECT_ARCHS_COMMAND ${DETECT_ARCHS_COMMAND} "-ccbin" "${host_compiler_bindir}")
  77   endif()
  78
  79   set(__cuda_arch_ptx "")
  80   if(CUDA_GENERATION STREQUAL "Fermi")
  81     set(__cuda_arch_bin "2.0")
  82   elseif(CUDA_GENERATION STREQUAL "Kepler")
  83     set(__cuda_arch_bin "3.0 3.5 3.7")
  84   elseif(CUDA_GENERATION STREQUAL "Maxwell")
  85     set(__cuda_arch_bin "5.0 5.2")
  86   elseif(CUDA_GENERATION STREQUAL "Pascal")
  87     set(__cuda_arch_bin "6.0 6.1")
  88   elseif(CUDA_GENERATION STREQUAL "Volta")
  89     set(__cuda_arch_bin "7.0")
  90   elseif(CUDA_GENERATION STREQUAL "Turing")
  91     set(__cuda_arch_bin "7.5")
  92   elseif(CUDA_GENERATION STREQUAL "Auto")
  93     execute_process( COMMAND ${DETECT_ARCHS_COMMAND}
  94                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
  95                      RESULT_VARIABLE _nvcc_res OUTPUT_VARIABLE _nvcc_out
  96                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  97     string(REGEX REPLACE ".*\n" "" _nvcc_out "${_nvcc_out}") #Strip leading warning messages, if any
  98     if(NOT _nvcc_res EQUAL 0)
  99       message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
 100     else()
 101       set(__cuda_arch_bin "${_nvcc_out}")
 102       string(REPLACE "2.1" "2.1(2.0)" __cuda_arch_bin "${__cuda_arch_bin}")
 103     endif()
 104   endif()
 105
 106   if(NOT DEFINED __cuda_arch_bin)
 107     if(ARM)
 108       set(__cuda_arch_bin "3.2")
 109       set(__cuda_arch_ptx "")
 110     elseif(AARCH64)
 111       execute_process( COMMAND ${DETECT_ARCHS_COMMAND}
 112                        WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
 113                        RESULT_VARIABLE _nvcc_res OUTPUT_VARIABLE _nvcc_out
 114                        ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
 115       string(REGEX REPLACE ".*\n" "" _nvcc_out "${_nvcc_out}") #Strip leading warning messages, if any
 116       if(NOT _nvcc_res EQUAL 0)
 117         message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
 118         set(__cuda_arch_bin "5.3 6.2 7.2")
 119       else()
 120         set(__cuda_arch_bin "${_nvcc_out}")
 121         string(REPLACE "2.1" "2.1(2.0)" __cuda_arch_bin "${__cuda_arch_bin}")
 122       endif()
 123       set(__cuda_arch_ptx "")
 124     else()
 125       if(CUDA_VERSION VERSION_LESS "9.0")
 126         set(__cuda_arch_bin "2.0 3.0 3.5 3.7 5.0 5.2 6.0 6.1")
 127       elseif(CUDA_VERSION VERSION_LESS "10.0")
 128         set(__cuda_arch_bin "3.0 3.5 3.7 5.0 5.2 6.0 6.1 7.0")
 129       else()
 130         set(__cuda_arch_bin "3.0 3.5 3.7 5.0 5.2 6.0 6.1 7.0 7.5")
 131       endif()
 132     endif()
 133   endif()
 134
 135   set(CUDA_ARCH_BIN ${__cuda_arch_bin} CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
 136   set(CUDA_ARCH_PTX ${__cuda_arch_ptx} CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
 137
 138   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
 139   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
 140
 141   # Ckeck if user specified 1.0 compute capability: we don't support it
 142   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
 143   set(CUDA_ARCH_BIN_OR_PTX_10 0)
 144   if(NOT ${HAS_ARCH_10} STREQUAL "")
 145     set(CUDA_ARCH_BIN_OR_PTX_10 1)
 146   endif()
 147
 148   # NVCC flags to be set
 149   set(NVCC_FLAGS_EXTRA "")
 150
 151   # These vars will be passed into the templates
 152   set(OPENCV_CUDA_ARCH_BIN "")
 153   set(OPENCV_CUDA_ARCH_PTX "")
 154   set(OPENCV_CUDA_ARCH_FEATURES "")
 155
 156   # Tell NVCC to add binaries for the specified GPUs
 157   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
 158   foreach(ARCH IN LISTS ARCH_LIST)
 159     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
 160       # User explicitly specified PTX for the concrete BIN
 161       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
 162       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
 163       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
 164     else()
 165       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
 166       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
 167       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
 168       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 169     endif()
 170   endforeach()
 171   set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -D_FORCE_INLINES)
 172
 173   # Tell NVCC to add PTX intermediate code for the specified architectures
 174   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
 175   foreach(ARCH IN LISTS ARCH_LIST)
 176     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
 177     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
 178     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 179   endforeach()
 180
 181   # These vars will be processed in other scripts
 182   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
 183   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
 184
 185   if(ANDROID)
 186     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} "-Xptxas;-dlcm=ca")
 187   endif()
 188
 189   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
 190
 191   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
 192
 193   if(CUDA_FAST_MATH)
 194     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
 195   endif()
 196
 197   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
 198
 199   macro(ocv_cuda_filter_options)
 200     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 201       set(${var}_backup_in_cuda_compile_ "${${var}}")
 202
 203       if (CV_CLANG)
 204         # we remove -Winconsistent-missing-override and -Qunused-arguments
 205         # just in case we are compiling CUDA with gcc but OpenCV with clang
 206         string(REPLACE "-Winconsistent-missing-override" "" ${var} "${${var}}")
 207         string(REPLACE "-Qunused-arguments" "" ${var} "${${var}}")
 208       endif()
 209
 210       # we remove /EHa as it generates warnings under windows
 211       string(REPLACE "/EHa" "" ${var} "${${var}}")
 212
 213       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 214       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 215
 216       # we remove -Wsign-promo as it generates warnings under linux
 217       string(REPLACE "-Wsign-promo" "" ${var} "${${var}}")
 218
 219       # we remove -Wno-sign-promo as it generates warnings under linux
 220       string(REPLACE "-Wno-sign-promo" "" ${var} "${${var}}")
 221
 222       # we remove -Wno-delete-non-virtual-dtor because it's used for C++ compiler
 223       # but NVCC uses C compiler by default
 224       string(REPLACE "-Wno-delete-non-virtual-dtor" "" ${var} "${${var}}")
 225
 226       # we remove -frtti because it's used for C++ compiler
 227       # but NVCC uses C compiler by default
 228       string(REPLACE "-frtti" "" ${var} "${${var}}")
 229
 230       string(REPLACE "-fvisibility-inlines-hidden" "" ${var} "${${var}}")
 231
 232       # cc1: warning: command line option '-Wsuggest-override' is valid for C++/ObjC++ but not for C
 233       string(REPLACE "-Wsuggest-override" "" ${var} "${${var}}")
 234
 235       # issue: #11552 (from OpenCVCompilerOptions.cmake)
 236       string(REGEX REPLACE "-Wimplicit-fallthrough(=[0-9]+)? " "" ${var} "${${var}}")
 237
 238       # removal of custom specified options
 239       if(OPENCV_CUDA_NVCC_FILTEROUT_OPTIONS)
 240         foreach(__flag ${OPENCV_CUDA_NVCC_FILTEROUT_OPTIONS})
 241           string(REPLACE "${__flag}" "" ${var} "${${var}}")
 242         endforeach()
 243       endif()
 244     endforeach()
 245   endmacro()
 246
 247   macro(ocv_cuda_compile VAR)
 248     ocv_cuda_filter_options()
 249
 250     if(BUILD_SHARED_LIBS)
 251       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 252     endif()
 253
 254     if(UNIX OR APPLE)
 255       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC --std=c++11)
 256     endif()
 257     if(APPLE)
 258       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 259     endif()
 260
 261     if(CMAKE_CROSSCOMPILING AND (ARM OR AARCH64))
 262       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xlinker --unresolved-symbols=ignore-in-shared-libs)
 263     endif()
 264
 265     # disabled because of multiple warnings during building nvcc auto generated files
 266     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "4.6.0")
 267       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 268     endif()
 269
 270     CUDA_COMPILE(${VAR} ${ARGN})
 271
 272     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 273       set(${var} "${${var}_backup_in_cuda_compile_}")
 274       unset(${var}_backup_in_cuda_compile_)
 275     endforeach()
 276   endmacro()
 277 else()
 278   unset(CUDA_ARCH_BIN CACHE)
 279   unset(CUDA_ARCH_PTX CACHE)
 280 endif()
 281
 282 if(HAVE_CUDA)
 283   set(CUDA_LIBS_PATH "")
 284   foreach(p ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 285     get_filename_component(_tmp ${p} PATH)
 286     list(APPEND CUDA_LIBS_PATH ${_tmp})
 287   endforeach()
 288
 289   if(HAVE_CUBLAS)
 290     foreach(p ${CUDA_cublas_LIBRARY})
 291       get_filename_component(_tmp ${p} PATH)
 292       list(APPEND CUDA_LIBS_PATH ${_tmp})
 293     endforeach()
 294   endif()
 295
 296   if(HAVE_CUFFT)
 297     foreach(p ${CUDA_cufft_LIBRARY})
 298       get_filename_component(_tmp ${p} PATH)
 299       list(APPEND CUDA_LIBS_PATH ${_tmp})
 300     endforeach()
 301   endif()
 302
 303   list(REMOVE_DUPLICATES CUDA_LIBS_PATH)
 304   link_directories(${CUDA_LIBS_PATH})
 305
 306   set(CUDA_LIBRARIES_ABS ${CUDA_LIBRARIES})
 307   ocv_convert_to_lib_name(CUDA_LIBRARIES ${CUDA_LIBRARIES})
 308   set(CUDA_npp_LIBRARY_ABS ${CUDA_npp_LIBRARY})
 309   ocv_convert_to_lib_name(CUDA_npp_LIBRARY ${CUDA_npp_LIBRARY})
 310   if(HAVE_CUBLAS)
 311     set(CUDA_cublas_LIBRARY_ABS ${CUDA_cublas_LIBRARY})
 312     ocv_convert_to_lib_name(CUDA_cublas_LIBRARY ${CUDA_cublas_LIBRARY})
 313   endif()
 314
 315   if(HAVE_CUFFT)
 316     set(CUDA_cufft_LIBRARY_ABS ${CUDA_cufft_LIBRARY})
 317     ocv_convert_to_lib_name(CUDA_cufft_LIBRARY ${CUDA_cufft_LIBRARY})
 318   endif()
 319 endif()