cmake/OpenCVDetectCUDA.cmake

   1 if(${CMAKE_VERSION} VERSION_LESS "2.8.3")
   2   message(STATUS "WITH_CUDA flag requires CMake 2.8.3 or newer. CUDA support is disabled.")
   3   return()
   4 endif()
   5
   6 if(WIN32 AND NOT MSVC)
   7   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   8   return()
   9 endif()
  10
  11 if(CMAKE_COMPILER_IS_GNUCXX AND NOT APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  12   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
  13   return()
  14 endif()
  15
  16 find_package(CUDA 4.2 QUIET)
  17
  18 if(CUDA_FOUND)
  19   set(HAVE_CUDA 1)
  20
  21   if(WITH_CUFFT)
  22     set(HAVE_CUFFT 1)
  23   endif()
  24
  25   if(WITH_CUBLAS)
  26     set(HAVE_CUBLAS 1)
  27   endif()
  28
  29   if(${CUDA_VERSION} VERSION_LESS "5.5")
  30     find_cuda_helper_libs(npp)
  31   else()
  32     find_cuda_helper_libs(nppc)
  33     find_cuda_helper_libs(nppi)
  34     find_cuda_helper_libs(npps)
  35     set(CUDA_npp_LIBRARY ${CUDA_nppc_LIBRARY} ${CUDA_nppi_LIBRARY} ${CUDA_npps_LIBRARY})
  36   endif()
  37
  38   if(WITH_NVCUVID)
  39     find_cuda_helper_libs(nvcuvid)
  40     set(HAVE_NVCUVID 1)
  41   endif()
  42
  43   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  44
  45   set(_generations "Fermi" "Kepler")
  46   if(NOT CMAKE_CROSSCOMPILING)
  47     list(APPEND _generations "Auto")
  48   endif()
  49   set(CUDA_GENERATION "" CACHE STRING "Build CUDA device code only for specific GPU architecture. Leave empty to build for all architectures.")
  50   if( CMAKE_VERSION VERSION_GREATER "2.8" )
  51     set_property( CACHE CUDA_GENERATION PROPERTY STRINGS "" ${_generations} )
  52   endif()
  53
  54   if(CUDA_GENERATION)
  55     if(NOT ";${_generations};" MATCHES ";${CUDA_GENERATION};")
  56       string(REPLACE ";" ", " _generations "${_generations}")
  57       message(FATAL_ERROR "ERROR: ${_generations} Generations are suppered.")
  58     endif()
  59     unset(CUDA_ARCH_BIN CACHE)
  60     unset(CUDA_ARCH_PTX CACHE)
  61   endif()
  62
  63   set(__cuda_arch_ptx "")
  64   if(CUDA_GENERATION STREQUAL "Fermi")
  65     set(__cuda_arch_bin "2.0 2.1(2.0)")
  66   elseif(CUDA_GENERATION STREQUAL "Kepler")
  67     set(__cuda_arch_bin "3.0")
  68   elseif(CUDA_GENERATION STREQUAL "Auto")
  69     execute_process( COMMAND "${CUDA_NVCC_EXECUTABLE}" "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" "--run"
  70                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
  71                      RESULT_VARIABLE _nvcc_res OUTPUT_VARIABLE _nvcc_out
  72                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  73     if(NOT _nvcc_res EQUAL 0)
  74       message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
  75     else()
  76       set(__cuda_arch_bin "${_nvcc_out}")
  77     endif()
  78   endif()
  79
  80   if(NOT DEFINED __cuda_arch_bin)
  81     set(__cuda_arch_bin "1.1 1.2 1.3 2.0 2.1(2.0) 3.0")
  82     set(__cuda_arch_ptx "2.0 3.0")
  83   endif()
  84
  85   set(CUDA_ARCH_BIN ${__cuda_arch_bin} CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
  86   set(CUDA_ARCH_PTX ${__cuda_arch_ptx} CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
  87
  88   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
  89   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
  90
  91   # Ckeck if user specified 1.0 compute capability: we don't support it
  92   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
  93   set(CUDA_ARCH_BIN_OR_PTX_10 0)
  94   if(NOT ${HAS_ARCH_10} STREQUAL "")
  95     set(CUDA_ARCH_BIN_OR_PTX_10 1)
  96   endif()
  97
  98   # NVCC flags to be set
  99   set(NVCC_FLAGS_EXTRA "")
 100
 101   # These vars will be passed into the templates
 102   set(OPENCV_CUDA_ARCH_BIN "")
 103   set(OPENCV_CUDA_ARCH_PTX "")
 104   set(OPENCV_CUDA_ARCH_FEATURES "")
 105
 106   # Tell NVCC to add binaries for the specified GPUs
 107   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
 108   foreach(ARCH IN LISTS ARCH_LIST)
 109     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
 110       # User explicitly specified PTX for the concrete BIN
 111       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
 112       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
 113       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
 114     else()
 115       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
 116       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
 117       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
 118       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 119     endif()
 120   endforeach()
 121
 122   # Tell NVCC to add PTX intermediate code for the specified architectures
 123   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
 124   foreach(ARCH IN LISTS ARCH_LIST)
 125     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
 126     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
 127     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 128   endforeach()
 129
 130   if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm")
 131     set(CUDA_NVCC_FLAGS "${CUDA_NVCC_FLAGS} --target-cpu-architecture=ARM")
 132   endif()
 133
 134   # These vars will be processed in other scripts
 135   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
 136   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
 137
 138   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
 139
 140   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
 141
 142   if(CUDA_FAST_MATH)
 143     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
 144   endif()
 145
 146   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
 147
 148   macro(ocv_cuda_compile VAR)
 149     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 150       set(${var}_backup_in_cuda_compile_ "${${var}}")
 151
 152       # we remove /EHa as it generates warnings under windows
 153       string(REPLACE "/EHa" "" ${var} "${${var}}")
 154
 155       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 156       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 157
 158       # we remove -Wsign-promo as it generates warnings under linux
 159       string(REPLACE "-Wsign-promo" "" ${var} "${${var}}")
 160     endforeach()
 161
 162     if(BUILD_SHARED_LIBS)
 163       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 164     endif()
 165
 166     if(UNIX OR APPLE)
 167       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 168     endif()
 169     if(APPLE)
 170       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 171     endif()
 172
 173     # disabled because of multiple warnings during building nvcc auto generated files
 174     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GCC_REGEX_VERSION VERSION_GREATER "4.6.0")
 175       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 176     endif()
 177
 178     CUDA_COMPILE(${VAR} ${ARGN})
 179
 180     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 181       set(${var} "${${var}_backup_in_cuda_compile_}")
 182       unset(${var}_backup_in_cuda_compile_)
 183     endforeach()
 184   endmacro()
 185 else()
 186   unset(CUDA_ARCH_BIN CACHE)
 187   unset(CUDA_ARCH_PTX CACHE)
 188 endif()