cmake/OpenCVDetectCUDA.cmake

   1 if(${CMAKE_VERSION} VERSION_LESS "2.8.3")
   2   message(STATUS "WITH_CUDA flag requires CMake 2.8.3 or newer. CUDA support is disabled.")
   3   return()
   4 endif()
   5
   6 if(WIN32 AND NOT MSVC)
   7   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   8   return()
   9 endif()
  10
  11 if(CMAKE_COMPILER_IS_GNUCXX AND NOT APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  12   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
  13   return()
  14 endif()
  15
  16 set(CMAKE_MODULE_PATH "${OpenCV_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
  17
  18 foreach(var INCLUDE LIBRARY PROGRAM)
  19   set(__old_frpm_${var} "${CMAKE_FIND_ROOT_PATH_MODE_${var}}")
  20 endforeach()
  21
  22 set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
  23 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
  24 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER)
  25
  26 find_package(CUDA 4.2 QUIET)
  27
  28 foreach(var INCLUDE LIBRARY PROGRAM)
  29   set(CMAKE_FIND_ROOT_PATH_MODE_${var} "${__old_frpm_${var}}")
  30 endforeach()
  31
  32 list(REMOVE_AT CMAKE_MODULE_PATH 0)
  33
  34 if(CUDA_FOUND)
  35   set(HAVE_CUDA 1)
  36
  37   if(WITH_CUFFT)
  38     set(HAVE_CUFFT 1)
  39   endif()
  40
  41   if(WITH_CUBLAS)
  42     set(HAVE_CUBLAS 1)
  43   endif()
  44
  45   if(WITH_NVCUVID)
  46     find_cuda_helper_libs(nvcuvid)
  47     set(HAVE_NVCUVID 1)
  48   endif()
  49
  50   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  51
  52   set(_generations "Fermi" "Kepler")
  53   if(NOT CMAKE_CROSSCOMPILING)
  54     list(APPEND _generations "Auto")
  55   endif()
  56   set(CUDA_GENERATION "" CACHE STRING "Build CUDA device code only for specific GPU architecture. Leave empty to build for all architectures.")
  57   if( CMAKE_VERSION VERSION_GREATER "2.8" )
  58     set_property( CACHE CUDA_GENERATION PROPERTY STRINGS "" ${_generations} )
  59   endif()
  60
  61   if(CUDA_GENERATION)
  62     if(NOT ";${_generations};" MATCHES ";${CUDA_GENERATION};")
  63       string(REPLACE ";" ", " _generations "${_generations}")
  64       message(FATAL_ERROR "ERROR: ${_generations} Generations are suppered.")
  65     endif()
  66     unset(CUDA_ARCH_BIN CACHE)
  67     unset(CUDA_ARCH_PTX CACHE)
  68   endif()
  69
  70   set(__cuda_arch_ptx "")
  71   if(CUDA_GENERATION STREQUAL "Fermi")
  72     set(__cuda_arch_bin "2.0 2.1(2.0)")
  73   elseif(CUDA_GENERATION STREQUAL "Kepler")
  74     if(${CUDA_VERSION} VERSION_LESS "5.0")
  75       set(__cuda_arch_bin "3.0")
  76     else()
  77       set(__cuda_arch_bin "3.0 3.5")
  78     endif()
  79   elseif(CUDA_GENERATION STREQUAL "Auto")
  80     execute_process( COMMAND "${CUDA_NVCC_EXECUTABLE}" "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" "--run"
  81                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
  82                      RESULT_VARIABLE _nvcc_res OUTPUT_VARIABLE _nvcc_out
  83                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  84     if(NOT _nvcc_res EQUAL 0)
  85       message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
  86     else()
  87       set(__cuda_arch_bin "${_nvcc_out}")
  88       string(REPLACE "2.1" "2.1(2.0)" __cuda_arch_bin "${__cuda_arch_bin}")
  89     endif()
  90   endif()
  91
  92   if(NOT DEFINED __cuda_arch_bin)
  93     if(ANDROID)
  94       set(__cuda_arch_bin "3.2")
  95       set(__cuda_arch_ptx "")
  96     else()
  97       if(${CUDA_VERSION} VERSION_LESS "5.0")
  98         set(__cuda_arch_bin "1.1 1.2 1.3 2.0 2.1(2.0) 3.0")
  99       else()
 100         set(__cuda_arch_bin "1.1 1.2 1.3 2.0 2.1(2.0) 3.0 3.5")
 101       endif()
 102       set(__cuda_arch_ptx "3.0")
 103     endif()
 104   endif()
 105
 106   set(CUDA_ARCH_BIN ${__cuda_arch_bin} CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
 107   set(CUDA_ARCH_PTX ${__cuda_arch_ptx} CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
 108
 109   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
 110   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
 111
 112   # Ckeck if user specified 1.0 compute capability: we don't support it
 113   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
 114   set(CUDA_ARCH_BIN_OR_PTX_10 0)
 115   if(NOT ${HAS_ARCH_10} STREQUAL "")
 116     set(CUDA_ARCH_BIN_OR_PTX_10 1)
 117   endif()
 118
 119   # NVCC flags to be set
 120   set(NVCC_FLAGS_EXTRA "")
 121
 122   # These vars will be passed into the templates
 123   set(OPENCV_CUDA_ARCH_BIN "")
 124   set(OPENCV_CUDA_ARCH_PTX "")
 125   set(OPENCV_CUDA_ARCH_FEATURES "")
 126
 127   # Tell NVCC to add binaries for the specified GPUs
 128   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
 129   foreach(ARCH IN LISTS ARCH_LIST)
 130     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
 131       # User explicitly specified PTX for the concrete BIN
 132       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
 133       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
 134       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
 135     else()
 136       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
 137       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
 138       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
 139       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 140     endif()
 141   endforeach()
 142
 143   # Tell NVCC to add PTX intermediate code for the specified architectures
 144   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
 145   foreach(ARCH IN LISTS ARCH_LIST)
 146     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
 147     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
 148     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 149   endforeach()
 150
 151   # These vars will be processed in other scripts
 152   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
 153   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
 154
 155   if(ANDROID)
 156     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} "-Xptxas;-dlcm=ca")
 157     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} "-target-os-variant=Android")
 158   endif()
 159
 160   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
 161
 162   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
 163
 164   if(CUDA_FAST_MATH)
 165     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
 166   endif()
 167
 168   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
 169
 170   macro(ocv_cuda_compile VAR)
 171     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 172       set(${var}_backup_in_cuda_compile_ "${${var}}")
 173
 174       # we remove /EHa as it generates warnings under windows
 175       string(REPLACE "/EHa" "" ${var} "${${var}}")
 176
 177       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 178       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 179
 180       # we remove -Wsign-promo as it generates warnings under linux
 181       string(REPLACE "-Wsign-promo" "" ${var} "${${var}}")
 182
 183       # we remove -Wno-sign-promo as it generates warnings under linux
 184       string(REPLACE "-Wno-sign-promo" "" ${var} "${${var}}")
 185
 186       # we remove -Wno-delete-non-virtual-dtor because it's used for C++ compiler
 187       # but NVCC uses C compiler by default
 188       string(REPLACE "-Wno-delete-non-virtual-dtor" "" ${var} "${${var}}")
 189
 190       # we remove -frtti because it's used for C++ compiler
 191       # but NVCC uses C compiler by default
 192       string(REPLACE "-frtti" "" ${var} "${${var}}")
 193     endforeach()
 194
 195     if(BUILD_SHARED_LIBS)
 196       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 197     endif()
 198
 199     if(UNIX OR APPLE)
 200       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 201     endif()
 202     if(APPLE)
 203       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 204     endif()
 205
 206     # disabled because of multiple warnings during building nvcc auto generated files
 207     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GCC_REGEX_VERSION VERSION_GREATER "4.6.0")
 208       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 209     endif()
 210
 211     CUDA_COMPILE(${VAR} ${ARGN})
 212
 213     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 214       set(${var} "${${var}_backup_in_cuda_compile_}")
 215       unset(${var}_backup_in_cuda_compile_)
 216     endforeach()
 217   endmacro()
 218 else()
 219   unset(CUDA_ARCH_BIN CACHE)
 220   unset(CUDA_ARCH_PTX CACHE)
 221 endif()
 222
 223 if(HAVE_CUDA)
 224   set(CUDA_LIBS_PATH "")
 225   foreach(p ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 226     get_filename_component(_tmp ${p} PATH)
 227     list(APPEND CUDA_LIBS_PATH ${_tmp})
 228   endforeach()
 229
 230   if(HAVE_CUBLAS)
 231     foreach(p ${CUDA_cublas_LIBRARY})
 232       get_filename_component(_tmp ${p} PATH)
 233       list(APPEND CUDA_LIBS_PATH ${_tmp})
 234     endforeach()
 235   endif()
 236
 237   if(HAVE_CUFFT)
 238     foreach(p ${CUDA_cufft_LIBRARY})
 239       get_filename_component(_tmp ${p} PATH)
 240       list(APPEND CUDA_LIBS_PATH ${_tmp})
 241     endforeach()
 242   endif()
 243
 244   list(REMOVE_DUPLICATES CUDA_LIBS_PATH)
 245   link_directories(${CUDA_LIBS_PATH})
 246
 247   set(CUDA_LIBRARIES_ABS ${CUDA_LIBRARIES})
 248   ocv_convert_to_lib_name(CUDA_LIBRARIES ${CUDA_LIBRARIES})
 249   set(CUDA_npp_LIBRARY_ABS ${CUDA_npp_LIBRARY})
 250   ocv_convert_to_lib_name(CUDA_npp_LIBRARY ${CUDA_npp_LIBRARY})
 251   if(HAVE_CUBLAS)
 252     set(CUDA_cublas_LIBRARY_ABS ${CUDA_cublas_LIBRARY})
 253     ocv_convert_to_lib_name(CUDA_cublas_LIBRARY ${CUDA_cublas_LIBRARY})
 254   endif()
 255
 256   if(HAVE_CUFFT)
 257     set(CUDA_cufft_LIBRARY_ABS ${CUDA_cufft_LIBRARY})
 258     ocv_convert_to_lib_name(CUDA_cufft_LIBRARY ${CUDA_cufft_LIBRARY})
 259   endif()
 260 endif()