cmake/OpenCVDetectCUDA.cmake

   1 if(${CMAKE_VERSION} VERSION_LESS "2.8.3")
   2   message(STATUS "WITH_CUDA flag requires CMake 2.8.3 or newer. CUDA support is disabled.")
   3   return()
   4 endif()
   5
   6 if (NOT MSVC AND NOT CMAKE_COMPILER_IS_GNUCXX OR MINGW)
   7   message(STATUS "CUDA compilation was disabled (due to unsuppoted host compiler).")
   8   return()
   9 endif()
  10
  11 find_package(CUDA 4.1)
  12
  13 if(CUDA_FOUND)
  14   set(HAVE_CUDA 1)
  15
  16   if(WITH_CUFFT)
  17     set(HAVE_CUFFT 1)
  18   endif()
  19
  20   if(WITH_CUBLAS)
  21     set(HAVE_CUBLAS 1)
  22   endif()
  23
  24   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  25
  26   if(${CUDA_VERSION_STRING} VERSION_GREATER "4.1")
  27     set(CUDA_ARCH_BIN "1.1 1.2 1.3 2.0 2.1(2.0) 3.0" CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
  28   else()
  29     set(CUDA_ARCH_BIN "1.1 1.2 1.3 2.0 2.1(2.0)" CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
  30   endif()
  31
  32   set(CUDA_ARCH_PTX "2.0" CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
  33
  34   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
  35   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
  36
  37   # Ckeck if user specified 1.0 compute capability: we don't support it
  38   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
  39   set(CUDA_ARCH_BIN_OR_PTX_10 0)
  40   if(NOT ${HAS_ARCH_10} STREQUAL "")
  41     set(CUDA_ARCH_BIN_OR_PTX_10 1)
  42   endif()
  43
  44   # NVCC flags to be set
  45   set(NVCC_FLAGS_EXTRA "")
  46
  47   # These vars will be passed into the templates
  48   set(OPENCV_CUDA_ARCH_BIN "")
  49   set(OPENCV_CUDA_ARCH_PTX "")
  50   set(OPENCV_CUDA_ARCH_FEATURES "")
  51
  52   # Tell NVCC to add binaries for the specified GPUs
  53   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
  54   foreach(ARCH IN LISTS ARCH_LIST)
  55     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
  56       # User explicitly specified PTX for the concrete BIN
  57       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
  58       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
  59       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
  60     else()
  61       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
  62       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
  63       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
  64       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
  65     endif()
  66   endforeach()
  67
  68   # Tell NVCC to add PTX intermediate code for the specified architectures
  69   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
  70     foreach(ARCH IN LISTS ARCH_LIST)
  71       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
  72       set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
  73       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
  74     endforeach()
  75
  76   # These vars will be processed in other scripts
  77   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
  78   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
  79
  80   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
  81
  82   unset(CUDA_npp_LIBRARY CACHE)
  83   find_cuda_helper_libs(npp)
  84
  85   macro(ocv_cuda_compile VAR)
  86     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
  87       set(${var}_backup_in_cuda_compile_ "${${var}}")
  88
  89       # we reomove /EHa as it leasd warnings under windows
  90       string(REPLACE "/EHa" "" ${var} "${${var}}")
  91
  92       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
  93       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
  94     endforeach()
  95
  96     if (BUILD_SHARED_LIBS)
  97       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
  98     endif()
  99
 100     if(UNIX OR APPLE)
 101       set (CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 102     endif()
 103     if(APPLE)
 104       set (CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 105     endif()
 106
 107     # disabled because of multiple warnings during building nvcc auto generated files
 108     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GCC_REGEX_VERSION VERSION_GREATER "4.6.0")
 109       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 110     endif()
 111
 112     CUDA_COMPILE(${VAR} ${ARGN})
 113
 114     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 115       set(${var} "${${var}_backup_in_cuda_compile_}")
 116       unset(${var}_backup_in_cuda_compile_)
 117     endforeach()
 118   endmacro()
 119 else()
 120   unset(CUDA_ARCH_BIN CACHE)
 121   unset(CUDA_ARCH_PTX CACHE)
 122 endif()