cmake/OpenCVDetectCUDA.cmake

   1 if(${CMAKE_VERSION} VERSION_LESS "2.8.3")
   2   message(STATUS "WITH_CUDA flag requires CMake 2.8.3 or newer. CUDA support is disabled.")
   3   return()
   4 endif()
   5
   6 if(WIN32 AND NOT MSVC)
   7   message(STATUS "CUDA compilation is disabled (due to only Visual Studio compiler supported on your platform).")
   8   return()
   9 endif()
  10
  11 if(CMAKE_COMPILER_IS_GNUCXX AND NOT APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  12   message(STATUS "CUDA compilation is disabled (due to Clang unsupported on your platform).")
  13   return()
  14 endif()
  15
  16 find_package(CUDA 4.2 QUIET)
  17
  18 if(CUDA_FOUND)
  19   set(HAVE_CUDA 1)
  20
  21   if(WITH_CUFFT)
  22     set(HAVE_CUFFT 1)
  23   endif()
  24
  25   if(WITH_CUBLAS)
  26     set(HAVE_CUBLAS 1)
  27   endif()
  28
  29   if(${CUDA_VERSION} VERSION_LESS "5.5")
  30     find_cuda_helper_libs(npp)
  31   else()
  32     # hack for CUDA 5.5
  33     if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm")
  34       unset(CUDA_TOOLKIT_INCLUDE CACHE)
  35       unset(CUDA_CUDART_LIBRARY CACHE)
  36       unset(CUDA_cublas_LIBRARY CACHE)
  37       unset(CUDA_cufft_LIBRARY CACHE)
  38       unset(CUDA_npp_LIBRARY CACHE)
  39
  40       if(SOFTFP)
  41         set(cuda_arm_path "${CUDA_TOOLKIT_ROOT_DIR}/targets/armv7-linux-gnueabi")
  42       else()
  43         set(cuda_arm_path "${CUDA_TOOLKIT_ROOT_DIR}/targets/armv7-linux-gnueabihf")
  44       endif()
  45
  46       set(CUDA_TOOLKIT_INCLUDE "${cuda_arm_path}/include" CACHE PATH "include path")
  47       set(CUDA_INCLUDE_DIRS ${CUDA_TOOLKIT_INCLUDE})
  48
  49       set(cuda_arm_library_path "${cuda_arm_path}/lib")
  50
  51       set(CUDA_CUDART_LIBRARY "${cuda_arm_library_path}/libcudart.so" CACHE FILEPATH "cudart library")
  52       set(CUDA_LIBRARIES ${CUDA_CUDART_LIBRARY})
  53       set(CUDA_cublas_LIBRARY "${cuda_arm_library_path}/libcublas.so" CACHE FILEPATH "cublas library")
  54       set(CUDA_cufft_LIBRARY "${cuda_arm_library_path}/libcufft.so" CACHE FILEPATH "cufft library")
  55       set(CUDA_nppc_LIBRARY "${cuda_arm_library_path}/libnppc.so" CACHE FILEPATH "nppc library")
  56       set(CUDA_nppi_LIBRARY "${cuda_arm_library_path}/libnppi.so" CACHE FILEPATH "nppi library")
  57       set(CUDA_npps_LIBRARY "${cuda_arm_library_path}/libnpps.so" CACHE FILEPATH "npps library")
  58       set(CUDA_npp_LIBRARY "${CUDA_nppc_LIBRARY};${CUDA_nppi_LIBRARY};${CUDA_npps_LIBRARY}" CACHE STRING "npp library")
  59     else()
  60       unset(CUDA_npp_LIBRARY CACHE)
  61
  62       find_cuda_helper_libs(nppc)
  63       find_cuda_helper_libs(nppi)
  64       find_cuda_helper_libs(npps)
  65
  66       set(CUDA_npp_LIBRARY "${CUDA_nppc_LIBRARY};${CUDA_nppi_LIBRARY};${CUDA_npps_LIBRARY}" CACHE STRING "npp library")
  67     endif()
  68   endif()
  69
  70   if(WITH_NVCUVID)
  71     find_cuda_helper_libs(nvcuvid)
  72     set(HAVE_NVCUVID 1)
  73   endif()
  74
  75   message(STATUS "CUDA detected: " ${CUDA_VERSION})
  76
  77   set(_generations "Fermi" "Kepler")
  78   if(NOT CMAKE_CROSSCOMPILING)
  79     list(APPEND _generations "Auto")
  80   endif()
  81   set(CUDA_GENERATION "" CACHE STRING "Build CUDA device code only for specific GPU architecture. Leave empty to build for all architectures.")
  82   if( CMAKE_VERSION VERSION_GREATER "2.8" )
  83     set_property( CACHE CUDA_GENERATION PROPERTY STRINGS "" ${_generations} )
  84   endif()
  85
  86   if(CUDA_GENERATION)
  87     if(NOT ";${_generations};" MATCHES ";${CUDA_GENERATION};")
  88       string(REPLACE ";" ", " _generations "${_generations}")
  89       message(FATAL_ERROR "ERROR: ${_generations} Generations are suppered.")
  90     endif()
  91     unset(CUDA_ARCH_BIN CACHE)
  92     unset(CUDA_ARCH_PTX CACHE)
  93   endif()
  94
  95   set(__cuda_arch_ptx "")
  96   if(CUDA_GENERATION STREQUAL "Fermi")
  97     set(__cuda_arch_bin "2.0 2.1(2.0)")
  98   elseif(CUDA_GENERATION STREQUAL "Kepler")
  99     if(${CUDA_VERSION} VERSION_LESS "5.0")
 100       set(__cuda_arch_bin "3.0")
 101     else()
 102       set(__cuda_arch_bin "3.0 3.5")
 103     endif()
 104   elseif(CUDA_GENERATION STREQUAL "Auto")
 105     execute_process( COMMAND "${CUDA_NVCC_EXECUTABLE}" "${OpenCV_SOURCE_DIR}/cmake/checks/OpenCVDetectCudaArch.cu" "--run"
 106                      WORKING_DIRECTORY "${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/"
 107                      RESULT_VARIABLE _nvcc_res OUTPUT_VARIABLE _nvcc_out
 108                      ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
 109     if(NOT _nvcc_res EQUAL 0)
 110       message(STATUS "Automatic detection of CUDA generation failed. Going to build for all known architectures.")
 111     else()
 112       set(__cuda_arch_bin "${_nvcc_out}")
 113     endif()
 114   endif()
 115
 116   if(NOT DEFINED __cuda_arch_bin)
 117     if(${CUDA_VERSION} VERSION_LESS "5.0")
 118       set(__cuda_arch_bin "1.1 1.2 1.3 2.0 2.1(2.0) 3.0")
 119     else()
 120       set(__cuda_arch_bin "1.1 1.2 1.3 2.0 2.1(2.0) 3.0 3.5")
 121     endif()
 122     set(__cuda_arch_ptx "3.0")
 123   endif()
 124
 125   set(CUDA_ARCH_BIN ${__cuda_arch_bin} CACHE STRING "Specify 'real' GPU architectures to build binaries for, BIN(PTX) format is supported")
 126   set(CUDA_ARCH_PTX ${__cuda_arch_ptx} CACHE STRING "Specify 'virtual' PTX architectures to build PTX intermediate code for")
 127
 128   string(REGEX REPLACE "\\." "" ARCH_BIN_NO_POINTS "${CUDA_ARCH_BIN}")
 129   string(REGEX REPLACE "\\." "" ARCH_PTX_NO_POINTS "${CUDA_ARCH_PTX}")
 130
 131   # Ckeck if user specified 1.0 compute capability: we don't support it
 132   string(REGEX MATCH "1.0" HAS_ARCH_10 "${CUDA_ARCH_BIN} ${CUDA_ARCH_PTX}")
 133   set(CUDA_ARCH_BIN_OR_PTX_10 0)
 134   if(NOT ${HAS_ARCH_10} STREQUAL "")
 135     set(CUDA_ARCH_BIN_OR_PTX_10 1)
 136   endif()
 137
 138   # NVCC flags to be set
 139   set(NVCC_FLAGS_EXTRA "")
 140
 141   # These vars will be passed into the templates
 142   set(OPENCV_CUDA_ARCH_BIN "")
 143   set(OPENCV_CUDA_ARCH_PTX "")
 144   set(OPENCV_CUDA_ARCH_FEATURES "")
 145
 146   # Tell NVCC to add binaries for the specified GPUs
 147   string(REGEX MATCHALL "[0-9()]+" ARCH_LIST "${ARCH_BIN_NO_POINTS}")
 148   foreach(ARCH IN LISTS ARCH_LIST)
 149     if(ARCH MATCHES "([0-9]+)\\(([0-9]+)\\)")
 150       # User explicitly specified PTX for the concrete BIN
 151       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${CMAKE_MATCH_2},code=sm_${CMAKE_MATCH_1})
 152       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${CMAKE_MATCH_1}")
 153       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${CMAKE_MATCH_2}")
 154     else()
 155       # User didn't explicitly specify PTX for the concrete BIN, we assume PTX=BIN
 156       set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=sm_${ARCH})
 157       set(OPENCV_CUDA_ARCH_BIN "${OPENCV_CUDA_ARCH_BIN} ${ARCH}")
 158       set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 159     endif()
 160   endforeach()
 161
 162   # Tell NVCC to add PTX intermediate code for the specified architectures
 163   string(REGEX MATCHALL "[0-9]+" ARCH_LIST "${ARCH_PTX_NO_POINTS}")
 164   foreach(ARCH IN LISTS ARCH_LIST)
 165     set(NVCC_FLAGS_EXTRA ${NVCC_FLAGS_EXTRA} -gencode arch=compute_${ARCH},code=compute_${ARCH})
 166     set(OPENCV_CUDA_ARCH_PTX "${OPENCV_CUDA_ARCH_PTX} ${ARCH}")
 167     set(OPENCV_CUDA_ARCH_FEATURES "${OPENCV_CUDA_ARCH_FEATURES} ${ARCH}")
 168   endforeach()
 169
 170   if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm")
 171     set(CUDA_NVCC_FLAGS "${CUDA_NVCC_FLAGS} --target-cpu-architecture=ARM")
 172   endif()
 173
 174   # These vars will be processed in other scripts
 175   set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} ${NVCC_FLAGS_EXTRA})
 176   set(OpenCV_CUDA_CC "${NVCC_FLAGS_EXTRA}")
 177
 178   message(STATUS "CUDA NVCC target flags: ${CUDA_NVCC_FLAGS}")
 179
 180   OCV_OPTION(CUDA_FAST_MATH "Enable --use_fast_math for CUDA compiler " OFF)
 181
 182   if(CUDA_FAST_MATH)
 183     set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} --use_fast_math)
 184   endif()
 185
 186   mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_VERBOSE_BUILD CUDA_SDK_ROOT_DIR)
 187
 188   macro(ocv_cuda_compile VAR)
 189     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 190       set(${var}_backup_in_cuda_compile_ "${${var}}")
 191
 192       # we remove /EHa as it generates warnings under windows
 193       string(REPLACE "/EHa" "" ${var} "${${var}}")
 194
 195       # we remove -ggdb3 flag as it leads to preprocessor errors when compiling CUDA files (CUDA 4.1)
 196       string(REPLACE "-ggdb3" "" ${var} "${${var}}")
 197
 198       # we remove -Wsign-promo as it generates warnings under linux
 199       string(REPLACE "-Wsign-promo" "" ${var} "${${var}}")
 200     endforeach()
 201
 202     if(BUILD_SHARED_LIBS)
 203       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -DCVAPI_EXPORTS)
 204     endif()
 205
 206     if(UNIX OR APPLE)
 207       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fPIC)
 208     endif()
 209     if(APPLE)
 210       set(CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS} -Xcompiler -fno-finite-math-only)
 211     endif()
 212
 213     # disabled because of multiple warnings during building nvcc auto generated files
 214     if(CMAKE_COMPILER_IS_GNUCXX AND CMAKE_GCC_REGEX_VERSION VERSION_GREATER "4.6.0")
 215       ocv_warnings_disable(CMAKE_CXX_FLAGS -Wunused-but-set-variable)
 216     endif()
 217
 218     CUDA_COMPILE(${VAR} ${ARGN})
 219
 220     foreach(var CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_DEBUG)
 221       set(${var} "${${var}_backup_in_cuda_compile_}")
 222       unset(${var}_backup_in_cuda_compile_)
 223     endforeach()
 224   endmacro()
 225 else()
 226   unset(CUDA_ARCH_BIN CACHE)
 227   unset(CUDA_ARCH_PTX CACHE)
 228 endif()