cmake/OpenCVDetectCUDA.cmake

   1 if(${CMAKE_VERSION} VERSION_LESS "2.8.3")
   2   message(STATUS "WITH_CUDA flag requires CMake 2.8.3 or newer. CUDA support is disabled.")
   3   return()
   4 endif()
   5
   6 if(WIN32 AND NOT MSVC)
   7   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   8   return()
   9 endif()
  10
  11 if(CMAKE_COMPILER_IS_GNUCXX AND NOT APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  12   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
  13   return()
  14 endif()
  15
  16 find_package(CUDA 4.2 QUIET)
  17
  18 if(CUDA_FOUND)
  19   set(HAVE_CUDA 1)
  20
  21   if(WITH_CUFFT)
  22     set(HAVE_CUFFT 1)
  23   endif()
  24
  25   if(WITH_CUBLAS)
  26     set(HAVE_CUBLAS 1)
  27   endif()
  28
  29   if(WITH_NVCUVID)
  30     find_cuda_helper_libs(nvcuvid)
  31     set(HAVE_NVCUVID 1)
  32   endif()
  33
  34   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  35
  36   set(CUDA_ARCH_BIN "1.1 1.2 1.3 2.0 2.1(2.0) 3.0" CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
  37   set(CUDA_ARCH_PTX "2.0 3.0" CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
  38
  39   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
  40   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
  41
  42   # Ckeck if user specified 1.0 compute capability: we don't support it
  43   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
  44   set(CUDA_ARCH_BIN_OR_PTX_10 0)
  45   if(NOT ${HAS_ARCH_10} STREQUAL "")
  46     set(CUDA_ARCH_BIN_OR_PTX_10 1)
  47   endif()
  48
  49   # NVCC flags to be set
  50   set(NVCC_FLAGS_EXTRA "")
  51
  52   # These vars will be passed into the templates
  53   set(OPENCV_CUDA_ARCH_BIN "")
  54   set(OPENCV_CUDA_ARCH_PTX "")
  55   set(OPENCV_CUDA_ARCH_FEATURES "")
  56
  57   # Tell NVCC to add binaries for the specified GPUs
  58   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
  59   foreach(ARCH IN LISTS ARCH_LIST)
  60     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
  61       # User explicitly specified PTX for the concrete BIN
  62       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
  63       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
  64       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
  65     else()
  66       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
  67       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
  68       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
  69       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
  70     endif()
  71   endforeach()
  72
  73   # Tell NVCC to add PTX intermediate code for the specified architectures
  74   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
  75   foreach(ARCH IN LISTS ARCH_LIST)
  76     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
  77     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
  78     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
  79   endforeach()
  80
  81   if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm")
  82     set(CUDA_NVCC_FLAGS "${CUDA_NVCC_FLAGS} --target-cpu-architecture=ARM")
  83   endif()
  84
  85   # These vars will be processed in other scripts
  86   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
  87   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
  88
  89   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
  90
  91   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
  92
  93   if(CUDA_FAST_MATH)
  94     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
  95   endif()
  96
  97   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
  98
  99   find_cuda_helper_libs(npp)
 100
 101   macro(ocv_cuda_compile VAR)
 102     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 103       set(${var}_backup_in_cuda_compile_ "${${var}}")
 104
 105       # we reomove /EHa as it leasd warnings under windows
 106       string(REPLACE "/EHa" "" ${var} "${${var}}")
 107
 108       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 109       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 110     endforeach()
 111
 112     if(BUILD_SHARED_LIBS)
 113       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 114     endif()
 115
 116     if(UNIX OR APPLE)
 117       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 118     endif()
 119     if(APPLE)
 120       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 121     endif()
 122
 123     # disabled because of multiple warnings during building nvcc auto generated files
 124     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GCC_REGEX_VERSION VERSION_GREATER "4.6.0")
 125       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 126     endif()
 127
 128     CUDA_COMPILE(${VAR} ${ARGN})
 129
 130     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 131       set(${var} "${${var}_backup_in_cuda_compile_}")
 132       unset(${var}_backup_in_cuda_compile_)
 133     endforeach()
 134   endmacro()
 135 else()
 136   unset(CUDA_ARCH_BIN CACHE)
 137   unset(CUDA_ARCH_PTX CACHE)
 138 endif()