cmake/OpenCVDetectCUDA.cmake

   1 if((WIN32 AND NOT MSVC) OR OPENCV_CMAKE_FORCE_CUDA)
   2   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   3   return()
   4 endif()
   5
   6 if((NOT UNIX AND CV_CLANG) OR OPENCV_CMAKE_FORCE_CUDA)
   7   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
   8   return()
   9 endif()
  10
  11 #set(OPENCV_CMAKE_CUDA_DEBUG 1)
  12
  13 if(((NOT CMAKE_VERSION VERSION_LESS "3.9.0")  # requires https://gitlab.kitware.com/cmake/cmake/merge_requests/663
  14       OR OPENCV_CUDA_FORCE_EXTERNAL_CMAKE_MODULE)
  15     AND NOT OPENCV_CUDA_FORCE_BUILTIN_CMAKE_MODULE)
  16   ocv_update(CUDA_LINK_LIBRARIES_KEYWORD "PRIVATE")
  17   find_host_package(CUDA "${MIN_VER_CUDA}" QUIET)
  18 else()
  19   # Use OpenCV's patched "FindCUDA" module
  20   set(CMAKE_MODULE_PATH "${OpenCV_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
  21
  22   if(ANDROID)
  23     set(CUDA_TARGET_OS_VARIANT "Android")
  24   endif()
  25   find_host_package(CUDA "${MIN_VER_CUDA}" QUIET)
  26
  27   list(REMOVE_AT CMAKE_MODULE_PATH 0)
  28 endif()
  29
  30 if(CUDA_FOUND)
  31   set(HAVE_CUDA 1)
  32   if(NOT CUDA_VERSION VERSION_LESS 11.0)
  33     # CUDA 11.0 removes nppicom
  34     ocv_list_filterout(CUDA_nppi_LIBRARY "nppicom")
  35     ocv_list_filterout(CUDA_npp_LIBRARY "nppicom")
  36   endif()
  37
  38   if(WITH_CUFFT)
  39     set(HAVE_CUFFT 1)
  40   endif()
  41
  42   if(WITH_CUBLAS)
  43     set(HAVE_CUBLAS 1)
  44   endif()
  45
  46   if(WITH_CUDNN)
  47       set(CMAKE_MODULE_PATH "${OpenCV_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
  48       find_host_package(CUDNN "${MIN_VER_CUDNN}")
  49       list(REMOVE_AT CMAKE_MODULE_PATH 0)
  50
  51       if(CUDNN_FOUND)
  52         set(HAVE_CUDNN 1)
  53       endif()
  54   endif()
  55
  56   if(WITH_NVCUVID)
  57     macro(ocv_cuda_SEARCH_NVCUVID_HEADER _filename _result)
  58       # place header file under CUDA_TOOLKIT_TARGET_DIR or CUDA_TOOLKIT_ROOT_DIR
  59       find_path(_header_result
  60         ${_filename}
  61         PATHS "${CUDA_TOOLKIT_TARGET_DIR}" "${CUDA_TOOLKIT_ROOT_DIR}"
  62         ENV CUDA_PATH
  63         ENV CUDA_INC_PATH
  64         PATH_SUFFIXES include
  65         NO_DEFAULT_PATH
  66         )
  67       if("x${_header_result}" STREQUAL "x_header_result-NOTFOUND")
  68         set(${_result} 0)
  69       else()
  70         set(${_result} 1)
  71       endif()
  72       unset(_header_result CACHE)
  73     endmacro()
  74     ocv_cuda_SEARCH_NVCUVID_HEADER("nvcuvid.h" HAVE_NVCUVID_HEADER)
  75     ocv_cuda_SEARCH_NVCUVID_HEADER("dynlink_nvcuvid.h" HAVE_DYNLINK_NVCUVID_HEADER)
  76     find_cuda_helper_libs(nvcuvid)
  77     if(WIN32)
  78       find_cuda_helper_libs(nvcuvenc)
  79     endif()
  80     if(CUDA_nvcuvid_LIBRARY AND (${HAVE_NVCUVID_HEADER} OR ${HAVE_DYNLINK_NVCUVID_HEADER}))
  81       # make sure to have both header and library before enabling
  82       set(HAVE_NVCUVID 1)
  83     endif()
  84     if(CUDA_nvcuvenc_LIBRARY)
  85       set(HAVE_NVCUVENC 1)
  86     endif()
  87   endif()
  88
  89   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  90
  91   OCV_OPTION(CUDA_ENABLE_DEPRECATED_GENERATION "Enable deprecated generations in the list" OFF)
  92   set(_generations "Maxwell" "Pascal" "Volta" "Turing" "Ampere")
  93   if(CUDA_ENABLE_DEPRECATED_GENERATION)
  94     set(_generations "Fermi" "${_generations}")
  95     set(_generations "Kepler" "${_generations}")
  96   endif()
  97   set(_arch_fermi   "2.0")
  98   set(_arch_kepler  "3.0;3.5;3.7")
  99   set(_arch_maxwell "5.0;5.2")
 100   set(_arch_pascal  "6.0;6.1")
 101   set(_arch_volta   "7.0")
 102   set(_arch_turing  "7.5")
 103   set(_arch_ampere  "8.0;8.6")
 104   if(NOT CMAKE_CROSSCOMPILING)
 105     list(APPEND _generations "Auto")
 106   endif()
 107   set(CUDA_GENERATION "" CACHE STRING "Build CUDA device code only for specific GPU architecture. Leave empty to build for all architectures.")
 108   if( CMAKE_VERSION VERSION_GREATER "2.8" )
 109     set_property( CACHE CUDA_GENERATION PROPERTY STRINGS "" ${_generations} )
 110   endif()
 111
 112   if(CUDA_GENERATION)
 113     if(NOT ";${_generations};" MATCHES ";${CUDA_GENERATION};")
 114       string(REPLACE ";" ", " _generations "${_generations}")
 115       message(FATAL_ERROR "ERROR: ${_generations} Generations are supported.")
 116     endif()
 117     unset(CUDA_ARCH_BIN CACHE)
 118     unset(CUDA_ARCH_PTX CACHE)
 119   endif()
 120
 121   if(OPENCV_CUDA_DETECTION_NVCC_FLAGS MATCHES "-ccbin")
 122     # already specified by user
 123   elseif(CUDA_HOST_COMPILER AND EXISTS "${CUDA_HOST_COMPILER}")
 124     get_filename_component(c_compiler_realpath "${CMAKE_C_COMPILER}" REALPATH)
 125     # C compiler doesn't work with --run option, forcing C++ compiler instead
 126     if(CUDA_HOST_COMPILER STREQUAL c_compiler_realpath OR CUDA_HOST_COMPILER STREQUAL CMAKE_C_COMPILER)
 127       if(DEFINED CMAKE_CXX_COMPILER)
 128         get_filename_component(cxx_compiler_realpath "${CMAKE_CXX_COMPILER}" REALPATH)
 129         LIST(APPEND OPENCV_CUDA_DETECTION_NVCC_FLAGS -ccbin "${cxx_compiler_realpath}")
 130       else()
 131         message(STATUS "CUDA: CMAKE_CXX_COMPILER is not available. You may need to specify CUDA_HOST_COMPILER.")
 132       endif()
 133     else()
 134       LIST(APPEND OPENCV_CUDA_DETECTION_NVCC_FLAGS -ccbin "${CUDA_HOST_COMPILER}")
 135     endif()
 136   elseif(WIN32 AND CMAKE_LINKER) # Workaround for VS cl.exe not being in the env. path
 137     get_filename_component(host_compiler_bindir ${CMAKE_LINKER} DIRECTORY)
 138     LIST(APPEND OPENCV_CUDA_DETECTION_NVCC_FLAGS -ccbin "${host_compiler_bindir}")
 139   else()
 140     if(CUDA_HOST_COMPILER)
 141       message(STATUS "CUDA: CUDA_HOST_COMPILER='${CUDA_HOST_COMPILER}' is not valid, autodetection may not work. Specify OPENCV_CUDA_DETECTION_NVCC_FLAGS with -ccbin option for fix that")
 142     endif()
 143   endif()
 144
 145   macro(ocv_filter_available_architecture result_list)
 146     set(__cache_key_check "${ARGN} : ${CUDA_NVCC_EXECUTABLE} ${OPENCV_CUDA_DETECTION_NVCC_FLAGS}")
 147     if(DEFINED OPENCV_CACHE_CUDA_SUPPORTED_CC AND OPENCV_CACHE_CUDA_SUPPORTED_CC_check STREQUAL __cache_key_check)
 148       set(${result_list} "${OPENCV_CACHE_CUDA_SUPPORTED_CC}")
 149     else()
 150       set(CC_LIST ${ARGN})
 151       foreach(target_arch ${CC_LIST})
 152         string(REPLACE "." "" target_arch_short "${target_arch}")
 153         set(NVCC_OPTION "-gencode;arch=compute_${target_arch_short},code=sm_${target_arch_short}")
 154         set(_cmd "${CUDA_NVCC_EXECUTABLE}" ${OPENCV_CUDA_DETECTION_NVCC_FLAGS} ${NVCC_OPTION} "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" --compile)
 155         execute_process(
 156             COMMAND ${_cmd}
 157             WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
 158             RESULT_VARIABLE _nvcc_res
 159             OUTPUT_VARIABLE _nvcc_out
 160             ERROR_VARIABLE _nvcc_err
 161             #ERROR_QUIET
 162             OUTPUT_STRIP_TRAILING_WHITESPACE
 163         )
 164         if(OPENCV_CMAKE_CUDA_DEBUG)
 165           message(WARNING "COMMAND: ${_cmd}")
 166           message(STATUS "Result: ${_nvcc_res}")
 167           message(STATUS "Out: ${_nvcc_out}")
 168           message(STATUS "Err: ${_nvcc_err}")
 169         endif()
 170         if(_nvcc_res EQUAL 0)
 171           LIST(APPEND ${result_list} "${target_arch}")
 172         endif()
 173       endforeach()
 174       string(STRIP "${${result_list}}" ${result_list})
 175       if(" ${${result_list}}" STREQUAL " ")
 176         message(WARNING "CUDA: Autodetection arch list is empty. Please enable OPENCV_CMAKE_CUDA_DEBUG=1 and check/specify OPENCV_CUDA_DETECTION_NVCC_FLAGS variable")
 177       endif()
 178
 179       # cache detected values
 180       set(OPENCV_CACHE_CUDA_SUPPORTED_CC ${${result_list}} CACHE INTERNAL "")
 181       set(OPENCV_CACHE_CUDA_SUPPORTED_CC_check "${__cache_key_check}" CACHE INTERNAL "")
 182     endif()
 183   endmacro()
 184
 185   macro(ocv_detect_native_cuda_arch status output)
 186     set(OPENCV_CUDA_DETECT_ARCHS_COMMAND "${CUDA_NVCC_EXECUTABLE}" ${OPENCV_CUDA_DETECTION_NVCC_FLAGS} "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" "--run")
 187     set(__cache_key_check "${OPENCV_CUDA_DETECT_ARCHS_COMMAND}")
 188     if(DEFINED OPENCV_CACHE_CUDA_ACTIVE_CC AND OPENCV_CACHE_CUDA_ACTIVE_CC_check STREQUAL __cache_key_check)
 189       set(${output} "${OPENCV_CACHE_CUDA_ACTIVE_CC}")
 190       set(${status} 0)
 191     else()
 192       execute_process(
 193           COMMAND ${OPENCV_CUDA_DETECT_ARCHS_COMMAND}
 194           WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
 195           RESULT_VARIABLE ${status}
 196           OUTPUT_VARIABLE _nvcc_out
 197           ERROR_VARIABLE _nvcc_err
 198           ERROR_QUIET
 199           OUTPUT_STRIP_TRAILING_WHITESPACE
 200       )
 201       if(OPENCV_CMAKE_CUDA_DEBUG)
 202         message(WARNING "COMMAND: ${OPENCV_CUDA_DETECT_ARCHS_COMMAND}")
 203         message(STATUS "Result: ${${status}}")
 204         message(STATUS "Out: ${_nvcc_out}")
 205         message(STATUS "Err: ${_nvcc_err}")
 206       endif()
 207       string(REGEX REPLACE ".*\n" "" ${output} "${_nvcc_out}") #Strip leading warning messages, if any
 208
 209       if(${status} EQUAL 0)
 210         # cache detected values
 211         set(OPENCV_CACHE_CUDA_ACTIVE_CC ${${output}} CACHE INTERNAL "")
 212         set(OPENCV_CACHE_CUDA_ACTIVE_CC_check "${__cache_key_check}" CACHE INTERNAL "")
 213       endif()
 214     endif()
 215   endmacro()
 216
 217   set(__cuda_arch_ptx "")
 218   if(CUDA_GENERATION STREQUAL "Fermi")
 219     set(__cuda_arch_bin ${_arch_fermi})
 220   elseif(CUDA_GENERATION STREQUAL "Kepler")
 221     set(__cuda_arch_bin ${_arch_kepler})
 222   elseif(CUDA_GENERATION STREQUAL "Maxwell")
 223     set(__cuda_arch_bin ${_arch_maxwell})
 224   elseif(CUDA_GENERATION STREQUAL "Pascal")
 225     set(__cuda_arch_bin ${_arch_pascal})
 226   elseif(CUDA_GENERATION STREQUAL "Volta")
 227     set(__cuda_arch_bin ${_arch_volta})
 228   elseif(CUDA_GENERATION STREQUAL "Turing")
 229     set(__cuda_arch_bin ${_arch_turing})
 230   elseif(CUDA_GENERATION STREQUAL "Ampere")
 231     set(__cuda_arch_bin ${_arch_ampere})
 232   elseif(CUDA_GENERATION STREQUAL "Auto")
 233     ocv_detect_native_cuda_arch(_nvcc_res _nvcc_out)
 234     if(NOT _nvcc_res EQUAL 0)
 235       message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
 236     else()
 237       string(REGEX MATCHALL "[0-9]+\\.[0-9]" __cuda_arch_bin "${_nvcc_out}")
 238     endif()
 239   elseif(CUDA_ARCH_BIN)
 240     message(STATUS "CUDA: Using CUDA_ARCH_BIN=${CUDA_ARCH_BIN}")
 241     set(__cuda_arch_bin ${CUDA_ARCH_BIN})
 242   endif()
 243
 244   if(NOT DEFINED __cuda_arch_bin)
 245     if(ARM)
 246       set(__cuda_arch_bin "3.2")
 247       set(__cuda_arch_ptx "")
 248     elseif(AARCH64)
 249       if(NOT CMAKE_CROSSCOMPILING)
 250         ocv_detect_native_cuda_arch(_nvcc_res _nvcc_out)
 251       else()
 252         set(_nvcc_res -1)  # emulate error, see below
 253       endif()
 254       if(NOT _nvcc_res EQUAL 0)
 255         message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
 256         # TX1 (5.3) TX2 (6.2) Xavier (7.2) V100 (7.0) Orin (8.7)
 257         ocv_filter_available_architecture(__cuda_arch_bin
 258             5.3
 259             6.2
 260             7.2
 261             7.0
 262             8.7
 263         )
 264       else()
 265         set(__cuda_arch_bin "${_nvcc_out}")
 266       endif()
 267       set(__cuda_arch_ptx "")
 268     else()
 269       ocv_filter_available_architecture(__cuda_arch_bin
 270           ${_arch_fermi}
 271           ${_arch_kepler}
 272           ${_arch_maxwell}
 273           ${_arch_pascal}
 274           ${_arch_volta}
 275           ${_arch_turing}
 276           ${_arch_ampere}
 277       )
 278     endif()
 279   endif()
 280
 281   set(CUDA_ARCH_BIN ${__cuda_arch_bin} CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
 282   set(CUDA_ARCH_PTX ${__cuda_arch_ptx} CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
 283
 284   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
 285   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
 286
 287   # Check if user specified 1.0/2.1 compute capability: we don't support it
 288   macro(ocv_wipeout_deprecated_cc target_cc)
 289     if(" ${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}" MATCHES " ${target_cc}")
 290       message(SEND_ERROR "CUDA: ${target_cc} compute capability is not supported - exclude it from ARCH/PTX list and re-run CMake")
 291     endif()
 292   endmacro()
 293   ocv_wipeout_deprecated_cc("1.0")
 294   ocv_wipeout_deprecated_cc("2.1")
 295
 296   # NVCC flags to be set
 297   set(NVCC_FLAGS_EXTRA "")
 298
 299   # These vars will be passed into the templates
 300   set(OPENCV_CUDA_ARCH_BIN "")
 301   set(OPENCV_CUDA_ARCH_PTX "")
 302   set(OPENCV_CUDA_ARCH_FEATURES "")
 303
 304   # Tell NVCC to add binaries for the specified GPUs
 305   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
 306   foreach(ARCH IN LISTS ARCH_LIST)
 307     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
 308       # User explicitly specified PTX for the concrete BIN
 309       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
 310       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
 311       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
 312     else()
 313       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
 314       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
 315       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
 316       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 317     endif()
 318   endforeach()
 319   set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -D_FORCE_INLINES)
 320
 321   # Tell NVCC to add PTX intermediate code for the specified architectures
 322   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
 323   foreach(ARCH IN LISTS ARCH_LIST)
 324     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
 325     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
 326     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 327   endforeach()
 328
 329   # These vars will be processed in other scripts
 330   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
 331   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
 332
 333   if(ANDROID)
 334     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} "-Xptxas;-dlcm=ca")
 335   endif()
 336
 337   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
 338
 339   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
 340
 341   if(CUDA_FAST_MATH)
 342     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
 343   endif()
 344
 345   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
 346
 347   macro(ocv_cuda_filter_options)
 348     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 349       set(${var}_backup_in_cuda_compile_ "${${var}}")
 350
 351       if (CV_CLANG)
 352         # we remove -Winconsistent-missing-override and -Qunused-arguments
 353         # just in case we are compiling CUDA with gcc but OpenCV with clang
 354         string(REPLACE "-Winconsistent-missing-override" "" ${var} "${${var}}")
 355         string(REPLACE "-Qunused-arguments" "" ${var} "${${var}}")
 356       endif()
 357
 358       # we remove /EHa as it generates warnings under windows
 359       string(REPLACE "/EHa" "" ${var} "${${var}}")
 360
 361       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 362       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 363
 364       # we remove -Wsign-promo as it generates warnings under linux
 365       string(REPLACE "-Wsign-promo" "" ${var} "${${var}}")
 366
 367       # we remove -Wno-sign-promo as it generates warnings under linux
 368       string(REPLACE "-Wno-sign-promo" "" ${var} "${${var}}")
 369
 370       # we remove -Wno-delete-non-virtual-dtor because it's used for C++ compiler
 371       # but NVCC uses C compiler by default
 372       string(REPLACE "-Wno-delete-non-virtual-dtor" "" ${var} "${${var}}")
 373
 374       # we remove -frtti because it's used for C++ compiler
 375       # but NVCC uses C compiler by default
 376       string(REPLACE "-frtti" "" ${var} "${${var}}")
 377
 378       string(REPLACE "-fvisibility-inlines-hidden" "" ${var} "${${var}}")
 379
 380       # cc1: warning: command line option '-Wsuggest-override' is valid for C++/ObjC++ but not for C
 381       string(REPLACE "-Wsuggest-override" "" ${var} "${${var}}")
 382
 383       # issue: #11552 (from OpenCVCompilerOptions.cmake)
 384       string(REGEX REPLACE "-Wimplicit-fallthrough(=[0-9]+)? " "" ${var} "${${var}}")
 385
 386       # removal of custom specified options
 387       if(OPENCV_CUDA_NVCC_FILTEROUT_OPTIONS)
 388         foreach(__flag ${OPENCV_CUDA_NVCC_FILTEROUT_OPTIONS})
 389           string(REPLACE "${__flag}" "" ${var} "${${var}}")
 390         endforeach()
 391       endif()
 392     endforeach()
 393   endmacro()
 394
 395   macro(ocv_cuda_compile VAR)
 396     ocv_cuda_filter_options()
 397
 398     if(BUILD_SHARED_LIBS)
 399       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 400     endif()
 401
 402     if(UNIX OR APPLE)
 403       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 404       if(NOT " ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} ${CMAKE_CXX_FLAGS_DEBUG} ${CUDA_NVCC_FLAGS}" MATCHES "-std=")
 405         if(CUDA_VERSION VERSION_LESS "11.0")
 406           list(APPEND CUDA_NVCC_FLAGS "--std=c++11")
 407         else()
 408           list(APPEND CUDA_NVCC_FLAGS "--std=c++14")
 409         endif()
 410       endif()
 411     endif()
 412     if(APPLE)
 413       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 414     endif()
 415
 416     if(CMAKE_CROSSCOMPILING AND (ARM OR AARCH64))
 417       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xlinker --unresolved-symbols=ignore-in-shared-libs)
 418     endif()
 419
 420     # disabled because of multiple warnings during building nvcc auto generated files
 421     if(CV_GCC AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER "4.6.0")
 422       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 423     endif()
 424
 425     CUDA_COMPILE(${VAR} ${ARGN})
 426
 427     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 428       set(${var} "${${var}_backup_in_cuda_compile_}")
 429       unset(${var}_backup_in_cuda_compile_)
 430     endforeach()
 431   endmacro()
 432 else()
 433   unset(CUDA_ARCH_BIN CACHE)
 434   unset(CUDA_ARCH_PTX CACHE)
 435 endif()
 436
 437 if(HAVE_CUDA)
 438   set(CUDA_LIBS_PATH "")
 439   foreach(p ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 440     get_filename_component(_tmp ${p} PATH)
 441     list(APPEND CUDA_LIBS_PATH ${_tmp})
 442   endforeach()
 443
 444   if(HAVE_CUBLAS)
 445     foreach(p ${CUDA_cublas_LIBRARY})
 446       get_filename_component(_tmp ${p} PATH)
 447       list(APPEND CUDA_LIBS_PATH ${_tmp})
 448     endforeach()
 449   endif()
 450
 451   if(HAVE_CUDNN)
 452     foreach(p ${CUDNN_LIBRARIES})
 453       get_filename_component(_tmp ${p} PATH)
 454       list(APPEND CUDA_LIBS_PATH ${_tmp})
 455     endforeach()
 456   endif()
 457
 458   if(HAVE_CUFFT)
 459     foreach(p ${CUDA_cufft_LIBRARY})
 460       get_filename_component(_tmp ${p} PATH)
 461       list(APPEND CUDA_LIBS_PATH ${_tmp})
 462     endforeach()
 463   endif()
 464
 465   list(REMOVE_DUPLICATES CUDA_LIBS_PATH)
 466   link_directories(${CUDA_LIBS_PATH})
 467
 468   set(CUDA_LIBRARIES_ABS ${CUDA_LIBRARIES})
 469   ocv_convert_to_lib_name(CUDA_LIBRARIES ${CUDA_LIBRARIES})
 470   set(CUDA_npp_LIBRARY_ABS ${CUDA_npp_LIBRARY})
 471   ocv_convert_to_lib_name(CUDA_npp_LIBRARY ${CUDA_npp_LIBRARY})
 472   if(HAVE_CUBLAS)
 473     set(CUDA_cublas_LIBRARY_ABS ${CUDA_cublas_LIBRARY})
 474     ocv_convert_to_lib_name(CUDA_cublas_LIBRARY ${CUDA_cublas_LIBRARY})
 475   endif()
 476   if(HAVE_CUDNN)
 477     set(CUDNN_LIBRARIES_ABS ${CUDNN_LIBRARIES})
 478     ocv_convert_to_lib_name(CUDNN_LIBRARIES ${CUDNN_LIBRARIES})
 479   endif()
 480   if(HAVE_CUFFT)
 481     set(CUDA_cufft_LIBRARY_ABS ${CUDA_cufft_LIBRARY})
 482     ocv_convert_to_lib_name(CUDA_cufft_LIBRARY ${CUDA_cufft_LIBRARY})
 483   endif()
 484
 485   if(CMAKE_GENERATOR MATCHES "Visual Studio"
 486       AND NOT OPENCV_SKIP_CUDA_CMAKE_SUPPRESS_REGENERATION
 487   )
 488     message(STATUS "CUDA: MSVS generator is detected. Disabling CMake re-run checks (CMAKE_SUPPRESS_REGENERATION=ON). You need to run CMake manually if updates are required.")
 489     set(CMAKE_SUPPRESS_REGENERATION ON)
 490   endif()
 491 endif()
 492
 493
 494 # ----------------------------------------------------------------------------
 495 # Add CUDA libraries (needed for apps/tools, samples)
 496 # ----------------------------------------------------------------------------
 497 if(HAVE_CUDA)
 498   # details: https://github.com/NVIDIA/nvidia-docker/issues/775
 499   if(" ${CUDA_CUDA_LIBRARY}" MATCHES "/stubs/libcuda.so" AND NOT OPENCV_SKIP_CUDA_STUB_WORKAROUND)
 500     set(CUDA_STUB_ENABLED_LINK_WORKAROUND 1)
 501     if(EXISTS "${CUDA_CUDA_LIBRARY}" AND NOT OPENCV_SKIP_CUDA_STUB_WORKAROUND_RPATH_LINK)
 502       set(CUDA_STUB_TARGET_PATH "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/")
 503       execute_process(COMMAND ${CMAKE_COMMAND} -E create_symlink "${CUDA_CUDA_LIBRARY}" "${CUDA_STUB_TARGET_PATH}/libcuda.so.1"
 504           RESULT_VARIABLE CUDA_STUB_SYMLINK_RESULT)
 505       if(NOT CUDA_STUB_SYMLINK_RESULT EQUAL 0)
 506         execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CUDA_CUDA_LIBRARY}" "${CUDA_STUB_TARGET_PATH}/libcuda.so.1"
 507           RESULT_VARIABLE CUDA_STUB_COPY_RESULT)
 508         if(NOT CUDA_STUB_COPY_RESULT EQUAL 0)
 509           set(CUDA_STUB_ENABLED_LINK_WORKAROUND 0)
 510         endif()
 511       endif()
 512       if(CUDA_STUB_ENABLED_LINK_WORKAROUND)
 513         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-rpath-link,\"${CUDA_STUB_TARGET_PATH}\"")
 514       endif()
 515     else()
 516       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--allow-shlib-undefined")
 517     endif()
 518     if(NOT CUDA_STUB_ENABLED_LINK_WORKAROUND)
 519       message(WARNING "CUDA: workaround for stubs/libcuda.so.1 is not applied")
 520     endif()
 521   endif()
 522
 523   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 524   if(HAVE_CUBLAS)
 525     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 526   endif()
 527   if(HAVE_CUDNN)
 528     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDNN_LIBRARIES})
 529   endif()
 530   if(HAVE_CUFFT)
 531     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 532   endif()
 533   foreach(p ${CUDA_LIBS_PATH})
 534     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 535       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 536     else()
 537       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 538     endif()
 539   endforeach()
 540 endif()